config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set lyx_cv_prog_clang to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 150 AC_DEFUN([LYX_LIB_STDCXX],
 151 [AC_CACHE_CHECK([whether STL is libstdc++],
 152                [lyx_cv_lib_stdcxx],
 153 [AC_TRY_COMPILE([#include<vector>], [
 154 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 155             this is not libstdc++
 156 #endif
 157 ],
 158 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 159 ])
 160
 161
 162 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 163 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 164 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 165 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 166                [lyx_cv_lib_stdcxx_cxx11_abi],
 167 [AC_TRY_COMPILE([#include<vector>], [
 168 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 169             this is not libstdc++ using the C++11 ABI
 170 #endif
 171 ],
 172 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 173 ])
 174
 175
 176 AC_DEFUN([LYX_PROG_CXX],
 177 [AC_REQUIRE([AC_PROG_CXX])
 178 AC_REQUIRE([AC_PROG_CXXCPP])
 179
 180 AC_LANG_PUSH(C++)
 181 LYX_PROG_CLANG
 182 LYX_LIB_STDCXX
 183 LYX_LIB_STDCXX_CXX11_ABI
 184 AC_LANG_POP(C++)
 185
 186 if test $lyx_cv_lib_stdcxx = "yes" ; then
 187   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 188     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 189   else
 190     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 191   fi
 192 else
 193   if test $lyx_cv_prog_clang = "yes" ; then
 194     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 195   fi
 196 fi
 197
 198 ### We might want to get or shut warnings.
 199 AC_ARG_ENABLE(warnings,
 200   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 201   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 202         enable_warnings=yes;
 203     else
 204         enable_warnings=no;
 205     fi;])
 206 if test x$enable_warnings = xyes ; then
 207   lyx_flags="$lyx_flags warnings"
 208 fi
 209
 210 ### We might want to disable debug
 211 AC_ARG_ENABLE(debug,
 212   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 213   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 214 )
 215
 216 AC_ARG_ENABLE(stdlib-debug,
 217   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 218   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 219           [enable_stdlib_debug=no])]
 220 )
 221
 222 AC_ARG_ENABLE(concept-checks,
 223   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 224   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 225           [enable_concept_checks=no])]
 226   if test x$USE_QT5 = xyes ; then
 227       enable_concept_checks=no
 228   fi
 229 )
 230
 231 ### set up optimization
 232 AC_ARG_ENABLE(optimization,
 233     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 234     enable_optimization=yes;)
 235 case $enable_optimization in
 236     yes)
 237         if test $lyx_devel_version = yes ; then
 238             lyx_optim=-O
 239         else
 240             lyx_optim=-O2
 241         fi;;
 242     no) lyx_optim=;;
 243     *) lyx_optim=${enable_optimization};;
 244 esac
 245
 246 AC_ARG_ENABLE(pch,
 247   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 248         enable_pch=no;)
 249 lyx_pch_comp=no
 250
 251 AC_ARG_ENABLE(cxx11,
 252   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode]),,
 253   enable_cxx11=no;)
 254
 255 AC_ARG_ENABLE(assertions,
 256   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 257   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 258           [enable_assertions=no])]
 259 )
 260 if test "x$enable_assertions" = xyes ; then
 261    lyx_flags="$lyx_flags assertions"
 262    AC_DEFINE(ENABLE_ASSERTIONS,1,
 263     [Define if you want assertions to be enabled in the code])
 264 fi
 265
 266 # set the compiler options correctly.
 267 lyx_std_regex=no
 268 if test x$GXX = xyes; then
 269   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 270   if test x$CLANG = xno; then
 271     dnl Useful for global version info
 272     gxx_version=`${CXX} -dumpversion`
 273     CXX_VERSION="($gxx_version)"
 274   else
 275     gxx_version=clang
 276   fi
 277
 278   AM_CXXFLAGS="$lyx_optim"
 279   if test x$enable_debug = xyes ; then
 280       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 281   fi
 282   if test $build_type = gprof ; then
 283     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 284     AM_LDFLAGS="$AM_LDFLAGS -pg"
 285   fi
 286   if test $build_type = profiling ; then
 287     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 288   fi
 289
 290   if test x$USE_QT5 = xyes ; then
 291       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 292   fi
 293   dnl Warnings are for preprocessor too
 294   if test x$enable_warnings = xyes ; then
 295       case $gxx_version in
 296           3.1*|3.2*|3.3*)
 297               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -W"
 298               ;;
 299           3.4*|4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*|clang)
 300               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 301               ;;
 302           *)
 303               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra -Wfloat-conversion"
 304               ;;
 305       esac
 306   fi
 307   case $gxx_version in
 308       3.1*)    AM_CXXFLAGS="$AM_CXXFLAGS -finline-limit=500";;
 309       3.2*|3.3*) ;;
 310       *)  test $enable_pch = yes && lyx_pch_comp=yes ;;
 311   esac
 312   if test x$enable_stdlib_debug = xyes ; then
 313     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 314     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 315     case $gxx_version in
 316       3.1*|3.2*|3.3*) ;;
 317       *)
 318         lyx_flags="$lyx_flags stdlib-debug"
 319         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 320         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 321         ;;
 322     esac
 323   fi
 324   if test x$enable_concept_checks = xyes ; then
 325     case $gxx_version in
 326       3.3*)
 327         lyx_flags="$lyx_flags concept-checks"
 328         dnl FIXME check whether this makes sense with clang/libc++
 329         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 330         ;;
 331       3.4*|4.*)
 332         lyx_flags="$lyx_flags concept-checks"
 333         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 334         ;;
 335     esac
 336   fi
 337   if test x$enable_cxx11 = xyes ; then
 338     case $gxx_version in
 339       3.*|4.0*|4.1*|4.2*) AC_ERROR([There is no C++11 support in gcc 3.x]);;
 340       4.3*|4.4*|4.5*|4.6*)
 341         lyx_flags="$lyx_flags c++11-mode"
 342         AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++0x";;
 343       clang)
 344         dnl presumably all clang version support c++11.
 345         lyx_flags="$lyx_flags c++11-mode"
 346         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 347         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11 -Wno-deprecated-register";;
 348       *)
 349         lyx_flags="$lyx_flags c++11-mode"
 350         AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++11"
 351         ;;
 352     esac
 353     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 354       dnl <regex> in gcc is unusable in versions less than 4.9.0
 355       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 356       case $gxx_version in
 357         3.*|4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 358         *) lyx_flags="$lyx_flags stdregex"
 359            lyx_std_regex=yes
 360            ;;
 361       esac
 362     else
 363       lyx_flags="$lyx_flags stdregex"
 364       lyx_std_regex=yes
 365     fi
 366
 367     if test $lyx_std_regex = yes ; then
 368       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 369     fi
 370   fi
 371 fi
 372 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 373 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 374 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 375 ])dnl
 376
 377 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 378 dnl        be used.
 379 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 380         AC_MSG_CHECKING([whether to use included boost library])
 381         AC_ARG_WITH(included-boost,
 382             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 383             [lyx_cv_with_included_boost=$withval],
 384             [lyx_cv_with_included_boost=yes])
 385         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 386         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 387         if test x$lyx_cv_with_included_boost = xyes ; then
 388             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 389             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 390         else
 391             AC_LANG_PUSH(C++)
 392             save_LIBS=$LIBS
 393
 394             AC_MSG_CHECKING([for multithreaded boost libraries])
 395             LIBS="$save_LIBS -lboost_signals-mt -lm $LIBTHREAD"
 396             AC_LINK_IFELSE(
 397                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 398                         [boost::signal<void ()> s;])],
 399                 [AC_MSG_RESULT([yes])
 400                  BOOST_MT="-mt"],
 401                 [AC_MSG_RESULT([no])
 402                  AC_MSG_CHECKING([for plain boost libraries])
 403                  LIBS="$save_LIBS -lboost_signals -lm"
 404                  AC_LINK_IFELSE(
 405                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 406                              [boost::signal<void ()> s;])],
 407                      [AC_MSG_RESULT([yes])
 408                       BOOST_MT=""],
 409                      [AC_MSG_RESULT([no])
 410                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 411                  ])
 412             ])
 413             LIBS=$save_LIBS
 414             AC_LANG_POP(C++)
 415             BOOST_INCLUDES=
 416             if test $lyx_std_regex = yes ; then
 417               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 418             else
 419               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 420             fi
 421         fi
 422         AC_SUBST(BOOST_INCLUDES)
 423         AC_SUBST(BOOST_LIBS)
 424 ])
 425
 426
 427 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 428 dnl        necessary APIs are available to print callstacks.
 429 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 430 [AC_CACHE_CHECK([whether printing callstack is possible],
 431                [lyx_cv_callstack_printing],
 432 [AC_TRY_COMPILE([
 433 #include <execinfo.h>
 434 #include <cxxabi.h>
 435 ], [
 436         void* array[200];
 437         size_t size = backtrace(array, 200);
 438         backtrace_symbols(array, size);
 439         int status = 0;
 440         abi::__cxa_demangle("abcd", 0, 0, &status);
 441 ],
 442 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 443 if test x"$lyx_cv_callstack_printing" = xyes; then
 444   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 445             [Define if callstack can be printed])
 446 fi
 447 ])
 448
 449
 450 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 451 dnl        be used.
 452 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 453         AC_MSG_CHECKING([whether to use included MyThes library])
 454         AC_ARG_WITH(included-mythes,
 455             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 456             [lyx_cv_with_included_mythes=$withval],
 457             [lyx_cv_with_included_mythes=yes])
 458         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 459         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 460         if test x$lyx_cv_with_included_mythes != xyes ; then
 461                 AC_LANG_PUSH(C++)
 462                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 463                 if test x$ac_cv_header_mythes_h != xyes; then
 464                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 465                 fi
 466                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 467                 if test x$lyx_mythes != xyes; then
 468                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 469                 fi
 470                 AC_LANG_POP(C++)
 471                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 472                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 473                 fi
 474                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 475                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 476                 AC_SUBST(MYTHES_LIBS)
 477         fi
 478 ])
 479
 480
 481 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 482 dnl                       [default-yes-value])
 483 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 484 dnl  resulting directory name in 'dir-var-name'.
 485 AC_DEFUN([LYX_WITH_DIR],[
 486   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 487   AC_MSG_CHECKING([for $2])
 488   if test -z "$with_$3"; then
 489      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 490   else
 491     test "x$with_$3" = xyes && with_$3=$5
 492     lyx_cv_$3="$with_$3"
 493   fi
 494   AC_MSG_RESULT($lyx_cv_$3)])
 495
 496
 497 dnl Usage: LYX_LOOP_DIR(value,action)
 498 dnl Executes action for values of variable `dir' in `values'. `values' can
 499 dnl use ":" as a separator.
 500 AC_DEFUN([LYX_LOOP_DIR],[
 501 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 502 for dir in `eval "echo $1"`; do
 503   if test ! "$dir" = NONE; then
 504     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 505     $2
 506   fi
 507 done
 508 IFS=$ac_save_ifs
 509 ])
 510
 511
 512 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 513 dnl var-name.
 514 AC_DEFUN([LYX_ADD_LIB_DIR],[
 515 $1="${$1} -L$2"
 516 if test "`(uname) 2>/dev/null`" = SunOS &&
 517     uname -r | grep '^5' >/dev/null; then
 518   if test $ac_cv_prog_gxx = yes ; then
 519     $1="${$1} -Wl[,]-R$2"
 520   else
 521     $1="${$1} -R$2"
 522   fi
 523 fi])
 524
 525
 526 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 527 dnl var-name.
 528 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 529
 530 ### Check for a headers existence and location iff it exists
 531 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 532 ## It almost works.  I've tried a few variations but they give errors
 533 ## of one sort or other: bad substitution or file not found etc.  The
 534 ## actual header _is_ found though and the cache variable is set however
 535 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 536 ## reason.
 537 ## Additionally, autoheader can't figure out what to use as the name in
 538 ## the config.h.in file so we need to write our own entries there -- one for
 539 ## each header in the form PATH_HEADER_NAME_H
 540 ##
 541 AC_DEFUN([LYX_PATH_HEADER],
 542 [ AC_CHECK_HEADER($1,[
 543   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 544 ### the only remaining problem is getting the second parameter to this
 545 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 546 ### of $ac_safe being printed.
 547   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 548   [ cat > conftest.$ac_ext <<EOF
 549 #line __oline__ "configure"
 550 #include "confdefs.h"
 551
 552 #include <$1>
 553 EOF
 554 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 555   grep $1  2>/dev/null | \
 556   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 557 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 558 rm -f conftest*])
 559   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 560 ])
 561 ### end of LYX_PATH_HEADER
 562
 563 ## Check what kind of packaging should be used at install time.
 564 ## The default is autodetected.
 565 AC_DEFUN([LYX_USE_PACKAGING],
 566 [AC_MSG_CHECKING([what packaging should be used])
 567 AC_ARG_WITH(packaging,
 568   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 569                             Possible values: posix, windows, macosx])],
 570   [lyx_use_packaging="$withval"], [
 571   case $host in
 572     *-apple-darwin*) lyx_use_packaging=macosx ;;
 573      *-pc-mingw32*) lyx_use_packaging=windows;;
 574                   *) lyx_use_packaging=posix;;
 575   esac])
 576 AC_MSG_RESULT($lyx_use_packaging)
 577 lyx_install_posix=false
 578 lyx_install_macosx=false
 579 lyx_install_cygwin=false
 580 lyx_install_windows=false
 581 case $lyx_use_packaging in
 582    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 583            PACKAGE=LyX${version_suffix}
 584            default_prefix="/Applications/${PACKAGE}.app"
 585            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 586            bindir='${prefix}/Contents/MacOS'
 587            libdir='${prefix}/Contents/Resources'
 588            datarootdir='${prefix}/Contents/Resources'
 589            pkgdatadir='${datadir}'
 590            mandir='${datadir}/man'
 591            lyx_install_macosx=true ;;
 592   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 593            PACKAGE=LyX${version_suffix}
 594            default_prefix="C:/Program Files/${PACKAGE}"
 595            bindir='${prefix}/bin'
 596            libdir='${prefix}/Resources'
 597            datarootdir='${prefix}/Resources'
 598            pkgdatadir='${datadir}'
 599            mandir='${prefix}/Resources/man'
 600            lyx_install_windows=true ;;
 601     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 602            PACKAGE=lyx${version_suffix}
 603            program_suffix=$version_suffix
 604            pkgdatadir='${datadir}/${PACKAGE}'
 605            default_prefix=$ac_default_prefix
 606            case ${host} in
 607            *cygwin*) lyx_install_cygwin=true ;;
 608                 *apple-darwin*) lyx_install_macosx=true ;;
 609            esac
 610            lyx_install_posix=true ;;
 611     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 612 esac
 613 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 614 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 615 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 616 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 617 AC_SUBST(pkgdatadir)
 618 AC_SUBST(program_suffix)
 619 ])
 620
 621
 622 ## ------------------------------------------------------------------------
 623 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 624 ## one or two arguments.
 625 ##
 626 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 627 ## ------------------------------------------------------------------------
 628 ##
 629 AC_DEFUN([AC_FUNC_MKDIR],
 630 [AC_CHECK_FUNCS([mkdir _mkdir])
 631 AC_CACHE_CHECK([whether mkdir takes one argument],
 632                [ac_cv_mkdir_takes_one_arg],
 633 [AC_TRY_COMPILE([
 634 #include <sys/stat.h>
 635 #if HAVE_UNISTD_H
 636 #  include <unistd.h>
 637 #endif
 638 ], [mkdir (".");],
 639 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 640 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 641   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 642             [Define if mkdir takes only one argument.])
 643 fi
 644 ])
 645
 646
 647 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 648 dnl (which may be a relative path, and need not refer to any existing
 649 dnl entity).
 650
 651 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 652 dnl native Win32 path name, (but with slashes, not backslashes).
 653
 654 dnl On any other system, it is simply the result which would be obtained
 655 dnl if PATHNAME represented an existing directory, and the pwd command was
 656 dnl executed in that directory.
 657 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 658 [ac_dir="$2"
 659  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 660     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 661  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 662  do
 663    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 664  done
 665  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 666  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 667  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 668    s?/*$[]??'`
 669 ])
 670
 671 dnl this is used by the macro blow to general a proper config.h.in entry
 672 m4_define([LYX_AH_CHECK_DECL],
 673 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 674   [Define if you have the prototype for function `$1'])])
 675
 676 dnl Check things are declared in headers to avoid errors or warnings.
 677 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 678 dnl Defines HAVE_DECL_{FUNCTION}
 679 AC_DEFUN([LYX_CHECK_DECL],
 680 [LYX_AH_CHECK_DECL($1)
 681 for ac_header in $2
 682 do
 683   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 684   AC_EGREP_HEADER($1, $ac_header,
 685       [AC_MSG_RESULT(yes)
 686        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 687        break],
 688       [AC_MSG_RESULT(no)])
 689 done])
 690
 691 dnl this is used by the macro below to generate a proper config.h.in entry
 692 m4_define([LYX_AH_CHECK_DEF],
 693 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 694   [Define to 1 if `$1' is defined in `$2'])])
 695
 696 dnl Check whether name is defined in header by using it in codesnippet.
 697 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 698 dnl Defines HAVE_DEF_{NAME}
 699 AC_DEFUN([LYX_CHECK_DEF],
 700 [LYX_AH_CHECK_DEF($1, $2)
 701  AC_MSG_CHECKING([whether $1 is defined by header $2])
 702  AC_TRY_COMPILE([#include <$2>], [$3],
 703      lyx_have_def_name=yes,
 704      lyx_have_def_name=no)
 705  AC_MSG_RESULT($lyx_have_def_name)
 706  if test "x$lyx_have_def_name" = xyes; then
 707    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 708  fi
 709 ])
 710
 711 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 712 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 713 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 714 AC_DEFUN([LYX_SET_VERSION_INFO],
 715 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 716  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 717  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 718  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 719  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 720  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 721  test "x$lyx_patch" = "x" && lyx_patch=0
 722  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 723  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 724  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 725  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 726  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 727  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 728  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 729  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 730 ])
 731
 732 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 733 # ---------------------------------------------------------------------------
 734 # Copied from autoconf 2.68, added a check that python version is < 3.0
 735 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 736 # Run ACTION-IF-FALSE otherwise.
 737 # This test uses sys.hexversion instead of the string equivalent (first
 738 # word of sys.version), in order to cope with versions such as 2.2c1.
 739 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 740 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 741  [prog="import sys
 742 # split strings by '.' and convert to numeric.  Append some zeros
 743 # because we need at least 4 digits for the hex conversion.
 744 # map returns an iterator in Python 3.0 and a list in 2.x
 745 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 746 minverhex = 0
 747 maxverhex = 50331648 # = 3.0.0.0
 748 # xrange is not present in Python 3.0 and range returns an iterator
 749 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 750 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 751   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])