config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_TRY_LINK([
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ],
  10         [
  11         QString s("mangle_failure");
  12         #if (QT_VERSION < 400)
  13         break_me_(\\\);
  14         #endif
  15         ],
  16         qt_cv_libname=$1,
  17         )
  18         LIBS="$SAVE_LIBS"
  19 ])
  20
  21 dnl check we can do a compile
  22 AC_DEFUN([QT_CHECK_COMPILE],
  23 [
  24         AC_MSG_CHECKING([for Qt library name])
  25
  26         AC_CACHE_VAL(qt_cv_libname,
  27         [
  28                 AC_LANG_CPLUSPLUS
  29                 SAVE_CXXFLAGS=$CXXFLAGS
  30                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  31                 qt_corelibs="-lQtCore -lQtCore4"
  32                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  33                 if test $USE_QT5 = "yes" ; then
  34                     qt_corelibs="-lQt5Core"
  35                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Widgets"
  36                 fi
  37                 for libname in $qt_corelibs '-framework QtCore'
  38                 do
  39                         QT_TRY_LINK($libname)
  40                         if test -n "$qt_cv_libname"; then
  41                                 QT_CORE_LIB="$qt_cv_libname"
  42                                 break;
  43                         fi
  44                 done
  45                 qt_cv_libname=
  46                 for libname in $qt_guilibs \
  47                                '-framework QtCore -framework QtConcurrent -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 AC_MSG_RESULT([failed])
  60                 AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  61         else
  62                 AC_MSG_RESULT([$qt_cv_libname])
  63         fi
  64 ])
  65
  66
  67 AC_DEFUN([QT_FIND_TOOL],
  68 [
  69         $1=
  70         qt_ext=qt4
  71         if test "x$USE_QT5" != "xno" ; then
  72                 qt_ext=qt5
  73         fi
  74         if test -n "$qt_cv_bin" ; then
  75                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  76         fi
  77         if test -z "$$1"; then
  78                 AC_PATH_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  79         fi
  80         if test -z "$$1"; then
  81                 AC_MSG_ERROR([cannot find $2 binary.])
  82         fi
  83 ])
  84
  85
  86 dnl get Qt version we're using
  87 AC_DEFUN([QT_GET_VERSION],
  88 [
  89         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  90         [
  91                 AC_LANG_CPLUSPLUS
  92                 SAVE_CPPFLAGS=$CPPFLAGS
  93                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
  94
  95                 cat > conftest.$ac_ext <<EOF
  96 #line __oline__ "configure"
  97 #include "confdefs.h"
  98 #include <qglobal.h>
  99 "%%%"QT_VERSION_STR"%%%"
 100 EOF
 101                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 102                         grep '^"%%%"'  2>/dev/null | \
 103                         sed -e 's/"%%%"//g' -e 's/"//g'`
 104                 rm -f conftest.$ac_ext
 105                 CPPFLAGS=$SAVE_CPPFLAGS
 106         ])
 107
 108         QTLIB_VERSION=$lyx_cv_qtversion
 109         AC_SUBST(QTLIB_VERSION)
 110 ])
 111
 112 dnl start here
 113 AC_DEFUN([QT_DO_IT_ALL],
 114 [
 115         dnl this variable is precious
 116         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 117
 118         AC_ARG_WITH(qt-dir, [AC_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 119                 [ qt_cv_dir=`eval echo "$withval"/` ])
 120
 121         AC_ARG_WITH(qt-includes, [AC_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 122                 [ qt_cv_includes=`eval echo "$withval"` ])
 123
 124         AC_ARG_WITH(qt-libraries, [AC_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 125                 [  qt_cv_libraries=`eval echo "$withval"` ])
 126
 127         dnl pay attention to $QTDIR unless overridden
 128         if test -z "$qt_cv_dir"; then
 129                 qt_cv_dir=$QTDIR
 130         fi
 131
 132         dnl derive inc/lib if needed
 133         if test -n "$qt_cv_dir"; then
 134                 if test -z "$qt_cv_includes"; then
 135                         qt_cv_includes=$qt_cv_dir/include
 136                 fi
 137                 if test -z "$qt_cv_libraries"; then
 138                         qt_cv_libraries=$qt_cv_dir/lib
 139                 fi
 140         fi
 141
 142         dnl compute the binary dir too
 143         if test -n "$qt_cv_dir"; then
 144                 qt_cv_bin=$qt_cv_dir/bin
 145         fi
 146
 147         dnl Preprocessor flags
 148         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 149         case ${host} in
 150         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 151         esac
 152         AC_SUBST(QT_CPPFLAGS)
 153
 154         dnl Check if it possible to do a pkg-config
 155         PKG_PROG_PKG_CONFIG
 156         if test -n "$PKG_CONFIG" ; then
 157                 QT_DO_PKG_CONFIG
 158         fi
 159         if test "$pkg_failed" != "no" ; then
 160                 QT_DO_MANUAL_CONFIG
 161         fi
 162
 163         if test -z "$QT_LIB"; then
 164           AC_MSG_ERROR([cannot find qt libraries.])
 165         fi
 166
 167         dnl Check qt version
 168         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 169         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 170         ])
 171
 172         QT_FIND_TOOL([QT_MOC], [moc])
 173         QT_FIND_TOOL([QT_UIC], [uic])
 174         QT_FIND_TOOL([QT_RCC], [rcc])
 175
 176         dnl Safety check
 177         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]\.[[0-9]]\).*/\1/'`
 178         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 179                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 180         fi
 181 ])
 182
 183 AC_DEFUN([QT_DO_PKG_CONFIG],
 184 [
 185         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 186         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 187         if test -n "$qt_cv_dir" ; then
 188           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 189           export PKG_CONFIG_PATH
 190         fi
 191         qt_corelibs="QtCore"
 192         qt_guilibs="QtCore QtGui"
 193         if test "x$USE_QT5" != "xno" ; then
 194                 qt_corelibs="Qt5Core"
 195                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Widgets"
 196                 lyx_use_winextras=false
 197                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 198                 if $lyx_use_winextras; then
 199                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 200                 fi
 201                 lyx_use_macextras=false
 202                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 203                 if $lyx_use_macextras; then
 204                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 205                 fi
 206         fi
 207         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 208         if test "$pkg_failed" = "no" ; then
 209                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 210                 AC_SUBST(QT_CORE_INCLUDES)
 211                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 212                 AC_SUBST(QT_CORE_LDFLAGS)
 213                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 214                 AC_SUBST(QT_CORE_LIB)
 215         fi
 216         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 217         if test "$pkg_failed" = "no" ; then
 218                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 219                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 220                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 221                 AC_SUBST(QT_INCLUDES)
 222                 AC_SUBST(QT_LDFLAGS)
 223                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 224                 AC_SUBST(QTLIB_VERSION)
 225                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 226                 AC_SUBST(QT_LIB)
 227                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 228         fi
 229         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 230         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 231         dnl wrong on OS X, where everything goes to --libs-only-other.
 232         dnl As a quick workaround, let us assign better values. A better patch
 233         dnl exists for next cycle.
 234         QT_CORE_LIB=$QT_CORE_LIBS
 235         QT_CORE_LDFLAGS=
 236         QT_LIB=$QT_FRONTEND_LIBS
 237         QT_LDFLAGS=
 238 ])
 239
 240 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 241 [
 242         dnl Check for X libraries
 243         AC_PATH_X
 244         AC_PATH_XTRA
 245         case $have_x in
 246             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 247                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 248              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 249         disable) ;;
 250         esac
 251
 252         dnl flags for compilation
 253         QT_INCLUDES=
 254         QT_LDFLAGS=
 255         QT_CORE_INCLUDES=
 256         QT_CORE_LDFLAGS=
 257         if test -n "$qt_cv_includes"; then
 258                 QT_INCLUDES="-I$qt_cv_includes"
 259                 for i in Qt QtCore QtGui QtWidgets QtConcurrent QtMacExtras; do
 260                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 261                 done
 262                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 263         fi
 264         case "$qt_cv_libraries" in
 265         *framework*)
 266                 QT_LDFLAGS="-F$qt_cv_libraries"
 267                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 268                 ;;
 269         "")
 270                 ;;
 271         *)
 272                 QT_LDFLAGS="-L$qt_cv_libraries"
 273                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 274                 ;;
 275         esac
 276         AC_SUBST(QT_INCLUDES)
 277         AC_SUBST(QT_CORE_INCLUDES)
 278         AC_SUBST(QT_LDFLAGS)
 279         AC_SUBST(QT_CORE_LDFLAGS)
 280
 281         QT_CHECK_COMPILE
 282
 283         QT_LIB=$qt_cv_libname;
 284         AC_SUBST(QT_LIB)
 285         AC_SUBST(QT_CORE_LIB)
 286
 287         if test -n "$qt_cv_libname"; then
 288                 QT_GET_VERSION
 289         fi
 290 ])