config/qt4.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 AC_LANG([C++])
  26                 SAVE_CXXFLAGS=$CXXFLAGS
  27                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  28                 qt_corelibs="-lQtCore -lQtCore4"
  29                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  30                 if test $USE_QT5 = "yes" ; then
  31                     qt_corelibs="-lQt5Core"
  32                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  33                 fi
  34                 for libname in $qt_corelibs '-framework QtCore'
  35                 do
  36                         QT_TRY_LINK($libname)
  37                         if test -n "$qt_cv_libname"; then
  38                                 QT_CORE_LIB="$qt_cv_libname"
  39                                 break;
  40                         fi
  41                 done
  42                 qt_cv_libname=
  43                 for libname in $qt_guilibs \
  44                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  45                                '-framework QtCore -framework QtGui'
  46                 do
  47                         QT_TRY_LINK($libname)
  48                         if test -n "$qt_cv_libname"; then
  49                                 break;
  50                         fi
  51                 done
  52                 CXXFLAGS=$SAVE_CXXFLAGS
  53         ])
  54
  55         if test -z "$qt_cv_libname"; then
  56                 AC_MSG_RESULT([failed])
  57                 AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  58         else
  59                 AC_MSG_RESULT([$qt_cv_libname])
  60         fi
  61 ])
  62
  63
  64 AC_DEFUN([QT_FIND_TOOL],
  65 [
  66         $1=
  67         qt_ext=qt4
  68         if test "x$USE_QT5" != "xno" ; then
  69                 qt_ext=qt5
  70         fi
  71
  72         if test -n "$qt_cv_bin" ; then
  73                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  74         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  75                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  76                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  77                 qtc_path=`dirname "$qtc_path"`
  78                 $2_path=`dirname "$$2_path"`
  79                 if test "$qtc_path" = "$$2_path" ; then
  80                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  81                 fi
  82         fi
  83         if test -z "$$1"; then
  84                 AC_CHECK_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  85         fi
  86         if test -z "$$1"; then
  87                 AC_MSG_ERROR([cannot find $2 binary.])
  88         fi
  89 ])
  90
  91
  92 dnl get Qt version we're using
  93 AC_DEFUN([QT_GET_VERSION],
  94 [
  95         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  96         [
  97                 AC_LANG([C++])
  98                 SAVE_CPPFLAGS=$CPPFLAGS
  99                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 100
 101                 cat > conftest.$ac_ext <<EOF
 102 #line __oline__ "configure"
 103 #include "confdefs.h"
 104 #include <qglobal.h>
 105 "%%%"QT_VERSION_STR"%%%"
 106 EOF
 107                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 108                         grep '^"%%%"'  2>/dev/null | \
 109                         sed -e 's/"%%%"//g' -e 's/"//g'`
 110                 rm -f conftest.$ac_ext
 111                 CPPFLAGS=$SAVE_CPPFLAGS
 112         ])
 113
 114         QTLIB_VERSION=$lyx_cv_qtversion
 115         AC_SUBST(QTLIB_VERSION)
 116 ])
 117
 118 dnl start here
 119 AC_DEFUN([QT_DO_IT_ALL],
 120 [
 121         dnl this variable is precious
 122         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 123
 124         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir],[where the root of Qt is installed])],
 125                 [ qt_cv_dir=`eval echo "$withval"/` ])
 126
 127         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes],[where the Qt includes are])],
 128                 [ qt_cv_includes=`eval echo "$withval"` ])
 129
 130         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries],[where the Qt library is installed])],
 131                 [  qt_cv_libraries=`eval echo "$withval"` ])
 132
 133         dnl pay attention to $QTDIR unless overridden
 134         if test -z "$qt_cv_dir"; then
 135                 qt_cv_dir=$QTDIR
 136         fi
 137
 138         dnl derive inc/lib if needed
 139         if test -n "$qt_cv_dir"; then
 140                 if test -z "$qt_cv_includes"; then
 141                         qt_cv_includes=$qt_cv_dir/include
 142                 fi
 143                 if test -z "$qt_cv_libraries"; then
 144                         qt_cv_libraries=$qt_cv_dir/lib
 145                 fi
 146         fi
 147
 148         dnl compute the binary dir too
 149         if test -n "$qt_cv_dir"; then
 150                 qt_cv_bin=$qt_cv_dir/bin
 151         fi
 152
 153         dnl Preprocessor flags
 154         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 155         case ${host} in
 156         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 157         esac
 158         AC_SUBST(QT_CPPFLAGS)
 159
 160         dnl Check if it possible to do a pkg-config
 161         PKG_PROG_PKG_CONFIG
 162         if test -n "$PKG_CONFIG" ; then
 163                 QT_DO_PKG_CONFIG
 164         fi
 165         if test "$pkg_failed" != "no" ; then
 166                 QT_DO_MANUAL_CONFIG
 167         fi
 168
 169         if test -z "$QT_LIB"; then
 170           AC_MSG_ERROR([cannot find qt libraries.])
 171         fi
 172
 173         dnl Check qt version
 174         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 175         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 176         ])
 177
 178         save_CPPFLAGS=$CPPFLAGS
 179         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 180         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 181           [lyx_qt5_config=QtGui/qtgui-config.h],
 182           [lyx_qt5_config=qconfig.h])
 183         AC_MSG_CHECKING([whether Qt uses the X Window system])
 184         if test x$USE_QT5 = xyes ; then
 185           AC_EGREP_CPP(xcb,
 186             [#include <$lyx_qt5_config>
 187             QT_QPA_DEFAULT_PLATFORM_NAME],
 188             [AC_MSG_RESULT(yes)
 189              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 190             [AC_MSG_RESULT(no)])
 191         else
 192           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 193             [#include <qglobal.h>],
 194             [#ifndef Q_WS_X11],
 195             [#error Fail],
 196             [#endif]])],
 197             qt_use_x11=yes,
 198             qt_use_x11=no)
 199           AC_MSG_RESULT($qt_use_x11)
 200           if test "x$qt_use_x11" = "xyes"; then
 201             QT_LIB="$QT_LIB -lX11"
 202           fi
 203         fi
 204         CPPFLAGS=$save_CPPFLAGS
 205
 206         QT_FIND_TOOL([QT_MOC], [moc])
 207         QT_FIND_TOOL([QT_UIC], [uic])
 208         QT_FIND_TOOL([QT_RCC], [rcc])
 209
 210         dnl Safety check
 211         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 212         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 213                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 214         fi
 215 ])
 216
 217 AC_DEFUN([QT_DO_PKG_CONFIG],
 218 [
 219         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 220         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 221         if test -n "$qt_cv_dir" ; then
 222           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 223           export PKG_CONFIG_PATH
 224         fi
 225         qt_corelibs="QtCore"
 226         qt_guilibs="QtCore QtGui QtSvg"
 227         if test "x$USE_QT5" != "xno" ; then
 228                 qt_corelibs="Qt5Core"
 229                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 230                 lyx_use_x11extras=false
 231                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 232                 if $lyx_use_x11extras; then
 233                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 234                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 235                                 [Define if you have the Qt5X11Extras module])
 236                 fi
 237                 lyx_use_winextras=false
 238                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 239                 if $lyx_use_winextras; then
 240                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 241                 fi
 242                 lyx_use_macextras=false
 243                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 244                 if $lyx_use_macextras; then
 245                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 246                 fi
 247         fi
 248         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 249         if test "$pkg_failed" = "no" ; then
 250                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 251                 AC_SUBST(QT_CORE_INCLUDES)
 252                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 253                 AC_SUBST(QT_CORE_LDFLAGS)
 254                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 255                 AC_SUBST(QT_CORE_LIB)
 256         fi
 257         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 258         if test "$pkg_failed" = "no" ; then
 259                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 260                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 261                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 262                 AC_SUBST(QT_INCLUDES)
 263                 AC_SUBST(QT_LDFLAGS)
 264                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 265                 AC_SUBST(QTLIB_VERSION)
 266                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 267                 AC_SUBST(QT_LIB)
 268                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 269         fi
 270         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 271         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 272         dnl wrong on OS X, where everything goes to --libs-only-other.
 273         dnl As a quick workaround, let us assign better values. A better patch
 274         dnl exists for next cycle.
 275         QT_CORE_LIB=$QT_CORE_LIBS
 276         QT_CORE_LDFLAGS=
 277         QT_LIB=$QT_FRONTEND_LIBS
 278         QT_LDFLAGS=
 279 ])
 280
 281 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 282 [
 283         dnl Check for X libraries
 284         case ${host} in
 285         *mingw*) ;;
 286         *) \
 287           AC_PATH_X \
 288           AC_PATH_XTRA \
 289         ;;
 290         esac
 291         case $have_x in
 292             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 293                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 294              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 295         disable) ;;
 296         esac
 297
 298         dnl flags for compilation
 299         QT_INCLUDES=
 300         QT_LDFLAGS=
 301         QT_CORE_INCLUDES=
 302         QT_CORE_LDFLAGS=
 303         if test -n "$qt_cv_includes"; then
 304                 QT_INCLUDES="-I$qt_cv_includes"
 305                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 306                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 307                 done
 308                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 309         fi
 310         case "$qt_cv_libraries" in
 311         *framework*)
 312                 QT_LDFLAGS="-F$qt_cv_libraries"
 313                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 314                 ;;
 315         "")
 316                 ;;
 317         *)
 318                 QT_LDFLAGS="-L$qt_cv_libraries"
 319                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 320                 ;;
 321         esac
 322         AC_SUBST(QT_INCLUDES)
 323         AC_SUBST(QT_CORE_INCLUDES)
 324         AC_SUBST(QT_LDFLAGS)
 325         AC_SUBST(QT_CORE_LDFLAGS)
 326
 327         QT_CHECK_COMPILE
 328
 329         QT_LIB=$qt_cv_libname;
 330         AC_SUBST(QT_LIB)
 331         AC_SUBST(QT_CORE_LIB)
 332
 333         if test -n "$qt_cv_libname"; then
 334                 QT_GET_VERSION
 335         fi
 336 ])