config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN(LYX_CHECK_VERSION,[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN(LYX_VERSION_SUFFIX,[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN(LYX_ERROR,[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN(LYX_WARNING,[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN(LYX_LIB_ERROR,[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN(LYX_CHECK_ERRORS,[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 EOF
  85 else
  86
  87 if test x$lyx_warning = xyes; then
  88 cat <<EOF
  89 === The following minor problems have been detected by configure.
  90 === Please check the messages below before running 'make'.
  91 === (see the section 'Problems' in the INSTALL file)
  92 $lyx_warning_txt
  93 EOF
  94 fi
  95 cat <<EOF
  96 Configuration of LyX was successful.
  97 Type 'make' to compile the program,
  98 and then 'make install' to install it.
  99 EOF
 100 fi])
 101
 102
 103 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 104 dnl
 105 define(LYX_SEARCH_PROG,[dnl
 106 for ac_prog in $2 ; do
 107 # Extract the first word of "$ac_prog", so it can be a program name with args.
 108   set dummy $ac_prog ; ac_word=$[2]
 109   if test -z "[$]$1"; then
 110     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 111     for ac_dir in $PATH; do
 112       test -z "$ac_dir" && ac_dir=.
 113       if test -f [$ac_dir/$ac_word]; then
 114         $1="$ac_prog"
 115         break
 116       fi
 117     done
 118     IFS="$ac_save_ifs"
 119   fi
 120
 121   if test -n "[$]$1"; then
 122     ac_result=yes
 123   else
 124     ac_result=no
 125   fi
 126   ifelse($3,,,[$3])
 127   test -n "[$]$1" && break
 128 done
 129 ])dnl
 130
 131
 132 AC_DEFUN([LYX_PROG_CXX_WORKS],
 133 [rm -f conftest.C
 134 cat >conftest.C <<EOF
 135 class foo {
 136    // we require the mutable keyword
 137    mutable int bar;
 138  };
 139  // we require namespace support
 140  namespace baz {
 141    int bar;
 142  }
 143  int main() {
 144    return(0);
 145  }
 146 EOF
 147 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 148 rm -f conftest.C conftest.o conftest.obj || true
 149 ])
 150
 151
 152 AC_DEFUN(LYX_PROG_CXX,
 153 [AC_MSG_CHECKING([for a good enough C++ compiler])
 154 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 155
 156 if test -z "$CXX" ; then
 157   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 158 fi
 159 AC_MSG_RESULT($CXX)
 160
 161 AC_PROG_CXX
 162
 163 ### We might want to get or shut warnings.
 164 AC_ARG_ENABLE(warnings,
 165   [  --enable-warnings       tell the compiler to display more warnings],,
 166   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 167         enable_warnings=yes;
 168     else
 169         enable_warnings=no;
 170     fi;])
 171 if test x$enable_warnings = xyes ; then
 172   lyx_flags="$lyx_flags warnings"
 173   AC_DEFINE(WITH_WARNINGS, 1,
 174   [Define this if you want to see the warning directives put here and
 175    there by the developpers to get attention])
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   [  --enable-debug          enable debug information],,
 181   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 182         enable_debug=yes;
 183     else
 184         enable_debug=no;
 185     fi;])
 186
 187 ### set up optimization
 188 AC_ARG_ENABLE(optimization,
 189   [  --enable-optimization[=value]   enable compiler optimisation],,
 190         enable_optimization=yes;)
 191 case $enable_optimization in
 192   yes) lyx_opt=-O;;
 193    no) lyx_opt=;;
 194     *) lyx_opt=${enable_optimization};;
 195 esac
 196
 197 # set the debug flags correctly.
 198 if test x$GXX = xyes; then
 199   dnl Useful for global version info
 200   gxx_version=`${CXX} -dumpversion`
 201   CXX_VERSION="($gxx_version)"
 202
 203   if test "$ac_test_CXXFLAGS" = set; then
 204     CXXFLAGS="$ac_save_CXXFLAGS"
 205   else
 206     case $gxx_version in
 207       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 208       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 209       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 210       3.0*)    CXXFLAGS="$lyx_opt";;
 211       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 212       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 213       *)       CXXFLAGS="$lyx_opt";;
 214     esac
 215     if test x$enable_debug = xyes ; then
 216         CXXFLAGS="-g $CXXFLAGS"
 217     fi
 218   fi
 219   if test x$enable_warnings = xyes ; then
 220     case $gxx_version in
 221         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 222         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 223         3.1*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 224         *)      CXXFLAGS="$CXXFLAGS -W -Wall";;
 225     esac
 226     if test $lyx_devel_version = yes ; then
 227       case $gxx_version in
 228           2.95.*) ;;
 229           2.96*) ;;
 230           *) CXXFLAGS="$CXXFLAGS -Winline";;
 231       esac
 232     fi
 233   fi
 234 fi])dnl
 235
 236
 237 dnl NOT USED CURRENTLY*************************************
 238 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 239 dnl   supports RTTI
 240 AC_DEFUN(LYX_CXX_RTTI,[
 241 ### Check whether the compiler supports runtime type information
 242 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 243  [AC_TRY_RUN([
 244 class rtti {
 245 public:
 246    virtual int tag() { return 0; }
 247 };
 248 class derived1 : public rtti {
 249 public:
 250     int tag() { return 1; }
 251 };
 252 class derived2 : public rtti {
 253 public:
 254     int tag() { return 2; }
 255 };
 256 int main() {
 257     derived1 * foo1 = new derived1();
 258     derived2 * foo2 = new derived2();
 259     rtti * bar = foo1;
 260     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 261     if (bar1 == 0)
 262         exit(1);
 263     bar = foo2;
 264     bar1 = dynamic_cast<derived1 *>(bar);
 265     if (bar1 != 0)
 266         exit(1);
 267     return 0;
 268 }
 269 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 270 ])
 271 if test x$lyx_cv_rtti = xyes ; then
 272   AC_DEFINE(HAVE_RTTI, 1,
 273    [Define to 1 if your compiler supports runtime type information])
 274 fi])
 275
 276
 277 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 278 dnl   understands the "explicit" directive.
 279 AC_DEFUN(LYX_CXX_EXPLICIT,[
 280 ### Check whether the compiler understands the keyword `explicit'
 281 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 282  [AC_TRY_COMPILE([
 283 class Expl {
 284 public:
 285         explicit Expl() {}
 286 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 287 ])
 288 if test $lyx_cv_explicit = no ; then
 289   AC_DEFINE(explicit,[ ],
 290    [Define to nothing if your compiler does not understand the
 291    'explicit' directive])
 292 fi])
 293
 294
 295 dnl NOT USED CURRENTLY*************************************
 296 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 297 dnl   has a working stl stack template
 298 AC_DEFUN(LYX_CXX_STL_STACK,[
 299 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 300  [AC_TRY_COMPILE([
 301 #include <stack>
 302 using std::stack;
 303 ],[
 304     stack<int> stakk;
 305     stakk.push(0);
 306 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 307 ])
 308 if test $lyx_cv_broken_stack = yes ; then
 309   AC_DEFINE(BROKEN_STL_STACK, 1,
 310    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 311    correctly])
 312 fi])
 313
 314
 315 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 316 dnl    count template, if not the old HP version is assumed.
 317 AC_DEFUN(LYX_STD_COUNT,[
 318 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 319  [AC_TRY_COMPILE([
 320 #include <algorithm>
 321 using std::count;
 322 int countChar(char * b, char * e, char const c)
 323 {
 324         return count(b, e, c);
 325 }
 326 ],[
 327     char a[] = "hello";
 328     int i = countChar(a, a + 5, 'l');
 329 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 330 ])
 331 if test $lyx_cv_std_count = yes ; then
 332     AC_DEFINE(HAVE_STD_COUNT, 1,
 333     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 334 fi])
 335
 336
 337 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 338 dnl   supports modern STL streams
 339 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 340 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 341  [AC_TRY_COMPILE([
 342 #include <iostream>
 343 ],[
 344  std::streambuf * test = std::cerr.rdbuf();
 345  test->pubsync();
 346 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 347 ])
 348 if test $lyx_cv_modern_streams = yes ; then
 349   AC_DEFINE(MODERN_STL_STREAMS, 1,
 350    [Define if you have modern standard-compliant STL streams])
 351 fi])
 352
 353
 354 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 355 dnl   has a std::string that is usable for LyX. LyX does not require this
 356 dnl   std::string to be standard.
 357 AC_DEFUN(LYX_CXX_STL_STRING,[
 358     AC_REQUIRE([AC_PROG_CXX])
 359     AC_MSG_CHECKING(whether the included std::string should be used)
 360     AC_ARG_WITH(included-string,
 361        [  --with-included-string  use LyX string class instead of STL string],
 362        [lyx_cv_with_included_string=$withval
 363         AC_MSG_RESULT([$with_included_string])],
 364        [AC_CACHE_CHECK([],lyx_cv_with_included_string,
 365         [AC_TRY_COMPILE([
 366             #include <string>
 367             using std::string;
 368         ],[
 369             // LyX has reduced its requirements on the basic_string
 370             // implementation so that the basic_string supplied
 371             // with gcc is usable. In particular this means that
 372             // lyx does not use std::string::clear and not the
 373             // strncmp version of std::string::compare. This is mainly
 374             // done so that LyX can use precompiled C++ libraries that
 375             // already uses the systems basic_string, e.g. gtk--
 376             string a("hello there");
 377             a.erase();
 378             a = "hey";
 379             //char s[] = "y";
 380             //int t = a.compare(a.length() - 1, 1, s);
 381             a.erase();
 382         ],[
 383             lyx_cv_with_included_string=no
 384         ],[
 385             lyx_cv_with_included_string=yes
 386         ])
 387         ])
 388     ])
 389     if test x$lyx_cv_with_included_string = xyes ; then
 390         AC_DEFINE(USE_INCLUDED_STRING, 1,
 391             [Define to use the lyxstring class bundled with LyX.])
 392             lyx_flags="$lyx_flags included-string"
 393     fi
 394     AM_CONDITIONAL(USE_LYXSTRING, test x$lyx_cv_with_included_string = xyes)
 395 dnl    AC_MSG_RESULT([$with_included_string])
 396 ])
 397
 398
 399 dnl Usage: LYX_CXX_GOOD_STD_STRING : checks whether the C++ compiler
 400 dnl   has a std::string that is close to the standard. So close that
 401 dnl   methods not found in "unstandard" std::strings are present here.
 402 AC_DEFUN(LYX_CXX_GOOD_STD_STRING,[
 403     AC_REQUIRE([AC_PROG_CXX])
 404     AC_CACHE_CHECK([whether the systems std::string is really good],
 405     [lyx_cv_std_string_good],
 406     [AC_TRY_COMPILE([
 407             #include <string>
 408             using std::string;
 409         ],[
 410             // From a std::string that is supposed to be close to the
 411             // standard we require at least three things:
 412             // - clear() and erase()
 413             // - the strncmp of compare()
 414             // - push_back()
 415             string a("hello there");
 416             a.erase();
 417             a = "hey";
 418             char s[] = "y";
 419             int t = a.compare(a.length() - 1, 1, s);
 420             a.push_back('g');
 421             a.clear();
 422         ],[
 423             lyx_cv_std_string_good=yes
 424         ],[
 425             lyx_cv_std_string_good=no
 426
 427         ])
 428     ])
 429     if test x$lyx_cv_std_string_good = xyes ; then
 430         AC_DEFINE(STD_STRING_IS_GOOD, 1,
 431             [Define if the systems std::string is really good.])
 432     fi
 433 ])
 434
 435
 436 dnl NOT USED CURRENTLY*************************************
 437 dnl LYX_CXX_PARTIAL
 438 AC_DEFUN(LYX_CXX_PARTIAL, [
 439     AC_REQUIRE([AC_PROG_CXX])
 440     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 441         [lyx_cv_cxx_partial_specialization],
 442         [AC_TRY_COMPILE(
 443             [
 444             template<class T, class K>
 445             class k {
 446             public:
 447             };
 448             template<class T> class k<void,T> { };
 449             ],[
 450             k<float, float> b;
 451             k<void,void> a;
 452             ],[
 453             lyx_cv_cxx_partial_specialization=yes
 454             ],[
 455             lyx_cv_cxx_partial_specialization=no
 456             ])
 457         ])
 458     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 459         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 460         [Defined if your compiler supports partial specialization.])
 461     fi
 462 ])
 463
 464
 465 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 466 dnl   provides wrappers for C headers and use our alternate version otherwise.
 467 AC_DEFUN(LYX_CXX_CHEADERS,[
 468 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 469  [AC_TRY_CPP([
 470 #include <clocale>
 471 #include <cctype>
 472 #include <cerrno>
 473 #include <cmath>
 474 #include <csignal>
 475 #include <cstdio>
 476 #include <cstdlib>
 477 #include <cstring>
 478 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 479 if test $lyx_cv_cxx_cheaders = no ; then
 480   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 481 fi])
 482
 483 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 484 dnl   are already in the global namespace
 485 AC_DEFUN(LYX_CXX_GLOBAL_CSTD,[
 486     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 487     lyx_cv_cxx_global_cstd,
 488     [AC_TRY_COMPILE([
 489     #include <cctype>
 490     using std::tolower;
 491     ],[
 492     return 0;
 493     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 494     if test x$lyx_cv_cxx_global_cstd = xyes; then
 495         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 496         [Define if your C++ compiler puts C library functions in the global namespace])
 497     fi
 498 ])
 499
 500 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 501 AC_DEFUN(LYX_PATH_XPM,[
 502 ### Check for Xpm library
 503 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage, XPM_LIB="-lXpm",
 504         [LYX_LIB_ERROR(libXpm,Xpm)])
 505 AC_SUBST(XPM_LIB)
 506 ### Check for Xpm headers
 507 lyx_cv_xpm_h_location="<xpm.h>"
 508 AC_CHECK_HEADER(X11/xpm.h,[
 509   ac_cv_header_xpm_h=yes
 510   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 511 AC_CHECK_HEADER(xpm.h,[],[
 512 LYX_LIB_ERROR(xpm.h,Xpm)])])
 513 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location,
 514   [define this to the location of xpm.h to be used with #include, e.g. <xpm.h>])
 515
 516 ### Test for the header version
 517 if test $ac_cv_header_xpm_h = yes; then
 518   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 519   [ cat > conftest.$ac_ext <<EOF
 520 #line __oline__ "configure"
 521 #include "confdefs.h"
 522
 523 #include XPM_H_LOCATION
 524 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 525 EOF
 526     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 527       grep '^"%%%"'  2>/dev/null | \
 528       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 529     case "$lyx_cv_xpmr" in
 530 changequote(,)
 531      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 532             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 533 changequote([,])
 534          *) ;;
 535     esac
 536     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 537     rm -f conftest*])
 538   XPM_VERSION=${lyx_cv_xpmversion}
 539   case "$lyx_cv_xpmr" in
 540 changequote(,)
 541         [789]|[0-9][0-9]*) ;;
 542 changequote([,])
 543         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 544    If you experience strange crashes with LyX, try to upgrade
 545    to at least version 4.7 (aka 3.4g).
 546    If you have installed a newer version of the library, check whether you
 547    have an old xpm.h header file in your include path.]);;
 548   esac
 549 fi])
 550
 551
 552 dnl Usage: LYX_FUNC_PUTENV_ARGTYPE
 553 dnl Checks whether putenv() takes 'char const *' or 'char *' as
 554 dnl argument. This is needed because Solaris 7 (wrongly?) uses 'char *',
 555 dnl while everybody else uses the former...
 556 AC_DEFUN(LYX_FUNC_PUTENV_ARGTYPE,
 557 [AC_MSG_CHECKING([type of argument for putenv()])
 558  AC_CACHE_VAL(lyx_cv_func_putenv_arg,dnl
 559   [AC_TRY_COMPILE(dnl
 560 [#include <cstdlib>],
 561 [char const * foo = "bar";
 562  putenv(foo);],dnl
 563    [lyx_cv_func_putenv_arg='char const *'],[lyx_cv_func_putenv_arg='char *'])])
 564  AC_MSG_RESULT($lyx_cv_func_putenv_arg)
 565  AC_DEFINE_UNQUOTED(PUTENV_TYPE_ARG,$lyx_cv_func_putenv_arg,dnl
 566    [Define to the type of the argument of putenv(). Needed on Solaris 7.])])
 567
 568
 569 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 570 dnl                       [default-yes-value])
 571 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 572 dnl  resulting directory name in 'dir-var-name'.
 573 AC_DEFUN(LYX_WITH_DIR,[
 574   AC_ARG_WITH($1,[  --with-$1        specify $2])
 575   AC_MSG_CHECKING([for $2])
 576   if test -z "$with_$3"; then
 577      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 578   else
 579     test "x$with_$3" = xyes && with_$3=$5
 580     lyx_cv_$3="$with_$3"
 581   fi
 582   AC_MSG_RESULT($lyx_cv_$3)])
 583
 584
 585 dnl Usage: LYX_LOOP_DIR(value,action)
 586 dnl Executes action for values of variable `dir' in `values'. `values' can
 587 dnl use ":" as a separator.
 588 AC_DEFUN(LYX_LOOP_DIR,[
 589 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 590 for dir in `eval "echo $1"`; do
 591   if test ! "$dir" = NONE; then
 592     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 593     $2
 594   fi
 595 done
 596 IFS=$ac_save_ifs
 597 ])
 598
 599
 600 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 601 dnl var-name.
 602 AC_DEFUN(LYX_ADD_LIB_DIR,[
 603 $1="${$1} -L$2"
 604 if test "`(uname) 2>/dev/null`" = SunOS &&
 605     uname -r | grep '^5' >/dev/null; then
 606   if test $ac_cv_prog_gxx = yes ; then
 607     $1="${$1} -Wl[,]-R$2"
 608   else
 609     $1="${$1} -R$2"
 610   fi
 611 fi])
 612
 613
 614 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 615 dnl var-name.
 616 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 617
 618 ### Check for a headers existence and location iff it exists
 619 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 620 ## It almost works.  I've tried a few variations but they give errors
 621 ## of one sort or other: bad substitution or file not found etc.  The
 622 ## actual header _is_ found though and the cache variable is set however
 623 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 624 ## reason.
 625 ## Additionally, autoheader can't figure out what to use as the name in
 626 ## the config.h.in file so we need to write our own entries there -- one for
 627 ## each header in the form PATH_HEADER_NAME_H
 628 ##
 629 AC_DEFUN(LYX_PATH_HEADER,
 630 [ AC_CHECK_HEADER($1,[
 631   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 632 ### the only remaining problem is getting the second parameter to this
 633 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 634 ### of $ac_safe being printed.
 635   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 636   [ cat > conftest.$ac_ext <<EOF
 637 #line __oline__ "configure"
 638 #include "confdefs.h"
 639
 640 #include <$1>
 641 EOF
 642 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 643   grep $1  2>/dev/null | \
 644   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 645 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 646 rm -f conftest*])
 647   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 648 ])
 649 ### end of LYX_PATH_HEADER
 650
 651 ### Check which frontend we want to use. The default is XForms
 652 ###
 653 AC_DEFUN(LYX_USE_FRONTEND,
 654 [AC_MSG_CHECKING([what frontend should be used as main GUI])
 655 AC_ARG_WITH(frontend,
 656   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 657                             Possible values: xforms, qt, gnome],
 658   [lyx_use_frontend="$withval"], [lyx_use_frontend="xforms"])
 659 AC_MSG_RESULT($lyx_use_frontend)
 660 AC_SUBST(FRONTEND)
 661 AC_SUBST(FRONTEND_GUILIB)
 662 AC_SUBST(FRONTEND_LDFLAGS)
 663 AC_SUBST(FRONTEND_INCLUDES)
 664 AC_SUBST(FRONTEND_LIBS)
 665 ])
 666
 667
 668
 669 ## ------------------------------------------------------------------------
 670 ## Find a file (or one of more files in a list of dirs)
 671 ## ------------------------------------------------------------------------
 672 ##
 673 AC_DEFUN(AC_FIND_FILE,
 674 [
 675 $3=NO
 676 for i in $2;
 677 do
 678   for j in $1;
 679   do
 680     if test -r "$i/$j"; then
 681       $3=$i
 682       break 2
 683     fi
 684   done
 685 done
 686 ])
 687
 688 dnl just a wrapper to clean up configure.in
 689 AC_DEFUN(LYX_PROG_LIBTOOL,
 690 [
 691 AC_REQUIRE([AC_ENABLE_SHARED])
 692 AC_REQUIRE([AC_ENABLE_STATIC])
 693 dnl libtool is only for C, so I must force him
 694 dnl to find the correct flags for C++
 695 ac_save_cc=$CC
 696 ac_save_cflags="$CFLAGS"
 697 CC=$CXX
 698 CFLAGS="$CXXFLAGS"
 699 AM_PROG_LIBTOOL dnl for libraries
 700 CC=$ac_save_cc
 701 CFLAGS="$ac_save_cflags"
 702 ])