config/qt.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 SAVE_CXXFLAGS=$CXXFLAGS
  26                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  27                 qt_corelibs="-lQtCore -lQtCore4"
  28                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  29                 if test $USE_QT6 = "yes" ; then
  30                     qt_corelibs="-lQt6Core -lQt6Core5Compat"
  31                     qt_guilibs="-lQt6Core -lQt6Core5Compat -lQt6Concurrent -lQt6Gui -lQt6Svg -lQt6Widgets"
  32                 elif test $USE_QT5 = "yes" ; then
  33                     qt_corelibs="-lQt5Core"
  34                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  35                 fi
  36                 for libname in $qt_corelibs '-framework QtCore'
  37                 do
  38                         QT_TRY_LINK($libname)
  39                         if test -n "$qt_cv_libname"; then
  40                                 QT_CORE_LIB="$qt_cv_libname"
  41                                 break;
  42                         fi
  43                 done
  44                 qt_cv_libname=
  45                 for libname in $qt_guilibs \
  46                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  47                                '-framework QtCore -framework QtGui'
  48                 do
  49                         QT_TRY_LINK($libname)
  50                         if test -n "$qt_cv_libname"; then
  51                                 break;
  52                         fi
  53                 done
  54                 CXXFLAGS=$SAVE_CXXFLAGS
  55         ])
  56
  57         if test -z "$qt_cv_libname"; then
  58                 if test x$USE_QT6 = xyes ; then
  59                         AC_MSG_RESULT([failed, retrying with Qt5])
  60                 elif test x$USE_QT5 = xyes ; then
  61                         AC_MSG_RESULT([failed, retrying with Qt4])
  62                 else
  63                         AC_MSG_RESULT([failed])
  64                         AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  65                 fi
  66         else
  67                 AC_MSG_RESULT([$qt_cv_libname])
  68         fi
  69 ])
  70
  71
  72 AC_DEFUN([QT_FIND_TOOL],
  73 [
  74         $1=
  75         qt_ext=qt4
  76         if test "x$USE_QT6" != "xno" ; then
  77                 qt_ext=qt6
  78         elif test "x$USE_QT5" != "xno" ; then
  79                 qt_ext=qt5
  80         fi
  81
  82         if test -n "$qt_cv_bin" ; then
  83                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  84         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  85                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  86                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  87                 qtc_path=`dirname "$qtc_path"`
  88                 $2_path=`dirname "$$2_path"`
  89                 if test "$qtc_path" = "$$2_path" ; then
  90                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  91                 fi
  92         fi
  93         if test -z "$$1"; then
  94                 AC_CHECK_PROGS($1, [$2-$qt_ext $2],[],$PATH)
  95         fi
  96         if test -z "$$1"; then
  97                 AC_MSG_ERROR([cannot find $2 binary.])
  98         fi
  99 ])
 100
 101
 102 dnl get Qt version we're using
 103 AC_DEFUN([QT_GET_VERSION],
 104 [
 105         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
 106         [
 107                 SAVE_CPPFLAGS=$CPPFLAGS
 108                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 109
 110                 cat > conftest.$ac_ext <<EOF
 111 #line __oline__ "configure"
 112 #include "confdefs.h"
 113 #include <qglobal.h>
 114 "%%%"QT_VERSION_STR"%%%"
 115 EOF
 116                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 117                         grep '^"%%%"'  2>/dev/null | \
 118                         sed -e 's/"%%%"//g' -e 's/"//g'`
 119                 rm -f conftest.$ac_ext
 120                 CPPFLAGS=$SAVE_CPPFLAGS
 121         ])
 122
 123         QTLIB_VERSION=$lyx_cv_qtversion
 124         AC_SUBST(QTLIB_VERSION)
 125 ])
 126
 127 dnl start here
 128 AC_DEFUN([QT_DO_IT_ALL],
 129 [
 130         dnl this variable is precious
 131         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 132
 133         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 134                 [ qt_cv_dir=`eval echo "$withval"/` ])
 135
 136         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 137                 [ qt_cv_includes=`eval echo "$withval"` ])
 138
 139         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 140                 [  qt_cv_libraries=`eval echo "$withval"` ])
 141
 142         dnl pay attention to $QTDIR unless overridden
 143         if test -z "$qt_cv_dir"; then
 144                 qt_cv_dir=$QTDIR
 145         fi
 146
 147         dnl derive inc/lib if needed
 148         if test -n "$qt_cv_dir"; then
 149                 if test -z "$qt_cv_includes"; then
 150                         qt_cv_includes=$qt_cv_dir/include
 151                 fi
 152                 if test -z "$qt_cv_libraries"; then
 153                         qt_cv_libraries=$qt_cv_dir/lib
 154                 fi
 155         fi
 156
 157         dnl compute the binary dir too
 158         if test -n "$qt_cv_dir"; then
 159                 qt_cv_bin=$qt_cv_dir/bin
 160         fi
 161
 162         dnl Preprocessor flags
 163         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 164         case ${host} in
 165         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 166         esac
 167         AC_SUBST(QT_CPPFLAGS)
 168
 169         dnl Check if it possible to do a pkg-config
 170         PKG_PROG_PKG_CONFIG
 171         dnl Not possible with Qt6 (QTBUG-86080)
 172         if test x$USE_QT6 = xno ; then
 173             if test -n "$PKG_CONFIG" ; then
 174                     QT_DO_PKG_CONFIG
 175             fi
 176             if test "$pkg_failed" != "no" ; then
 177                     QT_DO_MANUAL_CONFIG
 178             fi
 179         else
 180             QT6_QMAKE_CONFIG
 181             if test -z "$QT_LIB"; then
 182                     QT_DO_MANUAL_CONFIG
 183             fi
 184         fi
 185
 186         if test -z "$QT_LIB"; then
 187           dnl Try again with Qt5 and then Qt4 if configuring for Qt6/5 fails
 188           if test x$USE_QT6 = xyes ; then
 189                 USE_QT6=no
 190                 USE_QT5=yes
 191                 AC_SUBST([USE_QT6])
 192                 AC_SUBST([USE_QT5])
 193                 if test -n "$PKG_CONFIG" ; then
 194                   QT_DO_PKG_CONFIG
 195                 fi
 196                 if test "$pkg_failed" != "no" ; then
 197                   QT_DO_MANUAL_CONFIG
 198                 fi
 199                 if test -z "$QT_LIB"; then
 200                   AC_MSG_ERROR([cannot find qt libraries.])
 201                 fi
 202           elif test x$USE_QT5 = xyes ; then
 203                 USE_QT6=no
 204                 USE_QT5=no
 205                 AC_SUBST([USE_QT6])
 206                 AC_SUBST([USE_QT5])
 207                 if test -n "$PKG_CONFIG" ; then
 208                   QT_DO_PKG_CONFIG
 209                 fi
 210                 if test "$pkg_failed" != "no" ; then
 211                   QT_DO_MANUAL_CONFIG
 212                 fi
 213                 if test -z "$QT_LIB"; then
 214                   AC_MSG_ERROR([cannot find qt libraries.])
 215                 fi
 216           else
 217                 AC_MSG_ERROR([cannot find qt libraries.])
 218           fi
 219         fi
 220
 221         dnl Check qt version
 222         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 223         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 224         ])
 225
 226         save_CPPFLAGS=$CPPFLAGS
 227         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 228         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 229           [lyx_qt5_config=QtGui/qtgui-config.h],
 230           [lyx_qt5_config=qconfig.h],[-])
 231         AC_CHECK_HEADER(QtGui/private/qtgui-config_p.h,
 232           [lyx_qt6_config=QtGui/private/qtgui-config_p.h],
 233           [lyx_qt6_config=qconfig.h],[-])
 234         AC_MSG_CHECKING([whether Qt uses the X Window system])
 235         if test x$USE_QT6 = xyes ; then
 236           dnl FIXME: Check whether defining QPA_XCB makes sense with Qt6
 237           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 238             [#include <$lyx_qt6_config>]
 239             [#if !defined(QT_FEATURE_xcb) || QT_FEATURE_xcb < 0]
 240             [#error Fail]
 241             [#endif]])],
 242             [AC_MSG_RESULT(yes)
 243              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 244             [AC_MSG_RESULT(no)])
 245         elif test x$USE_QT5 = xyes ; then
 246           AC_EGREP_CPP(xcb,
 247             [#include <$lyx_qt5_config>
 248             QT_QPA_DEFAULT_PLATFORM_NAME],
 249             [AC_MSG_RESULT(yes)
 250              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 251             [AC_MSG_RESULT(no)])
 252         else
 253           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 254             [#include <qglobal.h>],
 255             [#ifndef Q_WS_X11],
 256             [#error Fail],
 257             [#endif]])],
 258             qt_use_x11=yes,
 259             qt_use_x11=no)
 260           AC_MSG_RESULT($qt_use_x11)
 261           if test "x$qt_use_x11" = "xyes"; then
 262             QT_LIB="$QT_LIB -lX11"
 263           fi
 264         fi
 265         CPPFLAGS=$save_CPPFLAGS
 266
 267         QT_FIND_TOOL([QT_MOC], [moc])
 268         QT_FIND_TOOL([QT_UIC], [uic])
 269         QT_FIND_TOOL([QT_RCC], [rcc])
 270
 271         dnl Safety check
 272         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 273         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 274                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 275         fi
 276 ])
 277
 278 AC_DEFUN([QT_DO_PKG_CONFIG],
 279 [
 280         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 281         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 282         if test -n "$qt_cv_dir" ; then
 283           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 284           export PKG_CONFIG_PATH
 285         fi
 286         qt_corelibs="QtCore"
 287         qt_guilibs="QtCore QtGui QtSvg"
 288         if test "x$USE_QT5" != "xno" ; then
 289                 qt_corelibs="Qt5Core"
 290                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 291                 lyx_use_x11extras=false
 292                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 293                 if $lyx_use_x11extras; then
 294                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 295                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 296                                 [Define if you have the Qt5X11Extras module])
 297                 fi
 298                 lyx_use_winextras=false
 299                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 300                 if $lyx_use_winextras; then
 301                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 302                 fi
 303                 lyx_use_macextras=false
 304                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 305                 if $lyx_use_macextras; then
 306                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 307                 fi
 308         fi
 309         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 310         if test "$pkg_failed" = "no" ; then
 311                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 312                 AC_SUBST(QT_CORE_INCLUDES)
 313                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 314                 AC_SUBST(QT_CORE_LDFLAGS)
 315                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 316                 AC_SUBST(QT_CORE_LIB)
 317         fi
 318         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 319         if test "$pkg_failed" = "no" ; then
 320                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 321                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 322                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 323                 AC_SUBST(QT_INCLUDES)
 324                 AC_SUBST(QT_LDFLAGS)
 325                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 326                 AC_SUBST(QTLIB_VERSION)
 327                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 328                 AC_SUBST(QT_LIB)
 329                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 330         fi
 331         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 332         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 333         dnl wrong on OS X, where everything goes to --libs-only-other.
 334         dnl As a quick workaround, let us assign better values. A better patch
 335         dnl exists for next cycle.
 336         QT_CORE_LIB=$QT_CORE_LIBS
 337         QT_CORE_LDFLAGS=
 338         QT_LIB=$QT_FRONTEND_LIBS
 339         QT_LDFLAGS=
 340 ])
 341
 342 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 343 [
 344         dnl Check for X libraries
 345         case ${host} in
 346         *mingw*) ;;
 347         *) \
 348           AC_PATH_X \
 349           AC_PATH_XTRA \
 350         ;;
 351         esac
 352         case $have_x in
 353             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 354                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 355              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 356         disable) ;;
 357         esac
 358
 359         dnl flags for compilation
 360         QT_INCLUDES=
 361         QT_LDFLAGS=
 362         QT_CORE_INCLUDES=
 363         QT_CORE_LDFLAGS=
 364         if test -n "$qt_cv_includes"; then
 365                 QT_INCLUDES="-I$qt_cv_includes"
 366                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtMacExtras; do
 367                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 368                 done
 369                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 370         fi
 371         case "$qt_cv_libraries" in
 372         *framework*)
 373                 QT_LDFLAGS="-F$qt_cv_libraries"
 374                 QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 375                 ;;
 376         "")
 377                 ;;
 378         *)
 379                 QT_LDFLAGS="-L$qt_cv_libraries"
 380                 QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 381                 ;;
 382         esac
 383         AC_SUBST(QT_INCLUDES)
 384         AC_SUBST(QT_CORE_INCLUDES)
 385         AC_SUBST(QT_LDFLAGS)
 386         AC_SUBST(QT_CORE_LDFLAGS)
 387
 388         QT_CHECK_COMPILE
 389
 390         QT_LIB=$qt_cv_libname;
 391         AC_SUBST(QT_LIB)
 392         AC_SUBST(QT_CORE_LIB)
 393
 394         if test -n "$qt_cv_libname"; then
 395                 QT_GET_VERSION
 396         fi
 397 ])
 398
 399 AC_DEFUN([QT6_QMAKE_CONFIG],
 400 [
 401         AC_MSG_CHECKING([for Qt6])
 402         dnl Use first qmake in PATH
 403         ver=`qmake -v | grep -o "Qt version ."`
 404         if test "$ver" = "Qt version 6"; then
 405             dnl Use a .pro file for getting qmake's variables
 406             lyx_test_qt_dir=`mktemp -d`
 407             lyx_test_qt_pro="$lyx_test_qt_dir/test.pro"
 408             lyx_test_qt_mak="$lyx_test_qt_dir/Makefile"
 409             cat > $lyx_test_qt_pro << EOF1
 410 qtHaveModule(core):             QT += core
 411 qtHaveModule(core5compat):      QT += core5compat
 412 percent.target = %
 413 percent.commands = @echo -n "\$(\$(@))\ "
 414 QMAKE_EXTRA_TARGETS += percent
 415 EOF1
 416             qmake $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 417             QT_CORE_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 418             qt_corelibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 419             QT_CORE_LDFLAGS=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 420             if test -z "$QT_CORE_LDFLAGS"; then
 421                 QT_CORE_LDFLAGS="-L`qmake -query QT_INSTALL_LIBS`"
 422                 QT_CORE_LIB="$qt_corelibs"
 423             else
 424                 QT_CORE_LIB=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-l" | tr '\n' ' '`
 425             fi
 426             if test -z "$QT_CORE_LIB"; then
 427                 AC_MSG_RESULT(no)
 428             else
 429                 AC_SUBST(QT_CORE_INCLUDES)
 430                 AC_SUBST(QT_CORE_LDFLAGS)
 431                 AC_SUBST(QT_CORE_LIB)
 432                 cat > $lyx_test_qt_pro << EOF2
 433 qtHaveModule(core):             QT += core
 434 qtHaveModule(core5compat):      QT += core5compat
 435 qtHaveModule(concurrent):       QT += concurrent
 436 qtHaveModule(gui):              QT += gui
 437 qtHaveModule(svg):              QT += svg
 438 qtHaveModule(widgets):          QT += widgets
 439 percent.target = %
 440 percent.commands = @echo -n "\$(\$(@))\ "
 441 QMAKE_EXTRA_TARGETS += percent
 442 EOF2
 443                 qmake $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 444                 QT_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 445                 qt_guilibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 446                 QT_LDFLAGS=`echo $qt_guilibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 447                 if test -z "$QT_LDFLAGS"; then
 448                     QT_LDFLAGS="-L`qmake -query QT_INSTALL_LIBS`"
 449                     QT_LIB="$qt_guilibs"
 450                 else
 451                     QT_LIB=`echo $qt_guilibs | tr ' ' '\n' | grep -e "^-l" | tr '\n' ' '`
 452                 fi
 453                 QTLIB_VERSION=`qmake -v | grep "Qt version" | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 454                 if test -z "$QT_LIB"; then
 455                     AC_MSG_RESULT(no)
 456                 else
 457                     AC_MSG_RESULT(yes)
 458                     AC_SUBST(QT_INCLUDES)
 459                     AC_SUBST(QT_LDFLAGS)
 460                     AC_SUBST(QT_LIB)
 461                     AC_SUBST(QTLIB_VERSION)
 462                 fi
 463             fi
 464             rm $lyx_test_qt_pro $lyx_test_qt_mak $lyx_test_qt_dir/.qmake.stash
 465             rmdir $lyx_test_qt_dir
 466         else
 467             AC_MSG_RESULT(no)
 468         fi
 469 ])