config/qt.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 SAVE_CXXFLAGS=$CXXFLAGS
  26                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  27                 qt_corelibs="-lQtCore -lQtCore4"
  28                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  29                 if test $USE_QT5 = "yes" ; then
  30                     qt_corelibs="-lQt5Core"
  31                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  32                 fi
  33                 for libname in $qt_corelibs '-framework QtCore'
  34                 do
  35                         QT_TRY_LINK($libname)
  36                         if test -n "$qt_cv_libname"; then
  37                                 QT_CORE_LIB="$qt_cv_libname"
  38                                 break;
  39                         fi
  40                 done
  41                 qt_cv_libname=
  42                 for libname in $qt_guilibs \
  43                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  44                                '-framework QtCore -framework QtGui'
  45                 do
  46                         QT_TRY_LINK($libname)
  47                         if test -n "$qt_cv_libname"; then
  48                                 break;
  49                         fi
  50                 done
  51                 CXXFLAGS=$SAVE_CXXFLAGS
  52         ])
  53
  54         if test -z "$qt_cv_libname"; then
  55                 if test x$USE_QT5 = xyes ; then
  56                         AC_MSG_RESULT([failed, retrying with Qt4])
  57                 else
  58                         AC_MSG_RESULT([failed])
  59                         AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  60                 fi
  61         else
  62                 AC_MSG_RESULT([$qt_cv_libname])
  63         fi
  64 ])
  65
  66
  67 AC_DEFUN([QT_FIND_TOOL],
  68 [
  69         $1=
  70         qt_ext=qt4
  71         if test "x$USE_QT5" != "xno" ; then
  72                 qt_ext=qt5
  73         fi
  74
  75         if test -n "$qt_cv_bin" ; then
  76                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  77         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  78                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  79                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  80                 qtc_path=`dirname "$qtc_path"`
  81                 $2_path=`dirname "$$2_path"`
  82                 if test "$qtc_path" = "$$2_path" ; then
  83                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  84                 fi
  85         fi
  86         if test -z "$$1"; then
  87                 AC_CHECK_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  88         fi
  89         if test -z "$$1"; then
  90                 AC_MSG_ERROR([cannot find $2 binary.])
  91         fi
  92 ])
  93
  94
  95 dnl get Qt version we're using
  96 AC_DEFUN([QT_GET_VERSION],
  97 [
  98         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
  99         [
 100                 SAVE_CPPFLAGS=$CPPFLAGS
 101                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 102
 103                 cat > conftest.$ac_ext <<EOF
 104 #line __oline__ "configure"
 105 #include "confdefs.h"
 106 #include <qglobal.h>
 107 "%%%"QT_VERSION_STR"%%%"
 108 EOF
 109                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 110                         grep '^"%%%"'  2>/dev/null | \
 111                         sed -e 's/"%%%"//g' -e 's/"//g'`
 112                 rm -f conftest.$ac_ext
 113                 CPPFLAGS=$SAVE_CPPFLAGS
 114         ])
 115
 116         QTLIB_VERSION=$lyx_cv_qtversion
 117         AC_SUBST(QTLIB_VERSION)
 118 ])
 119
 120 dnl start here
 121 AC_DEFUN([QT_DO_IT_ALL],
 122 [
 123         dnl this variable is precious
 124         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 125
 126         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 127                 [ qt_cv_dir=`eval echo "$withval"/` ])
 128
 129         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 130                 [ qt_cv_includes=`eval echo "$withval"` ])
 131
 132         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 133                 [  qt_cv_libraries=`eval echo "$withval"` ])
 134
 135         dnl pay attention to $QTDIR unless overridden
 136         if test -z "$qt_cv_dir"; then
 137                 qt_cv_dir=$QTDIR
 138         fi
 139
 140         dnl derive inc/lib if needed
 141         if test -n "$qt_cv_dir"; then
 142                 if test -z "$qt_cv_includes"; then
 143                         qt_cv_includes=$qt_cv_dir/include
 144                 fi
 145                 if test -z "$qt_cv_libraries"; then
 146                         qt_cv_libraries=$qt_cv_dir/lib
 147                 fi
 148         fi
 149
 150         dnl compute the binary dir too
 151         if test -n "$qt_cv_dir"; then
 152                 qt_cv_bin=$qt_cv_dir/bin
 153         fi
 154
 155         dnl Preprocessor flags
 156         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 157         case ${host} in
 158         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 159         esac
 160         AC_SUBST(QT_CPPFLAGS)
 161
 162         dnl Check if it possible to do a pkg-config
 163         PKG_PROG_PKG_CONFIG
 164         if test -n "$PKG_CONFIG" ; then
 165                 QT_DO_PKG_CONFIG
 166         fi
 167         if test "$pkg_failed" != "no" ; then
 168                 QT_DO_MANUAL_CONFIG
 169         fi
 170
 171         if test -z "$QT_LIB"; then
 172           dnl Try again with Qt4 if configuring for Qt5 fails
 173           if test x$USE_QT5 = xyes ; then
 174                 USE_QT5=no
 175                 AC_SUBST([USE_QT5])
 176                 if test -n "$PKG_CONFIG" ; then
 177                   QT_DO_PKG_CONFIG
 178                 fi
 179                 if test "$pkg_failed" != "no" ; then
 180                   QT_DO_MANUAL_CONFIG
 181                 fi
 182                 if test -z "$QT_LIB"; then
 183                   AC_MSG_ERROR([cannot find qt libraries.])
 184                 fi
 185           else
 186                 AC_MSG_ERROR([cannot find qt libraries.])
 187           fi
 188         fi
 189
 190         dnl Check qt version
 191         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 192         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 193         ])
 194
 195         save_CPPFLAGS=$CPPFLAGS
 196         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 197         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 198           [lyx_qt5_config=QtGui/qtgui-config.h],
 199           [lyx_qt5_config=qconfig.h],[-])
 200         AC_MSG_CHECKING([whether Qt uses the X Window system])
 201         if test x$USE_QT5 = xyes ; then
 202           AC_EGREP_CPP(xcb,
 203             [#include <$lyx_qt5_config>
 204             QT_QPA_DEFAULT_PLATFORM_NAME],
 205             [AC_MSG_RESULT(yes)
 206              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 207             [AC_MSG_RESULT(no)])
 208         else
 209           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 210             [#include <qglobal.h>],
 211             [#ifndef Q_WS_X11],
 212             [#error Fail],
 213             [#endif]])],
 214             qt_use_x11=yes,
 215             qt_use_x11=no)
 216           AC_MSG_RESULT($qt_use_x11)
 217           if test "x$qt_use_x11" = "xyes"; then
 218             QT_LIB="$QT_LIB -lX11"
 219           fi
 220         fi
 221         CPPFLAGS=$save_CPPFLAGS
 222
 223         QT_FIND_TOOL([QT_MOC], [moc])
 224         QT_FIND_TOOL([QT_UIC], [uic])
 225         QT_FIND_TOOL([QT_RCC], [rcc])
 226
 227         dnl Safety check
 228         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 229         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 230                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 231         fi
 232 ])
 233
 234 AC_DEFUN([QT_DO_PKG_CONFIG],
 235 [
 236         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 237         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 238         if test -n "$qt_cv_dir" ; then
 239           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 240           export PKG_CONFIG_PATH
 241         fi
 242         qt_corelibs="QtCore"
 243         qt_guilibs="QtCore QtGui QtSvg"
 244         if test "x$USE_QT5" != "xno" ; then
 245                 qt_corelibs="Qt5Core"
 246                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 247                 lyx_use_x11extras=false
 248                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 249                 if $lyx_use_x11extras; then
 250                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 251                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 252                                 [Define if you have the Qt5X11Extras module])
 253                 fi
 254                 lyx_use_winextras=false
 255                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 256                 if $lyx_use_winextras; then
 257                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 258                 fi
 259                 lyx_use_macextras=false
 260                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 261                 if $lyx_use_macextras; then
 262                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 263                 fi
 264         fi
 265         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 266         if test "$pkg_failed" = "no" ; then
 267                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 268                 AC_SUBST(QT_CORE_INCLUDES)
 269                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 270                 AC_SUBST(QT_CORE_LDFLAGS)
 271                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 272                 AC_SUBST(QT_CORE_LIB)
 273         fi
 274         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 275         if test "$pkg_failed" = "no" ; then
 276                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 277                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 278                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 279                 AC_SUBST(QT_INCLUDES)
 280                 AC_SUBST(QT_LDFLAGS)
 281                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 282                 AC_SUBST(QTLIB_VERSION)
 283                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 284                 AC_SUBST(QT_LIB)
 285                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 286         fi
 287         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 288         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 289         dnl wrong on OS X, where everything goes to --libs-only-other.
 290         dnl As a quick workaround, let us assign better values. A better patch
 291         dnl exists for next cycle.
 292         QT_CORE_LIB=$QT_CORE_LIBS
 293         QT_CORE_LDFLAGS=
 294         QT_LIB=$QT_FRONTEND_LIBS
 295         QT_LDFLAGS=
 296 ])
 297
 298 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 299 [
 300         dnl Check for X libraries
 301         case ${host} in
 302         *mingw*) ;;
 303         *) \
 304           AC_PATH_X \
 305           AC_PATH_XTRA \
 306         ;;
 307         esac
 308         case $have_x in
 309             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 310                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 311              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 312         disable) ;;
 313         esac
 314
 315         dnl flags for compilation
 316         QT_INCLUDES=
 317         QT_LDFLAGS=
 318         QT_CORE_INCLUDES=
 319         QT_CORE_LDFLAGS=
 320         if test -n "$qt_cv_includes"; then
 321                 QT_INCLUDES="-I$qt_cv_includes"
 322                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 323                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 324                 done
 325                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 326         fi
 327         case "$qt_cv_libraries" in
 328         *framework*)
 329                 QT_LDFLAGS="-F$qt_cv_libraries"
 330                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 331                 ;;
 332         "")
 333                 ;;
 334         *)
 335                 QT_LDFLAGS="-L$qt_cv_libraries"
 336                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 337                 ;;
 338         esac
 339         AC_SUBST(QT_INCLUDES)
 340         AC_SUBST(QT_CORE_INCLUDES)
 341         AC_SUBST(QT_LDFLAGS)
 342         AC_SUBST(QT_CORE_LDFLAGS)
 343
 344         QT_CHECK_COMPILE
 345
 346         QT_LIB=$qt_cv_libname;
 347         AC_SUBST(QT_LIB)
 348         AC_SUBST(QT_CORE_LIB)
 349
 350         if test -n "$qt_cv_libname"; then
 351                 QT_GET_VERSION
 352         fi
 353 ])