config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt library name])
  25
  26         AC_CACHE_VAL(qt_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  31                 qt_corelibs="-lQtCore -lQtCore4"
  32                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  33                 if test $USE_QT5 = "yes" ; then
  34                     qt_corelibs="-lQt5Core"
  35                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Widgets"
  36                 fi
  37                 for libname in $qt_corelibs '-framework QtCore'
  38                 do
  39                         QT_TRY_LINK($libname)
  40                         if test -n "$qt_cv_libname"; then
  41                                 QT_CORE_LIB="$qt_cv_libname"
  42                                 break;
  43                         fi
  44                 done
  45                 qt_cv_libname=
  46                 for libname in $qt_guilibs \
  47                                '-framework QtCore -framework QtConcurrent -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 AC_MSG_RESULT([failed])
  60                 AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  61         else
  62                 AC_MSG_RESULT([$qt_cv_libname])
  63         fi
  64 ])
  65
  66
  67 AC_DEFUN([QT_FIND_TOOL],
  68 [
  69         $1=
  70         qt_ext=qt4
  71         if test "x$USE_QT5" != "xno" ; then
  72                 qt_ext=qt5
  73         fi
  74         if test -n "$qt_cv_bin" ; then
  75                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  76         fi
  77         if test -z "$$1"; then
  78                 AC_PATH_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  79         fi
  80         if test -z "$$1"; then
  81                 AC_MSG_ERROR([cannot find $2 binary.])
  82         fi
  83 ])
  84
  85
  86 dnl get Qt version we're using
  87 AC_DEFUN([QT_GET_VERSION],
  88 [
  89         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  90         [
  91                 AC_LANG_CPLUSPLUS
  92                 SAVE_CPPFLAGS=$CPPFLAGS
  93                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
  94
  95                 cat > conftest.$ac_ext <<EOF
  96 #line __oline__ "configure"
  97 #include "confdefs.h"
  98 #include <qglobal.h>
  99 "%%%"QT_VERSION_STR"%%%"
 100 EOF
 101                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 102                         grep '^"%%%"'  2>/dev/null | \
 103                         sed -e 's/"%%%"//g' -e 's/"//g'`
 104                 rm -f conftest.$ac_ext
 105                 CPPFLAGS=$SAVE_CPPFLAGS
 106         ])
 107
 108         QTLIB_VERSION=$lyx_cv_qtversion
 109         AC_SUBST(QTLIB_VERSION)
 110 ])
 111
 112 dnl start here
 113 AC_DEFUN([QT_DO_IT_ALL],
 114 [
 115         AC_MSG_CHECKING([whether Qt5 is requested])
 116         dnl Default is Qt4
 117         AC_ARG_ENABLE([qt5],
 118           [  --enable-qt5            use Qt5 for building],
 119           USE_QT5=$enableval, USE_QT5=no)
 120         AC_MSG_RESULT([$USE_QT5])
 121         AC_SUBST([USE_QT5])
 122
 123         dnl this variable is precious
 124         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 125
 126         AC_ARG_WITH(qt-dir, [AC_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 127                 [ qt_cv_dir=`eval echo "$withval"/` ])
 128
 129         AC_ARG_WITH(qt-includes, [AC_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 130                 [ qt_cv_includes=`eval echo "$withval"` ])
 131
 132         AC_ARG_WITH(qt-libraries, [AC_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 133                 [  qt_cv_libraries=`eval echo "$withval"` ])
 134
 135         dnl pay attention to $QTDIR unless overridden
 136         if test -z "$qt_cv_dir"; then
 137                 qt_cv_dir=$QTDIR
 138         fi
 139
 140         dnl derive inc/lib if needed
 141         if test -n "$qt_cv_dir"; then
 142                 if test -z "$qt_cv_includes"; then
 143                         qt_cv_includes=$qt_cv_dir/include
 144                 fi
 145                 if test -z "$qt_cv_libraries"; then
 146                         qt_cv_libraries=$qt_cv_dir/lib
 147                 fi
 148         fi
 149
 150         dnl compute the binary dir too
 151         if test -n "$qt_cv_dir"; then
 152                 qt_cv_bin=$qt_cv_dir/bin
 153         fi
 154
 155         dnl Preprocessor flags
 156         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 157         case ${host} in
 158         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 159         esac
 160         AC_SUBST(QT_CPPFLAGS)
 161
 162         dnl Check if it possible to do a pkg-config
 163         PKG_PROG_PKG_CONFIG
 164         if test -n "$PKG_CONFIG" ; then
 165                 QT_DO_PKG_CONFIG
 166         fi
 167         if test "$pkg_failed" != "no" ; then
 168                 QT_DO_MANUAL_CONFIG
 169         fi
 170
 171         if test -z "$QT_LIB"; then
 172           AC_MSG_ERROR([cannot find qt libraries.])
 173         fi
 174
 175         dnl Check qt version
 176         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 177         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 178         ])
 179
 180         QT_FIND_TOOL([QT_MOC], [moc])
 181         QT_FIND_TOOL([QT_UIC], [uic])
 182         QT_FIND_TOOL([QT_RCC], [rcc])
 183
 184         dnl Safety check
 185         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]\.[[0-9]]\).*/\1/'`
 186         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 187                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 188         fi
 189 ])
 190
 191 AC_DEFUN([QT_DO_PKG_CONFIG],
 192 [
 193         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 194         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 195         if test -n "$qt_cv_dir" ; then
 196           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 197           export PKG_CONFIG_PATH
 198         fi
 199         qt_corelibs="QtCore"
 200         qt_guilibs="QtCore QtGui"
 201         if test "x$USE_QT5" != "xno" ; then
 202                 qt_corelibs="Qt5Core"
 203                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Widgets"
 204         fi
 205         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 206         if test "$pkg_failed" = "no" ; then
 207                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 208                 AC_SUBST(QT_CORE_INCLUDES)
 209                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 210                 AC_SUBST(QT_CORE_LDFLAGS)
 211                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 212                 AC_SUBST(QT_CORE_LIB)
 213         fi
 214         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 215         if test "$pkg_failed" = "no" ; then
 216                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 217                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 218                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 219                 AC_SUBST(QT_INCLUDES)
 220                 AC_SUBST(QT_LDFLAGS)
 221                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 222                 AC_SUBST(QTLIB_VERSION)
 223                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 224                 AC_SUBST(QT_LIB)
 225                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 226         fi
 227         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 228         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 229         dnl wrong on OS X, where everything goes to --libs-only-other.
 230         dnl As a quick workaround, let us assign better values. A better patch
 231         dnl exists for next cycle.
 232         QT_CORE_LIB=$QT_CORE_LIBS
 233         QT_CORE_LDFLAGS=
 234         QT_LIB=$QT_FRONTEND_LIBS
 235         QT_LDFLAGS=
 236 ])
 237
 238 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 239 [
 240         dnl Check for X libraries
 241         AC_PATH_X
 242         AC_PATH_XTRA
 243         case $have_x in
 244             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 245                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 246              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 247         disable) ;;
 248         esac
 249
 250         dnl flags for compilation
 251         QT_INCLUDES=
 252         QT_LDFLAGS=
 253         QT_CORE_INCLUDES=
 254         QT_CORE_LDFLAGS=
 255         if test -n "$qt_cv_includes"; then
 256                 QT_INCLUDES="-I$qt_cv_includes"
 257                 for i in Qt QtCore QtGui QtWidgets QtConcurrent QtMacExtras; do
 258                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 259                 done
 260                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 261         fi
 262         case "$qt_cv_libraries" in
 263         *framework*)
 264                 QT_LDFLAGS="-F$qt_cv_libraries"
 265                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 266                 ;;
 267         "")
 268                 ;;
 269         *)
 270                 QT_LDFLAGS="-L$qt_cv_libraries"
 271                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 272                 ;;
 273         esac
 274         AC_SUBST(QT_INCLUDES)
 275         AC_SUBST(QT_CORE_INCLUDES)
 276         AC_SUBST(QT_LDFLAGS)
 277         AC_SUBST(QT_CORE_LDFLAGS)
 278
 279         QT_CHECK_COMPILE
 280
 281         QT_LIB=$qt_cv_libname;
 282         AC_SUBST(QT_LIB)
 283         AC_SUBST(QT_CORE_LIB)
 284
 285         if test -n "$qt_cv_libname"; then
 286                 QT_GET_VERSION
 287         fi
 288 ])