config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171
 172 dnl Usage: LYX_CXX_USE_REGEX(cxx11_flags)
 173 dnl decide whether we want to use std::regex and set the
 174 dnl LYX_USE_STD_REGEX accordingly.
 175 dnl the extra cxx11 flags have to be passed to the preprocessor. They are
 176 dnl not plainly added to AM_CPPFLAGS because then the objc compiler (mac)
 177 dnl would fail.
 178 AC_DEFUN([LYX_CXX_USE_REGEX],
 179 [lyx_std_regex=no
 180  if test $lyx_use_cxx11 = yes; then
 181    save_CPPFLAGS=$CPPFLAGS
 182    # we want to pass -std=c++11 to clang/cpp if necessary
 183    CPPFLAGS="$AM_CPPFLAGS $1 $CPPFLAGS"
 184    save_CXXFLAGS=$CXXFLAGS
 185    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 186    AC_LANG_PUSH(C++)
 187    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 188    AC_LANG_POP(C++)
 189    CXXFLAGS=$save_CXXFLAGS
 190    CPPFLAGS=$save_CPPFLAGS
 191    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 192      AC_MSG_CHECKING([for correct regex implementation])
 193      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 194        dnl <regex> in gcc is unusable in versions less than 4.9.0
 195        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 196        case $gxx_version in
 197          4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 198          *) ;;
 199        esac
 200      fi
 201    fi
 202    AC_MSG_RESULT([$lyx_std_regex])
 203  fi
 204
 205  if test $lyx_std_regex = yes ; then
 206   lyx_flags="$lyx_flags std-regex"
 207   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 208  fi
 209  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 210 ])
 211
 212
 213 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 214 AC_DEFUN([LYX_LIB_STDCXX],
 215 [AC_CACHE_CHECK([whether STL is libstdc++],
 216                [lyx_cv_lib_stdcxx],
 217 [AC_TRY_COMPILE([#include<vector>], [
 218 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 219             this is not libstdc++
 220 #endif
 221 ],
 222 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 223 ])
 224
 225
 226 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 227 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 228 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 229 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 230                [lyx_cv_lib_stdcxx_cxx11_abi],
 231 [AC_TRY_COMPILE([#include<vector>], [
 232 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 233             this is not libstdc++ using the C++11 ABI
 234 #endif
 235 ],
 236 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 237 ])
 238
 239
 240 AC_DEFUN([LYX_PROG_CXX],
 241 [AC_REQUIRE([AC_PROG_CXX])
 242 AC_REQUIRE([AC_PROG_CXXCPP])
 243
 244 AC_LANG_PUSH(C++)
 245 LYX_PROG_CLANG
 246 LYX_LIB_STDCXX
 247 LYX_LIB_STDCXX_CXX11_ABI
 248 AC_LANG_POP(C++)
 249
 250 if test $lyx_cv_lib_stdcxx = "yes" ; then
 251   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 252     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 253   else
 254     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 255   fi
 256 else
 257   if test $lyx_cv_prog_clang = "yes" ; then
 258     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 259   fi
 260 fi
 261
 262 ### We might want to get or shut warnings.
 263 AC_ARG_ENABLE(warnings,
 264   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 265   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 266         enable_warnings=yes;
 267     else
 268         enable_warnings=no;
 269     fi;])
 270 if test x$enable_warnings = xyes ; then
 271   lyx_flags="$lyx_flags warnings"
 272 fi
 273
 274 ### We might want to disable debug
 275 AC_ARG_ENABLE(debug,
 276   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 277   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 278 )
 279
 280 AC_ARG_ENABLE(stdlib-debug,
 281   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 282   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 283           [enable_stdlib_debug=no])]
 284 )
 285
 286 ### set up optimization
 287 AC_ARG_ENABLE(optimization,
 288     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 289     enable_optimization=yes;)
 290 case $enable_optimization in
 291     yes)
 292         if test $lyx_devel_version = yes ; then
 293             lyx_optim=-O
 294         else
 295             lyx_optim=-O2
 296         fi;;
 297     no) lyx_optim=;;
 298     *) lyx_optim=${enable_optimization};;
 299 esac
 300
 301 AC_ARG_ENABLE(cxx11,
 302   AC_HELP_STRING([--disable-cxx11],[disable C++11 mode (default: enabled for known good compilers)]),,
 303   enable_cxx11=auto;)
 304
 305 AC_ARG_ENABLE(assertions,
 306   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 307   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 308           [enable_assertions=no])]
 309 )
 310 if test "x$enable_assertions" = xyes ; then
 311    lyx_flags="$lyx_flags assertions"
 312    AC_DEFINE(ENABLE_ASSERTIONS,1,
 313     [Define if you want assertions to be enabled in the code])
 314 fi
 315
 316 # set the compiler options correctly.
 317 if test x$GXX = xyes; then
 318   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 319   if test x$CLANG = xno; then
 320     dnl Useful for global version info
 321     gxx_version=`${CXX} -dumpversion`
 322     CXX_VERSION="($gxx_version)"
 323   else
 324     gxx_version=clang
 325   fi
 326
 327   AM_CXXFLAGS="$lyx_optim"
 328   if test x$enable_debug = xyes ; then
 329       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 330   fi
 331   if test $build_type = gprof ; then
 332     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 333     AM_LDFLAGS="$AM_LDFLAGS -pg"
 334   fi
 335   if test $build_type = profiling ; then
 336     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 337   fi
 338
 339   if test x$USE_QT5 = xyes ; then
 340       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 341   fi
 342   dnl Warnings are for preprocessor too
 343   if test x$enable_warnings = xyes ; then
 344       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 345   fi
 346   case $gxx_version in
 347       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 348   esac
 349   if test x$enable_stdlib_debug = xyes ; then
 350     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 351     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 352     case $gxx_version in
 353       *)
 354         lyx_flags="$lyx_flags stdlib-debug"
 355         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 356         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 357         ;;
 358     esac
 359   fi
 360   dnl enable_cxx11 can be yes/no/auto.
 361   dnl By default, it is auto and we enable C++11 when possible
 362   if test x$enable_cxx11 != xno ; then
 363     case $gxx_version in
 364       4.0*|4.1*|4.2*)
 365          if test x$enable_cxx11 = xyes; then
 366             AC_ERROR([There is no C++11 support in gcc 4.2 or older])
 367          fi;;
 368       4.3*|4.4*|4.5*|4.6*)
 369         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 370         dnl The source code relies on that.
 371         cxx11_flags="-std=c++0x";;
 372       clang)
 373         dnl presumably all clang versions support c++11.
 374         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 375         cxx11_flags="-std=c++11"
 376         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 377       *)
 378         AS_CASE([$host], [*cygwin*],
 379                 [cxx11_flags="-std=gnu++11"],
 380                 [cxx11_flags="-std=c++11"]);;
 381     esac
 382     # cxx11_flags is useful when running preprocessor alone
 383     # (see detection of regex).
 384     AM_CXXFLAGS="$cxx11_flags $AM_CXXFLAGS"
 385   fi
 386 fi
 387
 388 LYX_CXX_CXX11
 389 if test $lyx_use_cxx11 = yes; then
 390   if test x$GXX = xyes; then
 391     dnl We still use auto_ptr, which is obsoleted. Shut off the warnings.
 392     AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-declarations"
 393   fi
 394 fi
 395 LYX_CXX_USE_REGEX([$cxx11_flags])
 396 ])
 397
 398 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 399 dnl        be used.
 400 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 401         AC_MSG_CHECKING([whether to use included boost library])
 402         AC_ARG_WITH(included-boost,
 403             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 404             [lyx_cv_with_included_boost=$withval],
 405             [lyx_cv_with_included_boost=yes])
 406         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 407         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 408         if test x$lyx_cv_with_included_boost = xyes ; then
 409             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 410             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 411         else
 412             AC_LANG_PUSH(C++)
 413             save_LIBS=$LIBS
 414
 415             AC_MSG_CHECKING([for multithreaded boost libraries])
 416             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 417             AC_LINK_IFELSE(
 418                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 419                         [boost::signal<void ()> s;])],
 420                 [AC_MSG_RESULT([yes])
 421                  BOOST_MT="-mt"],
 422                 [AC_MSG_RESULT([no])
 423                  AC_MSG_CHECKING([for plain boost libraries])
 424                  LIBS="$save_LIBS -lboost_signals"
 425                  AC_LINK_IFELSE(
 426                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 427                              [boost::signal<void ()> s;])],
 428                      [AC_MSG_RESULT([yes])
 429                       BOOST_MT=""],
 430                      [AC_MSG_RESULT([no])
 431                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 432                  ])
 433             ])
 434             LIBS=$save_LIBS
 435             AC_LANG_POP(C++)
 436             BOOST_INCLUDES=
 437             if test $lyx_std_regex = yes ; then
 438               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 439             else
 440               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 441             fi
 442
 443             dnl In general, system boost libraries are incompatible with
 444             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 445             dnl details.
 446             if test $enable_stdlib_debug = "yes" ; then
 447                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 448    crashes. Consider using --disable-stdlib-debug or removing
 449    --without-included-boost.])
 450             fi
 451         fi
 452         AC_SUBST(BOOST_INCLUDES)
 453         AC_SUBST(BOOST_LIBS)
 454 ])
 455
 456
 457 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 458 dnl        necessary APIs are available to print callstacks.
 459 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 460 [AC_CACHE_CHECK([whether printing callstack is possible],
 461                [lyx_cv_callstack_printing],
 462 [AC_TRY_COMPILE([
 463 #include <execinfo.h>
 464 #include <cxxabi.h>
 465 ], [
 466         void* array[200];
 467         size_t size = backtrace(array, 200);
 468         backtrace_symbols(array, size);
 469         int status = 0;
 470         abi::__cxa_demangle("abcd", 0, 0, &status);
 471 ],
 472 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 473 if test x"$lyx_cv_callstack_printing" = xyes; then
 474   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 475             [Define if callstack can be printed])
 476 fi
 477 ])
 478
 479
 480 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 481 dnl        be used.
 482 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 483         AC_MSG_CHECKING([whether to use included MyThes library])
 484         AC_ARG_WITH(included-mythes,
 485             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 486             [lyx_cv_with_included_mythes=$withval],
 487             [lyx_cv_with_included_mythes=yes])
 488         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 489         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 490         if test x$lyx_cv_with_included_mythes != xyes ; then
 491                 AC_LANG_PUSH(C++)
 492                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 493                 if test x$ac_cv_header_mythes_h != xyes; then
 494                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 495                 fi
 496                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 497                 if test x$lyx_mythes != xyes; then
 498                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 499                 fi
 500                 AC_LANG_POP(C++)
 501                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 502                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 503                 fi
 504                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 505                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 506                 AC_SUBST(MYTHES_LIBS)
 507         fi
 508 ])
 509
 510
 511 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 512 dnl                       [default-yes-value])
 513 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 514 dnl  resulting directory name in 'dir-var-name'.
 515 AC_DEFUN([LYX_WITH_DIR],[
 516   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 517   AC_MSG_CHECKING([for $2])
 518   if test -z "$with_$3"; then
 519      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 520   else
 521     test "x$with_$3" = xyes && with_$3=$5
 522     lyx_cv_$3="$with_$3"
 523   fi
 524   AC_MSG_RESULT($lyx_cv_$3)])
 525
 526
 527 dnl Usage: LYX_LOOP_DIR(value,action)
 528 dnl Executes action for values of variable `dir' in `values'. `values' can
 529 dnl use ":" as a separator.
 530 AC_DEFUN([LYX_LOOP_DIR],[
 531 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 532 for dir in `eval "echo $1"`; do
 533   if test ! "$dir" = NONE; then
 534     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 535     $2
 536   fi
 537 done
 538 IFS=$ac_save_ifs
 539 ])
 540
 541
 542 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 543 dnl var-name.
 544 AC_DEFUN([LYX_ADD_LIB_DIR],[
 545 $1="${$1} -L$2"
 546 if test "`(uname) 2>/dev/null`" = SunOS &&
 547     uname -r | grep '^5' >/dev/null; then
 548   if test $ac_cv_prog_gxx = yes ; then
 549     $1="${$1} -Wl[,]-R$2"
 550   else
 551     $1="${$1} -R$2"
 552   fi
 553 fi])
 554
 555
 556 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 557 dnl var-name.
 558 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 559
 560 ### Check for a headers existence and location iff it exists
 561 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 562 ## It almost works.  I've tried a few variations but they give errors
 563 ## of one sort or other: bad substitution or file not found etc.  The
 564 ## actual header _is_ found though and the cache variable is set however
 565 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 566 ## reason.
 567 ## Additionally, autoheader can't figure out what to use as the name in
 568 ## the config.h.in file so we need to write our own entries there -- one for
 569 ## each header in the form PATH_HEADER_NAME_H
 570 ##
 571 AC_DEFUN([LYX_PATH_HEADER],
 572 [ AC_CHECK_HEADER($1,[
 573   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 574 ### the only remaining problem is getting the second parameter to this
 575 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 576 ### of $ac_safe being printed.
 577   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 578   [ cat > conftest.$ac_ext <<EOF
 579 #line __oline__ "configure"
 580 #include "confdefs.h"
 581
 582 #include <$1>
 583 EOF
 584 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 585   grep $1  2>/dev/null | \
 586   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 587 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 588 rm -f conftest*])
 589   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 590 ])
 591 ### end of LYX_PATH_HEADER
 592
 593 ## Check what kind of packaging should be used at install time.
 594 ## The default is autodetected.
 595 AC_DEFUN([LYX_USE_PACKAGING],
 596 [AC_MSG_CHECKING([what packaging should be used])
 597 AC_ARG_WITH(packaging,
 598   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 599                             Possible values: posix, windows, macosx, haiku])],
 600   [lyx_use_packaging="$withval"], [
 601   case $host in
 602     *-apple-darwin*) lyx_use_packaging=macosx ;;
 603     *-pc-mingw32*) lyx_use_packaging=windows ;;
 604     *haiku*) lyx_use_packaging=haiku ;;
 605     *) lyx_use_packaging=posix ;;
 606   esac])
 607 AC_MSG_RESULT($lyx_use_packaging)
 608 lyx_install_posix=false
 609 lyx_install_macosx=false
 610 lyx_install_cygwin=false
 611 lyx_install_windows=false
 612 case $lyx_use_packaging in
 613    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 614            PACKAGE=LyX${version_suffix}
 615            default_prefix="/Applications/${PACKAGE}.app"
 616            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 617            bindir='${prefix}/Contents/MacOS'
 618            libdir='${prefix}/Contents/Resources'
 619            datarootdir='${prefix}/Contents/Resources'
 620            pkgdatadir='${datadir}'
 621            mandir='${datadir}/man'
 622            lyx_install_macosx=true ;;
 623   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 624            PACKAGE=LyX${version_suffix}
 625            default_prefix="C:/Program Files/${PACKAGE}"
 626            bindir='${prefix}/bin'
 627            libdir='${prefix}/Resources'
 628            datarootdir='${prefix}/Resources'
 629            pkgdatadir='${datadir}'
 630            mandir='${prefix}/Resources/man'
 631            lyx_install_windows=true ;;
 632     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 633            PACKAGE=lyx${version_suffix}
 634            program_suffix=$version_suffix
 635            pkgdatadir='${datadir}/${PACKAGE}'
 636            default_prefix=$ac_default_prefix
 637            case ${host} in
 638              *cygwin*) lyx_install_cygwin=true ;;
 639              *apple-darwin*) lyx_install_macosx=true ;;
 640            esac
 641            lyx_install_posix=true ;;
 642         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 643            PACKAGE=lyx${version_suffix}
 644            program_suffix=$version_suffix
 645            pkgdatadir='${datadir}/${PACKAGE}'
 646            default_prefix=$ac_default_prefix
 647            lyx_install_posix=true ;;
 648     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 649 esac
 650 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 651 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 652 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 653 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 654 AC_SUBST(pkgdatadir)
 655 AC_SUBST(program_suffix)
 656 ])
 657
 658
 659 ## ------------------------------------------------------------------------
 660 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 661 ## one or two arguments.
 662 ##
 663 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 664 ## ------------------------------------------------------------------------
 665 ##
 666 AC_DEFUN([AC_FUNC_MKDIR],
 667 [AC_CHECK_FUNCS([mkdir _mkdir])
 668 AC_CACHE_CHECK([whether mkdir takes one argument],
 669                [ac_cv_mkdir_takes_one_arg],
 670 [AC_TRY_COMPILE([
 671 #include <sys/stat.h>
 672 #if HAVE_UNISTD_H
 673 #  include <unistd.h>
 674 #endif
 675 ], [mkdir (".");],
 676 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 677 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 678   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 679             [Define if mkdir takes only one argument.])
 680 fi
 681 ])
 682
 683
 684 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 685 dnl (which may be a relative path, and need not refer to any existing
 686 dnl entity).
 687
 688 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 689 dnl native Win32 path name, (but with slashes, not backslashes).
 690
 691 dnl On any other system, it is simply the result which would be obtained
 692 dnl if PATHNAME represented an existing directory, and the pwd command was
 693 dnl executed in that directory.
 694 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 695 [ac_dir="$2"
 696  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 697     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 698  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 699  do
 700    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 701  done
 702  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 703  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 704  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 705    s?/*$[]??'`
 706 ])
 707
 708 dnl this is used by the macro blow to general a proper config.h.in entry
 709 m4_define([LYX_AH_CHECK_DECL],
 710 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 711   [Define if you have the prototype for function `$1'])])
 712
 713 dnl Check things are declared in headers to avoid errors or warnings.
 714 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 715 dnl Defines HAVE_DECL_{FUNCTION}
 716 AC_DEFUN([LYX_CHECK_DECL],
 717 [LYX_AH_CHECK_DECL($1)
 718 for ac_header in $2
 719 do
 720   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 721   AC_EGREP_HEADER($1, $ac_header,
 722       [AC_MSG_RESULT(yes)
 723        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 724        break],
 725       [AC_MSG_RESULT(no)])
 726 done])
 727
 728 dnl this is used by the macro below to generate a proper config.h.in entry
 729 m4_define([LYX_AH_CHECK_DEF],
 730 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 731   [Define to 1 if `$1' is defined in `$2'])])
 732
 733 dnl Check whether name is defined in header by using it in codesnippet.
 734 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 735 dnl Defines HAVE_DEF_{NAME}
 736 AC_DEFUN([LYX_CHECK_DEF],
 737 [LYX_AH_CHECK_DEF($1, $2)
 738  AC_MSG_CHECKING([whether $1 is defined by header $2])
 739  AC_TRY_COMPILE([#include <$2>], [$3],
 740      lyx_have_def_name=yes,
 741      lyx_have_def_name=no)
 742  AC_MSG_RESULT($lyx_have_def_name)
 743  if test "x$lyx_have_def_name" = xyes; then
 744    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 745  fi
 746 ])
 747
 748 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 749 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 750 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 751 AC_DEFUN([LYX_SET_VERSION_INFO],
 752 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 753  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 754  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 755  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 756  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 757  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 758  test "x$lyx_patch" = "x" && lyx_patch=0
 759  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 760  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 761  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 762  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 763  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 764  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 765  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 766  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 767 ])
 768
 769 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 770 # ---------------------------------------------------------------------------
 771 # Copied from autoconf 2.68, added a check that python version is < 3.0
 772 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 773 # Run ACTION-IF-FALSE otherwise.
 774 # This test uses sys.hexversion instead of the string equivalent (first
 775 # word of sys.version), in order to cope with versions such as 2.2c1.
 776 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 777 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 778  [prog="import sys
 779 # split strings by '.' and convert to numeric.  Append some zeros
 780 # because we need at least 4 digits for the hex conversion.
 781 # map returns an iterator in Python 3.0 and a list in 2.x
 782 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 783 minverhex = 0
 784 maxverhex = 50331648 # = 3.0.0.0
 785 # xrange is not present in Python 3.0 and range returns an iterator
 786 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 787 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 788   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])