configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 # The list of languages known to LyX
  26 # This is needed by GNU gettext
  27 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### check which frontend we want to use
  59 LYX_USE_FRONTENDS
  60
  61 ### Check for a C++ compiler
  62 LYX_PROG_CXX
  63 ### Some checks on what the C++ compiler can(not) do
  64 AC_LANG(C++)
  65 dnl we do not need that currently (and probably all our supported
  66 dnl compiler allow that)
  67 dnl LYX_CXX_PARTIAL
  68 LYX_CXX_EXPLICIT
  69 LYX_CXX_GLOBAL_CSTD
  70 LYX_STD_COUNT
  71 dnl we disable rtti for now
  72 dnl LYX_CXX_RTTI
  73 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  74 LYX_CXX_STL_MODERN_STREAMS
  75
  76 ### and now some special lyx flags.
  77 AC_ARG_ENABLE(assertions,
  78   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  79   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  80         enable_assertions=yes;
  81     else
  82         enable_assertions=no;
  83     fi;])
  84 if test "x$enable_assertions" = xyes ; then
  85    lyx_flags="$lyx_flags assertions"
  86    AC_DEFINE(ENABLE_ASSERTIONS,1,
  87     [Define if you want assertions to be enabled in the code])
  88 fi
  89
  90 ### Library Files
  91 dnl by testing these we check if it is ok to have
  92 dnl -lc and -lm as args to the compiler
  93 AC_CHECK_LIB(m, sin)
  94 AC_CHECK_LIB(c, fopen)
  95
  96 ### Add extra directories to check for libraries.
  97 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  98 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  99 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 100
 101 ### Add extra directories to check for include files.
 102 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 104 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 105
 106 ### Add both includes and libraries
 107 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 108 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 109 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 110   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 111
 112 AC_ARG_WITH(aiksaurus,
 113   [  --without-aiksaurus     do not use the Aiksaurus library],
 114   [lyx_use_aiksaurus=$withval])
 115 if test x$lyx_use_aiksaurus != xno; then
 116 AC_CHECK_LIB(Aiksaurus, main,
 117         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 118          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 119          lyx_flags="$lyx_flags aiksaurus"
 120         ],,"-lbz2")
 121 AC_CHECK_HEADER(Aiksaurus.h,[
 122   ac_cv_header_aiksaurus_h=yes
 123   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 124 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 125   ac_cv_header_aiksaurus_h=yes
 126   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 127 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 128 fi
 129 AC_SUBST(AIKSAURUS_LIBS)
 130
 131 LYX_USE_INCLUDED_BOOST
 132
 133 ### Setup libtool
 134 AC_DISABLE_SHARED
 135 AC_LIBTOOL_WIN32_DLL
 136 #AM_PROG_LIBTOOL
 137 LYX_PROG_LIBTOOL
 138
 139 ### Check if we want spell libraries, prefer new aspell
 140 CHECK_WITH_ASPELL
 141 if test "$USING_ASPELL" != "yes"; then
 142         CHECK_WITH_PSPELL
 143 fi
 144
 145 ### Check for some Cygwin-specific details.
 146 CHECK_WITH_CYGWIN
 147
 148 ### Check for X libraries
 149 AC_PATH_XTRA
 150 case $have_x in
 151   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 152        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 153   no) LYX_ERROR(dnl
 154 [Cannot find X window libraries and/or headers. Check your installation.
 155   If you use a Linux system, check that you have installed
 156   the development tools.]);;
 157   disable) ;;
 158 esac
 159
 160 ### check which frontend we want to use
 161
 162 dnl if the gtk frontend has been specified, then xforms is needed too
 163 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 164   FRONTENDS="$FRONTENDS xforms"
 165 fi
 166
 167 dnl The code below is not in a macro, because this would cause big
 168 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 169 for frontend in $FRONTENDS ; do
 170   case "$frontend" in
 171     xforms)
 172           XFORMS_DO_IT_ALL
 173           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 174           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 175           RPM_FRONTEND="xforms"
 176           FRONTEND_INFO="${FRONTEND_INFO}\
 177   XForms Frontend:\n\
 178       libXpm version:\t\t${XPM_VERSION}\n\
 179       libforms version:\t\t${XFORMS_VERSION}\n"
 180           ;;
 181   dnl   gnome)
 182   dnl     XFORMS_DO_IT_ALL
 183   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 184   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 185   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 186
 187   dnl     FRONTEND="xforms gnome"
 188   dnl     FRONTEND_GUILIB="gnome/*.lo"
 189   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 190   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 191   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 192   dnl   ;;
 193     gtk)
 194           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 195           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 196           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 197           RPM_FRONTEND="gtk"
 198           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 199           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 200           FRONTEND_INFO="${FRONTEND_INFO}\
 201   GTK Frontend:\n\
 202     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 203     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 204           ;;
 205
 206     qt)
 207           QT_DO_IT_ALL
 208           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 209           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 210           RPM_FRONTEND="qt"
 211           FRONTEND_INFO="${FRONTEND_INFO}\
 212   Qt Frontend:\n\
 213       Qt version:\t\t${QT_VERSION}\n"
 214 dnl qt build will fail without moc or uic
 215           if test -z "$MOC"; then
 216             LYX_ERROR([moc binary not found !])
 217           fi
 218           if test -z "$UIC"; then
 219             LYX_ERROR([uic binary not found !])
 220           fi
 221       ;;
 222     *)
 223           LYX_ERROR(Unknown frontend '$frontend');;
 224   esac
 225 done
 226
 227 ### Check how the files should be packaged
 228 LYX_USE_PACKAGING
 229 # fix the value of the prefixes.
 230 test "x$prefix" = xNONE && prefix=$default_prefix
 231 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 232
 233 ### Setup GNU gettext
 234 dnl GNU gettext is written in C
 235 AC_LANG_PUSH(C)
 236 # Some tests that may be useful for gettext
 237 AC_C_CONST
 238 AC_C_INLINE
 239 # Do the real setup now
 240 AM_GNU_GETTEXT
 241 # a hack for those who try to change LyX, but do not have gettext installed
 242 case  "${XGETTEXT}" in
 243  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 244 esac
 245
 246 AC_SUBST(LINGUAS)
 247
 248 AC_LANG_POP(C)
 249
 250 # some standard header files
 251 AC_HEADER_DIRENT
 252 AC_HEADER_MAJOR
 253 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 254
 255 # some standard structures
 256 AC_HEADER_STAT
 257 AC_HEADER_TIME
 258
 259 # some standard types
 260 AC_TYPE_MODE_T
 261 AC_TYPE_OFF_T
 262 AC_TYPE_PID_T
 263 AC_TYPE_SIGNAL
 264 AC_TYPE_SIZE_T
 265 AC_TYPE_UID_T
 266
 267 AC_CHECK_FUNCS(strerror)
 268 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 269 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 270
 271 # Check the form of mkdir()
 272 AC_FUNC_MKDIR
 273
 274 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 275     case "${enableval}" in
 276         yes) use_compression=true ;;
 277         no) use_compression=false ;;
 278         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 279     esac
 280 ],[use_compression=true])
 281 if test $use_compression=true ; then
 282         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 283         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 284         if test $use_compression = true ; then
 285                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 286                 lyx_flags="$lyx_flags compression"
 287         fi
 288 fi
 289 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 290 AC_MSG_CHECKING([whether to support compressed files])
 291 AC_MSG_RESULT($use_compression)
 292
 293
 294 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 295 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 296 dnl We aim to remove this eventually, since we should test as much as
 297 dnl possible with the compiler which will use the functions (JMarc)
 298 AC_LANG_PUSH(C)
 299 AC_CHECK_FUNCS(mkfifo mkstemp mktemp lstat readlink)
 300 AC_LANG_POP(C)
 301
 302 AC_FUNC_SELECT_ARGTYPES
 303
 304 ### Some information on what just happened
 305 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 306 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 307 VERSION_INFO="Configuration\n\
 308   Host type:                      ${host}\n\
 309   Special build flags:           ${lyx_flags}\n\
 310   C   Compiler:                   ${CC}\n\
 311   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 312   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 313   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 314   Linker flags:                   ${LDFLAGS}\n\
 315 ${FRONTEND_INFO}\
 316   Packaging:                      ${lyx_use_packaging}\n\
 317   LyX binary dir:                 ${real_bindir}\n\
 318   LyX files dir:                  ${real_datadir}\n"
 319
 320
 321 AC_SUBST(VERSION_INFO)
 322 AC_SUBST(RPM_FRONTEND)
 323
 324 ## Some config.h stuff
 325
 326 AH_TOP([
 327 /* -*- C++ -*- */
 328 /*
 329  * \file config.h
 330  * This file is part of LyX, the document processor.
 331  * Licence details can be found in the file COPYING.
 332  *
 333  * This is the compilation configuration file for LyX.
 334  * It was generated by autoconfs configure.
 335  * You might want to change some of the defaults if something goes wrong
 336  * during the compilation.
 337  */
 338
 339 #ifndef _CONFIG_H
 340 #define _CONFIG_H
 341 ])
 342
 343 AH_BOTTOM([
 344 /************************************************************
 345  ** You should not need to change anything beyond this point */
 346
 347 #ifndef HAVE_STRERROR
 348 #if defined(__cplusplus)
 349 extern "C"
 350 #endif
 351 char * strerror(int n);
 352 #endif
 353
 354 #ifdef HAVE_MKSTEMP
 355 #ifndef HAVE_DECL_MKSTEMP
 356 #if defined(__cplusplus)
 357 extern "C"
 358 #endif
 359 int mkstemp(char*);
 360 #endif
 361 #endif
 362
 363 #ifdef __EMX__
 364 #include "support/os2_defines.h"
 365 #endif
 366
 367 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 368 #define USE_BOOST_FORMAT 1
 369 #else
 370 #define USE_BOOST_FORMAT 0
 371 #endif
 372
 373 #define BOOST_USER_CONFIG <config.h>
 374
 375 #if defined(ENABLE_ASSERTIONS)
 376 #define BOOST_ENABLE_ASSERT_HANDLER 1
 377 #else
 378 #define BOOST_DISABLE_ASSERTS 1
 379 #endif
 380
 381 #define BOOST_DISABLE_THREADS 1
 382 #define BOOST_NO_WREGEX 1
 383 #define BOOST_NO_WSTRING 1
 384
 385 #endif
 386 ])
 387
 388 ### Finish the work.
 389 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 390 AC_CONFIG_FILES([Makefile  m4/Makefile \
 391        boost/Makefile \
 392        boost/libs/Makefile \
 393        boost/libs/filesystem/Makefile \
 394        boost/libs/filesystem/src/Makefile \
 395        boost/libs/regex/Makefile \
 396        boost/libs/regex/src/Makefile \
 397        boost/libs/signals/Makefile \
 398        boost/libs/signals/src/Makefile \
 399        config/Makefile \
 400        development/Makefile \
 401        development/lyx.spec \
 402        lib/Makefile \
 403        lib/doc/Makefile \
 404        intl/Makefile \
 405        po/Makefile.in \
 406        sourcedoc/Doxyfile \
 407        sourcedoc/Makefile \
 408        src/client/Makefile \
 409        src/Makefile \
 410        src/version.C-tmp:src/version.C.in \
 411        src/tex2lyx/Makefile \
 412        src/mathed/Makefile \
 413        src/graphics/Makefile \
 414        src/insets/Makefile \
 415        src/support/Makefile \
 416        src/support/tests/Makefile \
 417        src/frontends/Makefile \
 418        src/frontends/controllers/Makefile \
 419        src/frontends/xforms/Makefile \
 420        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 421        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 422        src/frontends/xforms/forms/Makefile \
 423        src/frontends/gtk/Makefile \
 424        src/frontends/gtk/gimages/Makefile \
 425        src/frontends/gtk/glade/Makefile \
 426        src/frontends/qt2/Makefile \
 427        src/frontends/qt2/moc/Makefile \
 428        src/frontends/qt2/ui/Makefile \
 429        src/frontends/qt2/ui/moc/Makefile \
 430        src/frontends/gnome/Makefile \
 431 ])
 432
 433 AC_OUTPUT
 434 # show version information
 435 echo
 436 printf "$VERSION_INFO"
 437 echo
 438
 439 # Display a final warning if there has been a LYX_ERROR
 440 LYX_CHECK_ERRORS