config/progtest.m4

   1 # Search path for a program which passes the given test.
   2 # Ulrich Drepper <drepper@cygnus.com>, 1996.
   3 #
   4 # This file can be copied and used freely without restrictions.  It can
   5 # be used in projects which are not available under the GNU Public License
   6 # but which still want to provide support for the GNU gettext functionality.
   7 # Please note that the actual code is *not* freely available.
   8
   9 # serial 1
  10
  11 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
  12 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
  13 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
  14 [case "`uname -s 2> /dev/null`" in
  15 OS/2)
  16   PATH=`echo -E "$PATH" | sed 's+\\\\+/+g'`
  17   PATH_IFS=';'
  18   EXE_EXT='.exe'
  19   CMD_EXT='.cmd'
  20   ;;
  21 *)
  22   PATH_IFS=':'
  23   EXE_EXT=''
  24   CMD_EXT=''
  25   ;;
  26 esac]
  27 [# Extract the first word of "$2", so it can be a program name with args.
  28 set dummy $2; ac_word=[$]2
  29 AC_MSG_CHECKING([for $ac_word])
  30 AC_CACHE_VAL(ac_cv_path_$1,
  31 [case "[$]$1" in
  32   /*)
  33   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
  34   ;;
  35   *)
  36   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}$PATH_IFS"
  37   for ac_dir in ifelse([$5], , $PATH, [$5]); do
  38     test -z "$ac_dir" && ac_dir=.
  39     if test -f $ac_dir/$ac_word \
  40          -o -f $ac_dir/$ac_word$EXE_EXT \
  41          -o -f $ac_dir/$ac_word$CMD_EXT; then
  42       if [$3]; then
  43         ac_cv_path_$1="$ac_dir/$ac_word"
  44         break
  45       fi
  46     fi
  47   done
  48   IFS="$ac_save_ifs"
  49 dnl If no 4th arg is given, leave the cache variable unset,
  50 dnl so AC_PATH_PROGS will keep looking.
  51 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
  52 ])dnl
  53   ;;
  54 esac])dnl
  55 $1="$ac_cv_path_$1"
  56 if test -n "[$]$1"; then
  57   AC_MSG_RESULT([$]$1)
  58 else
  59   AC_MSG_RESULT(no)
  60 fi
  61 AC_SUBST($1)dnl
  62 ])