config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT4_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt4_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT4_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt 4 library name])
  25
  26         AC_CACHE_VAL(qt4_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT4_INCLUDES $QT4_LDFLAGS"
  31                 for libname in -lQtCore -lQtCore4
  32                 do
  33                         QT4_TRY_LINK($libname)
  34                         if test -n "$qt4_cv_libname"; then
  35                                 QT4_CORE_LIB="$qt4_cv_libname"
  36                                 break;
  37                         fi
  38                 done
  39                 qt4_cv_libname=
  40                 for libname in '-lQtCore -lQtGui' \
  41                                '-lQtCore4 -lQtGui4'
  42                 do
  43                         QT4_TRY_LINK($libname)
  44                         if test -n "$qt4_cv_libname"; then
  45                                 break;
  46                         fi
  47                 done
  48                 CXXFLAGS=$SAVE_CXXFLAGS
  49         ])
  50
  51         if test -z "$qt4_cv_libname"; then
  52                 AC_MSG_RESULT([failed])
  53                 if test "$FATAL" = 1 ; then
  54                         AC_MSG_ERROR([Cannot compile a simple Qt 4 executable. Check you have the right \$QT4DIR !])
  55                 fi
  56         else
  57                 AC_MSG_RESULT([$qt4_cv_libname])
  58         fi
  59 ])
  60
  61 dnl get Qt version we're using
  62 AC_DEFUN([QT4_GET_VERSION],
  63 [
  64         AC_CACHE_CHECK([Qt 4 version],lyx_cv_qt4version,
  65         [
  66                 AC_LANG_CPLUSPLUS
  67                 SAVE_CPPFLAGS=$CPPFLAGS
  68                 CPPFLAGS="$CPPFLAGS $QT4_INCLUDES"
  69
  70                 cat > conftest.$ac_ext <<EOF
  71 #line __oline__ "configure"
  72 #include "confdefs.h"
  73 #include <qglobal.h>
  74 "%%%"QT_VERSION_STR"%%%"
  75 EOF
  76                 lyx_cv_qt4version=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
  77                         grep '^"%%%"'  2>/dev/null | \
  78                         sed -e 's/"%%%"//g' -e 's/"//g'`
  79                 rm -f conftest.$ac_ext
  80                 CPPFLAGS=$SAVE_CPPFLAGS
  81         ])
  82
  83         QT4_VERSION=$lyx_cv_qt4version
  84         AC_SUBST(QT4_VERSION)
  85 ])
  86
  87 dnl start here
  88 AC_DEFUN([QT4_DO_IT_ALL],
  89 [
  90         dnl this variable is precious
  91         AC_ARG_VAR(QT4DIR, [the place where the Qt 4 files are, e.g. /usr/lib/qt4])
  92
  93         dnl Please leave this alone. I use this file in
  94         dnl oprofile.
  95         FATAL=0
  96
  97         AC_ARG_WITH(qt4-dir, [  --with-qt4-dir           where the root of Qt 4 is installed ],
  98                 [ qt4_cv_dir=`eval echo "$withval"/` ])
  99
 100         AC_ARG_WITH(qt4-includes, [  --with-qt4-includes      where the Qt 4 includes are. ],
 101                 [ qt4_cv_includes=`eval echo "$withval"` ])
 102
 103         AC_ARG_WITH(qt4-libraries, [  --with-qt4-libraries     where the Qt 4 library is installed.],
 104                 [  qt4_cv_libraries=`eval echo "$withval"` ])
 105
 106         dnl pay attention to $QT4DIR unless overridden
 107         if test -z "$qt4_cv_dir"; then
 108                 qt4_cv_dir=$QT4DIR
 109         fi
 110
 111         dnl derive inc/lib if needed
 112         if test -n "$qt4_cv_dir"; then
 113                 if test -z "$qt4_cv_includes"; then
 114                         qt4_cv_includes=$qt4_cv_dir/include
 115                 fi
 116                 if test -z "$qt4_cv_libraries"; then
 117                         qt4_cv_libraries=$qt4_cv_dir/lib
 118                 fi
 119         fi
 120
 121         dnl compute the binary dir too
 122         if test -n "$qt4_cv_dir"; then
 123                 qt4_cv_bin=$qt4_cv_dir/bin
 124         fi
 125
 126         dnl Preprocessor flags
 127         QT4_CPPFLAGS="-DQT_CLEAN_NAMESPACE -DQT_GENUINE_STR -DQT_NO_STL -DQT_NO_KEYWORDS"
 128         case ${host} in
 129         *mingw*) QT4_CPPFLAGS="-DQT_DLL $QT4_CPPFLAGS";;
 130         *cygwin*)
 131         if test "x$with_x" = xno ; then
 132                 QT4_CPPFLAGS="$QT4_CPPFLAGS -DQ_CYGWIN_WIN"
 133         fi;;
 134         esac
 135         AC_SUBST(QT4_CPPFLAGS)
 136
 137         dnl Check if it possible to do a pkg-config
 138         PKG_PROG_PKG_CONFIG
 139         if test -n "$PKG_CONFIG" ; then
 140                 QT4_DO_PKG_CONFIG
 141         fi
 142         if test "$pkg_failed" != "no" ; then
 143                 QT4_DO_MANUAL_CONFIG
 144         fi
 145         AC_PATH_PROGS(MOC4, [moc-qt4 moc],[],$qt4_cv_bin:$PATH)
 146         AC_PATH_PROGS(UIC4, [uic-qt4 uic],[],$qt4_cv_bin:$PATH)
 147         AC_PATH_PROGS(RCC4, [rcc-qt4 rcc],[],$qt4_cv_bin:$PATH)
 148 ])
 149
 150 AC_DEFUN([QT4_DO_PKG_CONFIG],
 151 [
 152         dnl tell pkg-config to look also in $qt4_cv_dir/lib.
 153         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 154         if test -n "$qt4_cv_dir" ; then
 155           PKG_CONFIG_PATH=$qt4_cv_dir/lib:$qt4_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 156           export PKG_CONFIG_PATH
 157         fi
 158         PKG_CHECK_MODULES(QT4_CORE, QtCore,,[:])
 159         if test "$pkg_failed" = "no" ; then
 160                 QT4_CORE_INCLUDES=$QT4_CORE_CFLAGS
 161                 AC_SUBST(QT4_CORE_INCLUDES)
 162                 QT4_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore`
 163                 AC_SUBST(QT4_CORE_LDFLAGS)
 164                 QT4_CORE_LIB=`$PKG_CONFIG --libs-only-l QtCore`
 165                 AC_SUBST(QT4_CORE_LIB)
 166         fi
 167         PKG_CHECK_MODULES(QT4_FRONTEND, QtCore QtGui,,[:])
 168         if test "$pkg_failed" = "no" ; then
 169                 QT4_INCLUDES=$QT4_FRONTEND_CFLAGS
 170                 dnl QT4_LDFLAGS=$QT4_FRONTEND_LIBS
 171                 QT4_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore QtGui`
 172                 AC_SUBST(QT4_INCLUDES)
 173                 AC_SUBST(QT4_LDFLAGS)
 174                 QT4_VERSION=`$PKG_CONFIG --modversion QtCore`
 175                 AC_SUBST(QT4_VERSION)
 176                 QT4_LIB=`$PKG_CONFIG --libs-only-l QtCore QtGui`
 177                 AC_SUBST(QT4_LIB)
 178                 LIBS="$LIBS `$PKG_CONFIG --libs-only-other QtCore QtGui`"
 179         fi
 180         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 181 ])
 182
 183 AC_DEFUN([QT4_DO_MANUAL_CONFIG],
 184 [
 185         dnl flags for compilation
 186         QT4_INCLUDES=
 187         QT4_LDFLAGS=
 188         QT4_CORE_INCLUDES=
 189         QT4_CORE_LDFLAGS=
 190         if test -n "$qt4_cv_includes"; then
 191                 QT4_INCLUDES="-I$qt4_cv_includes"
 192                 for i in Qt QtCore QtGui; do
 193                         QT4_INCLUDES="$QT4_INCLUDES -I$qt4_cv_includes/$i"
 194                 done
 195                 QT4_CORE_INCLUDES="-I$qt4_cv_includes -I$qt4_cv_includes/QtCore"
 196         fi
 197         if test -n "$qt4_cv_libraries"; then
 198                 QT4_LDFLAGS="-L$qt4_cv_libraries"
 199                 QT4_CORE_LDFLAGS="-L$qt4_cv_libraries"
 200         fi
 201         AC_SUBST(QT4_INCLUDES)
 202         AC_SUBST(QT4_CORE_INCLUDES)
 203         AC_SUBST(QT4_LDFLAGS)
 204         AC_SUBST(QT4_CORE_LDFLAGS)
 205
 206         QT4_CHECK_COMPILE
 207
 208         QT4_LIB=$qt4_cv_libname;
 209         AC_SUBST(QT4_LIB)
 210         AC_SUBST(QT4_CORE_LIB)
 211
 212         if test -n "$qt4_cv_libname"; then
 213                 QT4_GET_VERSION
 214         fi
 215 ])