config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <QtCore/QString>
   8                 ],
   9         [
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ],
  15         qt_cv_libname=$1,
  16         )
  17         LIBS="$SAVE_LIBS"
  18 ])
  19
  20 dnl check we can do a compile
  21 AC_DEFUN([QT_CHECK_COMPILE],
  22 [
  23         AC_MSG_CHECKING([for Qt library name])
  24
  25         AC_CACHE_VAL(qt_cv_libname,
  26         [
  27                 AC_LANG_CPLUSPLUS
  28                 SAVE_CXXFLAGS=$CXXFLAGS
  29                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  30                 qt_corelibs="-lQtCore -lQtCore4"
  31                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  32                 if test $USE_QT5 = "yes" ; then
  33                     qt_corelibs="-lQt5Core"
  34                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  35                 fi
  36                 for libname in $qt_corelibs '-framework QtCore'
  37                 do
  38                         QT_TRY_LINK($libname)
  39                         if test -n "$qt_cv_libname"; then
  40                                 QT_CORE_LIB="$qt_cv_libname"
  41                                 break;
  42                         fi
  43                 done
  44                 qt_cv_libname=
  45                 for libname in $qt_guilibs \
  46                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  47                                '-framework QtCore -framework QtGui'
  48                 do
  49                         QT_TRY_LINK($libname)
  50                         if test -n "$qt_cv_libname"; then
  51                                 break;
  52                         fi
  53                 done
  54                 CXXFLAGS=$SAVE_CXXFLAGS
  55         ])
  56
  57         if test -z "$qt_cv_libname"; then
  58                 AC_MSG_RESULT([failed])
  59                 AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  60         else
  61                 AC_MSG_RESULT([$qt_cv_libname])
  62         fi
  63 ])
  64
  65
  66 AC_DEFUN([QT_FIND_TOOL],
  67 [
  68         $1=
  69         qt_ext=qt4
  70         if test "x$USE_QT5" != "xno" ; then
  71                 qt_ext=qt5
  72         fi
  73
  74         if test -n "$qt_cv_bin" ; then
  75                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  76         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  77                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  78                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  79                 qtc_path=`dirname "$qtc_path"`
  80                 $2_path=`dirname "$$2_path"`
  81                 if test "$qtc_path" = "$$2_path" ; then
  82                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  83                 fi
  84         fi
  85         if test -z "$$1"; then
  86                 AC_CHECK_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  87         fi
  88         if test -z "$$1"; then
  89                 AC_MSG_ERROR([cannot find $2 binary.])
  90         fi
  91 ])
  92
  93
  94 dnl get Qt version we're using
  95 AC_DEFUN([QT_GET_VERSION],
  96 [
  97         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  98         [
  99                 AC_LANG_CPLUSPLUS
 100                 SAVE_CPPFLAGS=$CPPFLAGS
 101                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 102
 103                 cat > conftest.$ac_ext <<EOF
 104 #line __oline__ "configure"
 105 #include "confdefs.h"
 106 #include <QtCore/qglobal.h>
 107 "%%%"QT_VERSION_STR"%%%"
 108 EOF
 109                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 110                         grep '^"%%%"'  2>/dev/null | \
 111                         sed -e 's/"%%%"//g' -e 's/"//g'`
 112                 rm -f conftest.$ac_ext
 113                 CPPFLAGS=$SAVE_CPPFLAGS
 114         ])
 115
 116         QTLIB_VERSION=$lyx_cv_qtversion
 117         AC_SUBST(QTLIB_VERSION)
 118 ])
 119
 120 dnl start here
 121 AC_DEFUN([QT_DO_IT_ALL],
 122 [
 123         dnl this variable is precious
 124         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 125
 126         AC_ARG_WITH(qt-dir, [AC_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 127                 [ qt_cv_dir=`eval echo "$withval"/` ])
 128
 129         AC_ARG_WITH(qt-includes, [AC_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 130                 [ qt_cv_includes=`eval echo "$withval"` ])
 131
 132         AC_ARG_WITH(qt-libraries, [AC_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 133                 [  qt_cv_libraries=`eval echo "$withval"` ])
 134
 135         dnl pay attention to $QTDIR unless overridden
 136         if test -z "$qt_cv_dir"; then
 137                 qt_cv_dir=$QTDIR
 138         fi
 139
 140         dnl derive inc/lib if needed
 141         if test -n "$qt_cv_dir"; then
 142                 if test -z "$qt_cv_includes"; then
 143                         qt_cv_includes=$qt_cv_dir/include
 144                 fi
 145                 if test -z "$qt_cv_libraries"; then
 146                         qt_cv_libraries=$qt_cv_dir/lib
 147                 fi
 148         fi
 149
 150         dnl compute the binary dir too
 151         if test -n "$qt_cv_dir"; then
 152                 qt_cv_bin=$qt_cv_dir/bin
 153         fi
 154
 155         dnl Preprocessor flags
 156         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 157         case ${host} in
 158         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 159         esac
 160         AC_SUBST(QT_CPPFLAGS)
 161
 162         dnl Check if it possible to do a pkg-config
 163         PKG_PROG_PKG_CONFIG
 164         if test -n "$PKG_CONFIG" ; then
 165                 QT_DO_PKG_CONFIG
 166         fi
 167         if test "$pkg_failed" != "no" ; then
 168                 QT_DO_MANUAL_CONFIG
 169         fi
 170
 171         if test -z "$QT_LIB"; then
 172           AC_MSG_ERROR([cannot find qt libraries.])
 173         fi
 174
 175         dnl Check qt version
 176         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 177         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 178         ])
 179
 180         save_CPPFLAGS=$CPPFLAGS
 181         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 182         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 183           [lyx_qt5_config=QtGui/qtgui-config.h],
 184           [lyx_qt5_config=qconfig.h],[-])
 185         AC_MSG_CHECKING([whether Qt uses the X Window system])
 186         if test x$USE_QT5 = xyes ; then
 187           AC_EGREP_CPP(xcb,
 188             [#include <$lyx_qt5_config>
 189             QT_QPA_DEFAULT_PLATFORM_NAME],
 190             [AC_MSG_RESULT(yes)
 191              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 192             [AC_MSG_RESULT(no)])
 193         else
 194           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 195             [#include <QtCore/qglobal.h>],
 196             [#ifndef Q_WS_X11],
 197             [#error Fail],
 198             [#endif]])],
 199             qt_use_x11=yes,
 200             qt_use_x11=no)
 201           AC_MSG_RESULT($qt_use_x11)
 202           if test "x$qt_use_x11" = "xyes"; then
 203             QT_LIB="$QT_LIB -lX11"
 204           fi
 205         fi
 206         CPPFLAGS=$save_CPPFLAGS
 207
 208         QT_FIND_TOOL([QT_MOC], [moc])
 209         QT_FIND_TOOL([QT_UIC], [uic])
 210         QT_FIND_TOOL([QT_RCC], [rcc])
 211
 212         dnl Safety check
 213         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]\.[[0-9]]\).*/\1/'`
 214         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 215                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 216         fi
 217 ])
 218
 219 AC_DEFUN([QT_DO_PKG_CONFIG],
 220 [
 221         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 222         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 223         if test -n "$qt_cv_dir" ; then
 224           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 225           export PKG_CONFIG_PATH
 226         fi
 227         qt_corelibs="QtCore"
 228         qt_guilibs="QtCore QtGui QtSvg"
 229         if test "x$USE_QT5" != "xno" ; then
 230                 qt_corelibs="Qt5Core"
 231                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 232                 lyx_use_x11extras=false
 233                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 234                 if $lyx_use_x11extras; then
 235                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 236                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 237                                 [Define if you have the Qt5X11Extras module])
 238                 fi
 239                 lyx_use_winextras=false
 240                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 241                 if $lyx_use_winextras; then
 242                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 243                 fi
 244                 lyx_use_macextras=false
 245                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 246                 if $lyx_use_macextras; then
 247                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 248                 fi
 249         fi
 250         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 251         if test "$pkg_failed" = "no" ; then
 252                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 253                 AC_SUBST(QT_CORE_INCLUDES)
 254                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 255                 AC_SUBST(QT_CORE_LDFLAGS)
 256                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 257                 AC_SUBST(QT_CORE_LIB)
 258         fi
 259         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 260         if test "$pkg_failed" = "no" ; then
 261                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 262                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 263                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 264                 AC_SUBST(QT_INCLUDES)
 265                 AC_SUBST(QT_LDFLAGS)
 266                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 267                 AC_SUBST(QTLIB_VERSION)
 268                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 269                 AC_SUBST(QT_LIB)
 270                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 271         fi
 272         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 273         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 274         dnl wrong on OS X, where everything goes to --libs-only-other.
 275         dnl As a quick workaround, let us assign better values. A better patch
 276         dnl exists for next cycle.
 277         QT_CORE_LIB=$QT_CORE_LIBS
 278         QT_CORE_LDFLAGS=
 279         QT_LIB=$QT_FRONTEND_LIBS
 280         QT_LDFLAGS=
 281 ])
 282
 283 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 284 [
 285         dnl Check for X libraries
 286         case ${host} in
 287         *mingw*) ;;
 288         *) \
 289           AC_PATH_X \
 290           AC_PATH_XTRA \
 291         ;;
 292         esac
 293         case $have_x in
 294             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 295                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 296              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 297         disable) ;;
 298         esac
 299
 300         dnl flags for compilation
 301         QT_INCLUDES=
 302         QT_LDFLAGS=
 303         QT_CORE_INCLUDES=
 304         QT_CORE_LDFLAGS=
 305         if test -n "$qt_cv_includes"; then
 306                 QT_INCLUDES="-I$qt_cv_includes"
 307                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 308                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 309                 done
 310                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 311         fi
 312         case "$qt_cv_libraries" in
 313         *framework*)
 314                 QT_LDFLAGS="-F$qt_cv_libraries"
 315                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 316                 ;;
 317         "")
 318                 ;;
 319         *)
 320                 QT_LDFLAGS="-L$qt_cv_libraries"
 321                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 322                 ;;
 323         esac
 324         AC_SUBST(QT_INCLUDES)
 325         AC_SUBST(QT_CORE_INCLUDES)
 326         AC_SUBST(QT_LDFLAGS)
 327         AC_SUBST(QT_CORE_LDFLAGS)
 328
 329         QT_CHECK_COMPILE
 330
 331         QT_LIB=$qt_cv_libname;
 332         AC_SUBST(QT_LIB)
 333         AC_SUBST(QT_CORE_LIB)
 334
 335         if test -n "$qt_cv_libname"; then
 336                 QT_GET_VERSION
 337         fi
 338 ])