config/qt.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 SAVE_CXXFLAGS=$CXXFLAGS
  26                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  27                 qt_corelibs="-lQtCore -lQtCore4"
  28                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  29                 if test $USE_QT6 = "yes" ; then
  30                     qt_corelibs="-lQt6Core"
  31                     qt_guilibs="-lQt6Core -lQt6Concurrent -lQt6Gui -lQt6Svg -lQt6Widgets"
  32                 else
  33                     qt_corelibs="-lQt5Core"
  34                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  35                 fi
  36                 for libname in $qt_corelibs '-framework QtCore'
  37                 do
  38                         QT_TRY_LINK($libname)
  39                         if test -n "$qt_cv_libname"; then
  40                                 QT_CORE_LIB="$qt_cv_libname"
  41                                 break;
  42                         fi
  43                 done
  44                 qt_cv_libname=
  45                 for libname in $qt_guilibs \
  46                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  47                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtSvgWidgets -framework QtWidgets -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 if test x$USE_QT6 = xyes ; then
  60                         AC_MSG_RESULT([failed, retrying with Qt5])
  61                 else
  62                         AC_MSG_RESULT([failed])
  63                         AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  64                 fi
  65         else
  66                 AC_MSG_RESULT([$qt_cv_libname])
  67         fi
  68 ])
  69
  70
  71 AC_DEFUN([QT_FIND_TOOL],
  72 [
  73         $1=
  74         qt_major=5
  75         if test "x$USE_QT6" != "xno" ; then
  76                 qt_major=6
  77         fi
  78         qt_ext="qt$qt_major"
  79
  80         if test -n "$qt_cv_libexec" ; then
  81                 AC_PATH_PROGS($1, [$2], [], $qt_cv_libexec)
  82         elif test -n "$qt_cv_bin" ; then
  83                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  84         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  85                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  86                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  87                 qtc_path=`dirname "$qtc_path"`
  88                 $2_path=`dirname "$$2_path"`
  89                 if test "$qtc_path" = "$$2_path" ; then
  90                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  91                 fi
  92         fi
  93         if test -z "$$1"; then
  94                 AC_CHECK_PROGS($1, [$2-$qt_ext $2$qt_major $2],[],$PATH)
  95         fi
  96         if test -z "$$1"; then
  97                 AC_MSG_ERROR([cannot find $2 binary.])
  98         fi
  99 ])
 100
 101
 102 dnl get Qt version we're using
 103 AC_DEFUN([QT_GET_VERSION],
 104 [
 105         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
 106         [
 107                 SAVE_CPPFLAGS=$CPPFLAGS
 108                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 109
 110                 cat > conftest.$ac_ext <<EOF
 111 #line __oline__ "configure"
 112 #include "confdefs.h"
 113 #include <qglobal.h>
 114 "%%%"QT_VERSION_STR"%%%"
 115 EOF
 116                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 117                         grep '^"%%%"'  2>/dev/null | \
 118                         sed -e 's/"%%%"//g' -e 's/"//g'`
 119                 rm -f conftest.$ac_ext
 120                 CPPFLAGS=$SAVE_CPPFLAGS
 121         ])
 122
 123         QTLIB_VERSION=$lyx_cv_qtversion
 124         AC_SUBST(QTLIB_VERSION)
 125 ])
 126
 127 dnl start here
 128 AC_DEFUN([QT_DO_IT_ALL],
 129 [
 130         dnl this variable is precious
 131         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt5])
 132
 133         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 134                 [ qt_cv_dir=`eval echo "$withval"/` ])
 135
 136         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 137                 [ qt_cv_includes=`eval echo "$withval"` ])
 138
 139         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 140                 [  qt_cv_libraries=`eval echo "$withval"` ])
 141
 142         dnl pay attention to $QTDIR unless overridden
 143         if test -z "$qt_cv_dir"; then
 144                 qt_cv_dir=$QTDIR
 145         fi
 146
 147         dnl derive inc/lib if needed
 148         if test -n "$qt_cv_dir"; then
 149                 if test -z "$qt_cv_includes"; then
 150                         qt_cv_includes=$qt_cv_dir/include
 151                 fi
 152                 if test -z "$qt_cv_libraries"; then
 153                         qt_cv_libraries=$qt_cv_dir/lib
 154                 fi
 155         fi
 156
 157         dnl compute the binary dir too
 158         if test -n "$qt_cv_dir"; then
 159                 qt_cv_bin=$qt_cv_dir/bin
 160         fi
 161
 162         dnl Preprocessor flags
 163         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 164         case ${host} in
 165         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 166         esac
 167         AC_SUBST(QT_CPPFLAGS)
 168
 169         dnl Check if it possible to do a pkg-config
 170         PKG_PROG_PKG_CONFIG
 171         dnl Not possible with Qt6 (QTBUG-86080)
 172         if test x$USE_QT6 = xno ; then
 173             if test -n "$PKG_CONFIG" ; then
 174                     QT_DO_PKG_CONFIG
 175             fi
 176             if test "$pkg_failed" != "no" ; then
 177                     QT_DO_MANUAL_CONFIG
 178             fi
 179         else
 180             QT6_QMAKE_CONFIG
 181             if test -z "$QT_LIB"; then
 182                     QT_DO_MANUAL_CONFIG
 183             fi
 184         fi
 185
 186         if test -z "$QT_LIB"; then
 187           dnl Try again with Qt5 and if configuring for Qt6/5 fails
 188           if test x$USE_QT6 = xyes ; then
 189                 USE_QT6=no
 190                 AC_SUBST([USE_QT6])
 191                 if test -n "$PKG_CONFIG" ; then
 192                   QT_DO_PKG_CONFIG
 193                 fi
 194                 if test "$pkg_failed" != "no" ; then
 195                   QT_DO_MANUAL_CONFIG
 196                 fi
 197                 if test -z "$QT_LIB"; then
 198                   AC_MSG_ERROR([cannot find qt libraries.])
 199                 fi
 200           else
 201                 AC_MSG_ERROR([cannot find qt libraries.])
 202           fi
 203         fi
 204
 205         dnl Check qt version
 206         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 207         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 208         ])
 209
 210         case $QTLIB_VERSION in
 211         6.*) if test $enable_stdlib_debug = "yes" ; then
 212                     LYX_WARNING([Compiling LyX with stdlib-debug and Qt6 library may lead to
 213    crashes. Consider dropping --enable-stdlib-debug.])
 214              fi;;
 215         esac
 216
 217
 218         save_CPPFLAGS=$CPPFLAGS
 219         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 220         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 221           [lyx_qt_config=QtGui/qtgui-config.h],
 222           [lyx_qt_config=qconfig.h])
 223         AC_MSG_CHECKING([whether Qt uses the X Window system])
 224         if test x$USE_QT6 = xyes ; then
 225           dnl FIXME: Check whether defining QPA_XCB makes sense with Qt6
 226           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 227             [#include <$lyx_qt_config>]
 228             [#if !defined(QT_FEATURE_xcb) || QT_FEATURE_xcb < 0]
 229             [#error Fail]
 230             [#endif]])],
 231             [AC_MSG_RESULT(yes)
 232              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 233             [AC_MSG_RESULT(no)])
 234         else
 235           AC_EGREP_CPP(xcb,
 236             [#include <$lyx_qt_config>
 237             QT_QPA_DEFAULT_PLATFORM_NAME],
 238             [AC_MSG_RESULT(yes)
 239              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 240             [AC_MSG_RESULT(no)])
 241         fi
 242         CPPFLAGS=$save_CPPFLAGS
 243
 244         QT_FIND_TOOL([QT_MOC], [moc])
 245         QT_FIND_TOOL([QT_UIC], [uic])
 246         QT_FIND_TOOL([QT_RCC], [rcc])
 247
 248         dnl Safety check
 249         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]*\).*/\1/'`
 250         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 251                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 252         fi
 253 ])
 254
 255 AC_DEFUN([QT_DO_PKG_CONFIG],
 256 [
 257         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 258         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 259         if test -n "$qt_cv_dir" ; then
 260           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 261           export PKG_CONFIG_PATH
 262         fi
 263         qt_corelibs="Qt5Core"
 264         qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 265         lyx_use_x11extras=false
 266         PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 267         if $lyx_use_x11extras; then
 268                 qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 269                 AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 270                         [Define if you have the Qt5X11Extras module])
 271         fi
 272         lyx_use_winextras=false
 273         PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 274         if $lyx_use_winextras; then
 275                 qt_guilibs="$qt_guilibs Qt5WinExtras"
 276         fi
 277         lyx_use_macextras=false
 278         PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 279         if $lyx_use_macextras; then
 280                 qt_guilibs="$qt_guilibs Qt5MacExtras"
 281         fi
 282         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 283         if test "$pkg_failed" = "no" ; then
 284                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 285                 AC_SUBST(QT_CORE_INCLUDES)
 286                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 287                 AC_SUBST(QT_CORE_LDFLAGS)
 288                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 289                 AC_SUBST(QT_CORE_LIB)
 290         fi
 291         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 292         if test "$pkg_failed" = "no" ; then
 293                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 294                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 295                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 296                 AC_SUBST(QT_INCLUDES)
 297                 AC_SUBST(QT_LDFLAGS)
 298                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 299                 AC_SUBST(QTLIB_VERSION)
 300                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 301                 AC_SUBST(QT_LIB)
 302                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 303         fi
 304         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 305         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 306         dnl wrong on OS X, where everything goes to --libs-only-other.
 307         dnl As a quick workaround, let us assign better values. A better patch
 308         dnl exists for next cycle.
 309         QT_CORE_LIB=$QT_CORE_LIBS
 310         QT_CORE_LDFLAGS=
 311         QT_LIB=$QT_FRONTEND_LIBS
 312         QT_LDFLAGS=
 313 ])
 314
 315 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 316 [
 317         dnl Check for X libraries
 318         case ${host} in
 319         *mingw*) ;;
 320         *) \
 321           AC_PATH_X \
 322           AC_PATH_XTRA \
 323         ;;
 324         esac
 325         case $have_x in
 326             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 327                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 328              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 329         disable) ;;
 330         esac
 331
 332         dnl flags for compilation
 333         QT_INCLUDES=
 334         QT_LDFLAGS=
 335         QT_CORE_INCLUDES=
 336         QT_CORE_LDFLAGS=
 337         if test -n "$qt_cv_includes"; then
 338                 QT_INCLUDES="-I$qt_cv_includes"
 339                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtSvgWidgets QtMacExtras; do
 340                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 341                         if test "$lyx_use_packaging" = "macosx" ; then
 342                                 QT_INCLUDES="$QT_INCLUDES -I$qt_cv_libraries/${i}.framework/Headers"
 343                         fi
 344                 done
 345                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 346         fi
 347         case "$qt_cv_libraries" in
 348         "")
 349                 ;;
 350         *)
 351                 if test "$lyx_use_packaging" = "macosx" ; then
 352                         QT_INCLUDES="$QT_INCLUDES -F$qt_cv_libraries"
 353                         QT_CORE_INCLUDES="$QT_CORE_INCLUDES -I$qt_cv_libraries/QtCore.framework/Headers -F$qt_cv_libraries"
 354                         QT_LDFLAGS="-F$qt_cv_libraries"
 355                         QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 356                 else
 357                         QT_LDFLAGS="-L$qt_cv_libraries"
 358                         QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 359                 fi
 360                 ;;
 361         esac
 362         AC_SUBST(QT_INCLUDES)
 363         AC_SUBST(QT_CORE_INCLUDES)
 364         AC_SUBST(QT_LDFLAGS)
 365         AC_SUBST(QT_CORE_LDFLAGS)
 366
 367         QT_CHECK_COMPILE
 368
 369         QT_LIB=$qt_cv_libname;
 370         AC_SUBST(QT_LIB)
 371         AC_SUBST(QT_CORE_LIB)
 372
 373         if test -n "$qt_cv_libname"; then
 374                 QT_GET_VERSION
 375         fi
 376 ])
 377
 378 AC_DEFUN([QT6_QMAKE_CONFIG],
 379 [
 380         dnl Use first suitable qmake in PATH
 381         AC_CHECK_PROGS([QT_QMAKE], [qmake-qt6 qmake6], [qmake], $PATH)
 382         AC_MSG_CHECKING([for Qt6])
 383         qtver=`$QT_QMAKE -v | grep -o "Qt version ."`
 384         if test "$qtver" = "Qt version 6"; then
 385             qt_cv_libexec=`$QT_QMAKE -query QT_INSTALL_LIBEXECS`
 386             dnl Use a .pro file for getting qmake's variables
 387             lyx_test_qt_dir=`mktemp -d`
 388             lyx_test_qt_pro="$lyx_test_qt_dir/test.pro"
 389             lyx_test_qt_mak="$lyx_test_qt_dir/Makefile"
 390             cat > $lyx_test_qt_pro << EOF1
 391 qtHaveModule(core):             QT += core
 392 percent.target = %
 393 percent.commands = @echo -n "\$(\$(@))\ "
 394 QMAKE_EXTRA_TARGETS += percent
 395 QMAKE_PROJECT_DEPTH = 0
 396 EOF1
 397             $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 398             QT_CORE_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 399             qt_corelibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 400             QT_CORE_LDFLAGS=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 401             if test -z "$QT_CORE_LDFLAGS"; then
 402                 QT_CORE_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 403                 QT_CORE_LIB="$qt_corelibs"
 404             else
 405                 QT_CORE_LIB=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-l" | tr '\n' ' '`
 406             fi
 407             if test -z "$QT_CORE_LIB"; then
 408                 AC_MSG_RESULT(no)
 409             else
 410                 AC_SUBST(QT_CORE_INCLUDES)
 411                 AC_SUBST(QT_CORE_LDFLAGS)
 412                 AC_SUBST(QT_CORE_LIB)
 413                 cat > $lyx_test_qt_pro << EOF2
 414 QMAKE_EXTRA_VARIABLES = MISSING
 415 qtHaveModule(core)              {QT += core} else {MISSING += core}
 416 qtHaveModule(concurrent)        {QT += concurrent} else {MISSING += concurrent}
 417 qtHaveModule(gui)               {QT += gui} else {MISSING += gui}
 418 qtHaveModule(gui-private)       {QT += gui-private} else {MISSING += gui-private}
 419 qtHaveModule(svg)               {QT += svg} else {MISSING += svg}
 420 qtHaveModule(svgwidgets)        {QT += svgwidgets} else {MISSING += svgwidgets}
 421 qtHaveModule(widgets)           {QT += widgets} else {MISSING += widgets}
 422 percent.target = %
 423 percent.commands = @echo -n "\$(\$(@))\ "
 424 QMAKE_EXTRA_TARGETS += percent
 425 QMAKE_PROJECT_DEPTH = 0
 426 EOF2
 427                 $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 428                 QT_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 429                 qt_guilibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 430                 QT_LDFLAGS=`echo $qt_guilibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 431                 if test -z "$QT_LDFLAGS"; then
 432                     QT_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 433                     QT_LIB="$qt_guilibs"
 434                 else
 435                     QT_LIB=`echo $qt_guilibs | tr ' ' '\n' | grep -v "^-L" | tr '\n' ' '`
 436                 fi
 437                 QTLIB_VERSION=`$QT_QMAKE -v | grep "Qt version" | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 438                 if test -z "$QT_LIB"; then
 439                     AC_MSG_RESULT(no)
 440                 else
 441                     QT_MISSING=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak EXPORT_MISSING | sed 's/^ *//'`
 442                     if test -n "$QT_MISSING"; then
 443                             AC_MSG_ERROR([Qt6 module(s) $QT_MISSING not found.])
 444                     fi
 445                     AC_MSG_RESULT(yes)
 446                     AC_SUBST(QT_INCLUDES)
 447                     AC_SUBST(QT_LDFLAGS)
 448                     AC_SUBST(QT_LIB)
 449                     AC_SUBST(QTLIB_VERSION)
 450                 fi
 451             fi
 452             rm $lyx_test_qt_pro $lyx_test_qt_mak $lyx_test_qt_dir/.qmake.stash
 453             rmdir $lyx_test_qt_dir
 454         else
 455             AC_MSG_RESULT(no)
 456         fi
 457 ])