config/qt.m4

   1 dnl check a particular libname
   2 AC_DEFUN([QT_TRY_LINK],
   3 [
   4         SAVE_LIBS="$LIBS"
   5         LIBS="$LIBS $1"
   6         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
   7         #include <qglobal.h>
   8         #include <qstring.h>
   9                 ]], [[
  10         QString s("mangle_failure");
  11         #if (QT_VERSION < 400)
  12         break_me_(\\\);
  13         #endif
  14         ]])],[qt_cv_libname=$1],[])
  15         LIBS="$SAVE_LIBS"
  16 ])
  17
  18 dnl check we can do a compile
  19 AC_DEFUN([QT_CHECK_COMPILE],
  20 [
  21         AC_MSG_CHECKING([for Qt library name])
  22
  23         AC_CACHE_VAL(qt_cv_libname,
  24         [
  25                 SAVE_CXXFLAGS=$CXXFLAGS
  26                 CXXFLAGS="$CXXFLAGS $QT_INCLUDES $QT_LDFLAGS"
  27                 qt_corelibs="-lQtCore -lQtCore4"
  28                 qt_guilibs="'-lQtCore -lQtGui' '-lQtCore4 -lQtGui4'"
  29                 if test $USE_QT6 = "yes" ; then
  30                     qt_corelibs="-lQt6Core -lQt6Core5Compat"
  31                     qt_guilibs="-lQt6Core -lQt6Core5Compat -lQt6Concurrent -lQt6Gui -lQt6Svg -lQt6Widgets"
  32                 elif test $USE_QT5 = "yes" ; then
  33                     qt_corelibs="-lQt5Core"
  34                     qt_guilibs="-lQt5Core -lQt5Concurrent -lQt5Gui -lQt5Svg -lQt5Widgets"
  35                 fi
  36                 for libname in $qt_corelibs '-framework QtCore'
  37                 do
  38                         QT_TRY_LINK($libname)
  39                         if test -n "$qt_cv_libname"; then
  40                                 QT_CORE_LIB="$qt_cv_libname"
  41                                 break;
  42                         fi
  43                 done
  44                 qt_cv_libname=
  45                 for libname in $qt_guilibs \
  46                                '-framework QtCore -framework QtConcurrent -framework QtSvg -framework QtWidgets -framework QtMacExtras -framework QtGui'\
  47                                '-framework QtCore -framework QtConcurrent -framework QtCore5Compat -framework QtSvg -framework QtSvgWidgets -framework QtWidgets -framework QtGui'\
  48                                '-framework QtCore -framework QtGui'
  49                 do
  50                         QT_TRY_LINK($libname)
  51                         if test -n "$qt_cv_libname"; then
  52                                 break;
  53                         fi
  54                 done
  55                 CXXFLAGS=$SAVE_CXXFLAGS
  56         ])
  57
  58         if test -z "$qt_cv_libname"; then
  59                 if test x$USE_QT6 = xyes ; then
  60                         AC_MSG_RESULT([failed, retrying with Qt5])
  61                 elif test x$USE_QT5 = xyes ; then
  62                         AC_MSG_RESULT([failed, retrying with Qt4])
  63                 else
  64                         AC_MSG_RESULT([failed])
  65                         AC_MSG_ERROR([cannot compile a simple Qt executable. Check you have the right \$QTDIR.])
  66                 fi
  67         else
  68                 AC_MSG_RESULT([$qt_cv_libname])
  69         fi
  70 ])
  71
  72
  73 AC_DEFUN([QT_FIND_TOOL],
  74 [
  75         $1=
  76         qt_major=4
  77         if test "x$USE_QT6" != "xno" ; then
  78                 qt_major=6
  79         elif test "x$USE_QT5" != "xno" ; then
  80                 qt_major=5
  81         fi
  82         qt_ext="qt$qt_major"
  83
  84         if test -n "$qt_cv_libexec" ; then
  85                 AC_PATH_PROGS($1, [$2], [], $qt_cv_libexec)
  86         elif test -n "$qt_cv_bin" ; then
  87                 AC_PATH_PROGS($1, [$2], [], $qt_cv_bin)
  88         elif qtchooser -l 2>/dev/null | grep -q ^$qt_ext\$ >/dev/null ; then
  89                 AC_PATH_PROG(qtc_path, qtchooser, [], [$PATH])
  90                 AC_PATH_PROG($2_path, $2, [], [$PATH])
  91                 qtc_path=`dirname "$qtc_path"`
  92                 $2_path=`dirname "$$2_path"`
  93                 if test "$qtc_path" = "$$2_path" ; then
  94                         AC_CHECK_PROG($1, $2, [$2 -qt=$qt_ext],, [$PATH])
  95                 fi
  96         fi
  97         if test -z "$$1"; then
  98                 AC_CHECK_PROGS($1, [$2-$qt_ext $2$qt_major $2],[],$PATH)
  99         fi
 100         if test -z "$$1"; then
 101                 AC_MSG_ERROR([cannot find $2 binary.])
 102         fi
 103 ])
 104
 105
 106 dnl get Qt version we're using
 107 AC_DEFUN([QT_GET_VERSION],
 108 [
 109         AC_CACHE_CHECK([Qt version],lyx_cv_qtversion,
 110         [
 111                 SAVE_CPPFLAGS=$CPPFLAGS
 112                 CPPFLAGS="$CPPFLAGS $QT_INCLUDES"
 113
 114                 cat > conftest.$ac_ext <<EOF
 115 #line __oline__ "configure"
 116 #include "confdefs.h"
 117 #include <qglobal.h>
 118 "%%%"QT_VERSION_STR"%%%"
 119 EOF
 120                 lyx_cv_qtversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 121                         grep '^"%%%"'  2>/dev/null | \
 122                         sed -e 's/"%%%"//g' -e 's/"//g'`
 123                 rm -f conftest.$ac_ext
 124                 CPPFLAGS=$SAVE_CPPFLAGS
 125         ])
 126
 127         QTLIB_VERSION=$lyx_cv_qtversion
 128         AC_SUBST(QTLIB_VERSION)
 129 ])
 130
 131 dnl start here
 132 AC_DEFUN([QT_DO_IT_ALL],
 133 [
 134         dnl this variable is precious
 135         AC_ARG_VAR(QTDIR, [the place where the Qt files are, e.g. /usr/lib/qt4])
 136
 137         AC_ARG_WITH(qt-dir, [AS_HELP_STRING([--with-qt-dir], [where the root of Qt is installed])],
 138                 [ qt_cv_dir=`eval echo "$withval"/` ])
 139
 140         AC_ARG_WITH(qt-includes, [AS_HELP_STRING([--with-qt-includes], [where the Qt includes are])],
 141                 [ qt_cv_includes=`eval echo "$withval"` ])
 142
 143         AC_ARG_WITH(qt-libraries, [AS_HELP_STRING([--with-qt-libraries], [where the Qt library is installed])],
 144                 [  qt_cv_libraries=`eval echo "$withval"` ])
 145
 146         dnl pay attention to $QTDIR unless overridden
 147         if test -z "$qt_cv_dir"; then
 148                 qt_cv_dir=$QTDIR
 149         fi
 150
 151         dnl derive inc/lib if needed
 152         if test -n "$qt_cv_dir"; then
 153                 if test -z "$qt_cv_includes"; then
 154                         qt_cv_includes=$qt_cv_dir/include
 155                 fi
 156                 if test -z "$qt_cv_libraries"; then
 157                         qt_cv_libraries=$qt_cv_dir/lib
 158                 fi
 159         fi
 160
 161         dnl compute the binary dir too
 162         if test -n "$qt_cv_dir"; then
 163                 qt_cv_bin=$qt_cv_dir/bin
 164         fi
 165
 166         dnl Preprocessor flags
 167         QT_CPPFLAGS="-DQT_NO_STL -DQT_NO_KEYWORDS"
 168         case ${host} in
 169         *mingw*) QT_CPPFLAGS="-DQT_DLL $QT_CPPFLAGS";;
 170         esac
 171         AC_SUBST(QT_CPPFLAGS)
 172
 173         dnl Check if it possible to do a pkg-config
 174         PKG_PROG_PKG_CONFIG
 175         dnl Not possible with Qt6 (QTBUG-86080)
 176         if test x$USE_QT6 = xno ; then
 177             if test -n "$PKG_CONFIG" ; then
 178                     QT_DO_PKG_CONFIG
 179             fi
 180             if test "$pkg_failed" != "no" ; then
 181                     QT_DO_MANUAL_CONFIG
 182             fi
 183         else
 184             QT6_QMAKE_CONFIG
 185             if test -z "$QT_LIB"; then
 186                     QT_DO_MANUAL_CONFIG
 187             fi
 188         fi
 189
 190         if test -z "$QT_LIB"; then
 191           dnl Try again with Qt5 and then Qt4 if configuring for Qt6/5 fails
 192           if test x$USE_QT6 = xyes ; then
 193                 USE_QT6=no
 194                 USE_QT5=yes
 195                 AC_SUBST([USE_QT6])
 196                 AC_SUBST([USE_QT5])
 197                 if test -n "$PKG_CONFIG" ; then
 198                   QT_DO_PKG_CONFIG
 199                 fi
 200                 if test "$pkg_failed" != "no" ; then
 201                   QT_DO_MANUAL_CONFIG
 202                 fi
 203                 if test -z "$QT_LIB"; then
 204                   AC_MSG_ERROR([cannot find qt libraries.])
 205                 fi
 206           elif test x$USE_QT5 = xyes ; then
 207                 USE_QT6=no
 208                 USE_QT5=no
 209                 AC_SUBST([USE_QT6])
 210                 AC_SUBST([USE_QT5])
 211                 if test -n "$PKG_CONFIG" ; then
 212                   QT_DO_PKG_CONFIG
 213                 fi
 214                 if test "$pkg_failed" != "no" ; then
 215                   QT_DO_MANUAL_CONFIG
 216                 fi
 217                 if test -z "$QT_LIB"; then
 218                   AC_MSG_ERROR([cannot find qt libraries.])
 219                 fi
 220           else
 221                 AC_MSG_ERROR([cannot find qt libraries.])
 222           fi
 223         fi
 224
 225         dnl Check qt version
 226         AS_VERSION_COMPARE($QTLIB_VERSION, $1,
 227         [AC_MSG_ERROR([LyX requires at least version $1 of Qt. Only version $QTLIB_VERSION has been found.])
 228         ])
 229
 230         save_CPPFLAGS=$CPPFLAGS
 231         CPPFLAGS="$save_CPPFLAGS $QT_CORE_INCLUDES"
 232         AC_CHECK_HEADER(QtGui/qtgui-config.h,
 233           [lyx_qt5_config=QtGui/qtgui-config.h],
 234           [lyx_qt5_config=qconfig.h])
 235         AC_CHECK_HEADER(QtGui/private/qtgui-config_p.h,
 236           [lyx_qt6_config=QtGui/private/qtgui-config_p.h],
 237           [lyx_qt6_config=qconfig.h])
 238         AC_MSG_CHECKING([whether Qt uses the X Window system])
 239         if test x$USE_QT6 = xyes ; then
 240           dnl FIXME: Check whether defining QPA_XCB makes sense with Qt6
 241           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 242             [#include <$lyx_qt6_config>]
 243             [#if !defined(QT_FEATURE_xcb) || QT_FEATURE_xcb < 0]
 244             [#error Fail]
 245             [#endif]])],
 246             [AC_MSG_RESULT(yes)
 247              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 248             [AC_MSG_RESULT(no)])
 249         elif test x$USE_QT5 = xyes ; then
 250           AC_EGREP_CPP(xcb,
 251             [#include <$lyx_qt5_config>
 252             QT_QPA_DEFAULT_PLATFORM_NAME],
 253             [AC_MSG_RESULT(yes)
 254              AC_DEFINE(QPA_XCB, 1, [Define if Qt uses the X Window System])],
 255             [AC_MSG_RESULT(no)])
 256         else
 257           AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 258             [#include <qglobal.h>],
 259             [#ifndef Q_WS_X11],
 260             [#error Fail],
 261             [#endif]])],
 262             qt_use_x11=yes,
 263             qt_use_x11=no)
 264           AC_MSG_RESULT($qt_use_x11)
 265           if test "x$qt_use_x11" = "xyes"; then
 266             QT_LIB="$QT_LIB -lX11"
 267           fi
 268         fi
 269         CPPFLAGS=$save_CPPFLAGS
 270
 271         QT_FIND_TOOL([QT_MOC], [moc])
 272         QT_FIND_TOOL([QT_UIC], [uic])
 273         QT_FIND_TOOL([QT_RCC], [rcc])
 274
 275         dnl Safety check
 276         mocqtver=`$QT_MOC -v 2>&1 | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]*\).*/\1/'`
 277         if test "x$mocqtver" != "x$QTLIB_VERSION"; then
 278                 LYX_WARNING([The found moc compiler is for Qt $mocqtver but the Qt library version is $QTLIB_VERSION.])
 279         fi
 280 ])
 281
 282 AC_DEFUN([QT_DO_PKG_CONFIG],
 283 [
 284         dnl tell pkg-config to look also in $qt_cv_dir/lib.
 285         save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
 286         if test -n "$qt_cv_dir" ; then
 287           PKG_CONFIG_PATH=$qt_cv_dir/lib:$qt_cv_dir/lib/pkgconfig:$PKG_CONFIG_PATH
 288           export PKG_CONFIG_PATH
 289         fi
 290         qt_corelibs="QtCore"
 291         qt_guilibs="QtCore QtGui QtSvg"
 292         if test "x$USE_QT5" != "xno" ; then
 293                 qt_corelibs="Qt5Core"
 294                 qt_guilibs="Qt5Core Qt5Concurrent Qt5Gui Qt5Svg Qt5Widgets"
 295                 lyx_use_x11extras=false
 296                 PKG_CHECK_EXISTS(Qt5X11Extras, [lyx_use_x11extras=true], [])
 297                 if $lyx_use_x11extras; then
 298                         qt_guilibs="$qt_guilibs Qt5X11Extras xcb"
 299                         AC_DEFINE(HAVE_QT5_X11_EXTRAS, 1,
 300                                 [Define if you have the Qt5X11Extras module])
 301                 fi
 302                 lyx_use_winextras=false
 303                 PKG_CHECK_EXISTS(Qt5WinExtras, [lyx_use_winextras=true], [])
 304                 if $lyx_use_winextras; then
 305                         qt_guilibs="$qt_guilibs Qt5WinExtras"
 306                 fi
 307                 lyx_use_macextras=false
 308                 PKG_CHECK_EXISTS(Qt5MacExtras, [lyx_use_macextras=true], [])
 309                 if $lyx_use_macextras; then
 310                         qt_guilibs="$qt_guilibs Qt5MacExtras"
 311                 fi
 312         fi
 313         PKG_CHECK_MODULES(QT_CORE, $qt_corelibs,,[:])
 314         if test "$pkg_failed" = "no" ; then
 315                 QT_CORE_INCLUDES=$QT_CORE_CFLAGS
 316                 AC_SUBST(QT_CORE_INCLUDES)
 317                 QT_CORE_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_corelibs`
 318                 AC_SUBST(QT_CORE_LDFLAGS)
 319                 QT_CORE_LIB=`$PKG_CONFIG --libs-only-l $qt_corelibs`
 320                 AC_SUBST(QT_CORE_LIB)
 321         fi
 322         PKG_CHECK_MODULES(QT_FRONTEND, $qt_guilibs,,[:])
 323         if test "$pkg_failed" = "no" ; then
 324                 QT_INCLUDES=$QT_FRONTEND_CFLAGS
 325                 dnl QT_LDFLAGS=$QT_FRONTEND_LIBS
 326                 QT_LDFLAGS=`$PKG_CONFIG --libs-only-L $qt_guilibs`
 327                 AC_SUBST(QT_INCLUDES)
 328                 AC_SUBST(QT_LDFLAGS)
 329                 QTLIB_VERSION=`$PKG_CONFIG --modversion $qt_corelibs`
 330                 AC_SUBST(QTLIB_VERSION)
 331                 QT_LIB=`$PKG_CONFIG --libs-only-l $qt_guilibs`
 332                 AC_SUBST(QT_LIB)
 333                 dnl LIBS="$LIBS `$PKG_CONFIG --libs-only-other $qt_guilibs`"
 334         fi
 335         PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 336         dnl Actually, the values of QT_LIB and QT_CORE_LIB can be completely
 337         dnl wrong on OS X, where everything goes to --libs-only-other.
 338         dnl As a quick workaround, let us assign better values. A better patch
 339         dnl exists for next cycle.
 340         QT_CORE_LIB=$QT_CORE_LIBS
 341         QT_CORE_LDFLAGS=
 342         QT_LIB=$QT_FRONTEND_LIBS
 343         QT_LDFLAGS=
 344 ])
 345
 346 AC_DEFUN([QT_DO_MANUAL_CONFIG],
 347 [
 348         dnl Check for X libraries
 349         case ${host} in
 350         *mingw*) ;;
 351         *) \
 352           AC_PATH_X \
 353           AC_PATH_XTRA \
 354         ;;
 355         esac
 356         case $have_x in
 357             yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 358                  CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 359              no) AC_MSG_ERROR([cannot find X window libraries and/or headers.]);;
 360         disable) ;;
 361         esac
 362
 363         dnl flags for compilation
 364         QT_INCLUDES=
 365         QT_LDFLAGS=
 366         QT_CORE_INCLUDES=
 367         QT_CORE_LDFLAGS=
 368         if test -n "$qt_cv_includes"; then
 369                 QT_INCLUDES="-I$qt_cv_includes"
 370                 for i in Qt QtCore QtGui QtWidgets QtSvg QtConcurrent QtSvgWidgets QtCore5Compat QtMacExtras; do
 371                         QT_INCLUDES="$QT_INCLUDES -I$qt_cv_includes/$i"
 372                         if test "$lyx_use_packaging" = "macosx" ; then
 373                                 QT_INCLUDES="$QT_INCLUDES -I$qt_cv_libraries/${i}.framework/Headers"
 374                         fi
 375                 done
 376                 QT_CORE_INCLUDES="-I$qt_cv_includes -I$qt_cv_includes/QtCore"
 377         fi
 378         case "$qt_cv_libraries" in
 379         "")
 380                 ;;
 381         *)
 382                 if test "$lyx_use_packaging" = "macosx" ; then
 383                         QT_INCLUDES="$QT_INCLUDES -F$qt_cv_libraries"
 384                         QT_CORE_INCLUDES="$QT_CORE_INCLUDES -I$qt_cv_libraries/QtCore.framework/Headers -F$qt_cv_libraries"
 385                         QT_LDFLAGS="-F$qt_cv_libraries"
 386                         QT_CORE_LDFLAGS="-F$qt_cv_libraries"
 387                 else
 388                         QT_LDFLAGS="-L$qt_cv_libraries"
 389                         QT_CORE_LDFLAGS="-L$qt_cv_libraries"
 390                 fi
 391                 ;;
 392         esac
 393         AC_SUBST(QT_INCLUDES)
 394         AC_SUBST(QT_CORE_INCLUDES)
 395         AC_SUBST(QT_LDFLAGS)
 396         AC_SUBST(QT_CORE_LDFLAGS)
 397
 398         QT_CHECK_COMPILE
 399
 400         QT_LIB=$qt_cv_libname;
 401         AC_SUBST(QT_LIB)
 402         AC_SUBST(QT_CORE_LIB)
 403
 404         if test -n "$qt_cv_libname"; then
 405                 QT_GET_VERSION
 406         fi
 407 ])
 408
 409 AC_DEFUN([QT6_QMAKE_CONFIG],
 410 [
 411         dnl Use first suitable qmake in PATH
 412         AC_CHECK_PROGS([QT_QMAKE], [qmake-qt6 qmake6], [qmake], $PATH)
 413         AC_MSG_CHECKING([for Qt6])
 414         qtver=`$QT_QMAKE -v | grep -o "Qt version ."`
 415         if test "$qtver" = "Qt version 6"; then
 416             qt_cv_libexec=`$QT_QMAKE -query QT_INSTALL_LIBEXECS`
 417             dnl Use a .pro file for getting qmake's variables
 418             lyx_test_qt_dir=`mktemp -d`
 419             lyx_test_qt_pro="$lyx_test_qt_dir/test.pro"
 420             lyx_test_qt_mak="$lyx_test_qt_dir/Makefile"
 421             cat > $lyx_test_qt_pro << EOF1
 422 qtHaveModule(core):             QT += core
 423 qtHaveModule(core5compat):      QT += core5compat
 424 percent.target = %
 425 percent.commands = @echo -n "\$(\$(@))\ "
 426 QMAKE_EXTRA_TARGETS += percent
 427 QMAKE_PROJECT_DEPTH = 0
 428 EOF1
 429             $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 430             QT_CORE_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 431             qt_corelibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 432             QT_CORE_LDFLAGS=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 433             if test -z "$QT_CORE_LDFLAGS"; then
 434                 QT_CORE_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 435                 QT_CORE_LIB="$qt_corelibs"
 436             else
 437                 QT_CORE_LIB=`echo $qt_corelibs | tr ' ' '\n' | grep -e "^-l" | tr '\n' ' '`
 438             fi
 439             if test -z "$QT_CORE_LIB"; then
 440                 AC_MSG_RESULT(no)
 441             else
 442                 AC_SUBST(QT_CORE_INCLUDES)
 443                 AC_SUBST(QT_CORE_LDFLAGS)
 444                 AC_SUBST(QT_CORE_LIB)
 445                 cat > $lyx_test_qt_pro << EOF2
 446 qtHaveModule(core):             QT += core
 447 qtHaveModule(core5compat):      QT += core5compat
 448 qtHaveModule(concurrent):       QT += concurrent
 449 qtHaveModule(gui):              QT += gui gui-private
 450 qtHaveModule(svg):              QT += svg
 451 qtHaveModule(svgwidgets):       QT += svgwidgets
 452 qtHaveModule(widgets):          QT += widgets
 453 percent.target = %
 454 percent.commands = @echo -n "\$(\$(@))\ "
 455 QMAKE_EXTRA_TARGETS += percent
 456 QMAKE_PROJECT_DEPTH = 0
 457 EOF2
 458                 $QT_QMAKE $lyx_test_qt_pro -o $lyx_test_qt_mak 1>/dev/null 2>&1
 459                 QT_INCLUDES=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak INCPATH | sed 's/-I\. //g'`
 460                 qt_guilibs=`cd $lyx_test_qt_dir; make -s -f $lyx_test_qt_mak LIBS`
 461                 QT_LDFLAGS=`echo $qt_guilibs | tr ' ' '\n' | grep -e "^-L" | tr '\n' ' '`
 462                 if test -z "$QT_LDFLAGS"; then
 463                     QT_LDFLAGS="-L`$QT_QMAKE -query QT_INSTALL_LIBS`"
 464                     QT_LIB="$qt_guilibs"
 465                 else
 466                     QT_LIB=`echo $qt_guilibs | tr ' ' '\n' | grep -v "^-L" | tr '\n' ' '`
 467                 fi
 468                 QTLIB_VERSION=`$QT_QMAKE -v | grep "Qt version" | sed -e 's/.*\([[0-9]]\.[[0-9]]*\.[[0-9]]\).*/\1/'`
 469                 if test -z "$QT_LIB"; then
 470                     AC_MSG_RESULT(no)
 471                 else
 472                     AC_MSG_RESULT(yes)
 473                     AC_SUBST(QT_INCLUDES)
 474                     AC_SUBST(QT_LDFLAGS)
 475                     AC_SUBST(QT_LIB)
 476                     AC_SUBST(QTLIB_VERSION)
 477                 fi
 478             fi
 479             rm $lyx_test_qt_pro $lyx_test_qt_mak $lyx_test_qt_dir/.qmake.stash
 480             rmdir $lyx_test_qt_dir
 481         else
 482             AC_MSG_RESULT(no)
 483         fi
 484 ])