config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6 dnl Compute the default build type from AC_PACKAGE_VERSION at autoconf time.
   7 m4_define([LYX_BUILD_TYPE], [m4_bmatch(AC_PACKAGE_VERSION,
   8     [dev], [development],
   9     [pre\|alpha\|beta\|rc], [prerelease],
  10     [release])])
  11
  12
  13 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
  14 dnl sets variable "build_type"
  15 AC_DEFUN([LYX_CHECK_VERSION],[
  16 echo "configuring LyX version" AC_PACKAGE_VERSION
  17
  18 AC_MSG_CHECKING([for build type])
  19 lyx_devel_version=no
  20 lyx_prerelease=no
  21 AC_ARG_ENABLE(build-type,
  22   AC_HELP_STRING([--enable-build-type=STR],[set build type to rel(ease), pre(release), dev(elopment), prof(iling), or gprof (default: LYX_BUILD_TYPE)]),
  23   [case $enableval in
  24     dev*) build_type=development;;
  25     pre*) build_type=prerelease;;
  26     prof*)  build_type=profiling;;
  27     gprof*) build_type=gprof;;
  28     rel*) build_type=release;;
  29     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  30    esac],
  31   [build_type=LYX_BUILD_TYPE])
  32 AC_MSG_RESULT([$build_type])
  33 lyx_flags="$lyx_flags build=$build_type"
  34 case $build_type in
  35     development) lyx_devel_version=yes
  36                  LYX_DATE="not released yet" ;;
  37     prerelease) lyx_prerelease=yes ;;
  38 esac
  39
  40 AC_SUBST(lyx_devel_version)
  41 ])
  42
  43
  44 dnl Define the option to set a LyX version on installed executables and directories
  45 dnl
  46 dnl
  47 AC_DEFUN([LYX_VERSION_SUFFIX],[
  48 AC_MSG_CHECKING([for version suffix])
  49 dnl We need the literal double quotes in the rpm spec file
  50 RPM_VERSION_SUFFIX='""'
  51 AC_ARG_WITH(version-suffix,
  52   [AC_HELP_STRING([--with-version-suffix@<:@=STR@:>@], install lyx files as lyxSTR (default STR: -AC_PACKAGE_VERSION))],
  53   [if test "x$withval" = "xyes";
  54    then
  55      withval="-"AC_PACKAGE_VERSION
  56      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  57    fi
  58    AC_SUBST(version_suffix,$withval)
  59    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  60 AC_SUBST(RPM_VERSION_SUFFIX)
  61 AC_SUBST(program_base_name,"lyx")
  62 AC_MSG_RESULT([$withval])
  63 ])
  64
  65
  66 dnl Check whether to configure for Qt5. Default is Qt4.
  67 dnl
  68 AC_DEFUN([LYX_CHECK_QT5],[
  69 AC_MSG_CHECKING([whether Qt5 is requested])
  70 AC_ARG_ENABLE([qt5],
  71   [  --enable-qt5            use Qt5 for building],
  72   USE_QT5=$enableval, USE_QT5=no)
  73 AC_MSG_RESULT([$USE_QT5])
  74 AC_SUBST([USE_QT5])
  75 ])
  76
  77
  78 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  79 dnl flag lyx_warning to yes.
  80 AC_DEFUN([LYX_WARNING],[
  81 lyx_warning_txt="$lyx_warning_txt
  82 == $1
  83 "
  84 lyx_warning=yes])
  85
  86
  87 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  88 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  89 AC_DEFUN([LYX_LIB_ERROR],[
  90 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  91    is correctly installed on your system.])])
  92
  93
  94 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  95 dnl   has occurred previously.
  96 AC_DEFUN([LYX_CHECK_WARNINGS],[
  97 if test x$lyx_warning = xyes; then
  98 cat <<EOF
  99 === The following minor problems have been detected by configure.
 100 === Please check the messages below before running 'make'.
 101 === (see the section 'Problems' in the INSTALL file)
 102 $lyx_warning_txt
 103
 104 EOF
 105 fi])
 106
 107
 108 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 109 dnl
 110 define(LYX_SEARCH_PROG,[dnl
 111 for ac_prog in $2 ; do
 112 # Extract the first word of "$ac_prog", so it can be a program name with args.
 113   set dummy $ac_prog ; ac_word=$[2]
 114   if test -z "[$]$1"; then
 115     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 116     for ac_dir in $PATH; do
 117       test -z "$ac_dir" && ac_dir=.
 118       if test -f [$ac_dir/$ac_word]; then
 119         $1="$ac_prog"
 120         break
 121       fi
 122     done
 123     IFS="$ac_save_ifs"
 124   fi
 125
 126   if test -n "[$]$1"; then
 127     ac_result=yes
 128   else
 129     ac_result=no
 130   fi
 131   ifelse($3,,,[$3])
 132   test -n "[$]$1" && break
 133 done
 134 ])dnl
 135
 136
 137 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 138 AC_DEFUN([LYX_PROG_CLANG],
 139 [AC_CACHE_CHECK([whether the compiler is clang],
 140                [lyx_cv_prog_clang],
 141 [AC_TRY_COMPILE([], [
 142 #ifndef __clang__
 143             this is not clang
 144 #endif
 145 ],
 146 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 147 if test $CLANG = yes ; then
 148   AC_CACHE_CHECK([for clang version],
 149     [lyx_cv_clang_version],
 150     [clang_noversion=no
 151      AC_COMPUTE_INT(clang_major,__clang_major__,,[clang_noversion_=yes])
 152      AC_COMPUTE_INT(clang_minor,__clang_minor__,,[clang_noversion_=yes])
 153      AC_COMPUTE_INT(clang_patchlevel,__clang_patchlevel__,,[clang_noversion_=yes])
 154      if test $clang_noversion = yes ; then
 155        clang_version=unknown
 156      else
 157        clang_version=$clang_major.$clang_minor.$clang_patchlevel
 158      fi
 159      lyx_cv_clang_version=$clang_version])
 160 fi
 161 ])
 162
 163
 164 dnl Usage: LYX_CXX_CXX11_FLAGS: add to AM_CXXFLAGS the best flag that
 165 selects C++11 mode; gives an error when C++11 mode is not found.
 166 AC_DEFUN([LYX_CXX_CXX11_FLAGS],
 167 [AC_CACHE_CHECK([for at least C++11 mode], [lyx_cv_cxx11_flags],
 168  [lyx_cv_cxx11_flags=none
 169   for flag in -std=c++14 -std=c++11 "" -std=c++0x -std=gnu++14 -std=gnu++11 -std=gnu++0x ; do
 170     save_CPPFLAGS=$CPPFLAGS
 171     CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 172     save_CXXFLAGS=$CXXFLAGS
 173     CXXFLAGS="$flag $AM_CXXFLAGS $CXXFLAGS"
 174     dnl sample openmp source code to test
 175     AC_TRY_COMPILE([
 176        template <typename T>
 177        struct check
 178        {
 179            static_assert(sizeof(int) <= sizeof(T), "not big enough");
 180        };
 181
 182        typedef check<check<bool>> right_angle_brackets;
 183
 184        class TestDeleted
 185        {
 186        public:
 187            TestDeleted() = delete;
 188        };
 189
 190
 191        int a;
 192        decltype(a) b;
 193
 194        typedef check<int> check_type;
 195        check_type c;
 196        check_type&& cr = static_cast<check_type&&>(c);
 197
 198        auto d = a;], [],
 199     [lyx_cv_cxx11_flags=$flag; break])
 200    CXXFLAGS=$save_CXXFLAGS
 201    CPPFLAGS=$save_CPPFLAGS
 202   done])
 203   if test $lyx_cv_cxx11_flags = none ; then
 204     AC_ERROR([Cannot find suitable C++11 mode for compiler $CXX])
 205   fi
 206   AM_CXXFLAGS="$lyx_cv_cxx11_flags $AM_CXXFLAGS"
 207 ])
 208
 209
 210 dnl Usage: LYX_CXX_USE_REGEX
 211 dnl decide whether we want to use std::regex and set the
 212 dnl LYX_USE_STD_REGEX macro and conditional accordingly.
 213 AC_DEFUN([LYX_CXX_USE_REGEX],
 214 [AC_ARG_ENABLE(std-regex,
 215   AC_HELP_STRING([--enable-std-regex],[use std::regex instead of boost::regex (default is autodetected)]),
 216   [lyx_std_regex=$enableval],
 217   [AC_MSG_CHECKING([for correct regex implementation])
 218    save_CPPFLAGS=$CPPFLAGS
 219    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 220    save_CXXFLAGS=$CXXFLAGS
 221    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 222    # The following code snippet has been taken taken from example in
 223    #   http://stackoverflow.com/questions/8561850/compile-stdregex-iterator-with-gcc
 224    AC_TRY_LINK(
 225      [
 226         #include <regex>
 227         #include <iostream>
 228
 229         #include <string.h>
 230
 231         typedef std::regex_iterator<const char *> Myiter;
 232      ], [
 233         const char *pat = "axayaz";
 234         Myiter::regex_type rx("a");
 235         Myiter next(pat, pat + strlen(pat), rx);
 236         Myiter end;
 237    ], [lyx_std_regex=yes], [lyx_std_regex=no])
 238    CXXFLAGS=$save_CXXFLAGS
 239    CPPFLAGS=$save_CPPFLAGS
 240    AC_MSG_RESULT([$lyx_std_regex])
 241  ])
 242
 243  if test $lyx_std_regex = yes ; then
 244   lyx_flags="$lyx_flags std-regex"
 245   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 246  fi
 247  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 248 ])
 249
 250
 251 dnl Usage: LYX_CXX_USE_CALL_ONCE
 252 dnl check whether we can use std::call_once and set the
 253 dnl LYX_USE_STD_CALL_ONCE macro and conditional accordingly.
 254 AC_DEFUN([LYX_CXX_USE_CALL_ONCE],
 255 [AC_MSG_CHECKING([for std::call_once availability])
 256    save_CPPFLAGS=$CPPFLAGS
 257    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 258    save_CXXFLAGS=$CXXFLAGS
 259    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 260    AC_TRY_LINK(
 261      [
 262         #include <mutex>
 263         static std::once_flag flag;
 264      ], [
 265         std::call_once(flag, [](){ return; });
 266    ], [lyx_std_call_once=yes], [lyx_std_call_once=no])
 267    CXXFLAGS=$save_CXXFLAGS
 268    CPPFLAGS=$save_CPPFLAGS
 269    AC_MSG_RESULT([$lyx_std_call_once])
 270
 271  if test $lyx_std_call_once = yes ; then
 272   AC_DEFINE([LYX_USE_STD_CALL_ONCE], 1, [define to 1 if std::call_once is supported by the compiler])
 273  fi
 274  AM_CONDITIONAL([LYX_USE_STD_CALL_ONCE], test $lyx_std_call_once = yes)
 275 ])
 276
 277
 278 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 279 AC_DEFUN([LYX_LIB_STDCXX],
 280 [AC_CACHE_CHECK([whether STL is libstdc++],
 281                [lyx_cv_lib_stdcxx],
 282 [AC_TRY_COMPILE([#include<vector>], [
 283 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 284             this is not libstdc++
 285 #endif
 286 ],
 287 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 288 ])
 289
 290
 291 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 292 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 293 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 294 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 295                [lyx_cv_lib_stdcxx_cxx11_abi],
 296 [AC_TRY_COMPILE([#include<vector>], [
 297 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 298             this is not libstdc++ using the C++11 ABI
 299 #endif
 300 ],
 301 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 302 ])
 303
 304
 305 AC_DEFUN([LYX_PROG_CXX],
 306 [AC_REQUIRE([AC_PROG_CXX])
 307 AC_REQUIRE([AC_PROG_CXXCPP])
 308
 309 AC_LANG_PUSH(C++)
 310 LYX_PROG_CLANG
 311 LYX_CXX_CXX11_FLAGS
 312 LYX_LIB_STDCXX
 313 LYX_LIB_STDCXX_CXX11_ABI
 314 LYX_CXX_USE_REGEX
 315 LYX_CXX_USE_CALL_ONCE
 316 AC_LANG_POP(C++)
 317
 318 if test $lyx_cv_lib_stdcxx = "yes" ; then
 319   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 320     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 321   else
 322     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 323   fi
 324 else
 325   if test $lyx_cv_prog_clang = "yes" ; then
 326     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 327   fi
 328 fi
 329
 330 ### We might want to get or shut warnings.
 331 AC_ARG_ENABLE(warnings,
 332   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 333   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 334         enable_warnings=yes;
 335     else
 336         enable_warnings=no;
 337     fi;])
 338 if test x$enable_warnings = xyes ; then
 339   lyx_flags="$lyx_flags warnings"
 340 fi
 341
 342 ### We might want to disable debug
 343 AC_ARG_ENABLE(debug,
 344   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 345   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 346 )
 347
 348 AC_ARG_ENABLE(stdlib-debug,
 349   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 350   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 351           [enable_stdlib_debug=no])]
 352 )
 353
 354 ### set up optimization
 355 AC_ARG_ENABLE(optimization,
 356     AC_HELP_STRING([--enable-optimization@<:@=ARG@:>@],[enable compiler optimisation]),,
 357     enable_optimization=yes;)
 358 case $enable_optimization in
 359     yes)
 360         if test $lyx_devel_version = yes ; then
 361             lyx_optim=-O
 362         else
 363             lyx_optim=-O2
 364         fi;;
 365     no) lyx_optim=;;
 366     *) lyx_optim=${enable_optimization};;
 367 esac
 368
 369 AC_ARG_ENABLE(assertions,
 370   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 371   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 372           [enable_assertions=no])]
 373 )
 374 if test "x$enable_assertions" = xyes ; then
 375    lyx_flags="$lyx_flags assertions"
 376    AC_DEFINE(ENABLE_ASSERTIONS,1,
 377     [Define if you want assertions to be enabled in the code])
 378 fi
 379
 380 # set the compiler options correctly.
 381 if test x$GXX = xyes; then
 382   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 383   if test x$CLANG = xno; then
 384     dnl Useful for global version info
 385     gxx_version=`${CXX} -dumpversion`
 386     CXX_VERSION="($gxx_version)"
 387   else
 388     gxx_version=clang-$clang_version
 389     CXX_VERSION="($clang_version)"
 390   fi
 391
 392   AM_CXXFLAGS="$lyx_optim $AM_CXXFLAGS"
 393   if test x$enable_debug = xyes ; then
 394       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 395   fi
 396   if test $build_type = gprof ; then
 397     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 398     AM_LDFLAGS="$AM_LDFLAGS -pg"
 399   fi
 400   if test $build_type = profiling ; then
 401     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 402   fi
 403
 404   if test x$USE_QT5 = xyes ; then
 405       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 406   fi
 407   dnl Warnings are for preprocessor too
 408   if test x$enable_warnings = xyes ; then
 409       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 410   fi
 411   case $gxx_version in
 412       2.*|3.*) AC_ERROR([gcc >= 4.6 is required]);;
 413       4.0*|4.1*|4.2*|4.3*|4.4*|4.5*) AC_ERROR([gcc >= 4.6 is required]);;
 414   esac
 415   if test x$enable_stdlib_debug = xyes ; then
 416     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 417     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 418     case $gxx_version in
 419       *)
 420         lyx_flags="$lyx_flags stdlib-debug"
 421         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 422         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 423         ;;
 424     esac
 425   fi
 426 fi
 427
 428 # Some additional flags may be needed
 429 if test x$GXX = xyes; then
 430     case $gxx_version in
 431       clang-3.0*|clang-3.1*|clang-3.2*|clang-3.3*)
 432         dnl boost contains pragmas that are annoying on older clang versions
 433         AM_CPPFLAGS="-Wno-unknown-pragmas $AM_CPPFLAGS";;
 434       clang*)
 435         dnl the more recent versions support the deprecated-register warning,
 436         dnl which  is very annoying with Qt4.x right now.
 437         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 438     esac
 439 fi
 440 ])
 441
 442 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 443 dnl        be used.
 444 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 445         AC_MSG_CHECKING([whether to use included boost library])
 446         AC_ARG_WITH(included-boost,
 447             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 448             [lyx_cv_with_included_boost=$withval],
 449             [lyx_cv_with_included_boost=yes])
 450         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 451         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 452         if test x$lyx_cv_with_included_boost = xyes ; then
 453             lyx_included_libs="$lyx_included_libs boost"
 454             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 455             if test $lyx_std_regex = yes ; then
 456               BOOST_LIBS=""
 457             else
 458               BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 459             fi
 460         else
 461             BOOST_INCLUDES=
 462             if test $lyx_std_regex = yes ; then
 463               BOOST_LIBS=""
 464             else
 465               AC_LANG_PUSH(C++)
 466               save_LIBS=$LIBS
 467
 468               AC_MSG_CHECKING([for multithreaded boost libraries])
 469               LIBS="$save_LIBS -lboost_regex-mt $LIBTHREAD"
 470               AC_LINK_IFELSE(
 471                 [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 472                         [boost::regex reg;])],
 473                 [AC_MSG_RESULT([yes])
 474                  BOOST_MT="-mt"],
 475                 [AC_MSG_RESULT([no])
 476                  AC_MSG_CHECKING([for plain boost libraries])
 477                  LIBS="$save_LIBS -lboost_regex"
 478                  AC_LINK_IFELSE(
 479                      [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 480                              [boost::regex reg;])],
 481                      [AC_MSG_RESULT([yes])
 482                       BOOST_MT=""],
 483                      [AC_MSG_RESULT([no])
 484                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 485                  ])
 486               ])
 487               LIBS=$save_LIBS
 488               AC_LANG_POP(C++)
 489
 490               dnl In general, system boost libraries are incompatible with
 491               dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 492               dnl details.
 493               if test $enable_stdlib_debug = "yes" ; then
 494                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 495    crashes. Consider using --disable-stdlib-debug or removing
 496    --without-included-boost.])
 497               fi
 498
 499               BOOST_LIBS="-lboost_regex${BOOST_MT}"
 500             fi
 501         fi
 502         AC_SUBST(BOOST_INCLUDES)
 503         AC_SUBST(BOOST_LIBS)
 504 ])
 505
 506
 507 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 508 dnl        be used.
 509 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 510   AC_MSG_CHECKING([whether to use included iconv library])
 511   AC_ARG_WITH(included-iconv,
 512     [AC_HELP_STRING([--with-included-iconv], [use the iconv lib supplied with LyX instead of the system one])],
 513     [lyx_cv_with_included_iconv=$withval],
 514     [lyx_cv_with_included_iconv=no])
 515   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 516   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 517   if test x$lyx_cv_with_included_iconv = xyes ; then
 518   lyx_included_libs="$lyx_included_libs iconv"
 519
 520 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 521     AC_EILSEQ
 522     AC_TYPE_MBSTATE_T
 523     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 524 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 525     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 526       USE_MBSTATE_T=1
 527     else
 528       USE_MBSTATE_T=0
 529     fi
 530     AC_SUBST([USE_MBSTATE_T])
 531     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 532       [gl_cv_header_wchar_h_standalone],
 533       [AC_COMPILE_IFELSE(
 534         [AC_LANG_PROGRAM(
 535           [[#include <wchar.h>
 536             wchar_t w;]],
 537           [[]])],
 538         [gl_cv_header_wchar_h_standalone=yes],
 539         [gl_cv_header_wchar_h_standalone=no])])
 540     if test $gl_cv_header_wchar_h_standalone = yes; then
 541       BROKEN_WCHAR_H=0
 542     else
 543       BROKEN_WCHAR_H=1
 544     fi
 545     AC_SUBST([BROKEN_WCHAR_H])
 546 dnl we want const correctness
 547     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 548       [Define as const if the declaration of iconv() needs const.])
 549     ICONV_CONST=const
 550     AC_SUBST([ICONV_CONST])
 551 dnl we build a static lib
 552     DLL_VARIABLE=
 553     AC_SUBST([DLL_VARIABLE])
 554     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 555     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 556     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 557   else
 558     ICONV_INCLUDES=
 559     AM_ICONV
 560     if test "$am_cv_func_iconv" = no; then
 561       AC_MSG_ERROR([cannot find required library iconv.])
 562     else
 563       ICONV_LIBS="$LIBICONV"
 564     fi
 565     ICONV_ICONV_H_IN=
 566   fi
 567   AC_SUBST(ICONV_INCLUDES)
 568   AC_SUBST(ICONV_LIBS)
 569   AC_SUBST(ICONV_ICONV_H_IN)
 570 ])
 571
 572
 573 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 574 dnl        be used.
 575 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 576   AC_MSG_CHECKING([whether to use included zlib library])
 577   AC_ARG_WITH(included-zlib,
 578     [AC_HELP_STRING([--with-included-zlib], [use the zlib lib supplied with LyX instead of the system one])],
 579     [lyx_cv_with_included_zlib=$withval],
 580     [lyx_cv_with_included_zlib=no])
 581   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 582   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 583   if test x$lyx_cv_with_included_zlib = xyes ; then
 584     lyx_included_libs="$lyx_included_libs zlib"
 585     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 586     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 587     mkdir -p 3rdparty/zlib
 588 dnl include standard config.h for HAVE_UNISTD_H
 589     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 590 dnl prevent clash with system zlib that might be dragged in by other libs
 591     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 592     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 593   else
 594     ZLIB_INCLUDES=
 595     AC_CHECK_HEADERS(zlib.h,
 596       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 597       [LYX_LIB_ERROR(zlib.h,zlib)])
 598   fi
 599   AC_SUBST(ZLIB_INCLUDES)
 600   AC_SUBST(ZLIB_LIBS)
 601 ])
 602
 603
 604 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 605 dnl        necessary APIs are available to print callstacks.
 606 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 607 [AC_CACHE_CHECK([whether printing callstack is possible],
 608                [lyx_cv_callstack_printing],
 609 [AC_TRY_COMPILE([
 610 #include <execinfo.h>
 611 #include <cxxabi.h>
 612 ], [
 613         void* array[200];
 614         size_t size = backtrace(array, 200);
 615         backtrace_symbols(array, size);
 616         int status = 0;
 617         abi::__cxa_demangle("abcd", 0, 0, &status);
 618 ],
 619 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 620 if test x"$lyx_cv_callstack_printing" = xyes; then
 621   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 622             [Define if callstack can be printed])
 623 fi
 624 ])
 625
 626
 627 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 628 dnl        be used.
 629 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 630   AC_ARG_WITH(included-mythes,
 631     [AC_HELP_STRING([--with-included-mythes], [force to use the MyThes lib supplied with LyX])],
 632     [use_included_mythes=$withval],
 633     [use_included_mythes=no])
 634   if test x$use_included_mythes != xyes ; then
 635     AC_LANG_PUSH(C++)
 636     use_included_mythes=yes
 637     AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
 638       [mythes_h_location="<$ac_header>"
 639        save_LIBS=$LIBS
 640        AC_MSG_CHECKING([checking for MyThes library])
 641        for ac_lib in mythes mythes-1.2 ; do
 642          LIBS="-l$ac_lib $save_LIBS"
 643          AC_LINK_IFELSE(
 644            [AC_LANG_PROGRAM([#include <cstdio>]
 645               [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
 646            [MYTHES_LIBS=-l$ac_lib
 647             AC_MSG_RESULT([$MYTHES_LIBS])
 648             use_included_mythes=no])
 649        done
 650        if test $use_included_mythes != no ; then
 651          AC_MSG_RESULT([not found])
 652        fi
 653        break])
 654     AC_LANG_POP(C++)
 655   fi
 656   if test $use_included_mythes = yes ; then
 657     mythes_h_location="<mythes.hxx>"
 658     MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
 659     MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
 660     lyx_included_libs="$lyx_included_libs mythes"
 661   fi
 662   AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
 663   AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
 664   AC_SUBST(MYTHES_INCLUDES)
 665   AC_SUBST(MYTHES_LIBS)
 666   AC_MSG_CHECKING([whether to use included MyThes library])
 667   AC_MSG_RESULT([$use_included_mythes])
 668 ])
 669
 670
 671 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 672 dnl                       [default-yes-value])
 673 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 674 dnl  resulting directory name in 'dir-var-name'.
 675 AC_DEFUN([LYX_WITH_DIR],[
 676   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 677   AC_MSG_CHECKING([for $2])
 678   if test -z "$with_$3"; then
 679      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 680   else
 681     test "x$with_$3" = xyes && with_$3=$5
 682     lyx_cv_$3="$with_$3"
 683   fi
 684   AC_MSG_RESULT($lyx_cv_$3)
 685 ])
 686
 687
 688 dnl Usage: LYX_LOOP_DIR(value,action)
 689 dnl Executes action for values of variable `dir' in `values'. `values' can
 690 dnl use ":" as a separator.
 691 AC_DEFUN([LYX_LOOP_DIR],[
 692 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 693 for dir in `eval "echo $1"`; do
 694   if test ! "$dir" = NONE; then
 695     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 696     $2
 697   fi
 698 done
 699 IFS=$ac_save_ifs
 700 ])
 701
 702
 703 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 704 dnl var-name.
 705 AC_DEFUN([LYX_ADD_LIB_DIR],[
 706 $1="${$1} -L$2"
 707 if test "`(uname) 2>/dev/null`" = SunOS &&
 708     uname -r | grep '^5' >/dev/null; then
 709   if test $ac_cv_prog_gxx = yes ; then
 710     $1="${$1} -Wl[,]-R$2"
 711   else
 712     $1="${$1} -R$2"
 713   fi
 714 fi])
 715
 716
 717 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 718 dnl var-name.
 719 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 720
 721 ### Check for a headers existence and location iff it exists
 722 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 723 ## It almost works.  I've tried a few variations but they give errors
 724 ## of one sort or other: bad substitution or file not found etc.  The
 725 ## actual header _is_ found though and the cache variable is set however
 726 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 727 ## reason.
 728 ## Additionally, autoheader can't figure out what to use as the name in
 729 ## the config.h.in file so we need to write our own entries there -- one for
 730 ## each header in the form PATH_HEADER_NAME_H
 731 ##
 732 AC_DEFUN([LYX_PATH_HEADER],
 733 [ AC_CHECK_HEADER($1,[
 734   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 735 ### the only remaining problem is getting the second parameter to this
 736 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 737 ### of $ac_safe being printed.
 738   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 739   [ cat > conftest.$ac_ext <<EOF
 740 #line __oline__ "configure"
 741 #include "confdefs.h"
 742
 743 #include <$1>
 744 EOF
 745 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 746   grep $1  2>/dev/null | \
 747   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 748 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 749 rm -f conftest*])
 750   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 751 ])
 752 ### end of LYX_PATH_HEADER
 753
 754 ## Check what kind of packaging should be used at install time.
 755 ## The default is autodetected.
 756 AC_DEFUN([LYX_USE_PACKAGING],
 757 [AC_MSG_CHECKING([what packaging should be used])
 758 AC_ARG_WITH(packaging,
 759   [AC_HELP_STRING([--with-packaging=STR], [set packaging for installation among:
 760                             posix, windows, macosx, haiku (default is autodetected)])],
 761   [lyx_use_packaging="$withval"], [
 762   case $host in
 763     *-apple-darwin*) lyx_use_packaging=macosx ;;
 764     *-pc-mingw*) lyx_use_packaging=windows ;;
 765     *-mingw32*) lyx_use_packaging=windows ;;
 766     *haiku*) lyx_use_packaging=haiku ;;
 767     *) lyx_use_packaging=posix ;;
 768   esac])
 769 AC_MSG_RESULT($lyx_use_packaging)
 770 lyx_install_posix=false
 771 lyx_install_macosx=false
 772 lyx_install_cygwin=false
 773 lyx_install_windows=false
 774 case $lyx_use_packaging in
 775    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 776            PACKAGE=LyX${version_suffix}
 777            default_prefix="/Applications/${PACKAGE}.app"
 778            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 779            bindir='${prefix}/Contents/MacOS'
 780            libdir='${prefix}/Contents/Resources'
 781            datarootdir='${prefix}/Contents/Resources'
 782            pkgdatadir='${datadir}'
 783            mandir='${datadir}/man'
 784            lyx_install_macosx=true ;;
 785   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 786            PACKAGE=LyX${version_suffix}
 787            default_prefix="C:/Program Files/${PACKAGE}"
 788            bindir='${prefix}/bin'
 789            libdir='${prefix}/Resources'
 790            datarootdir='${prefix}/Resources'
 791            pkgdatadir='${datadir}'
 792            mandir='${prefix}/Resources/man'
 793            lyx_install_windows=true ;;
 794     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 795            PACKAGE=lyx${version_suffix}
 796            program_suffix=$version_suffix
 797            pkgdatadir='${datadir}/${PACKAGE}'
 798            default_prefix=$ac_default_prefix
 799            case ${host} in
 800              *cygwin*) lyx_install_cygwin=true ;;
 801              *apple-darwin*) lyx_install_macosx=true ;;
 802            esac
 803            lyx_install_posix=true ;;
 804         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 805            PACKAGE=lyx${version_suffix}
 806            program_suffix=$version_suffix
 807            pkgdatadir='${datadir}/${PACKAGE}'
 808            default_prefix=$ac_default_prefix
 809            lyx_install_posix=true ;;
 810     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 811 esac
 812 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 813 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 814 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 815 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 816 AC_SUBST(pkgdatadir)
 817 AC_SUBST(program_suffix)
 818 ])
 819
 820
 821 ## ------------------------------------------------------------------------
 822 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 823 ## one or two arguments.
 824 ##
 825 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 826 ## ------------------------------------------------------------------------
 827 ##
 828 AC_DEFUN([AC_FUNC_MKDIR],
 829 [AC_CHECK_FUNCS([mkdir _mkdir])
 830 AC_CACHE_CHECK([whether mkdir takes one argument],
 831                [ac_cv_mkdir_takes_one_arg],
 832 [AC_TRY_COMPILE([
 833 #include <sys/stat.h>
 834 #if HAVE_UNISTD_H
 835 #  include <unistd.h>
 836 #endif
 837 ], [mkdir (".");],
 838 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 839 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 840   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 841             [Define if mkdir takes only one argument.])
 842 fi
 843 ])
 844
 845
 846 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 847 dnl (which may be a relative path, and need not refer to any existing
 848 dnl entity).
 849
 850 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 851 dnl native Win32 path name, (but with slashes, not backslashes).
 852
 853 dnl On any other system, it is simply the result which would be obtained
 854 dnl if PATHNAME represented an existing directory, and the pwd command was
 855 dnl executed in that directory.
 856 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 857 [ac_dir="$2"
 858  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 859     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 860  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 861  do
 862    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 863  done
 864  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 865  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 866  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 867    s?/*$[]??'`
 868 ])
 869
 870 dnl this is used by the macro blow to general a proper config.h.in entry
 871 m4_define([LYX_AH_CHECK_DECL],
 872 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 873   [Define if you have the prototype for function `$1'])])
 874
 875 dnl Check things are declared in headers to avoid errors or warnings.
 876 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 877 dnl Defines HAVE_DECL_{FUNCTION}
 878 AC_DEFUN([LYX_CHECK_DECL],
 879 [LYX_AH_CHECK_DECL($1)
 880 for ac_header in $2
 881 do
 882   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 883   AC_EGREP_HEADER($1, $ac_header,
 884       [AC_MSG_RESULT(yes)
 885        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 886        break],
 887       [AC_MSG_RESULT(no)])
 888 done])
 889
 890 dnl this is used by the macro below to generate a proper config.h.in entry
 891 m4_define([LYX_AH_CHECK_DEF],
 892 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 893   [Define to 1 if `$1' is defined in `$2'])])
 894
 895 dnl Check whether name is defined in header by using it in codesnippet.
 896 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 897 dnl Defines HAVE_DEF_{NAME}
 898 AC_DEFUN([LYX_CHECK_DEF],
 899 [LYX_AH_CHECK_DEF($1, $2)
 900  AC_MSG_CHECKING([whether $1 is defined by header $2])
 901  save_CPPFLAGS=$CPPFLAGS
 902  CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 903  save_CXXFLAGS=$CXXFLAGS
 904  CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 905  AC_LANG_PUSH(C++)
 906  AC_TRY_COMPILE([#include <$2>], [$3],
 907      lyx_have_def_name=yes,
 908      lyx_have_def_name=no)
 909  AC_LANG_POP(C++)
 910  CXXFLAGS=$save_CXXFLAGS
 911  CPPFLAGS=$save_CPPFLAGS
 912  AC_MSG_RESULT($lyx_have_def_name)
 913  if test "x$lyx_have_def_name" = xyes; then
 914    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 915  fi
 916 ])
 917
 918 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 919 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 920 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 921 AC_DEFUN([LYX_SET_VERSION_INFO],
 922 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 923  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 924  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 925  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 926  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 927  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 928  test "x$lyx_patch" = "x" && lyx_patch=0
 929  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 930  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 931  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 932  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 933  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 934  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 935  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 936  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 937 ])
 938