config/qt.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 SAVE_CXXFLAGS=$CXXFLAGS
  26                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  27                 qt_corelibs="-lQtCore -lQtCore4"
  28                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  29                 if test $USE_QT6 = "yes" ; then
  30                     qt_corelibs="-lQt6Core -lQt6Core5Compat"
  31                     qt_guilibs="-lQt6Core -lQt6Core5Compat -lQt6Concurrent -lQt6Gui -lQt6Svg -lQt6Widgets"
  32                 else
  33                     qt_corelibs="-lQt5Core"
  34                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  35                 fi
  36                 for libname in $qt_corelibs '-framework QtCore'
  37                 do
  38                         QT_TRY_LINK($libname)
  39                         if test -n "$qt_cv_libname"; then
  40                                 QT_CORE_LIB="$qt_cv_libname"
  41                                 break;
  42                         fi
  43                 done
  44                 qt_cv_libname=
  45                 for libname in $qt_guilibs \
  46                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  47                                '-framework QtCore -framework QtConcurrent -framework QtCore5Compat -framework QtSvg -framework QtSvgWidgets -framework QtWidgets -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 if test x$USE_QT6 = xyes ; then
  60                         AC_MSG_RESULT([failed, retrying with Qt5])
  61                 else
  62                         AC_MSG_RESULT([failed])
  63                         AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  64                 fi
  65         else
  66                 AC_MSG_RESULT([$qt_cv_libname])
  67         fi
  68 ])
  69
  70
  71 AC_DEFUN([QT_FIND_TOOL],
  72 [
  73         $1=
  74         qt_major=5
  75         if test "x$USE_QT6" != "xno" ; then
  76                 qt_major=6
  77         fi
  78         qt_ext="qt$qt_major"
  79
  80         if test -n "$qt_cv_libexec" ; then
  81                 AC_PATH_PROGS($1, [$2], [], $qt_cv_libexec)
  82         elif test -n "$qt_cv_bin" ; then
  83                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  84         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  85                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  86                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  87                 qtc_path=`dirname "$qtc_path"`
  88                 $2_path=`dirname "$$2_path"`
  89                 if test "$qtc_path" = "$$2_path" ; then
  90                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  91                 fi
  92         fi
  93         if test -z "$$1"; then
  94                 AC_CHECK_PROGS($1, [$2-$qt_ext $2$qt_major $2],[],$PATH)
  95         fi
  96         if test -z "$$1"; then
  97                 AC_MSG_ERROR([cannot find $2 binary.])
  98         fi
  99 ])
 100
 101
 102 dnl get Qt version we're using
 103 AC_DEFUN([QT_GET_VERSION],
 104 [
 105         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
 106         [
 107                 SAVE_CPPFLAGS=$CPPFLAGS
 108                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 109
 110                 cat > conftest.$ac_ext <<EOF
 111 #line __oline__ "configure"
 112 #include "confdefs.h"
 113 #include <qglobal.h>
 114 "%%%"QT_VERSION_STR"%%%"
 115 EOF
 116                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 117                         grep '^"%%%"'  2>/dev/null | \
 118                         sed -e 's/"%%%"//g' -e 's/"//g'`
 119                 rm -f conftest.$ac_ext
 120                 CPPFLAGS=$SAVE_CPPFLAGS
 121         ])
 122
 123         QTLIB_VERSION=$lyx_cv_qtversion
 124         AC_SUBST(QTLIB_VERSION)
 125 ])
 126
 127 dnl start here
 128 AC_DEFUN([QT_DO_IT_ALL],
 129 [
 130         dnl this variable is precious
 131         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt5])
 132
 133         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 134                 [ qt_cv_dir=`eval echo "$withval"/` ])
 135
 136         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 137                 [ qt_cv_includes=`eval echo "$withval"` ])
 138
 139         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 140                 [  qt_cv_libraries=`eval echo "$withval"` ])
 141
 142         dnl pay attention to $QTDIR unless overridden
 143         if test -z "$qt_cv_dir"; then
 144                 qt_cv_dir=$QTDIR
 145         fi
 146
 147         dnl derive inc/lib if needed
 148         if test -n "$qt_cv_dir"; then
 149                 if test -z "$qt_cv_includes"; then
 150                         qt_cv_includes=$qt_cv_dir/include
 151                 fi
 152                 if test -z "$qt_cv_libraries"; then
 153                         qt_cv_libraries=$qt_cv_dir/lib
 154                 fi
 155         fi
 156
 157         dnl compute the binary dir too
 158         if test -n "$qt_cv_dir"; then
 159                 qt_cv_bin=$qt_cv_dir/bin
 160         fi
 161
 162         dnl Preprocessor flags
 163         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 164         case ${host} in
 165         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 166         esac
 167         AC_SUBST(QT_CPPFLAGS)
 168
 169         dnl Check if it possible to do a pkg-config
 170         PKG_PROG_PKG_CONFIG
 171         dnl Not possible with Qt6 (QTBUG-86080)
 172         if test x$USE_QT6 = xno ; then
 173             if test -n "$PKG_CONFIG" ; then
 174                     QT_DO_PKG_CONFIG
 175             fi
 176             if test "$pkg_failed" != "no" ; then
 177                     QT_DO_MANUAL_CONFIG
 178             fi
 179         else
 180             QT6_QMAKE_CONFIG
 181             if test -z "$QT_LIB"; then
 182                     QT_DO_MANUAL_CONFIG
 183             fi
 184         fi
 185
 186         if test -z "$QT_LIB"; then
 187           dnl Try again with Qt5 and if configuring for Qt6/5 fails
 188           if test x$USE_QT6 = xyes ; then
 189                 USE_QT6=no
 190                 AC_SUBST([USE_QT6])
 191                 if test -n "$PKG_CONFIG" ; then
 192                   QT_DO_PKG_CONFIG
 193                 fi
 194                 if test "$pkg_failed" != "no" ; then
 195                   QT_DO_MANUAL_CONFIG
 196                 fi
 197                 if test -z "$QT_LIB"; then
 198                   AC_MSG_ERROR([cannot find qt libraries.])
 199                 fi
 200           else
 201                 AC_MSG_ERROR([cannot find qt libraries.])
 202           fi
 203         fi
 204
 205         dnl Check qt version
 206         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 207         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 208         ])
 209
 210         case $QTLIB_VERSION in
 211         6.*) if test $enable_stdlib_debug = "yes" ; then
 212                     LYX_WARNING([Compiling LyX with stdlib-debug and Qt6 library may lead to
 213    crashes. Consider dropping --enable-stdlib-debug.])
 214              fi;;
 215         esac
 216
 217
 218         save_CPPFLAGS=$CPPFLAGS
 219         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 220         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 221           [lyx_qt5_config=QtGui/qtgui-config.h],
 222           [lyx_qt5_config=qconfig.h])
 223         AC_CHECK_HEADER(QtGui/private/qtgui-config_p.h,
 224           [lyx_qt6_config=QtGui/private/qtgui-config_p.h],
 225           [lyx_qt6_config=qconfig.h])
 226         AC_MSG_CHECKING([whether Qt uses the X Window system])
 227         if test x$USE_QT6 = xyes ; then
 228           dnl FIXME: Check whether defining QPA_XCB makes sense with Qt6
 229           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 230             [#include <$lyx_qt6_config>]
 231             [#if !defined(QT_FEATURE_xcb) || QT_FEATURE_xcb < 0]
 232             [#error Fail]
 233             [#endif]])],
 234             [AC_MSG_RESULT(yes)
 235              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 236             [AC_MSG_RESULT(no)])
 237         else
 238           AC_EGREP_CPP(xcb,
 239             [#include <$lyx_qt5_config>
 240             QT_QPA_DEFAULT_PLATFORM_NAME],
 241             [AC_MSG_RESULT(yes)
 242              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 243             [AC_MSG_RESULT(no)])
 244         fi
 245         CPPFLAGS=$save_CPPFLAGS
 246
 247         QT_FIND_TOOL([QT_MOC], [moc])
 248         QT_FIND_TOOL([QT_UIC], [uic])
 249         QT_FIND_TOOL([QT_RCC], [rcc])
 250
 251         dnl Safety check
 252         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]*\).*/\1/'`
 253         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 254                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 255         fi
 256 ])
 257
 258 AC_DEFUN([QT_DO_PKG_CONFIG],
 259 [
 260         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 261         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 262         if test -n "$qt_cv_dir" ; then
 263           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 264           export PKG_CONFIG_PATH
 265         fi
 266         qt_corelibs="Qt5Core"
 267         qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 268         lyx_use_x11extras=false
 269         PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 270         if $lyx_use_x11extras; then
 271                 qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 272                 AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 273                         [Define if you have the Qt5X11Extras module])
 274         fi
 275         lyx_use_winextras=false
 276         PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 277         if $lyx_use_winextras; then
 278                 qt_guilibs="$qt_guilibs Qt5WinExtras"
 279         fi
 280         lyx_use_macextras=false
 281         PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 282         if $lyx_use_macextras; then
 283                 qt_guilibs="$qt_guilibs Qt5MacExtras"
 284         fi
 285         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 286         if test "$pkg_failed" = "no" ; then
 287                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 288                 AC_SUBST(QT_CORE_INCLUDES)
 289                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 290                 AC_SUBST(QT_CORE_LDFLAGS)
 291                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 292                 AC_SUBST(QT_CORE_LIB)
 293         fi
 294         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 295         if test "$pkg_failed" = "no" ; then
 296                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 297                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 298                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 299                 AC_SUBST(QT_INCLUDES)
 300                 AC_SUBST(QT_LDFLAGS)
 301                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 302                 AC_SUBST(QTLIB_VERSION)
 303                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 304                 AC_SUBST(QT_LIB)
 305                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 306         fi
 307         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 308         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 309         dnl wrong on OS X, where everything goes to --libs-only-other.
 310         dnl As a quick workaround, let us assign better values. A better patch
 311         dnl exists for next cycle.
 312         QT_CORE_LIB=$QT_CORE_LIBS
 313         QT_CORE_LDFLAGS=
 314         QT_LIB=$QT_FRONTEND_LIBS
 315         QT_LDFLAGS=
 316 ])
 317
 318 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 319 [
 320         dnl Check for X libraries
 321         case ${host} in
 322         *mingw*) ;;
 323         *) \
 324           AC_PATH_X \
 325           AC_PATH_XTRA \
 326         ;;
 327         esac
 328         case $have_x in
 329             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 330                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 331              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 332         disable) ;;
 333         esac
 334
 335         dnl flags for compilation
 336         QT_INCLUDES=
 337         QT_LDFLAGS=
 338         QT_CORE_INCLUDES=
 339         QT_CORE_LDFLAGS=
 340         if test -n "$qt_cv_includes"; then
 341                 QT_INCLUDES="-I$qt_cv_includes"
 342                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtSvgWidgets QtCore5Compat QtMacExtras; do
 343                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 344                         if test "$lyx_use_packaging" = "macosx" ; then
 345                                 QT_INCLUDES="$QT_INCLUDES -I$qt_cv_libraries/${i}.framework/Headers"
 346                         fi
 347                 done
 348                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 349         fi
 350         case "$qt_cv_libraries" in
 351         "")
 352                 ;;
 353         *)
 354                 if test "$lyx_use_packaging" = "macosx" ; then
 355                         QT_INCLUDES="$QT_INCLUDES -F$qt_cv_libraries"
 356                         QT_CORE_INCLUDES="$QT_CORE_INCLUDES -I$qt_cv_libraries/QtCore.framework/Headers -F$qt_cv_libraries"
 357                         QT_LDFLAGS="-F$qt_cv_libraries"
 358                         QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 359                 else
 360                         QT_LDFLAGS="-L$qt_cv_libraries"
 361                         QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 362                 fi
 363                 ;;
 364         esac
 365         AC_SUBST(QT_INCLUDES)
 366         AC_SUBST(QT_CORE_INCLUDES)
 367         AC_SUBST(QT_LDFLAGS)
 368         AC_SUBST(QT_CORE_LDFLAGS)
 369
 370         QT_CHECK_COMPILE
 371
 372         QT_LIB=$qt_cv_libname;
 373         AC_SUBST(QT_LIB)
 374         AC_SUBST(QT_CORE_LIB)
 375
 376         if test -n "$qt_cv_libname"; then
 377                 QT_GET_VERSION
 378         fi
 379 ])
 380
 381 AC_DEFUN([QT6_QMAKE_CONFIG],
 382 [
 383         dnl Use first suitable qmake in PATH
 384         AC_CHECK_PROGS([QT_QMAKE], [qmake-qt6 qmake6], [qmake], $PATH)
 385         AC_MSG_CHECKING([for Qt6])
 386         qtver=`$QT_QMAKE -v | grep -o "Qt version ."`
 387         if test "$qtver" = "Qt version 6"; then
 388             qt_cv_libexec=`$QT_QMAKE -query QT_INSTALL_LIBEXECS`
 389             dnl Use a .pro file for getting qmake's variables
 390             lyx_test_qt_dir=`mktemp -d`
 391             lyx_test_qt_pro="$lyx_test_qt_dir/test.pro"
 392             lyx_test_qt_mak="$lyx_test_qt_dir/Makefile"
 393             cat > $lyx_test_qt_pro << EOF1
 394 qtHaveModule(core):             QT += core
 395 qtHaveModule(core5compat):      QT += core5compat
 396 percent.target = %
 397 percent.commands = @echo -n "\$(\$(@))\ "
 398 QMAKE_EXTRA_TARGETS += percent
 399 QMAKE_PROJECT_DEPTH = 0
 400 EOF1
 401             $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 402             QT_CORE_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 403             qt_corelibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 404             QT_CORE_LDFLAGS=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 405             if test -z "$QT_CORE_LDFLAGS"; then
 406                 QT_CORE_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 407                 QT_CORE_LIB="$qt_corelibs"
 408             else
 409                 QT_CORE_LIB=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-l" | tr '\n' ' '`
 410             fi
 411             if test -z "$QT_CORE_LIB"; then
 412                 AC_MSG_RESULT(no)
 413             else
 414                 AC_SUBST(QT_CORE_INCLUDES)
 415                 AC_SUBST(QT_CORE_LDFLAGS)
 416                 AC_SUBST(QT_CORE_LIB)
 417                 cat > $lyx_test_qt_pro << EOF2
 418 qtHaveModule(core):             QT += core
 419 qtHaveModule(core5compat):      QT += core5compat
 420 qtHaveModule(concurrent):       QT += concurrent
 421 qtHaveModule(gui):              QT += gui gui-private
 422 qtHaveModule(svg):              QT += svg
 423 qtHaveModule(svgwidgets):       QT += svgwidgets
 424 qtHaveModule(widgets):          QT += widgets
 425 percent.target = %
 426 percent.commands = @echo -n "\$(\$(@))\ "
 427 QMAKE_EXTRA_TARGETS += percent
 428 QMAKE_PROJECT_DEPTH = 0
 429 EOF2
 430                 $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 431                 QT_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 432                 qt_guilibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 433                 QT_LDFLAGS=`echo $qt_guilibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 434                 if test -z "$QT_LDFLAGS"; then
 435                     QT_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 436                     QT_LIB="$qt_guilibs"
 437                 else
 438                     QT_LIB=`echo $qt_guilibs | tr ' ' '\n' | grep -v "^-L" | tr '\n' ' '`
 439                 fi
 440                 QTLIB_VERSION=`$QT_QMAKE -v | grep "Qt version" | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 441                 if test -z "$QT_LIB"; then
 442                     AC_MSG_RESULT(no)
 443                 else
 444                     AC_MSG_RESULT(yes)
 445                     AC_SUBST(QT_INCLUDES)
 446                     AC_SUBST(QT_LDFLAGS)
 447                     AC_SUBST(QT_LIB)
 448                     AC_SUBST(QTLIB_VERSION)
 449                 fi
 450             fi
 451             rm $lyx_test_qt_pro $lyx_test_qt_mak $lyx_test_qt_dir/.qmake.stash
 452             rmdir $lyx_test_qt_dir
 453         else
 454             AC_MSG_RESULT(no)
 455         fi
 456 ])