config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6 dnl Compute the default build type from AC_PACKAGE_VERSION at autoconf time.
   7 m4_define([LYX_BUILD_TYPE], [m4_bmatch(AC_PACKAGE_VERSION,
   8     [dev], [development],
   9     [pre\|alpha\|beta\|rc], [prerelease],
  10     [release])])
  11
  12
  13 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
  14 dnl sets variable "build_type"
  15 AC_DEFUN([LYX_CHECK_VERSION],[
  16 echo "configuring LyX version" AC_PACKAGE_VERSION
  17
  18 AC_MSG_CHECKING([for build type])
  19 lyx_devel_version=no
  20 lyx_prerelease=no
  21 AC_ARG_ENABLE(build-type,
  22   AS_HELP_STRING([--enable-build-type=STR],[set build type to rel(ease), pre(release), dev(elopment), prof(iling), or gprof (default: LYX_BUILD_TYPE)]),
  23   [case $enableval in
  24     dev*) build_type=development;;
  25     pre*) build_type=prerelease;;
  26     prof*)  build_type=profiling;;
  27     gprof*) build_type=gprof;;
  28     rel*) build_type=release;;
  29     *) AC_MSG_ERROR([bad build type specification '$enableval'. Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  30    esac],
  31   [build_type=LYX_BUILD_TYPE])
  32 AC_MSG_RESULT([$build_type])
  33 lyx_flags="$lyx_flags build=$build_type"
  34 case $build_type in
  35     development) lyx_devel_version=yes
  36                  LYX_DATE="not released yet" ;;
  37     prerelease) lyx_prerelease=yes ;;
  38 esac
  39
  40 AC_SUBST(lyx_devel_version)
  41 ])
  42
  43
  44 dnl Define the option to set a LyX version on installed executables and directories
  45 dnl
  46 dnl
  47 AC_DEFUN([LYX_VERSION_SUFFIX],[
  48 AC_MSG_CHECKING([for version suffix])
  49 dnl We need the literal double quotes in the rpm spec file
  50 RPM_VERSION_SUFFIX='""'
  51 AC_ARG_WITH(version-suffix,
  52   [AS_HELP_STRING([--with-version-suffix@<:@=STR@:>@], install lyx files as lyxSTR (default STR: -AC_PACKAGE_VERSION))],
  53   [if test "x$withval" = "xyes";
  54    then
  55      withval="-"AC_PACKAGE_VERSION
  56      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  57    fi
  58    AC_SUBST(version_suffix,$withval)
  59    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  60 AC_SUBST(RPM_VERSION_SUFFIX)
  61 AC_SUBST(program_base_name,"lyx")
  62 AC_MSG_RESULT([$withval])
  63 ])
  64
  65
  66 dnl Check whether to configure for Qt4 or Qt5. Default is Qt5.
  67 dnl
  68 AC_DEFUN([LYX_CHECK_QT5],[
  69 AC_MSG_CHECKING([whether Qt5 is disabled])
  70 AC_ARG_ENABLE([qt5],
  71   [AS_HELP_STRING([--disable-qt5],[do not use Qt5 for building])],
  72   USE_QT5=$enableval, USE_QT5=yes)
  73 if test x$USE_QT5 != xno ; then
  74   AC_MSG_RESULT([no])
  75 else
  76   AC_MSG_RESULT([yes])
  77 fi
  78 AC_SUBST([USE_QT5])
  79 ])
  80
  81
  82 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  83 dnl flag lyx_warning to yes.
  84 AC_DEFUN([LYX_WARNING],[
  85 lyx_warning_txt="$lyx_warning_txt
  86 == $1
  87 "
  88 lyx_warning=yes])
  89
  90
  91 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  92 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  93 AC_DEFUN([LYX_LIB_ERROR],[
  94 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  95    is correctly installed on your system.])])
  96
  97
  98 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  99 dnl   has occurred previously.
 100 AC_DEFUN([LYX_CHECK_WARNINGS],[
 101 if test x$lyx_warning = xyes; then
 102 cat <<EOF
 103 === The following minor problems have been detected by configure.
 104 === Please check the messages below before running 'make'.
 105 === (see the section 'Problems' in the INSTALL file)
 106 $lyx_warning_txt
 107
 108 EOF
 109 fi])
 110
 111
 112 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 113 dnl
 114 define(LYX_SEARCH_PROG,[dnl
 115 for ac_prog in $2 ; do
 116 # Extract the first word of "$ac_prog", so it can be a program name with args.
 117   set dummy $ac_prog ; ac_word=$[2]
 118   if test -z "[$]$1"; then
 119     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 120     for ac_dir in $PATH; do
 121       test -z "$ac_dir" && ac_dir=.
 122       if test -f [$ac_dir/$ac_word]; then
 123         $1="$ac_prog"
 124         break
 125       fi
 126     done
 127     IFS="$ac_save_ifs"
 128   fi
 129
 130   if test -n "[$]$1"; then
 131     ac_result=yes
 132   else
 133     ac_result=no
 134   fi
 135   ifelse($3,,,[$3])
 136   test -n "[$]$1" && break
 137 done
 138 ])dnl
 139
 140
 141 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 142 AC_DEFUN([LYX_PROG_CLANG],
 143 [AC_CACHE_CHECK([whether the compiler is clang],
 144                [lyx_cv_prog_clang],
 145 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 146 #ifndef __clang__
 147             this is not clang
 148 #endif
 149 ]])],[lyx_cv_prog_clang=yes ; CLANG=yes],[lyx_cv_prog_clang=no ; CLANG=no])])
 150 if test $CLANG = yes ; then
 151   AC_CACHE_CHECK([for clang version],
 152     [lyx_cv_clang_version],
 153     [clang_noversion=no
 154      AC_COMPUTE_INT(clang_major,__clang_major__,,[clang_noversion_=yes])
 155      AC_COMPUTE_INT(clang_minor,__clang_minor__,,[clang_noversion_=yes])
 156      AC_COMPUTE_INT(clang_patchlevel,__clang_patchlevel__,,[clang_noversion_=yes])
 157      if test $clang_noversion = yes ; then
 158        clang_version=unknown
 159      else
 160        clang_version=$clang_major.$clang_minor.$clang_patchlevel
 161      fi
 162      lyx_cv_clang_version=$clang_version])
 163 fi
 164 ])
 165
 166
 167 dnl Usage: LYX_CXX_CXX11_FLAGS: add to AM_CXXFLAGS the best flag that
 168 selects C++11 mode; gives an error when C++11 mode is not found.
 169 AC_DEFUN([LYX_CXX_CXX11_FLAGS],
 170 [AC_CACHE_CHECK([for at least C++11 mode], [lyx_cv_cxx11_flags],
 171  [lyx_cv_cxx11_flags=none
 172   for flag in -std=c++14 -std=c++11 "" -std=gnu++14 -std=gnu++11 ; do
 173     save_CPPFLAGS=$CPPFLAGS
 174     CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 175     save_CXXFLAGS=$CXXFLAGS
 176     CXXFLAGS="$flag $AM_CXXFLAGS $CXXFLAGS"
 177     dnl sample openmp source code to test
 178     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 179        template <typename T>
 180        struct check
 181        {
 182            static_assert(sizeof(int) <= sizeof(T), "not big enough");
 183        };
 184
 185        typedef check<check<bool>> right_angle_brackets;
 186
 187        class TestDeleted
 188        {
 189        public:
 190            TestDeleted() = delete;
 191        };
 192
 193
 194        int a;
 195        decltype(a) b;
 196
 197        typedef check<int> check_type;
 198        check_type c;
 199        check_type&& cr = static_cast<check_type&&>(c);
 200
 201        auto d = a;]], [[]])],[lyx_cv_cxx11_flags=$flag; break],[])
 202    CXXFLAGS=$save_CXXFLAGS
 203    CPPFLAGS=$save_CPPFLAGS
 204   done])
 205   if test $lyx_cv_cxx11_flags = none ; then
 206     AC_MSG_ERROR([Cannot find suitable C++11 mode for compiler $CXX])
 207   fi
 208   AM_CXXFLAGS="$lyx_cv_cxx11_flags $AM_CXXFLAGS"
 209 ])
 210
 211
 212 dnl Usage: LYX_CXX_USE_REGEX
 213 dnl decide whether we want to use std::regex and set the
 214 dnl LYX_USE_STD_REGEX macro and conditional accordingly.
 215 AC_DEFUN([LYX_CXX_USE_REGEX],
 216 [AC_ARG_ENABLE(std-regex,
 217   AS_HELP_STRING([--enable-std-regex],[use std::regex instead of boost::regex (default is autodetected)]),
 218   [lyx_std_regex=$enableval],
 219   [AC_MSG_CHECKING([for correct regex implementation])
 220    save_CPPFLAGS=$CPPFLAGS
 221    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 222    save_CXXFLAGS=$CXXFLAGS
 223    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 224    # The following code snippet has been taken taken from example in
 225    #   http://stackoverflow.com/questions/8561850/compile-stdregex-iterator-with-gcc
 226    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 227         #include <regex>
 228         #include <iostream>
 229
 230         #include <string.h>
 231
 232         typedef std::regex_iterator<const char *> Myiter;
 233      ]], [[
 234         const char *pat = "axayaz";
 235         Myiter::regex_type rx("a");
 236         Myiter next(pat, pat + strlen(pat), rx);
 237         Myiter end;
 238    ]])],[lyx_std_regex=yes],[lyx_std_regex=no])
 239    CXXFLAGS=$save_CXXFLAGS
 240    CPPFLAGS=$save_CPPFLAGS
 241    AC_MSG_RESULT([$lyx_std_regex])
 242  ])
 243
 244  if test $lyx_std_regex = yes ; then
 245   lyx_flags="$lyx_flags std-regex"
 246   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 247  fi
 248  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 249 ])
 250
 251
 252 dnl Usage: LYX_CXX_USE_CALL_ONCE
 253 dnl check whether we can use std::call_once and set the
 254 dnl LYX_USE_STD_CALL_ONCE macro and conditional accordingly.
 255 AC_DEFUN([LYX_CXX_USE_CALL_ONCE],
 256 [AC_MSG_CHECKING([for std::call_once availability])
 257    save_CPPFLAGS=$CPPFLAGS
 258    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 259    save_CXXFLAGS=$CXXFLAGS
 260    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 261    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 262         #include <mutex>
 263         static std::once_flag flag;
 264      ]], [[
 265         std::call_once(flag, [](){ return; });
 266    ]])],[lyx_std_call_once=yes],[lyx_std_call_once=no])
 267    CXXFLAGS=$save_CXXFLAGS
 268    CPPFLAGS=$save_CPPFLAGS
 269    AC_MSG_RESULT([$lyx_std_call_once])
 270
 271  if test $lyx_std_call_once = yes ; then
 272   AC_DEFINE([LYX_USE_STD_CALL_ONCE], 1, [define to 1 if std::call_once is supported by the compiler])
 273  fi
 274  AM_CONDITIONAL([LYX_USE_STD_CALL_ONCE], test $lyx_std_call_once = yes)
 275 ])
 276
 277
 278 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 279 AC_DEFUN([LYX_LIB_STDCXX],
 280 [AC_CACHE_CHECK([whether STL is libstdc++],
 281                [lyx_cv_lib_stdcxx],
 282 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 283 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 284             this is not libstdc++
 285 #endif
 286 ]])],[lyx_cv_lib_stdcxx=yes],[lyx_cv_lib_stdcxx=no])])
 287 ])
 288
 289
 290 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 291 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 292 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 293 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 294                [lyx_cv_lib_stdcxx_cxx11_abi],
 295 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 296 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 297             this is not libstdc++ using the C++11 ABI
 298 #endif
 299 ]])],[lyx_cv_lib_stdcxx_cxx11_abi=yes],[lyx_cv_lib_stdcxx_cxx11_abi=no])])
 300 ])
 301
 302
 303 AC_DEFUN([LYX_PROG_CXX],
 304 [AC_REQUIRE([AC_PROG_CXX])
 305 AC_REQUIRE([AC_PROG_CXXCPP])
 306
 307 AC_LANG_PUSH(C++)
 308 LYX_PROG_CLANG
 309 LYX_CXX_CXX11_FLAGS
 310 LYX_LIB_STDCXX
 311 LYX_LIB_STDCXX_CXX11_ABI
 312 LYX_CXX_USE_REGEX
 313 LYX_CXX_USE_CALL_ONCE
 314 AC_LANG_POP(C++)
 315
 316 if test $lyx_cv_lib_stdcxx = "yes" ; then
 317   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 318     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 319   else
 320     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 321   fi
 322 else
 323   if test $lyx_cv_prog_clang = "yes" ; then
 324     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 325   fi
 326 fi
 327
 328 ### We might want to get or shut warnings.
 329 AC_ARG_ENABLE(warnings,
 330   AS_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 331   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $GXX = yes ; then
 332         enable_warnings=yes;
 333     else
 334         enable_warnings=no;
 335     fi;])
 336 if test x$enable_warnings = xyes ; then
 337   lyx_flags="$lyx_flags warnings"
 338 fi
 339
 340 ### We might want to disable debug
 341 AC_ARG_ENABLE(debug,
 342   AS_HELP_STRING([--enable-debug],[enable debug information]),,
 343   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 344 )
 345
 346 AC_ARG_ENABLE(stdlib-debug,
 347   AS_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 348   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 349           [enable_stdlib_debug=no])]
 350 )
 351
 352 ### set up optimization
 353 AC_ARG_ENABLE(optimization,
 354     AS_HELP_STRING([--enable-optimization@<:@=ARG@:>@],[enable compiler optimisation]),,
 355     enable_optimization=yes;)
 356 case $enable_optimization in
 357     yes)
 358         if test $lyx_devel_version = yes ; then
 359             lyx_optim=-O
 360         else
 361             lyx_optim=-O2
 362         fi;;
 363     no) lyx_optim=;;
 364     *) lyx_optim=${enable_optimization};;
 365 esac
 366
 367 AC_ARG_ENABLE(assertions,
 368   AS_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 369   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 370           [enable_assertions=no])]
 371 )
 372 if test "x$enable_assertions" = xyes ; then
 373    lyx_flags="$lyx_flags assertions"
 374    AC_DEFINE(ENABLE_ASSERTIONS,1,
 375     [Define if you want assertions to be enabled in the code])
 376 fi
 377
 378 # set the compiler options correctly.
 379 if test x$GXX = xyes; then
 380   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 381   if test x$CLANG = xno; then
 382     dnl Useful for global version info
 383     gxx_version=`${CXX} -dumpversion`
 384     CXX_VERSION="($gxx_version)"
 385   else
 386     gxx_version=clang-$clang_version
 387     CXX_VERSION="($clang_version)"
 388   fi
 389
 390   AM_CXXFLAGS="$lyx_optim $AM_CXXFLAGS"
 391   if test x$enable_debug = xyes ; then
 392       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 393   fi
 394   if test $build_type = gprof ; then
 395     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 396     AM_LDFLAGS="$AM_LDFLAGS -pg"
 397   fi
 398   if test $build_type = profiling ; then
 399     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 400   fi
 401
 402   if test x$USE_QT5 = xyes ; then
 403       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 404   fi
 405   dnl Warnings are for preprocessor too
 406   if test x$enable_warnings = xyes ; then
 407       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 408   fi
 409   case $gxx_version in
 410       2.*|3.*|4.@<:@0-6@:>@) AC_MSG_ERROR([gcc >= 4.7 is required]);;
 411   esac
 412   if test x$enable_stdlib_debug = xyes ; then
 413     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 414     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 415     case $gxx_version in
 416       *)
 417         lyx_flags="$lyx_flags stdlib-debug"
 418         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 419         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 420         AC_SUBST(STDLIB_DEBUG, "-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 421         ;;
 422     esac
 423   fi
 424 fi
 425
 426 # Some additional flags may be needed
 427 if test x$GXX = xyes; then
 428     case $gxx_version in
 429       clang-3.0*|clang-3.1*|clang-3.2*|clang-3.3*)
 430         dnl boost contains pragmas that are annoying on older clang versions
 431         AM_CPPFLAGS="-Wno-unknown-pragmas $AM_CPPFLAGS";;
 432       clang*)
 433         dnl the more recent versions support the deprecated-register warning,
 434         dnl which  is very annoying with Qt4.x right now.
 435         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 436     esac
 437 fi
 438 ])
 439
 440 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 441 dnl        be used.
 442 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 443         AC_MSG_CHECKING([whether to use included boost library])
 444         AC_ARG_WITH(included-boost,
 445             [AS_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 446             [lyx_cv_with_included_boost=$withval],
 447             [lyx_cv_with_included_boost=yes])
 448         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 449         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 450         if test x$lyx_cv_with_included_boost = xyes ; then
 451             lyx_included_libs="$lyx_included_libs boost"
 452             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 453             if test $lyx_std_regex = yes ; then
 454               BOOST_LIBS=""
 455             else
 456               BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 457             fi
 458         else
 459             BOOST_INCLUDES=
 460             if test $lyx_std_regex = yes ; then
 461               BOOST_LIBS=""
 462             else
 463               AC_LANG_PUSH(C++)
 464               save_LIBS=$LIBS
 465
 466               AC_MSG_CHECKING([for multithreaded boost libraries])
 467               LIBS="$save_LIBS -lboost_regex-mt $LIBTHREAD"
 468               AC_LINK_IFELSE(
 469                 [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 470                         [boost::regex reg;])],
 471                 [AC_MSG_RESULT([yes])
 472                  BOOST_MT="-mt"],
 473                 [AC_MSG_RESULT([no])
 474                  AC_MSG_CHECKING([for plain boost libraries])
 475                  LIBS="$save_LIBS -lboost_regex"
 476                  AC_LINK_IFELSE(
 477                      [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 478                              [boost::regex reg;])],
 479                      [AC_MSG_RESULT([yes])
 480                       BOOST_MT=""],
 481                      [AC_MSG_RESULT([no])
 482                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 483                  ])
 484               ])
 485               LIBS=$save_LIBS
 486               AC_LANG_POP(C++)
 487
 488               dnl In general, system boost libraries are incompatible with
 489               dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 490               dnl details.
 491               if test $enable_stdlib_debug = "yes" ; then
 492                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 493    crashes. Consider using --disable-stdlib-debug or removing
 494    --without-included-boost.])
 495               fi
 496
 497               BOOST_LIBS="-lboost_regex${BOOST_MT}"
 498             fi
 499         fi
 500         AC_SUBST(BOOST_INCLUDES)
 501         AC_SUBST(BOOST_LIBS)
 502 ])
 503
 504
 505 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 506 dnl        be used.
 507 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 508   AC_MSG_CHECKING([whether to use included iconv library])
 509   AC_ARG_WITH(included-iconv,
 510     [AS_HELP_STRING([--with-included-iconv], [use the iconv lib supplied with LyX instead of the system one])],
 511     [lyx_cv_with_included_iconv=$withval],
 512     [lyx_cv_with_included_iconv=no])
 513   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 514   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 515   if test x$lyx_cv_with_included_iconv = xyes ; then
 516   lyx_included_libs="$lyx_included_libs iconv"
 517
 518 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 519     AC_EILSEQ
 520     AC_TYPE_MBSTATE_T
 521     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 522 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 523     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 524       USE_MBSTATE_T=1
 525     else
 526       USE_MBSTATE_T=0
 527     fi
 528     AC_SUBST([USE_MBSTATE_T])
 529     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 530       [gl_cv_header_wchar_h_standalone],
 531       [AC_COMPILE_IFELSE(
 532         [AC_LANG_PROGRAM(
 533           [[#include <wchar.h>
 534             wchar_t w;]],
 535           [[]])],
 536         [gl_cv_header_wchar_h_standalone=yes],
 537         [gl_cv_header_wchar_h_standalone=no])])
 538     if test $gl_cv_header_wchar_h_standalone = yes; then
 539       BROKEN_WCHAR_H=0
 540     else
 541       BROKEN_WCHAR_H=1
 542     fi
 543     AC_SUBST([BROKEN_WCHAR_H])
 544 dnl we want const correctness
 545     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 546       [Define as const if the declaration of iconv() needs const.])
 547     ICONV_CONST=const
 548     AC_SUBST([ICONV_CONST])
 549 dnl we build a static lib
 550     DLL_VARIABLE=
 551     AC_SUBST([DLL_VARIABLE])
 552     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 553     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 554     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 555   else
 556     ICONV_INCLUDES=
 557     AM_ICONV
 558     if test "$am_cv_func_iconv" = no; then
 559       AC_MSG_ERROR([cannot find required library iconv.])
 560     else
 561       ICONV_LIBS="$LIBICONV"
 562     fi
 563     ICONV_ICONV_H_IN=
 564   fi
 565   AC_SUBST(ICONV_INCLUDES)
 566   AC_SUBST(ICONV_LIBS)
 567   AC_SUBST(ICONV_ICONV_H_IN)
 568 ])
 569
 570
 571 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 572 dnl        be used.
 573 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 574   AC_MSG_CHECKING([whether to use included zlib library])
 575   AC_ARG_WITH(included-zlib,
 576     [AS_HELP_STRING([--with-included-zlib], [use the zlib lib supplied with LyX instead of the system one])],
 577     [lyx_cv_with_included_zlib=$withval],
 578     [lyx_cv_with_included_zlib=no])
 579   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 580   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 581   if test x$lyx_cv_with_included_zlib = xyes ; then
 582     lyx_included_libs="$lyx_included_libs zlib"
 583     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 584     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 585     mkdir -p 3rdparty/zlib
 586 dnl include standard config.h for HAVE_UNISTD_H
 587     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 588 dnl prevent clash with system zlib that might be dragged in by other libs
 589     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 590     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 591   else
 592     ZLIB_INCLUDES=
 593     AC_CHECK_HEADERS(zlib.h,
 594       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 595       [LYX_LIB_ERROR(zlib.h,zlib)])
 596   fi
 597   AC_SUBST(ZLIB_INCLUDES)
 598   AC_SUBST(ZLIB_LIBS)
 599 ])
 600
 601
 602 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 603 dnl        necessary APIs are available to print callstacks.
 604 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 605 [AC_ARG_ENABLE([callstack-printing],
 606                [AS_HELP_STRING([--disable-callstack-printing],[do not print a callstack when crashing])],
 607                lyx_cv_callstack_printing=$enableval, lyx_cv_callstack_printing=yes)
 608
 609 if test x"$lyx_cv_callstack_printing" = xyes; then
 610   AC_CACHE_CHECK([whether printing callstack is possible],
 611                  [lyx_cv_callstack_printing],
 612   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 613   #include <execinfo.h>
 614   #include <cxxabi.h>
 615   ]], [[
 616           void* array[200];
 617           size_t size = backtrace(array, 200);
 618           backtrace_symbols(array, size);
 619           int status = 0;
 620           abi::__cxa_demangle("abcd", 0, 0, &status);
 621   ]])],[],[lyx_cv_callstack_printing=no])])
 622 fi
 623 if test x"$lyx_cv_callstack_printing" = xyes; then
 624   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 625             [Define if callstack can be printed])
 626   lyx_flags="$lyx_flags callback-printing"
 627   AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"
 628 fi
 629 ])
 630
 631
 632 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 633 dnl        be used.
 634 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 635   AC_ARG_WITH(included-mythes,
 636     [AS_HELP_STRING([--with-included-mythes], [force to use the MyThes lib supplied with LyX])],
 637     [use_included_mythes=$withval],
 638     [use_included_mythes=no])
 639   if test x$use_included_mythes != xyes ; then
 640     AC_LANG_PUSH(C++)
 641     use_included_mythes=yes
 642     AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
 643       [mythes_h_location="<$ac_header>"
 644        save_LIBS=$LIBS
 645        AC_MSG_CHECKING([checking for MyThes library])
 646        for ac_lib in mythes mythes-1.2 ; do
 647          LIBS="-l$ac_lib $save_LIBS"
 648          AC_LINK_IFELSE(
 649            [AC_LANG_PROGRAM([#include <cstdio>]
 650               [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
 651            [MYTHES_LIBS=-l$ac_lib
 652             AC_MSG_RESULT([$MYTHES_LIBS])
 653             use_included_mythes=no])
 654        done
 655        if test $use_included_mythes != no ; then
 656          AC_MSG_RESULT([not found])
 657        fi
 658        break])
 659     AC_LANG_POP(C++)
 660   fi
 661   if test $use_included_mythes = yes ; then
 662     mythes_h_location="<mythes.hxx>"
 663     MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
 664     MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
 665     lyx_included_libs="$lyx_included_libs mythes"
 666   fi
 667   AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
 668   AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
 669   AC_SUBST(MYTHES_INCLUDES)
 670   AC_SUBST(MYTHES_LIBS)
 671   AC_MSG_CHECKING([whether to use included MyThes library])
 672   AC_MSG_RESULT([$use_included_mythes])
 673 ])
 674
 675
 676 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 677 dnl                       [default-yes-value])
 678 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 679 dnl  resulting directory name in 'dir-var-name'.
 680 AC_DEFUN([LYX_WITH_DIR],[
 681   AC_ARG_WITH($1,[AS_HELP_STRING([--with-$1],[specify $2])])
 682   AC_MSG_CHECKING([for $2])
 683   if test -z "$with_$3"; then
 684      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 685   else
 686     test "x$with_$3" = xyes && with_$3=$5
 687     lyx_cv_$3="$with_$3"
 688   fi
 689   AC_MSG_RESULT($lyx_cv_$3)
 690 ])
 691
 692
 693 dnl Usage: LYX_LOOP_DIR(value,action)
 694 dnl Executes action for values of variable `dir' in `values'. `values' can
 695 dnl use ":" as a separator.
 696 AC_DEFUN([LYX_LOOP_DIR],[
 697 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 698 for dir in `eval "echo $1"`; do
 699   if test ! "$dir" = NONE; then
 700     test ! -d "$dir" && AC_MSG_ERROR(['$dir' is not a directory])
 701     $2
 702   fi
 703 done
 704 IFS=$ac_save_ifs
 705 ])
 706
 707
 708 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 709 dnl var-name.
 710 AC_DEFUN([LYX_ADD_LIB_DIR],[
 711 $1="${$1} -L$2"
 712 if test "`(uname) 2>/dev/null`" = SunOS &&
 713     uname -r | grep '^5' >/dev/null; then
 714   if test $GXX = yes ; then
 715     $1="${$1} -Wl[,]-R$2"
 716   else
 717     $1="${$1} -R$2"
 718   fi
 719 fi])
 720
 721
 722 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 723 dnl var-name.
 724 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 725
 726 ### Check for a headers existence and location iff it exists
 727 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 728 ## It almost works.  I've tried a few variations but they give errors
 729 ## of one sort or other: bad substitution or file not found etc.  The
 730 ## actual header _is_ found though and the cache variable is set however
 731 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 732 ## reason.
 733 ## Additionally, autoheader can't figure out what to use as the name in
 734 ## the config.h.in file so we need to write our own entries there -- one for
 735 ## each header in the form PATH_HEADER_NAME_H
 736 ##
 737 AC_DEFUN([LYX_PATH_HEADER],
 738 [ AC_CHECK_HEADER($1,[
 739   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 740 ### the only remaining problem is getting the second parameter to this
 741 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 742 ### of $ac_safe being printed.
 743   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 744   [ cat > conftest.$ac_ext <<EOF
 745 #line __oline__ "configure"
 746 #include "confdefs.h"
 747
 748 #include <$1>
 749 EOF
 750 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 751   grep $1  2>/dev/null | \
 752   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 753 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 754 rm -f conftest*])
 755   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 756 ])
 757 ### end of LYX_PATH_HEADER
 758
 759 ## Check what kind of packaging should be used at install time.
 760 ## The default is autodetected.
 761 AC_DEFUN([LYX_USE_PACKAGING],
 762 [AC_MSG_CHECKING([what packaging should be used])
 763 AC_ARG_WITH(packaging,
 764   [AS_HELP_STRING([--with-packaging=STR], [set packaging for installation among:
 765                             posix, windows, macosx, haiku (default is autodetected)])],
 766   [lyx_use_packaging="$withval"], [
 767   case $host in
 768     *-apple-darwin*) lyx_use_packaging=macosx ;;
 769     *-pc-mingw*) lyx_use_packaging=windows ;;
 770     *-mingw32*) lyx_use_packaging=windows ;;
 771     *haiku*) lyx_use_packaging=haiku ;;
 772     *) lyx_use_packaging=posix ;;
 773   esac])
 774 AC_MSG_RESULT($lyx_use_packaging)
 775 lyx_install_posix=false
 776 lyx_install_macosx=false
 777 lyx_install_cygwin=false
 778 lyx_install_windows=false
 779 case $lyx_use_packaging in
 780    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 781            PACKAGE=LyX${version_suffix}
 782            default_prefix="/Applications/${PACKAGE}.app"
 783            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 784            bindir='${prefix}/Contents/MacOS'
 785            libdir='${prefix}/Contents/Resources'
 786            datarootdir='${prefix}/Contents/Resources'
 787            pkgdatadir='${datadir}'
 788            mandir='${datadir}/man'
 789            lyx_install_macosx=true ;;
 790   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 791            PACKAGE=LyX${version_suffix}
 792            default_prefix="C:/Program Files/${PACKAGE}"
 793            bindir='${prefix}/bin'
 794            libdir='${prefix}/Resources'
 795            datarootdir='${prefix}/Resources'
 796            pkgdatadir='${datadir}'
 797            mandir='${prefix}/Resources/man'
 798            lyx_install_windows=true ;;
 799     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 800            PACKAGE=lyx${version_suffix}
 801            program_suffix=$version_suffix
 802            pkgdatadir='${datadir}/${PACKAGE}'
 803            default_prefix=$ac_default_prefix
 804            case ${host} in
 805              *cygwin*) lyx_install_cygwin=true ;;
 806              *apple-darwin*) lyx_install_macosx=true ;;
 807            esac
 808            lyx_install_posix=true ;;
 809         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 810            PACKAGE=lyx${version_suffix}
 811            program_suffix=$version_suffix
 812            pkgdatadir='${datadir}/${PACKAGE}'
 813            default_prefix=$ac_default_prefix
 814            lyx_install_posix=true ;;
 815     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 816 esac
 817 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 818 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 819 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 820 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 821 AC_SUBST(pkgdatadir)
 822 AC_SUBST(program_suffix)
 823 ])
 824
 825
 826 ## ------------------------------------------------------------------------
 827 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 828 ## one or two arguments.
 829 ##
 830 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 831 ## ------------------------------------------------------------------------
 832 ##
 833 AC_DEFUN([AC_FUNC_MKDIR],
 834 [AC_CHECK_FUNCS([mkdir _mkdir])
 835 AC_CACHE_CHECK([whether mkdir takes one argument],
 836                [ac_cv_mkdir_takes_one_arg],
 837 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 838 #include <sys/stat.h>
 839 #if HAVE_UNISTD_H
 840 #  include <unistd.h>
 841 #endif
 842 ]], [[mkdir (".");]])],[ac_cv_mkdir_takes_one_arg=yes],[ac_cv_mkdir_takes_one_arg=no])])
 843 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 844   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 845             [Define if mkdir takes only one argument.])
 846 fi
 847 ])
 848
 849
 850 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 851 dnl (which may be a relative path, and need not refer to any existing
 852 dnl entity).
 853
 854 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 855 dnl native Win32 path name, (but with slashes, not backslashes).
 856
 857 dnl On any other system, it is simply the result which would be obtained
 858 dnl if PATHNAME represented an existing directory, and the pwd command was
 859 dnl executed in that directory.
 860 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 861 [ac_dir="$2"
 862  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 863     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 864  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 865  do
 866    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 867  done
 868  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 869  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 870  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 871    s?/*$[]??'`
 872 ])
 873
 874 dnl this is used by the macro blow to general a proper config.h.in entry
 875 m4_define([LYX_AH_CHECK_DECL],
 876 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 877   [Define if you have the prototype for function `$1'])])
 878
 879 dnl Check things are declared in headers to avoid errors or warnings.
 880 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 881 dnl Defines HAVE_DECL_{FUNCTION}
 882 AC_DEFUN([LYX_CHECK_DECL],
 883 [LYX_AH_CHECK_DECL($1)
 884 for ac_header in $2
 885 do
 886   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 887   AC_EGREP_HEADER($1, $ac_header,
 888       [AC_MSG_RESULT(yes)
 889        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 890        break],
 891       [AC_MSG_RESULT(no)])
 892 done])
 893
 894 dnl this is used by the macro below to generate a proper config.h.in entry
 895 m4_define([LYX_AH_CHECK_DEF],
 896 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 897   [Define to 1 if `$1' is defined in `$2'])])
 898
 899 dnl Check whether name is defined in header by using it in codesnippet.
 900 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 901 dnl Defines HAVE_DEF_{NAME}
 902 AC_DEFUN([LYX_CHECK_DEF],
 903 [LYX_AH_CHECK_DEF($1, $2)
 904  AC_MSG_CHECKING([whether $1 is defined by header $2])
 905  save_CPPFLAGS=$CPPFLAGS
 906  CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 907  save_CXXFLAGS=$CXXFLAGS
 908  CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 909  AC_LANG_PUSH(C++)
 910  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <$2>]], [[$3]])],[lyx_have_def_name=yes],[lyx_have_def_name=no])
 911  AC_LANG_POP(C++)
 912  CXXFLAGS=$save_CXXFLAGS
 913  CPPFLAGS=$save_CPPFLAGS
 914  AC_MSG_RESULT($lyx_have_def_name)
 915  if test "x$lyx_have_def_name" = xyes; then
 916    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 917  fi
 918 ])
 919
 920 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 921 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 922 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 923 AC_DEFUN([LYX_SET_VERSION_INFO],
 924 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 925  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 926  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 927  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 928  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 929  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 930  test "x$lyx_patch" = "x" && lyx_patch=0
 931  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 932  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 933  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 934  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 935  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 936  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 937  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 938  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 939 ])
 940