config/qt.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 SAVE_CXXFLAGS=$CXXFLAGS
  26                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  27                 qt_corelibs="-lQtCore -lQtCore4"
  28                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  29                 if test $USE_QT6 = "yes" ; then
  30                     qt_corelibs="-lQt6Core -lQt6Core5Compat"
  31                     qt_guilibs="-lQt6Core -lQt6Core5Compat -lQt6Concurrent -lQt6Gui -lQt6Svg -lQt6Widgets"
  32                 elif test $USE_QT5 = "yes" ; then
  33                     qt_corelibs="-lQt5Core"
  34                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  35                 fi
  36                 for libname in $qt_corelibs '-framework QtCore'
  37                 do
  38                         QT_TRY_LINK($libname)
  39                         if test -n "$qt_cv_libname"; then
  40                                 QT_CORE_LIB="$qt_cv_libname"
  41                                 break;
  42                         fi
  43                 done
  44                 qt_cv_libname=
  45                 for libname in $qt_guilibs \
  46                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  47                                '-framework QtCore -framework QtGui'
  48                 do
  49                         QT_TRY_LINK($libname)
  50                         if test -n "$qt_cv_libname"; then
  51                                 break;
  52                         fi
  53                 done
  54                 CXXFLAGS=$SAVE_CXXFLAGS
  55         ])
  56
  57         if test -z "$qt_cv_libname"; then
  58                 if test x$USE_QT6 = xyes ; then
  59                         AC_MSG_RESULT([failed, retrying with Qt5])
  60                 elif test x$USE_QT5 = xyes ; then
  61                         AC_MSG_RESULT([failed, retrying with Qt4])
  62                 else
  63                         AC_MSG_RESULT([failed])
  64                         AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  65                 fi
  66         else
  67                 AC_MSG_RESULT([$qt_cv_libname])
  68         fi
  69 ])
  70
  71
  72 AC_DEFUN([QT_FIND_TOOL],
  73 [
  74         $1=
  75         qt_major=4
  76         if test "x$USE_QT6" != "xno" ; then
  77                 qt_major=6
  78         elif test "x$USE_QT5" != "xno" ; then
  79                 qt_major=5
  80         fi
  81         qt_ext="qt$qt_major"
  82
  83         if test -n "$qt_cv_libexec" ; then
  84                 AC_PATH_PROGS($1, [$2], [], $qt_cv_libexec)
  85         elif test -n "$qt_cv_bin" ; then
  86                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  87         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  88                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  89                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  90                 qtc_path=`dirname "$qtc_path"`
  91                 $2_path=`dirname "$$2_path"`
  92                 if test "$qtc_path" = "$$2_path" ; then
  93                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  94                 fi
  95         fi
  96         if test -z "$$1"; then
  97                 AC_CHECK_PROGS($1, [$2-$qt_ext $2$qt_major $2],[],$PATH)
  98         fi
  99         if test -z "$$1"; then
 100                 AC_MSG_ERROR([cannot find $2 binary.])
 101         fi
 102 ])
 103
 104
 105 dnl get Qt version we're using
 106 AC_DEFUN([QT_GET_VERSION],
 107 [
 108         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
 109         [
 110                 SAVE_CPPFLAGS=$CPPFLAGS
 111                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 112
 113                 cat > conftest.$ac_ext <<EOF
 114 #line __oline__ "configure"
 115 #include "confdefs.h"
 116 #include <qglobal.h>
 117 "%%%"QT_VERSION_STR"%%%"
 118 EOF
 119                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 120                         grep '^"%%%"'  2>/dev/null | \
 121                         sed -e 's/"%%%"//g' -e 's/"//g'`
 122                 rm -f conftest.$ac_ext
 123                 CPPFLAGS=$SAVE_CPPFLAGS
 124         ])
 125
 126         QTLIB_VERSION=$lyx_cv_qtversion
 127         AC_SUBST(QTLIB_VERSION)
 128 ])
 129
 130 dnl start here
 131 AC_DEFUN([QT_DO_IT_ALL],
 132 [
 133         dnl this variable is precious
 134         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 135
 136         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 137                 [ qt_cv_dir=`eval echo "$withval"/` ])
 138
 139         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 140                 [ qt_cv_includes=`eval echo "$withval"` ])
 141
 142         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 143                 [  qt_cv_libraries=`eval echo "$withval"` ])
 144
 145         dnl pay attention to $QTDIR unless overridden
 146         if test -z "$qt_cv_dir"; then
 147                 qt_cv_dir=$QTDIR
 148         fi
 149
 150         dnl derive inc/lib if needed
 151         if test -n "$qt_cv_dir"; then
 152                 if test -z "$qt_cv_includes"; then
 153                         qt_cv_includes=$qt_cv_dir/include
 154                 fi
 155                 if test -z "$qt_cv_libraries"; then
 156                         qt_cv_libraries=$qt_cv_dir/lib
 157                 fi
 158         fi
 159
 160         dnl compute the binary dir too
 161         if test -n "$qt_cv_dir"; then
 162                 qt_cv_bin=$qt_cv_dir/bin
 163         fi
 164
 165         dnl Preprocessor flags
 166         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 167         case ${host} in
 168         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 169         esac
 170         AC_SUBST(QT_CPPFLAGS)
 171
 172         dnl Check if it possible to do a pkg-config
 173         PKG_PROG_PKG_CONFIG
 174         dnl Not possible with Qt6 (QTBUG-86080)
 175         if test x$USE_QT6 = xno ; then
 176             if test -n "$PKG_CONFIG" ; then
 177                     QT_DO_PKG_CONFIG
 178             fi
 179             if test "$pkg_failed" != "no" ; then
 180                     QT_DO_MANUAL_CONFIG
 181             fi
 182         else
 183             QT6_QMAKE_CONFIG
 184             if test -z "$QT_LIB"; then
 185                     QT_DO_MANUAL_CONFIG
 186             fi
 187         fi
 188
 189         if test -z "$QT_LIB"; then
 190           dnl Try again with Qt5 and then Qt4 if configuring for Qt6/5 fails
 191           if test x$USE_QT6 = xyes ; then
 192                 USE_QT6=no
 193                 USE_QT5=yes
 194                 AC_SUBST([USE_QT6])
 195                 AC_SUBST([USE_QT5])
 196                 if test -n "$PKG_CONFIG" ; then
 197                   QT_DO_PKG_CONFIG
 198                 fi
 199                 if test "$pkg_failed" != "no" ; then
 200                   QT_DO_MANUAL_CONFIG
 201                 fi
 202                 if test -z "$QT_LIB"; then
 203                   AC_MSG_ERROR([cannot find qt libraries.])
 204                 fi
 205           elif test x$USE_QT5 = xyes ; then
 206                 USE_QT6=no
 207                 USE_QT5=no
 208                 AC_SUBST([USE_QT6])
 209                 AC_SUBST([USE_QT5])
 210                 if test -n "$PKG_CONFIG" ; then
 211                   QT_DO_PKG_CONFIG
 212                 fi
 213                 if test "$pkg_failed" != "no" ; then
 214                   QT_DO_MANUAL_CONFIG
 215                 fi
 216                 if test -z "$QT_LIB"; then
 217                   AC_MSG_ERROR([cannot find qt libraries.])
 218                 fi
 219           else
 220                 AC_MSG_ERROR([cannot find qt libraries.])
 221           fi
 222         fi
 223
 224         dnl Check qt version
 225         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 226         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 227         ])
 228
 229         save_CPPFLAGS=$CPPFLAGS
 230         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 231         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 232           [lyx_qt5_config=QtGui/qtgui-config.h],
 233           [lyx_qt5_config=qconfig.h],[-])
 234         AC_CHECK_HEADER(QtGui/private/qtgui-config_p.h,
 235           [lyx_qt6_config=QtGui/private/qtgui-config_p.h],
 236           [lyx_qt6_config=qconfig.h],[-])
 237         AC_MSG_CHECKING([whether Qt uses the X Window system])
 238         if test x$USE_QT6 = xyes ; then
 239           dnl FIXME: Check whether defining QPA_XCB makes sense with Qt6
 240           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 241             [#include <$lyx_qt6_config>]
 242             [#if !defined(QT_FEATURE_xcb) || QT_FEATURE_xcb < 0]
 243             [#error Fail]
 244             [#endif]])],
 245             [AC_MSG_RESULT(yes)
 246              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 247             [AC_MSG_RESULT(no)])
 248         elif test x$USE_QT5 = xyes ; then
 249           AC_EGREP_CPP(xcb,
 250             [#include <$lyx_qt5_config>
 251             QT_QPA_DEFAULT_PLATFORM_NAME],
 252             [AC_MSG_RESULT(yes)
 253              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 254             [AC_MSG_RESULT(no)])
 255         else
 256           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 257             [#include <qglobal.h>],
 258             [#ifndef Q_WS_X11],
 259             [#error Fail],
 260             [#endif]])],
 261             qt_use_x11=yes,
 262             qt_use_x11=no)
 263           AC_MSG_RESULT($qt_use_x11)
 264           if test "x$qt_use_x11" = "xyes"; then
 265             QT_LIB="$QT_LIB -lX11"
 266           fi
 267         fi
 268         CPPFLAGS=$save_CPPFLAGS
 269
 270         QT_FIND_TOOL([QT_MOC], [moc])
 271         QT_FIND_TOOL([QT_UIC], [uic])
 272         QT_FIND_TOOL([QT_RCC], [rcc])
 273
 274         dnl Safety check
 275         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]*\).*/\1/'`
 276         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 277                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 278         fi
 279 ])
 280
 281 AC_DEFUN([QT_DO_PKG_CONFIG],
 282 [
 283         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 284         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 285         if test -n "$qt_cv_dir" ; then
 286           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 287           export PKG_CONFIG_PATH
 288         fi
 289         qt_corelibs="QtCore"
 290         qt_guilibs="QtCore QtGui QtSvg"
 291         if test "x$USE_QT5" != "xno" ; then
 292                 qt_corelibs="Qt5Core"
 293                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 294                 lyx_use_x11extras=false
 295                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 296                 if $lyx_use_x11extras; then
 297                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 298                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 299                                 [Define if you have the Qt5X11Extras module])
 300                 fi
 301                 lyx_use_winextras=false
 302                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 303                 if $lyx_use_winextras; then
 304                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 305                 fi
 306                 lyx_use_macextras=false
 307                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 308                 if $lyx_use_macextras; then
 309                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 310                 fi
 311         fi
 312         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 313         if test "$pkg_failed" = "no" ; then
 314                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 315                 AC_SUBST(QT_CORE_INCLUDES)
 316                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 317                 AC_SUBST(QT_CORE_LDFLAGS)
 318                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 319                 AC_SUBST(QT_CORE_LIB)
 320         fi
 321         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 322         if test "$pkg_failed" = "no" ; then
 323                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 324                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 325                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 326                 AC_SUBST(QT_INCLUDES)
 327                 AC_SUBST(QT_LDFLAGS)
 328                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 329                 AC_SUBST(QTLIB_VERSION)
 330                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 331                 AC_SUBST(QT_LIB)
 332                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 333         fi
 334         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 335         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 336         dnl wrong on OS X, where everything goes to --libs-only-other.
 337         dnl As a quick workaround, let us assign better values. A better patch
 338         dnl exists for next cycle.
 339         QT_CORE_LIB=$QT_CORE_LIBS
 340         QT_CORE_LDFLAGS=
 341         QT_LIB=$QT_FRONTEND_LIBS
 342         QT_LDFLAGS=
 343 ])
 344
 345 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 346 [
 347         dnl Check for X libraries
 348         case ${host} in
 349         *mingw*) ;;
 350         *) \
 351           AC_PATH_X \
 352           AC_PATH_XTRA \
 353         ;;
 354         esac
 355         case $have_x in
 356             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 357                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 358              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 359         disable) ;;
 360         esac
 361
 362         dnl flags for compilation
 363         QT_INCLUDES=
 364         QT_LDFLAGS=
 365         QT_CORE_INCLUDES=
 366         QT_CORE_LDFLAGS=
 367         if test -n "$qt_cv_includes"; then
 368                 QT_INCLUDES="-I$qt_cv_includes"
 369                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 370                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 371                 done
 372                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 373         fi
 374         case "$qt_cv_libraries" in
 375         *framework*)
 376                 QT_LDFLAGS="-F$qt_cv_libraries"
 377                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 378                 ;;
 379         "")
 380                 ;;
 381         *)
 382                 QT_LDFLAGS="-L$qt_cv_libraries"
 383                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 384                 ;;
 385         esac
 386         AC_SUBST(QT_INCLUDES)
 387         AC_SUBST(QT_CORE_INCLUDES)
 388         AC_SUBST(QT_LDFLAGS)
 389         AC_SUBST(QT_CORE_LDFLAGS)
 390
 391         QT_CHECK_COMPILE
 392
 393         QT_LIB=$qt_cv_libname;
 394         AC_SUBST(QT_LIB)
 395         AC_SUBST(QT_CORE_LIB)
 396
 397         if test -n "$qt_cv_libname"; then
 398                 QT_GET_VERSION
 399         fi
 400 ])
 401
 402 AC_DEFUN([QT6_QMAKE_CONFIG],
 403 [
 404         dnl Use first suitable qmake in PATH
 405         AC_CHECK_PROGS([QT_QMAKE], [qmake-qt6 qmake6], [qmake], $PATH)
 406         AC_MSG_CHECKING([for Qt6])
 407         qtver=`$QT_QMAKE -v | grep -o "Qt version ."`
 408         if test "$qtver" = "Qt version 6"; then
 409             qt_cv_libexec=`$QT_QMAKE -query QT_INSTALL_LIBEXECS`
 410             dnl Use a .pro file for getting qmake's variables
 411             lyx_test_qt_dir=`mktemp -d`
 412             lyx_test_qt_pro="$lyx_test_qt_dir/test.pro"
 413             lyx_test_qt_mak="$lyx_test_qt_dir/Makefile"
 414             cat > $lyx_test_qt_pro << EOF1
 415 qtHaveModule(core):             QT += core
 416 qtHaveModule(core5compat):      QT += core5compat
 417 percent.target = %
 418 percent.commands = @echo -n "\$(\$(@))\ "
 419 QMAKE_EXTRA_TARGETS += percent
 420 EOF1
 421             $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 422             QT_CORE_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 423             qt_corelibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 424             QT_CORE_LDFLAGS=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 425             if test -z "$QT_CORE_LDFLAGS"; then
 426                 QT_CORE_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 427                 QT_CORE_LIB="$qt_corelibs"
 428             else
 429                 QT_CORE_LIB=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-l" | tr '\n' ' '`
 430             fi
 431             if test -z "$QT_CORE_LIB"; then
 432                 AC_MSG_RESULT(no)
 433             else
 434                 AC_SUBST(QT_CORE_INCLUDES)
 435                 AC_SUBST(QT_CORE_LDFLAGS)
 436                 AC_SUBST(QT_CORE_LIB)
 437                 cat > $lyx_test_qt_pro << EOF2
 438 qtHaveModule(core):             QT += core
 439 qtHaveModule(core5compat):      QT += core5compat
 440 qtHaveModule(concurrent):       QT += concurrent
 441 qtHaveModule(gui):              QT += gui
 442 qtHaveModule(svg):              QT += svg
 443 qtHaveModule(svgwidgets):       QT += svgwidgets
 444 qtHaveModule(widgets):          QT += widgets
 445 percent.target = %
 446 percent.commands = @echo -n "\$(\$(@))\ "
 447 QMAKE_EXTRA_TARGETS += percent
 448 EOF2
 449                 $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 450                 QT_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 451                 qt_guilibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 452                 QT_LDFLAGS=`echo $qt_guilibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 453                 if test -z "$QT_LDFLAGS"; then
 454                     QT_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 455                     QT_LIB="$qt_guilibs"
 456                 else
 457                     QT_LIB=`echo $qt_guilibs | tr ' ' '\n' | grep -v "^-L" | tr '\n' ' '`
 458                 fi
 459                 QTLIB_VERSION=`$QT_QMAKE -v | grep "Qt version" | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 460                 if test -z "$QT_LIB"; then
 461                     AC_MSG_RESULT(no)
 462                 else
 463                     AC_MSG_RESULT(yes)
 464                     AC_SUBST(QT_INCLUDES)
 465                     AC_SUBST(QT_LDFLAGS)
 466                     AC_SUBST(QT_LIB)
 467                     AC_SUBST(QTLIB_VERSION)
 468                 fi
 469             fi
 470             rm $lyx_test_qt_pro $lyx_test_qt_mak $lyx_test_qt_dir/.qmake.stash
 471             rmdir $lyx_test_qt_dir
 472         else
 473             AC_MSG_RESULT(no)
 474         fi
 475 ])