config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt library name])
  25
  26         AC_CACHE_VAL(qt_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  31                 qt_corelibs="-lQtCore -lQtCore4"
  32                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  33                 if test $USE_QT5 = "yes" ; then
  34                     qt_corelibs="-lQt5Core"
  35                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  36                 fi
  37                 for libname in $qt_corelibs '-framework QtCore'
  38                 do
  39                         QT_TRY_LINK($libname)
  40                         if test -n "$qt_cv_libname"; then
  41                                 QT_CORE_LIB="$qt_cv_libname"
  42                                 break;
  43                         fi
  44                 done
  45                 qt_cv_libname=
  46                 for libname in $qt_guilibs \
  47                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 AC_MSG_RESULT([failed])
  60                 AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  61         else
  62                 AC_MSG_RESULT([$qt_cv_libname])
  63         fi
  64 ])
  65
  66
  67 AC_DEFUN([QT_FIND_TOOL],
  68 [
  69         $1=
  70         qt_ext=qt4
  71         if test "x$USE_QT5" != "xno" ; then
  72                 qt_ext=qt5
  73         fi
  74         if test -n "$qt_cv_bin" ; then
  75                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  76         fi
  77         if test -z "$$1"; then
  78                 AC_PATH_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  79         fi
  80         if test -z "$$1"; then
  81                 AC_MSG_ERROR([cannot find $2 binary.])
  82         fi
  83 ])
  84
  85
  86 dnl get Qt version we're using
  87 AC_DEFUN([QT_GET_VERSION],
  88 [
  89         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  90         [
  91                 AC_LANG_CPLUSPLUS
  92                 SAVE_CPPFLAGS=$CPPFLAGS
  93                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
  94
  95                 cat > conftest.$ac_ext <<EOF
  96 #line __oline__ "configure"
  97 #include "confdefs.h"
  98 #include <qglobal.h>
  99 "%%%"QT_VERSION_STR"%%%"
 100 EOF
 101                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 102                         grep '^"%%%"'  2>/dev/null | \
 103                         sed -e 's/"%%%"//g' -e 's/"//g'`
 104                 rm -f conftest.$ac_ext
 105                 CPPFLAGS=$SAVE_CPPFLAGS
 106         ])
 107
 108         QTLIB_VERSION=$lyx_cv_qtversion
 109         AC_SUBST(QTLIB_VERSION)
 110 ])
 111
 112 dnl start here
 113 AC_DEFUN([QT_DO_IT_ALL],
 114 [
 115         dnl this variable is precious
 116         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 117
 118         AC_ARG_WITH(qt-dir, [AC_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 119                 [ qt_cv_dir=`eval echo "$withval"/` ])
 120
 121         AC_ARG_WITH(qt-includes, [AC_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 122                 [ qt_cv_includes=`eval echo "$withval"` ])
 123
 124         AC_ARG_WITH(qt-libraries, [AC_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 125                 [  qt_cv_libraries=`eval echo "$withval"` ])
 126
 127         dnl pay attention to $QTDIR unless overridden
 128         if test -z "$qt_cv_dir"; then
 129                 qt_cv_dir=$QTDIR
 130         fi
 131
 132         dnl derive inc/lib if needed
 133         if test -n "$qt_cv_dir"; then
 134                 if test -z "$qt_cv_includes"; then
 135                         qt_cv_includes=$qt_cv_dir/include
 136                 fi
 137                 if test -z "$qt_cv_libraries"; then
 138                         qt_cv_libraries=$qt_cv_dir/lib
 139                 fi
 140         fi
 141
 142         dnl compute the binary dir too
 143         if test -n "$qt_cv_dir"; then
 144                 qt_cv_bin=$qt_cv_dir/bin
 145         fi
 146
 147         dnl Preprocessor flags
 148         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 149         case ${host} in
 150         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 151         esac
 152         AC_SUBST(QT_CPPFLAGS)
 153
 154         dnl Check if it possible to do a pkg-config
 155         PKG_PROG_PKG_CONFIG
 156         if test -n "$PKG_CONFIG" ; then
 157                 QT_DO_PKG_CONFIG
 158         fi
 159         if test "$pkg_failed" != "no" ; then
 160                 QT_DO_MANUAL_CONFIG
 161         fi
 162
 163         if test -z "$QT_LIB"; then
 164           AC_MSG_ERROR([cannot find qt libraries.])
 165         fi
 166
 167         dnl Check qt version
 168         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 169         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 170         ])
 171
 172         if test x$USE_QT5 = xyes ; then
 173           save_CPPFLAGS=$CPPFLAGS
 174           AC_MSG_CHECKING([whether Qt uses the X Window system])
 175           CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 176           AC_EGREP_CPP(xcb,
 177             [#include <qconfig.h>
 178             QT_QPA_DEFAULT_PLATFORM_NAME],
 179             [AC_MSG_RESULT(yes)
 180              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 181             [AC_MSG_RESULT(no)])
 182           CPPFLAGS=$save_CPPFLAGS
 183         fi
 184
 185         QT_FIND_TOOL([QT_MOC], [moc])
 186         QT_FIND_TOOL([QT_UIC], [uic])
 187         QT_FIND_TOOL([QT_RCC], [rcc])
 188
 189         dnl Safety check
 190         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]\.[[0-9]]\).*/\1/'`
 191         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 192                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 193         fi
 194 ])
 195
 196 AC_DEFUN([QT_DO_PKG_CONFIG],
 197 [
 198         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 199         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 200         if test -n "$qt_cv_dir" ; then
 201           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 202           export PKG_CONFIG_PATH
 203         fi
 204         qt_corelibs="QtCore"
 205         qt_guilibs="QtCore QtGui QtSvg"
 206         if test "x$USE_QT5" != "xno" ; then
 207                 qt_corelibs="Qt5Core"
 208                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 209                 lyx_use_winextras=false
 210                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 211                 if $lyx_use_winextras; then
 212                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 213                 fi
 214                 lyx_use_macextras=false
 215                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 216                 if $lyx_use_macextras; then
 217                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 218                 fi
 219         fi
 220         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 221         if test "$pkg_failed" = "no" ; then
 222                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 223                 AC_SUBST(QT_CORE_INCLUDES)
 224                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 225                 AC_SUBST(QT_CORE_LDFLAGS)
 226                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 227                 AC_SUBST(QT_CORE_LIB)
 228         fi
 229         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 230         if test "$pkg_failed" = "no" ; then
 231                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 232                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 233                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 234                 AC_SUBST(QT_INCLUDES)
 235                 AC_SUBST(QT_LDFLAGS)
 236                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 237                 AC_SUBST(QTLIB_VERSION)
 238                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 239                 AC_SUBST(QT_LIB)
 240                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 241         fi
 242         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 243         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 244         dnl wrong on OS X, where everything goes to --libs-only-other.
 245         dnl As a quick workaround, let us assign better values. A better patch
 246         dnl exists for next cycle.
 247         QT_CORE_LIB=$QT_CORE_LIBS
 248         QT_CORE_LDFLAGS=
 249         QT_LIB=$QT_FRONTEND_LIBS
 250         QT_LDFLAGS=
 251 ])
 252
 253 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 254 [
 255         dnl Check for X libraries
 256         case ${host} in
 257         *mingw*) ;;
 258         *) \
 259           AC_PATH_X \
 260           AC_PATH_XTRA \
 261         ;;
 262         esac
 263         case $have_x in
 264             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 265                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 266              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 267         disable) ;;
 268         esac
 269
 270         dnl flags for compilation
 271         QT_INCLUDES=
 272         QT_LDFLAGS=
 273         QT_CORE_INCLUDES=
 274         QT_CORE_LDFLAGS=
 275         if test -n "$qt_cv_includes"; then
 276                 QT_INCLUDES="-I$qt_cv_includes"
 277                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 278                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 279                 done
 280                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 281         fi
 282         case "$qt_cv_libraries" in
 283         *framework*)
 284                 QT_LDFLAGS="-F$qt_cv_libraries"
 285                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 286                 ;;
 287         "")
 288                 ;;
 289         *)
 290                 QT_LDFLAGS="-L$qt_cv_libraries"
 291                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 292                 ;;
 293         esac
 294         AC_SUBST(QT_INCLUDES)
 295         AC_SUBST(QT_CORE_INCLUDES)
 296         AC_SUBST(QT_LDFLAGS)
 297         AC_SUBST(QT_CORE_LDFLAGS)
 298
 299         QT_CHECK_COMPILE
 300
 301         QT_LIB=$qt_cv_libname;
 302         AC_SUBST(QT_LIB)
 303         AC_SUBST(QT_CORE_LIB)
 304
 305         if test -n "$qt_cv_libname"; then
 306                 QT_GET_VERSION
 307         fi
 308 ])