config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt library name])
  25
  26         AC_CACHE_VAL(qt_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  31                 qt_corelibs="-lQtCore -lQtCore4"
  32                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  33                 if test $USE_QT5 = "yes" ; then
  34                     qt_corelibs="-lQt5Core"
  35                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  36                 fi
  37                 for libname in $qt_corelibs '-framework QtCore'
  38                 do
  39                         QT_TRY_LINK($libname)
  40                         if test -n "$qt_cv_libname"; then
  41                                 QT_CORE_LIB="$qt_cv_libname"
  42                                 break;
  43                         fi
  44                 done
  45                 qt_cv_libname=
  46                 for libname in $qt_guilibs \
  47                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 AC_MSG_RESULT([failed])
  60                 AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  61         else
  62                 AC_MSG_RESULT([$qt_cv_libname])
  63         fi
  64 ])
  65
  66
  67 AC_DEFUN([QT_FIND_TOOL],
  68 [
  69         $1=
  70         qt_ext=qt4
  71         if test "x$USE_QT5" != "xno" ; then
  72                 qt_ext=qt5
  73         fi
  74
  75         if test -n "$qt_cv_bin" ; then
  76                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  77         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  78                 AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  79         fi
  80         if test -z "$$1"; then
  81                 AC_CHECK_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  82         fi
  83         if test -z "$$1"; then
  84                 AC_MSG_ERROR([cannot find $2 binary.])
  85         fi
  86 ])
  87
  88
  89 dnl get Qt version we're using
  90 AC_DEFUN([QT_GET_VERSION],
  91 [
  92         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  93         [
  94                 AC_LANG_CPLUSPLUS
  95                 SAVE_CPPFLAGS=$CPPFLAGS
  96                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
  97
  98                 cat > conftest.$ac_ext <<EOF
  99 #line __oline__ "configure"
 100 #include "confdefs.h"
 101 #include <qglobal.h>
 102 "%%%"QT_VERSION_STR"%%%"
 103 EOF
 104                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 105                         grep '^"%%%"'  2>/dev/null | \
 106                         sed -e 's/"%%%"//g' -e 's/"//g'`
 107                 rm -f conftest.$ac_ext
 108                 CPPFLAGS=$SAVE_CPPFLAGS
 109         ])
 110
 111         QTLIB_VERSION=$lyx_cv_qtversion
 112         AC_SUBST(QTLIB_VERSION)
 113 ])
 114
 115 dnl start here
 116 AC_DEFUN([QT_DO_IT_ALL],
 117 [
 118         dnl this variable is precious
 119         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 120
 121         AC_ARG_WITH(qt-dir, [AC_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 122                 [ qt_cv_dir=`eval echo "$withval"/` ])
 123
 124         AC_ARG_WITH(qt-includes, [AC_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 125                 [ qt_cv_includes=`eval echo "$withval"` ])
 126
 127         AC_ARG_WITH(qt-libraries, [AC_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 128                 [  qt_cv_libraries=`eval echo "$withval"` ])
 129
 130         dnl pay attention to $QTDIR unless overridden
 131         if test -z "$qt_cv_dir"; then
 132                 qt_cv_dir=$QTDIR
 133         fi
 134
 135         dnl derive inc/lib if needed
 136         if test -n "$qt_cv_dir"; then
 137                 if test -z "$qt_cv_includes"; then
 138                         qt_cv_includes=$qt_cv_dir/include
 139                 fi
 140                 if test -z "$qt_cv_libraries"; then
 141                         qt_cv_libraries=$qt_cv_dir/lib
 142                 fi
 143         fi
 144
 145         dnl compute the binary dir too
 146         if test -n "$qt_cv_dir"; then
 147                 qt_cv_bin=$qt_cv_dir/bin
 148         fi
 149
 150         dnl Preprocessor flags
 151         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 152         case ${host} in
 153         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 154         esac
 155         AC_SUBST(QT_CPPFLAGS)
 156
 157         dnl Check if it possible to do a pkg-config
 158         PKG_PROG_PKG_CONFIG
 159         if test -n "$PKG_CONFIG" ; then
 160                 QT_DO_PKG_CONFIG
 161         fi
 162         if test "$pkg_failed" != "no" ; then
 163                 QT_DO_MANUAL_CONFIG
 164         fi
 165
 166         if test -z "$QT_LIB"; then
 167           AC_MSG_ERROR([cannot find qt libraries.])
 168         fi
 169
 170         dnl Check qt version
 171         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 172         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 173         ])
 174
 175         save_CPPFLAGS=$CPPFLAGS
 176         AC_MSG_CHECKING([whether Qt uses the X Window system])
 177         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 178         if test x$USE_QT5 = xyes ; then
 179           AC_EGREP_CPP(xcb,
 180             [#include <qconfig.h>
 181             QT_QPA_DEFAULT_PLATFORM_NAME],
 182             [AC_MSG_RESULT(yes)
 183              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 184             [AC_MSG_RESULT(no)])
 185         else
 186           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 187             [#include <qglobal.h>],
 188             [#ifndef Q_WS_X11],
 189             [#error Fail],
 190             [#endif]])],
 191             qt_use_x11=yes,
 192             qt_use_x11=no)
 193           AC_MSG_RESULT($qt_use_x11)
 194           if test "x$qt_use_x11" = "xyes"; then
 195             QT_LIB="$QT_LIB -lX11"
 196           fi
 197         fi
 198         CPPFLAGS=$save_CPPFLAGS
 199
 200         QT_FIND_TOOL([QT_MOC], [moc])
 201         QT_FIND_TOOL([QT_UIC], [uic])
 202         QT_FIND_TOOL([QT_RCC], [rcc])
 203
 204         dnl Safety check
 205         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]\.[[0-9]]\).*/\1/'`
 206         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 207                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 208         fi
 209 ])
 210
 211 AC_DEFUN([QT_DO_PKG_CONFIG],
 212 [
 213         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 214         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 215         if test -n "$qt_cv_dir" ; then
 216           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 217           export PKG_CONFIG_PATH
 218         fi
 219         qt_corelibs="QtCore"
 220         qt_guilibs="QtCore QtGui QtSvg"
 221         if test "x$USE_QT5" != "xno" ; then
 222                 qt_corelibs="Qt5Core"
 223                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 224                 lyx_use_x11extras=false
 225                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 226                 if $lyx_use_x11extras; then
 227                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 228                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 229                                 [Define if you have the Qt5X11Extras module])
 230                 fi
 231                 lyx_use_winextras=false
 232                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 233                 if $lyx_use_winextras; then
 234                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 235                 fi
 236                 lyx_use_macextras=false
 237                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 238                 if $lyx_use_macextras; then
 239                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 240                 fi
 241         fi
 242         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 243         if test "$pkg_failed" = "no" ; then
 244                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 245                 AC_SUBST(QT_CORE_INCLUDES)
 246                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 247                 AC_SUBST(QT_CORE_LDFLAGS)
 248                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 249                 AC_SUBST(QT_CORE_LIB)
 250         fi
 251         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 252         if test "$pkg_failed" = "no" ; then
 253                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 254                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 255                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 256                 AC_SUBST(QT_INCLUDES)
 257                 AC_SUBST(QT_LDFLAGS)
 258                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 259                 AC_SUBST(QTLIB_VERSION)
 260                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 261                 AC_SUBST(QT_LIB)
 262                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 263         fi
 264         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 265         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 266         dnl wrong on OS X, where everything goes to --libs-only-other.
 267         dnl As a quick workaround, let us assign better values. A better patch
 268         dnl exists for next cycle.
 269         QT_CORE_LIB=$QT_CORE_LIBS
 270         QT_CORE_LDFLAGS=
 271         QT_LIB=$QT_FRONTEND_LIBS
 272         QT_LDFLAGS=
 273 ])
 274
 275 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 276 [
 277         dnl Check for X libraries
 278         case ${host} in
 279         *mingw*) ;;
 280         *) \
 281           AC_PATH_X \
 282           AC_PATH_XTRA \
 283         ;;
 284         esac
 285         case $have_x in
 286             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 287                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 288              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 289         disable) ;;
 290         esac
 291
 292         dnl flags for compilation
 293         QT_INCLUDES=
 294         QT_LDFLAGS=
 295         QT_CORE_INCLUDES=
 296         QT_CORE_LDFLAGS=
 297         if test -n "$qt_cv_includes"; then
 298                 QT_INCLUDES="-I$qt_cv_includes"
 299                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 300                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 301                 done
 302                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 303         fi
 304         case "$qt_cv_libraries" in
 305         *framework*)
 306                 QT_LDFLAGS="-F$qt_cv_libraries"
 307                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 308                 ;;
 309         "")
 310                 ;;
 311         *)
 312                 QT_LDFLAGS="-L$qt_cv_libraries"
 313                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 314                 ;;
 315         esac
 316         AC_SUBST(QT_INCLUDES)
 317         AC_SUBST(QT_CORE_INCLUDES)
 318         AC_SUBST(QT_LDFLAGS)
 319         AC_SUBST(QT_CORE_LDFLAGS)
 320
 321         QT_CHECK_COMPILE
 322
 323         QT_LIB=$qt_cv_libname;
 324         AC_SUBST(QT_LIB)
 325         AC_SUBST(QT_CORE_LIB)
 326
 327         if test -n "$qt_cv_libname"; then
 328                 QT_GET_VERSION
 329         fi
 330 ])