config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT4_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt4_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT4_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt 4 library name])
  25
  26         AC_CACHE_VAL(qt4_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT4_INCLUDES $QT4_LDFLAGS"
  31                 for libname in -lQtCore -lQtCore4 '-framework QtCore'
  32                 do
  33                         QT4_TRY_LINK($libname)
  34                         if test -n "$qt4_cv_libname"; then
  35                                 QT4_CORE_LIB="$qt4_cv_libname"
  36                                 break;
  37                         fi
  38                 done
  39                 qt4_cv_libname=
  40                 for libname in '-lQtCore -lQtGui' \
  41                                '-lQtCore4 -lQtGui4' \
  42                                '-framework QtCore -framework QtConcurrent -framework QtWidgets -framework QtGui'\
  43                                '-framework QtCore -framework QtGui'
  44                 do
  45                         QT4_TRY_LINK($libname)
  46                         if test -n "$qt4_cv_libname"; then
  47                                 break;
  48                         fi
  49                 done
  50                 CXXFLAGS=$SAVE_CXXFLAGS
  51         ])
  52
  53         if test -z "$qt4_cv_libname"; then
  54                 AC_MSG_RESULT([failed])
  55                 AC_MSG_ERROR([cannot compile a simple Qt 4 executable. Check you have the right \$QT4DIR.])
  56         else
  57                 AC_MSG_RESULT([$qt4_cv_libname])
  58         fi
  59 ])
  60
  61
  62 AC_DEFUN([QT4_FIND_TOOL],
  63 [
  64         $1=
  65         if test -n "$qt4_cv_bin" ; then
  66                 AC_PATH_PROGS($1, [$2], [], $qt4_cv_bin)
  67         fi
  68         if test -z "$$1"; then
  69                 AC_PATH_PROGS($1, [$2-qt4 $2],[],$PATH)
  70         fi
  71         if test -z "$$1"; then
  72                 AC_MSG_ERROR([cannot find $2 binary.])
  73         fi
  74 ])
  75
  76
  77 dnl get Qt version we're using
  78 AC_DEFUN([QT4_GET_VERSION],
  79 [
  80         AC_CACHE_CHECK([Qt 4 version],lyx_cv_qt4version,
  81         [
  82                 AC_LANG_CPLUSPLUS
  83                 SAVE_CPPFLAGS=$CPPFLAGS
  84                 CPPFLAGS="$CPPFLAGS $QT4_INCLUDES"
  85
  86                 cat > conftest.$ac_ext <<EOF
  87 #line __oline__ "configure"
  88 #include "confdefs.h"
  89 #include <qglobal.h>
  90 "%%%"QT_VERSION_STR"%%%"
  91 EOF
  92                 lyx_cv_qt4version=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
  93                         grep '^"%%%"'  2>/dev/null | \
  94                         sed -e 's/"%%%"//g' -e 's/"//g'`
  95                 rm -f conftest.$ac_ext
  96                 CPPFLAGS=$SAVE_CPPFLAGS
  97         ])
  98
  99         QT4_VERSION=$lyx_cv_qt4version
 100         AC_SUBST(QT4_VERSION)
 101 ])
 102
 103 dnl start here
 104 AC_DEFUN([QT4_DO_IT_ALL],
 105 [
 106         dnl this variable is precious
 107         AC_ARG_VAR(QT4DIR, [the place where the Qt 4 files are, e.g. /usr/lib/qt4])
 108
 109         AC_ARG_WITH(qt4-dir, [AC_HELP_STRING([--with-qt4-dir], [where the root of Qt 4 is installed])],
 110                 [ qt4_cv_dir=`eval echo "$withval"/` ])
 111
 112         AC_ARG_WITH(qt4-includes, [AC_HELP_STRING([--with-qt4-includes], [where the Qt 4 includes are])],
 113                 [ qt4_cv_includes=`eval echo "$withval"` ])
 114
 115         AC_ARG_WITH(qt4-libraries, [AC_HELP_STRING([--with-qt4-libraries], [where the Qt 4 library is installed])],
 116                 [  qt4_cv_libraries=`eval echo "$withval"` ])
 117
 118         dnl pay attention to $QT4DIR unless overridden
 119         if test -z "$qt4_cv_dir"; then
 120                 qt4_cv_dir=$QT4DIR
 121         fi
 122
 123         dnl derive inc/lib if needed
 124         if test -n "$qt4_cv_dir"; then
 125                 if test -z "$qt4_cv_includes"; then
 126                         qt4_cv_includes=$qt4_cv_dir/include
 127                 fi
 128                 if test -z "$qt4_cv_libraries"; then
 129                         qt4_cv_libraries=$qt4_cv_dir/lib
 130                 fi
 131         fi
 132
 133         dnl compute the binary dir too
 134         if test -n "$qt4_cv_dir"; then
 135                 qt4_cv_bin=$qt4_cv_dir/bin
 136         fi
 137
 138         dnl Preprocessor flags
 139         QT4_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 140         case ${host} in
 141         *mingw*) QT4_CPPFLAGS="-DQT_DLL $QT4_CPPFLAGS";;
 142         esac
 143         AC_SUBST(QT4_CPPFLAGS)
 144
 145         dnl Check if it possible to do a pkg-config
 146         PKG_PROG_PKG_CONFIG
 147         if test -n "$PKG_CONFIG" ; then
 148                 QT4_DO_PKG_CONFIG
 149         fi
 150         if test "$pkg_failed" != "no" ; then
 151                 QT4_DO_MANUAL_CONFIG
 152         fi
 153
 154         if test -z "$QT4_LIB"; then
 155           AC_MSG_ERROR([cannot find qt4 library.])
 156         fi
 157
 158         dnl Check qt version
 159         AS_VERSION_COMPARE($QT4_VERSION, $1,
 160         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QT4_VERSION has been found.])
 161         ])
 162
 163         QT4_FIND_TOOL([MOC4], [moc])
 164         QT4_FIND_TOOL([UIC4], [uic])
 165         QT4_FIND_TOOL([RCC4], [rcc])
 166 ])
 167
 168 AC_DEFUN([QT4_DO_PKG_CONFIG],
 169 [
 170         dnl tell pkg-config to look also in $qt4_cv_dir/lib.
 171         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 172         if test -n "$qt4_cv_dir" ; then
 173           PKG_CONFIG_PATH=$qt4_cv_dir/lib:$qt4_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 174           export PKG_CONFIG_PATH
 175         fi
 176         PKG_CHECK_MODULES(QT4_CORE, QtCore,,[:])
 177         if test "$pkg_failed" = "no" ; then
 178                 QT4_CORE_INCLUDES=$QT4_CORE_CFLAGS
 179                 AC_SUBST(QT4_CORE_INCLUDES)
 180                 QT4_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore`
 181                 AC_SUBST(QT4_CORE_LDFLAGS)
 182                 QT4_CORE_LIB=`$PKG_CONFIG --libs-only-l QtCore`
 183                 AC_SUBST(QT4_CORE_LIB)
 184         fi
 185         PKG_CHECK_MODULES(QT4_FRONTEND, QtCore QtGui,,[:])
 186         if test "$pkg_failed" = "no" ; then
 187                 QT4_INCLUDES=$QT4_FRONTEND_CFLAGS
 188                 dnl QT4_LDFLAGS=$QT4_FRONTEND_LIBS
 189                 QT4_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore QtGui`
 190                 AC_SUBST(QT4_INCLUDES)
 191                 AC_SUBST(QT4_LDFLAGS)
 192                 QT4_VERSION=`$PKG_CONFIG --modversion QtCore`
 193                 AC_SUBST(QT4_VERSION)
 194                 QT4_LIB=`$PKG_CONFIG --libs-only-l QtCore QtGui`
 195                 AC_SUBST(QT4_LIB)
 196                 LIBS="$LIBS `$PKG_CONFIG --libs-only-other QtCore QtGui`"
 197         fi
 198         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 199 ])
 200
 201 AC_DEFUN([QT4_DO_MANUAL_CONFIG],
 202 [
 203         dnl Check for X libraries
 204         AC_PATH_X
 205         AC_PATH_XTRA
 206         case $have_x in
 207             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 208                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 209              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 210         disable) ;;
 211         esac
 212
 213         dnl flags for compilation
 214         QT4_INCLUDES=
 215         QT4_LDFLAGS=
 216         QT4_CORE_INCLUDES=
 217         QT4_CORE_LDFLAGS=
 218         if test -n "$qt4_cv_includes"; then
 219                 QT4_INCLUDES="-I$qt4_cv_includes"
 220                 for i in Qt QtCore QtGui QtWidgets QtConcurrent; do
 221                         QT4_INCLUDES="$QT4_INCLUDES -I$qt4_cv_includes/$i"
 222                 done
 223                 QT4_CORE_INCLUDES="-I$qt4_cv_includes -I$qt4_cv_includes/QtCore"
 224         fi
 225         case "$qt4_cv_libraries" in
 226         *framework*)
 227                 QT4_LDFLAGS="-F$qt4_cv_libraries"
 228                 QT4_CORE_LDFLAGS="-F$qt4_cv_libraries"
 229                 ;;
 230         "")
 231                 ;;
 232         *)
 233                 QT4_LDFLAGS="-L$qt4_cv_libraries"
 234                 QT4_CORE_LDFLAGS="-L$qt4_cv_libraries"
 235                 ;;
 236         esac
 237         AC_SUBST(QT4_INCLUDES)
 238         AC_SUBST(QT4_CORE_INCLUDES)
 239         AC_SUBST(QT4_LDFLAGS)
 240         AC_SUBST(QT4_CORE_LDFLAGS)
 241
 242         QT4_CHECK_COMPILE
 243
 244         QT4_LIB=$qt4_cv_libname;
 245         AC_SUBST(QT4_LIB)
 246         AC_SUBST(QT4_CORE_LIB)
 247
 248         if test -n "$qt4_cv_libname"; then
 249                 QT4_GET_VERSION
 250         fi
 251 ])