config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT4_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt4_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT4_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt 4 library name])
  25
  26         AC_CACHE_VAL(qt4_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT4_INCLUDES $QT4_LDFLAGS"
  31                 for libname in -lQtCore -lQtCore4 '-framework QtCore'
  32                 do
  33                         QT4_TRY_LINK($libname)
  34                         if test -n "$qt4_cv_libname"; then
  35                                 QT4_CORE_LIB="$qt4_cv_libname"
  36                                 break;
  37                         fi
  38                 done
  39                 qt4_cv_libname=
  40                 for libname in '-lQtCore -lQtGui' \
  41                                '-lQtCore4 -lQtGui4' \
  42                                '-framework QtCore -framework QtConcurrent -framework QtWidgets -framework QtGui'\
  43                                '-framework QtCore -framework QtGui'
  44                 do
  45                         QT4_TRY_LINK($libname)
  46                         if test -n "$qt4_cv_libname"; then
  47                                 break;
  48                         fi
  49                 done
  50                 CXXFLAGS=$SAVE_CXXFLAGS
  51         ])
  52
  53         if test -z "$qt4_cv_libname"; then
  54                 AC_MSG_RESULT([failed])
  55                 if test "$FATAL" = 1 ; then
  56                         AC_MSG_ERROR([Cannot compile a simple Qt 4 executable. Check you have the right \$QT4DIR !])
  57                 fi
  58         else
  59                 AC_MSG_RESULT([$qt4_cv_libname])
  60         fi
  61 ])
  62
  63 dnl get Qt version we're using
  64 AC_DEFUN([QT4_GET_VERSION],
  65 [
  66         AC_CACHE_CHECK([Qt 4 version],lyx_cv_qt4version,
  67         [
  68                 AC_LANG_CPLUSPLUS
  69                 SAVE_CPPFLAGS=$CPPFLAGS
  70                 CPPFLAGS="$CPPFLAGS $QT4_INCLUDES"
  71
  72                 cat > conftest.$ac_ext <<EOF
  73 #line __oline__ "configure"
  74 #include "confdefs.h"
  75 #include <qglobal.h>
  76 "%%%"QT_VERSION_STR"%%%"
  77 EOF
  78                 lyx_cv_qt4version=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
  79                         grep '^"%%%"'  2>/dev/null | \
  80                         sed -e 's/"%%%"//g' -e 's/"//g'`
  81                 rm -f conftest.$ac_ext
  82                 CPPFLAGS=$SAVE_CPPFLAGS
  83         ])
  84
  85         QT4_VERSION=$lyx_cv_qt4version
  86         AC_SUBST(QT4_VERSION)
  87 ])
  88
  89 dnl start here
  90 AC_DEFUN([QT4_DO_IT_ALL],
  91 [
  92         dnl this variable is precious
  93         AC_ARG_VAR(QT4DIR, [the place where the Qt 4 files are, e.g. /usr/lib/qt4])
  94
  95         dnl Please leave this alone. I use this file in
  96         dnl oprofile.
  97         FATAL=0
  98
  99         AC_ARG_WITH(qt4-dir, [AC_HELP_STRING([--with-qt4-dir], [where the root of Qt 4 is installed])],
 100                 [ qt4_cv_dir=`eval echo "$withval"/` ])
 101
 102         AC_ARG_WITH(qt4-includes, [AC_HELP_STRING([--with-qt4-includes], [where the Qt 4 includes are])],
 103                 [ qt4_cv_includes=`eval echo "$withval"` ])
 104
 105         AC_ARG_WITH(qt4-libraries, [AC_HELP_STRING([--with-qt4-libraries], [where the Qt 4 library is installed])],
 106                 [  qt4_cv_libraries=`eval echo "$withval"` ])
 107
 108         dnl pay attention to $QT4DIR unless overridden
 109         if test -z "$qt4_cv_dir"; then
 110                 qt4_cv_dir=$QT4DIR
 111         fi
 112
 113         dnl derive inc/lib if needed
 114         if test -n "$qt4_cv_dir"; then
 115                 if test -z "$qt4_cv_includes"; then
 116                         qt4_cv_includes=$qt4_cv_dir/include
 117                 fi
 118                 if test -z "$qt4_cv_libraries"; then
 119                         qt4_cv_libraries=$qt4_cv_dir/lib
 120                 fi
 121         fi
 122
 123         dnl compute the binary dir too
 124         if test -n "$qt4_cv_dir"; then
 125                 qt4_cv_bin=$qt4_cv_dir/bin
 126         fi
 127
 128         dnl Preprocessor flags
 129         QT4_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 130         case ${host} in
 131         *mingw*) QT4_CPPFLAGS="-DQT_DLL $QT4_CPPFLAGS";;
 132         esac
 133         AC_SUBST(QT4_CPPFLAGS)
 134
 135         dnl Check if it possible to do a pkg-config
 136         PKG_PROG_PKG_CONFIG
 137         if test -n "$PKG_CONFIG" ; then
 138                 QT4_DO_PKG_CONFIG
 139         fi
 140         if test "$pkg_failed" != "no" ; then
 141                 QT4_DO_MANUAL_CONFIG
 142         fi
 143
 144         dnl Check qt version
 145         AS_VERSION_COMPARE($QT4_VERSION, $1,
 146         [LYX_ERROR([LyX requires version $1 of Qt. Only version $QT4_VERSION has been found.])
 147         ])
 148
 149         AC_PATH_PROGS(MOC4, [moc-qt4 moc],[],$qt4_cv_bin:$PATH)
 150         AC_PATH_PROGS(UIC4, [uic-qt4 uic],[],$qt4_cv_bin:$PATH)
 151         AC_PATH_PROGS(RCC4, [rcc-qt4 rcc],[],$qt4_cv_bin:$PATH)
 152         AC_CHECK_PROG(bc_found,[bc],[yes],[no],$PATH)
 153 ])
 154
 155 AC_DEFUN([QT4_DO_PKG_CONFIG],
 156 [
 157         dnl tell pkg-config to look also in $qt4_cv_dir/lib.
 158         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 159         if test -n "$qt4_cv_dir" ; then
 160           PKG_CONFIG_PATH=$qt4_cv_dir/lib:$qt4_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 161           export PKG_CONFIG_PATH
 162         fi
 163         PKG_CHECK_MODULES(QT4_CORE, QtCore,,[:])
 164         if test "$pkg_failed" = "no" ; then
 165                 QT4_CORE_INCLUDES=$QT4_CORE_CFLAGS
 166                 AC_SUBST(QT4_CORE_INCLUDES)
 167                 QT4_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore`
 168                 AC_SUBST(QT4_CORE_LDFLAGS)
 169                 QT4_CORE_LIB=`$PKG_CONFIG --libs-only-l QtCore`
 170                 AC_SUBST(QT4_CORE_LIB)
 171         fi
 172         PKG_CHECK_MODULES(QT4_FRONTEND, QtCore QtGui,,[:])
 173         if test "$pkg_failed" = "no" ; then
 174                 QT4_INCLUDES=$QT4_FRONTEND_CFLAGS
 175                 dnl QT4_LDFLAGS=$QT4_FRONTEND_LIBS
 176                 QT4_LDFLAGS=`$PKG_CONFIG --libs-only-L QtCore QtGui`
 177                 AC_SUBST(QT4_INCLUDES)
 178                 AC_SUBST(QT4_LDFLAGS)
 179                 QT4_VERSION=`$PKG_CONFIG --modversion QtCore`
 180                 AC_SUBST(QT4_VERSION)
 181                 QT4_LIB=`$PKG_CONFIG --libs-only-l QtCore QtGui`
 182                 AC_SUBST(QT4_LIB)
 183                 LIBS="$LIBS `$PKG_CONFIG --libs-only-other QtCore QtGui`"
 184         fi
 185         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 186 ])
 187
 188 AC_DEFUN([QT4_DO_MANUAL_CONFIG],
 189 [
 190         dnl Check for X libraries
 191         AC_PATH_X
 192         AC_PATH_XTRA
 193         case $have_x in
 194             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 195                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 196              no) LYX_ERROR([Cannot find X window libraries and/or headers.]);;
 197         disable) ;;
 198         esac
 199
 200         dnl flags for compilation
 201         QT4_INCLUDES=
 202         QT4_LDFLAGS=
 203         QT4_CORE_INCLUDES=
 204         QT4_CORE_LDFLAGS=
 205         if test -n "$qt4_cv_includes"; then
 206                 QT4_INCLUDES="-I$qt4_cv_includes"
 207                 for i in Qt QtCore QtGui QtWidgets QtConcurrent; do
 208                         QT4_INCLUDES="$QT4_INCLUDES -I$qt4_cv_includes/$i"
 209                 done
 210                 QT4_CORE_INCLUDES="-I$qt4_cv_includes -I$qt4_cv_includes/QtCore"
 211         fi
 212         case "$qt4_cv_libraries" in
 213         *framework*)
 214                 QT4_LDFLAGS="-F$qt4_cv_libraries"
 215                 QT4_CORE_LDFLAGS="-F$qt4_cv_libraries"
 216                 ;;
 217         "")
 218                 ;;
 219         *)
 220                 QT4_LDFLAGS="-L$qt4_cv_libraries"
 221                 QT4_CORE_LDFLAGS="-L$qt4_cv_libraries"
 222                 ;;
 223         esac
 224         AC_SUBST(QT4_INCLUDES)
 225         AC_SUBST(QT4_CORE_INCLUDES)
 226         AC_SUBST(QT4_LDFLAGS)
 227         AC_SUBST(QT4_CORE_LDFLAGS)
 228
 229         QT4_CHECK_COMPILE
 230
 231         QT4_LIB=$qt4_cv_libname;
 232         AC_SUBST(QT4_LIB)
 233         AC_SUBST(QT4_CORE_LIB)
 234
 235         if test -n "$qt4_cv_libname"; then
 236                 QT4_GET_VERSION
 237         fi
 238 ])