config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT4_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt4_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT4_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt 4 library name])
  25
  26         AC_CACHE_VAL(qt4_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT4_INCLUDES $QT4_LDFLAGS"
  31                 for libname in -lQtCore -lQtCore4 '-framework QtCore'
  32                 do
  33                         QT4_TRY_LINK($libname)
  34                         if test -n "$qt4_cv_libname"; then
  35                                 QT4_CORE_LIB="$qt4_cv_libname"
  36                                 break;
  37                         fi
  38                 done
  39                 qt4_cv_libname=
  40                 for libname in '-lQtCore -lQtGui' \
  41                                '-lQtCore4 -lQtGui4' \
  42                                '-framework QtCore -framework QtConcurrent -framework QtWidgets -framework QtGui'\
  43                                '-framework QtCore -framework QtGui'
  44                 do
  45                         QT4_TRY_LINK($libname)
  46                         if test -n "$qt4_cv_libname"; then
  47                                 break;
  48                         fi
  49                 done
  50                 CXXFLAGS=$SAVE_CXXFLAGS
  51         ])
  52
  53         if test -z "$qt4_cv_libname"; then
  54                 AC_MSG_RESULT([failed])
  55                 AC_MSG_ERROR([cannot compile a simple Qt 4 executable. Check you have the right \$QT4DIR.])
  56         else
  57                 AC_MSG_RESULT([$qt4_cv_libname])
  58         fi
  59 ])
  60
  61 dnl get Qt version we're using
  62 AC_DEFUN([QT4_GET_VERSION],
  63 [
  64         AC_CACHE_CHECK([Qt 4 version],lyx_cv_qt4version,
  65         [
  66                 AC_LANG_CPLUSPLUS
  67                 SAVE_CPPFLAGS=$CPPFLAGS
  68                 CPPFLAGS="$CPPFLAGS $QT4_INCLUDES"
  69
  70                 cat > conftest.$ac_ext <<EOF
  71 #line __oline__ "configure"
  72 #include "confdefs.h"
  73 #include <qglobal.h>
  74 "%%%"QT_VERSION_STR"%%%"
  75 EOF
  76                 lyx_cv_qt4version=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
  77                         grep '^"%%%"'  2>/dev/null | \
  78                         sed -e 's/"%%%"//g' -e 's/"//g'`
  79                 rm -f conftest.$ac_ext
  80                 CPPFLAGS=$SAVE_CPPFLAGS
  81         ])
  82
  83         QT4_VERSION=$lyx_cv_qt4version
  84         AC_SUBST(QT4_VERSION)
  85 ])
  86
  87 dnl start here
  88 AC_DEFUN([QT4_DO_IT_ALL],
  89 [
  90         dnl this variable is precious
  91         AC_ARG_VAR(QT4DIR, [the place where the Qt 4 files are, e.g. /usr/lib/qt4])
  92
  93         AC_ARG_WITH(qt4-dir, [AC_HELP_STRING([--with-qt4-dir], [where the root of Qt 4 is installed])],
  94                 [ qt4_cv_dir=`eval echo "$withval"/` ])
  95
  96         AC_ARG_WITH(qt4-includes, [AC_HELP_STRING([--with-qt4-includes], [where the Qt 4 includes are])],
  97                 [ qt4_cv_includes=`eval echo "$withval"` ])
  98
  99         AC_ARG_WITH(qt4-libraries, [AC_HELP_STRING([--with-qt4-libraries], [where the Qt 4 library is installed])],
 100                 [  qt4_cv_libraries=`eval echo "$withval"` ])
 101
 102         dnl pay attention to $QT4DIR unless overridden
 103         if test -z "$qt4_cv_dir"; then
 104                 qt4_cv_dir=$QT4DIR
 105         fi
 106
 107         dnl derive inc/lib if needed
 108         if test -n "$qt4_cv_dir"; then
 109                 if test -z "$qt4_cv_includes"; then
 110                         qt4_cv_includes=$qt4_cv_dir/include
 111                 fi
 112                 if test -z "$qt4_cv_libraries"; then
 113                         qt4_cv_libraries=$qt4_cv_dir/lib
 114                 fi
 115         fi
 116
 117         dnl compute the binary dir too
 118         if test -n "$qt4_cv_dir"; then
 119                 qt4_cv_bin=$qt4_cv_dir/bin
 120         fi
 121
 122         dnl Preprocessor flags
 123         QT4_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 124         case ${host} in
 125         *mingw*) QT4_CPPFLAGS="-DQT_DLL $QT4_CPPFLAGS";;
 126         esac
 127         AC_SUBST(QT4_CPPFLAGS)
 128
 129         dnl Check if it possible to do a pkg-config
 130         PKG_PROG_PKG_CONFIG
 131         if test -n "$PKG_CONFIG" ; then
 132                 QT4_DO_PKG_CONFIG
 133         fi
 134         if test "$pkg_failed" != "no" ; then
 135                 QT4_DO_MANUAL_CONFIG
 136         fi
 137
 138         dnl Check qt version
 139         AS_VERSION_COMPARE($QT4_VERSION, $1,
 140         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QT4_VERSION has been found.])
 141         ])
 142
 143         AC_PATH_PROGS(MOC4, [moc-qt4 moc],[],$qt4_cv_bin:$PATH)
 144         AC_PATH_PROGS(UIC4, [uic-qt4 uic],[],$qt4_cv_bin:$PATH)
 145         AC_PATH_PROGS(RCC4, [rcc-qt4 rcc],[],$qt4_cv_bin:$PATH)
 146         AC_CHECK_PROG(bc_found,[bc],[yes],[no],$PATH)
 147 ])
 148
 149 AC_DEFUN([QT4_DO_PKG_CONFIG],
 150 [
 151         dnl tell pkg-config to look also in $qt4_cv_dir/lib.
 152         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 153         if test -n "$qt4_cv_dir" ; then
 154           PKG_CONFIG_PATH=$qt4_cv_dir/lib:$qt4_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 155           export PKG_CONFIG_PATH
 156         fi
 157         PKG_CHECK_MODULES(QT4_CORE, QtCore,,[:])
 158         if test "$pkg_failed" = "no" ; then
 159                 QT4_CORE_INCLUDES=$QT4_CORE_CFLAGS
 160                 AC_SUBST(QT4_CORE_INCLUDES)
 161                 QT4_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore`
 162                 AC_SUBST(QT4_CORE_LDFLAGS)
 163                 QT4_CORE_LIB=`$PKG_CONFIG --libs-only-l QtCore`
 164                 AC_SUBST(QT4_CORE_LIB)
 165         fi
 166         PKG_CHECK_MODULES(QT4_FRONTEND, QtCore QtGui,,[:])
 167         if test "$pkg_failed" = "no" ; then
 168                 QT4_INCLUDES=$QT4_FRONTEND_CFLAGS
 169                 dnl QT4_LDFLAGS=$QT4_FRONTEND_LIBS
 170                 QT4_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore QtGui`
 171                 AC_SUBST(QT4_INCLUDES)
 172                 AC_SUBST(QT4_LDFLAGS)
 173                 QT4_VERSION=`$PKG_CONFIG --modversion QtCore`
 174                 AC_SUBST(QT4_VERSION)
 175                 QT4_LIB=`$PKG_CONFIG --libs-only-l QtCore QtGui`
 176                 AC_SUBST(QT4_LIB)
 177                 LIBS="$LIBS `$PKG_CONFIG --libs-only-other QtCore QtGui`"
 178         fi
 179         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 180 ])
 181
 182 AC_DEFUN([QT4_DO_MANUAL_CONFIG],
 183 [
 184         dnl Check for X libraries
 185         AC_PATH_X
 186         AC_PATH_XTRA
 187         case $have_x in
 188             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 189                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 190              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 191         disable) ;;
 192         esac
 193
 194         dnl flags for compilation
 195         QT4_INCLUDES=
 196         QT4_LDFLAGS=
 197         QT4_CORE_INCLUDES=
 198         QT4_CORE_LDFLAGS=
 199         if test -n "$qt4_cv_includes"; then
 200                 QT4_INCLUDES="-I$qt4_cv_includes"
 201                 for i in Qt QtCore QtGui QtWidgets QtConcurrent; do
 202                         QT4_INCLUDES="$QT4_INCLUDES -I$qt4_cv_includes/$i"
 203                 done
 204                 QT4_CORE_INCLUDES="-I$qt4_cv_includes -I$qt4_cv_includes/QtCore"
 205         fi
 206         case "$qt4_cv_libraries" in
 207         *framework*)
 208                 QT4_LDFLAGS="-F$qt4_cv_libraries"
 209                 QT4_CORE_LDFLAGS="-F$qt4_cv_libraries"
 210                 ;;
 211         "")
 212                 ;;
 213         *)
 214                 QT4_LDFLAGS="-L$qt4_cv_libraries"
 215                 QT4_CORE_LDFLAGS="-L$qt4_cv_libraries"
 216                 ;;
 217         esac
 218         AC_SUBST(QT4_INCLUDES)
 219         AC_SUBST(QT4_CORE_INCLUDES)
 220         AC_SUBST(QT4_LDFLAGS)
 221         AC_SUBST(QT4_CORE_LDFLAGS)
 222
 223         QT4_CHECK_COMPILE
 224
 225         QT4_LIB=$qt4_cv_libname;
 226         AC_SUBST(QT4_LIB)
 227         AC_SUBST(QT4_CORE_LIB)
 228
 229         if test -n "$qt4_cv_libname"; then
 230                 QT4_GET_VERSION
 231         fi
 232 ])