config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT4_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt4_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT4_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt 4 library name])
  25
  26         AC_CACHE_VAL(qt4_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT4_INCLUDES $QT4_LDFLAGS"
  31                 for libname in -lQtCore -lQtCore4 '-framework QtCore'
  32                 do
  33                         QT4_TRY_LINK($libname)
  34                         if test -n "$qt4_cv_libname"; then
  35                                 QT4_CORE_LIB="$qt4_cv_libname"
  36                                 break;
  37                         fi
  38                 done
  39                 qt4_cv_libname=
  40                 for libname in '-lQtCore -lQtGui' \
  41                                '-lQtCore4 -lQtGui4' \
  42                                '-framework QtCore -framework QtGui'
  43                 do
  44                         QT4_TRY_LINK($libname)
  45                         if test -n "$qt4_cv_libname"; then
  46                                 break;
  47                         fi
  48                 done
  49                 CXXFLAGS=$SAVE_CXXFLAGS
  50         ])
  51
  52         if test -z "$qt4_cv_libname"; then
  53                 AC_MSG_RESULT([failed])
  54                 if test "$FATAL" = 1 ; then
  55                         AC_MSG_ERROR([Cannot compile a simple Qt 4 executable. Check you have the right \$QT4DIR !])
  56                 fi
  57         else
  58                 AC_MSG_RESULT([$qt4_cv_libname])
  59         fi
  60 ])
  61
  62 dnl get Qt version we're using
  63 AC_DEFUN([QT4_GET_VERSION],
  64 [
  65         AC_CACHE_CHECK([Qt 4 version],lyx_cv_qt4version,
  66         [
  67                 AC_LANG_CPLUSPLUS
  68                 SAVE_CPPFLAGS=$CPPFLAGS
  69                 CPPFLAGS="$CPPFLAGS $QT4_INCLUDES"
  70
  71                 cat > conftest.$ac_ext <<EOF
  72 #line __oline__ "configure"
  73 #include "confdefs.h"
  74 #include <qglobal.h>
  75 "%%%"QT_VERSION_STR"%%%"
  76 EOF
  77                 lyx_cv_qt4version=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
  78                         grep '^"%%%"'  2>/dev/null | \
  79                         sed -e 's/"%%%"//g' -e 's/"//g'`
  80                 rm -f conftest.$ac_ext
  81                 CPPFLAGS=$SAVE_CPPFLAGS
  82         ])
  83
  84         QT4_VERSION=$lyx_cv_qt4version
  85         AC_SUBST(QT4_VERSION)
  86 ])
  87
  88 dnl start here
  89 AC_DEFUN([QT4_DO_IT_ALL],
  90 [
  91         dnl this variable is precious
  92         AC_ARG_VAR(QT4DIR, [the place where the Qt 4 files are, e.g. /usr/lib/qt4])
  93
  94         dnl Please leave this alone. I use this file in
  95         dnl oprofile.
  96         FATAL=0
  97
  98         AC_ARG_WITH(qt4-dir, [AC_HELP_STRING([--with-qt4-dir], [where the root of Qt 4 is installed])],
  99                 [ qt4_cv_dir=`eval echo "$withval"/` ])
 100
 101         AC_ARG_WITH(qt4-includes, [AC_HELP_STRING([--with-qt4-includes], [where the Qt 4 includes are])],
 102                 [ qt4_cv_includes=`eval echo "$withval"` ])
 103
 104         AC_ARG_WITH(qt4-libraries, [AC_HELP_STRING([--with-qt4-libraries], [where the Qt 4 library is installed])],
 105                 [  qt4_cv_libraries=`eval echo "$withval"` ])
 106
 107         dnl pay attention to $QT4DIR unless overridden
 108         if test -z "$qt4_cv_dir"; then
 109                 qt4_cv_dir=$QT4DIR
 110         fi
 111
 112         dnl derive inc/lib if needed
 113         if test -n "$qt4_cv_dir"; then
 114                 if test -z "$qt4_cv_includes"; then
 115                         qt4_cv_includes=$qt4_cv_dir/include
 116                 fi
 117                 if test -z "$qt4_cv_libraries"; then
 118                         qt4_cv_libraries=$qt4_cv_dir/lib
 119                 fi
 120         fi
 121
 122         dnl compute the binary dir too
 123         if test -n "$qt4_cv_dir"; then
 124                 qt4_cv_bin=$qt4_cv_dir/bin
 125         fi
 126
 127         dnl Preprocessor flags
 128         QT4_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 129         case ${host} in
 130         *mingw*) QT4_CPPFLAGS="-DQT_DLL $QT4_CPPFLAGS";;
 131         esac
 132         AC_SUBST(QT4_CPPFLAGS)
 133
 134         dnl Check if it possible to do a pkg-config
 135         PKG_PROG_PKG_CONFIG
 136         if test -n "$PKG_CONFIG" ; then
 137                 QT4_DO_PKG_CONFIG
 138         fi
 139         if test "$pkg_failed" != "no" ; then
 140                 QT4_DO_MANUAL_CONFIG
 141         fi
 142         AC_PATH_PROGS(MOC4, [moc-qt4 moc],[],$qt4_cv_bin:$PATH)
 143         AC_PATH_PROGS(UIC4, [uic-qt4 uic],[],$qt4_cv_bin:$PATH)
 144         AC_PATH_PROGS(RCC4, [rcc-qt4 rcc],[],$qt4_cv_bin:$PATH)
 145 ])
 146
 147 AC_DEFUN([QT4_DO_PKG_CONFIG],
 148 [
 149         dnl tell pkg-config to look also in $qt4_cv_dir/lib.
 150         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 151         if test -n "$qt4_cv_dir" ; then
 152           PKG_CONFIG_PATH=$qt4_cv_dir/lib:$qt4_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 153           export PKG_CONFIG_PATH
 154         fi
 155         PKG_CHECK_MODULES(QT4_CORE, QtCore,,[:])
 156         if test "$pkg_failed" = "no" ; then
 157                 QT4_CORE_INCLUDES=$QT4_CORE_CFLAGS
 158                 AC_SUBST(QT4_CORE_INCLUDES)
 159                 QT4_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore`
 160                 AC_SUBST(QT4_CORE_LDFLAGS)
 161                 QT4_CORE_LIB=`$PKG_CONFIG --libs-only-l QtCore`
 162                 AC_SUBST(QT4_CORE_LIB)
 163         fi
 164         PKG_CHECK_MODULES(QT4_FRONTEND, QtCore QtGui,,[:])
 165         if test "$pkg_failed" = "no" ; then
 166                 QT4_INCLUDES=$QT4_FRONTEND_CFLAGS
 167                 dnl QT4_LDFLAGS=$QT4_FRONTEND_LIBS
 168                 QT4_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore QtGui`
 169                 AC_SUBST(QT4_INCLUDES)
 170                 AC_SUBST(QT4_LDFLAGS)
 171                 QT4_VERSION=`$PKG_CONFIG --modversion QtCore`
 172                 AC_SUBST(QT4_VERSION)
 173                 QT4_LIB=`$PKG_CONFIG --libs-only-l QtCore QtGui`
 174                 AC_SUBST(QT4_LIB)
 175                 LIBS="$LIBS `$PKG_CONFIG --libs-only-other QtCore QtGui`"
 176         fi
 177         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 178 ])
 179
 180 AC_DEFUN([QT4_DO_MANUAL_CONFIG],
 181 [
 182         dnl Check for X libraries
 183         AC_PATH_X
 184         AC_PATH_XTRA
 185         case $have_x in
 186             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 187                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 188              no) LYX_ERROR([Cannot find X window libraries and/or headers.]);;
 189         disable) ;;
 190         esac
 191
 192         dnl flags for compilation
 193         QT4_INCLUDES=
 194         QT4_LDFLAGS=
 195         QT4_CORE_INCLUDES=
 196         QT4_CORE_LDFLAGS=
 197         if test -n "$qt4_cv_includes"; then
 198                 QT4_INCLUDES="-I$qt4_cv_includes"
 199                 for i in Qt QtCore QtGui; do
 200                         QT4_INCLUDES="$QT4_INCLUDES -I$qt4_cv_includes/$i"
 201                 done
 202                 QT4_CORE_INCLUDES="-I$qt4_cv_includes -I$qt4_cv_includes/QtCore"
 203         fi
 204         if test -n "$qt4_cv_libraries"; then
 205                 QT4_LDFLAGS="-L$qt4_cv_libraries"
 206                 QT4_CORE_LDFLAGS="-L$qt4_cv_libraries"
 207         fi
 208         AC_SUBST(QT4_INCLUDES)
 209         AC_SUBST(QT4_CORE_INCLUDES)
 210         AC_SUBST(QT4_LDFLAGS)
 211         AC_SUBST(QT4_CORE_LDFLAGS)
 212
 213         QT4_CHECK_COMPILE
 214
 215         QT4_LIB=$qt4_cv_libname;
 216         AC_SUBST(QT4_LIB)
 217         AC_SUBST(QT4_CORE_LIB)
 218
 219         if test -n "$qt4_cv_libname"; then
 220                 QT4_GET_VERSION
 221         fi
 222 ])