config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171
 172 dnl Usage: LYX_CXX_USE_REGEX(cxx11_flags)
 173 dnl decide whether we want to use std::regex and set the
 174 dnl LYX_USE_STD_REGEX accordingly.
 175 dnl the extra cxx11 flags have to be passed to the preprocessor. They are
 176 dnl not plainly added to AM_CPPFLAGS because then the objc compiler (mac)
 177 dnl would fail.
 178 AC_DEFUN([LYX_CXX_USE_REGEX],
 179 [lyx_std_regex=no
 180    save_CPPFLAGS=$CPPFLAGS
 181    # we want to pass -std=c++11 to clang/cpp if necessary
 182    CPPFLAGS="$AM_CPPFLAGS $1 $CPPFLAGS"
 183    save_CXXFLAGS=$CXXFLAGS
 184    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 185    AC_LANG_PUSH(C++)
 186    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 187    AC_LANG_POP(C++)
 188    CXXFLAGS=$save_CXXFLAGS
 189    CPPFLAGS=$save_CPPFLAGS
 190    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 191      AC_MSG_CHECKING([for correct regex implementation])
 192      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 193        dnl <regex> in gcc is unusable in versions less than 4.9.0
 194        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 195        case $gxx_version in
 196          4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 197          *) ;;
 198        esac
 199      fi
 200    fi
 201    AC_MSG_RESULT([$lyx_std_regex])
 202
 203  if test $lyx_std_regex = yes ; then
 204   lyx_flags="$lyx_flags std-regex"
 205   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 206  fi
 207  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 208 ])
 209
 210
 211 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 212 AC_DEFUN([LYX_LIB_STDCXX],
 213 [AC_CACHE_CHECK([whether STL is libstdc++],
 214                [lyx_cv_lib_stdcxx],
 215 [AC_TRY_COMPILE([#include<vector>], [
 216 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 217             this is not libstdc++
 218 #endif
 219 ],
 220 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 221 ])
 222
 223
 224 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 225 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 226 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 227 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 228                [lyx_cv_lib_stdcxx_cxx11_abi],
 229 [AC_TRY_COMPILE([#include<vector>], [
 230 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 231             this is not libstdc++ using the C++11 ABI
 232 #endif
 233 ],
 234 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 235 ])
 236
 237
 238 AC_DEFUN([LYX_PROG_CXX],
 239 [AC_REQUIRE([AC_PROG_CXX])
 240 AC_REQUIRE([AC_PROG_CXXCPP])
 241
 242 AC_LANG_PUSH(C++)
 243 LYX_PROG_CLANG
 244 LYX_LIB_STDCXX
 245 LYX_LIB_STDCXX_CXX11_ABI
 246 AC_LANG_POP(C++)
 247
 248 if test $lyx_cv_lib_stdcxx = "yes" ; then
 249   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 250     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 251   else
 252     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 253   fi
 254 else
 255   if test $lyx_cv_prog_clang = "yes" ; then
 256     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 257   fi
 258 fi
 259
 260 ### We might want to get or shut warnings.
 261 AC_ARG_ENABLE(warnings,
 262   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 263   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 264         enable_warnings=yes;
 265     else
 266         enable_warnings=no;
 267     fi;])
 268 if test x$enable_warnings = xyes ; then
 269   lyx_flags="$lyx_flags warnings"
 270 fi
 271
 272 ### We might want to disable debug
 273 AC_ARG_ENABLE(debug,
 274   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 275   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 276 )
 277
 278 AC_ARG_ENABLE(stdlib-debug,
 279   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 280   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 281           [enable_stdlib_debug=no])]
 282 )
 283
 284 ### set up optimization
 285 AC_ARG_ENABLE(optimization,
 286     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 287     enable_optimization=yes;)
 288 case $enable_optimization in
 289     yes)
 290         if test $lyx_devel_version = yes ; then
 291             lyx_optim=-O
 292         else
 293             lyx_optim=-O2
 294         fi;;
 295     no) lyx_optim=;;
 296     *) lyx_optim=${enable_optimization};;
 297 esac
 298
 299 AC_ARG_ENABLE(assertions,
 300   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 301   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 302           [enable_assertions=no])]
 303 )
 304 if test "x$enable_assertions" = xyes ; then
 305    lyx_flags="$lyx_flags assertions"
 306    AC_DEFINE(ENABLE_ASSERTIONS,1,
 307     [Define if you want assertions to be enabled in the code])
 308 fi
 309
 310 # set the compiler options correctly.
 311 if test x$GXX = xyes; then
 312   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 313   if test x$CLANG = xno; then
 314     dnl Useful for global version info
 315     gxx_version=`${CXX} -dumpversion`
 316     CXX_VERSION="($gxx_version)"
 317   else
 318     gxx_version=clang
 319   fi
 320
 321   AM_CXXFLAGS="$lyx_optim"
 322   if test x$enable_debug = xyes ; then
 323       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 324   fi
 325   if test $build_type = gprof ; then
 326     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 327     AM_LDFLAGS="$AM_LDFLAGS -pg"
 328   fi
 329   if test $build_type = profiling ; then
 330     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 331   fi
 332
 333   if test x$USE_QT5 = xyes ; then
 334       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 335   fi
 336   dnl Warnings are for preprocessor too
 337   if test x$enable_warnings = xyes ; then
 338       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 339   fi
 340   case $gxx_version in
 341       2.*|3.*) AC_ERROR([gcc >= 4.3 is required]);;
 342       4.0*|4.1*|4.2*) AC_ERROR([gcc >= 4.3 is required]);;
 343   esac
 344   if test x$enable_stdlib_debug = xyes ; then
 345     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 346     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 347     case $gxx_version in
 348       *)
 349         lyx_flags="$lyx_flags stdlib-debug"
 350         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 351         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 352         ;;
 353     esac
 354   fi
 355     case $gxx_version in
 356       4.3*|4.4*|4.5*|4.6*)
 357         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 358         dnl The source code relies on that.
 359         cxx11_flags="-std=c++0x";;
 360       clang)
 361         dnl presumably all clang versions support c++11.
 362         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 363         cxx11_flags="-std=c++11"
 364         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 365       *)
 366         AS_CASE([$host], [*cygwin*],
 367                 [cxx11_flags="-std=gnu++11"],
 368                 [cxx11_flags="-std=c++11"]);;
 369     esac
 370     # cxx11_flags is useful when running preprocessor alone
 371     # (see detection of regex).
 372     AM_CXXFLAGS="$cxx11_flags $AM_CXXFLAGS"
 373 fi
 374
 375 LYX_CXX_CXX11
 376 if test $lyx_use_cxx11 = no; then
 377   AC_ERROR([A C++11 compatible compiler is required])
 378 fi
 379 LYX_CXX_USE_REGEX([$cxx11_flags])
 380 ])
 381
 382 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 383 dnl        be used.
 384 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 385         AC_MSG_CHECKING([whether to use included boost library])
 386         AC_ARG_WITH(included-boost,
 387             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 388             [lyx_cv_with_included_boost=$withval],
 389             [lyx_cv_with_included_boost=yes])
 390         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 391         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 392         if test x$lyx_cv_with_included_boost = xyes ; then
 393             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 394             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 395         else
 396             AC_LANG_PUSH(C++)
 397             save_LIBS=$LIBS
 398
 399             AC_MSG_CHECKING([for multithreaded boost libraries])
 400             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 401             AC_LINK_IFELSE(
 402                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 403                         [boost::signal<void ()> s;])],
 404                 [AC_MSG_RESULT([yes])
 405                  BOOST_MT="-mt"],
 406                 [AC_MSG_RESULT([no])
 407                  AC_MSG_CHECKING([for plain boost libraries])
 408                  LIBS="$save_LIBS -lboost_signals"
 409                  AC_LINK_IFELSE(
 410                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 411                              [boost::signal<void ()> s;])],
 412                      [AC_MSG_RESULT([yes])
 413                       BOOST_MT=""],
 414                      [AC_MSG_RESULT([no])
 415                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 416                  ])
 417             ])
 418             LIBS=$save_LIBS
 419             AC_LANG_POP(C++)
 420             BOOST_INCLUDES=
 421             if test $lyx_std_regex = yes ; then
 422               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 423             else
 424               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 425             fi
 426
 427             dnl In general, system boost libraries are incompatible with
 428             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 429             dnl details.
 430             if test $enable_stdlib_debug = "yes" ; then
 431                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 432    crashes. Consider using --disable-stdlib-debug or removing
 433    --without-included-boost.])
 434             fi
 435         fi
 436         AC_SUBST(BOOST_INCLUDES)
 437         AC_SUBST(BOOST_LIBS)
 438 ])
 439
 440
 441 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 442 dnl        be used.
 443 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 444   AC_MSG_CHECKING([whether to use included iconv library])
 445   AC_ARG_WITH(included-iconv,
 446     [AC_HELP_STRING([--without-included-iconv], [do not use the iconv lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 447     [lyx_cv_with_included_iconv=$withval],
 448     [lyx_cv_with_included_iconv=no])
 449   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 450   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 451   if test x$lyx_cv_with_included_iconv = xyes ; then
 452 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 453     AC_EILSEQ
 454     AC_TYPE_MBSTATE_T
 455     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 456 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 457     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 458       USE_MBSTATE_T=1
 459     else
 460       USE_MBSTATE_T=0
 461     fi
 462     AC_SUBST([USE_MBSTATE_T])
 463     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 464       [gl_cv_header_wchar_h_standalone],
 465       [AC_COMPILE_IFELSE(
 466         [AC_LANG_PROGRAM(
 467           [[#include <wchar.h>
 468             wchar_t w;]],
 469           [[]])],
 470         [gl_cv_header_wchar_h_standalone=yes],
 471         [gl_cv_header_wchar_h_standalone=no])])
 472     if test $gl_cv_header_wchar_h_standalone = yes; then
 473       BROKEN_WCHAR_H=0
 474     else
 475       BROKEN_WCHAR_H=1
 476     fi
 477     AC_SUBST([BROKEN_WCHAR_H])
 478 dnl we want const correctness
 479     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 480       [Define as const if the declaration of iconv() needs const.])
 481     ICONV_CONST=const
 482     AC_SUBST([ICONV_CONST])
 483 dnl we build a static lib
 484     DLL_VARIABLE=
 485     AC_SUBST([DLL_VARIABLE])
 486     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 487     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 488     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 489   else
 490     ICONV_INCLUDES=
 491     AM_ICONV
 492     if test "$am_cv_func_iconv" = no; then
 493       AC_MSG_ERROR([cannot find required library iconv.])
 494     else
 495       ICONV_LIBS="$LIBICONV"
 496     fi
 497     ICONV_ICONV_H_IN=
 498   fi
 499   AC_SUBST(ICONV_INCLUDES)
 500   AC_SUBST(ICONV_LIBS)
 501   AC_SUBST(ICONV_ICONV_H_IN)
 502 ])
 503
 504
 505 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 506 dnl        be used.
 507 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 508   AC_MSG_CHECKING([whether to use included zlib library])
 509   AC_ARG_WITH(included-zlib,
 510     [AC_HELP_STRING([--without-included-zlib], [do not use the zlib lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 511     [lyx_cv_with_included_zlib=$withval],
 512     [lyx_cv_with_included_zlib=no])
 513   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 514   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 515   if test x$lyx_cv_with_included_zlib = xyes ; then
 516     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 517     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 518     mkdir -p 3rdparty/zlib
 519 dnl include standard config.h for HAVE_UNISTD_H
 520     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 521 dnl prevent clash with system zlib that might be dragged in by other libs
 522     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 523     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 524   else
 525     ZLIB_INCLUDES=
 526     AC_CHECK_HEADERS(zlib.h,
 527       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 528       [LYX_LIB_ERROR(zlib.h,zlib)])
 529   fi
 530   AC_SUBST(ZLIB_INCLUDES)
 531   AC_SUBST(ZLIB_LIBS)
 532 ])
 533
 534
 535 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 536 dnl        necessary APIs are available to print callstacks.
 537 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 538 [AC_CACHE_CHECK([whether printing callstack is possible],
 539                [lyx_cv_callstack_printing],
 540 [AC_TRY_COMPILE([
 541 #include <execinfo.h>
 542 #include <cxxabi.h>
 543 ], [
 544         void* array[200];
 545         size_t size = backtrace(array, 200);
 546         backtrace_symbols(array, size);
 547         int status = 0;
 548         abi::__cxa_demangle("abcd", 0, 0, &status);
 549 ],
 550 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 551 if test x"$lyx_cv_callstack_printing" = xyes; then
 552   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 553             [Define if callstack can be printed])
 554 fi
 555 ])
 556
 557
 558 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 559 dnl        be used.
 560 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 561         AC_MSG_CHECKING([whether to use included MyThes library])
 562         AC_ARG_WITH(included-mythes,
 563             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 564             [lyx_cv_with_included_mythes=$withval],
 565             [lyx_cv_with_included_mythes=yes])
 566         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 567         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 568         if test x$lyx_cv_with_included_mythes != xyes ; then
 569                 AC_LANG_PUSH(C++)
 570                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 571                 if test x$ac_cv_header_mythes_h != xyes; then
 572                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 573                 fi
 574                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 575                 if test x$lyx_mythes != xyes; then
 576                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 577                 fi
 578                 AC_LANG_POP(C++)
 579                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 580                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 581                 fi
 582                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 583                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 584                 AC_SUBST(MYTHES_LIBS)
 585         fi
 586 ])
 587
 588
 589 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 590 dnl                       [default-yes-value])
 591 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 592 dnl  resulting directory name in 'dir-var-name'.
 593 AC_DEFUN([LYX_WITH_DIR],[
 594   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 595   AC_MSG_CHECKING([for $2])
 596   if test -z "$with_$3"; then
 597      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 598   else
 599     test "x$with_$3" = xyes && with_$3=$5
 600     lyx_cv_$3="$with_$3"
 601   fi
 602   AC_MSG_RESULT($lyx_cv_$3)])
 603
 604
 605 dnl Usage: LYX_LOOP_DIR(value,action)
 606 dnl Executes action for values of variable `dir' in `values'. `values' can
 607 dnl use ":" as a separator.
 608 AC_DEFUN([LYX_LOOP_DIR],[
 609 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 610 for dir in `eval "echo $1"`; do
 611   if test ! "$dir" = NONE; then
 612     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 613     $2
 614   fi
 615 done
 616 IFS=$ac_save_ifs
 617 ])
 618
 619
 620 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 621 dnl var-name.
 622 AC_DEFUN([LYX_ADD_LIB_DIR],[
 623 $1="${$1} -L$2"
 624 if test "`(uname) 2>/dev/null`" = SunOS &&
 625     uname -r | grep '^5' >/dev/null; then
 626   if test $ac_cv_prog_gxx = yes ; then
 627     $1="${$1} -Wl[,]-R$2"
 628   else
 629     $1="${$1} -R$2"
 630   fi
 631 fi])
 632
 633
 634 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 635 dnl var-name.
 636 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 637
 638 ### Check for a headers existence and location iff it exists
 639 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 640 ## It almost works.  I've tried a few variations but they give errors
 641 ## of one sort or other: bad substitution or file not found etc.  The
 642 ## actual header _is_ found though and the cache variable is set however
 643 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 644 ## reason.
 645 ## Additionally, autoheader can't figure out what to use as the name in
 646 ## the config.h.in file so we need to write our own entries there -- one for
 647 ## each header in the form PATH_HEADER_NAME_H
 648 ##
 649 AC_DEFUN([LYX_PATH_HEADER],
 650 [ AC_CHECK_HEADER($1,[
 651   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 652 ### the only remaining problem is getting the second parameter to this
 653 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 654 ### of $ac_safe being printed.
 655   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 656   [ cat > conftest.$ac_ext <<EOF
 657 #line __oline__ "configure"
 658 #include "confdefs.h"
 659
 660 #include <$1>
 661 EOF
 662 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 663   grep $1  2>/dev/null | \
 664   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 665 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 666 rm -f conftest*])
 667   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 668 ])
 669 ### end of LYX_PATH_HEADER
 670
 671 ## Check what kind of packaging should be used at install time.
 672 ## The default is autodetected.
 673 AC_DEFUN([LYX_USE_PACKAGING],
 674 [AC_MSG_CHECKING([what packaging should be used])
 675 AC_ARG_WITH(packaging,
 676   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 677                             Possible values: posix, windows, macosx, haiku])],
 678   [lyx_use_packaging="$withval"], [
 679   case $host in
 680     *-apple-darwin*) lyx_use_packaging=macosx ;;
 681     *-pc-mingw*) lyx_use_packaging=windows ;;
 682     *-mingw32*) lyx_use_packaging=windows ;;
 683     *haiku*) lyx_use_packaging=haiku ;;
 684     *) lyx_use_packaging=posix ;;
 685   esac])
 686 AC_MSG_RESULT($lyx_use_packaging)
 687 lyx_install_posix=false
 688 lyx_install_macosx=false
 689 lyx_install_cygwin=false
 690 lyx_install_windows=false
 691 case $lyx_use_packaging in
 692    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 693            PACKAGE=LyX${version_suffix}
 694            default_prefix="/Applications/${PACKAGE}.app"
 695            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 696            bindir='${prefix}/Contents/MacOS'
 697            libdir='${prefix}/Contents/Resources'
 698            datarootdir='${prefix}/Contents/Resources'
 699            pkgdatadir='${datadir}'
 700            mandir='${datadir}/man'
 701            lyx_install_macosx=true ;;
 702   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 703            PACKAGE=LyX${version_suffix}
 704            default_prefix="C:/Program Files/${PACKAGE}"
 705            bindir='${prefix}/bin'
 706            libdir='${prefix}/Resources'
 707            datarootdir='${prefix}/Resources'
 708            pkgdatadir='${datadir}'
 709            mandir='${prefix}/Resources/man'
 710            lyx_install_windows=true ;;
 711     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 712            PACKAGE=lyx${version_suffix}
 713            program_suffix=$version_suffix
 714            pkgdatadir='${datadir}/${PACKAGE}'
 715            default_prefix=$ac_default_prefix
 716            case ${host} in
 717              *cygwin*) lyx_install_cygwin=true ;;
 718              *apple-darwin*) lyx_install_macosx=true ;;
 719            esac
 720            lyx_install_posix=true ;;
 721         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 722            PACKAGE=lyx${version_suffix}
 723            program_suffix=$version_suffix
 724            pkgdatadir='${datadir}/${PACKAGE}'
 725            default_prefix=$ac_default_prefix
 726            lyx_install_posix=true ;;
 727     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 728 esac
 729 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 730 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 731 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 732 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 733 AC_SUBST(pkgdatadir)
 734 AC_SUBST(program_suffix)
 735 ])
 736
 737
 738 ## ------------------------------------------------------------------------
 739 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 740 ## one or two arguments.
 741 ##
 742 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 743 ## ------------------------------------------------------------------------
 744 ##
 745 AC_DEFUN([AC_FUNC_MKDIR],
 746 [AC_CHECK_FUNCS([mkdir _mkdir])
 747 AC_CACHE_CHECK([whether mkdir takes one argument],
 748                [ac_cv_mkdir_takes_one_arg],
 749 [AC_TRY_COMPILE([
 750 #include <sys/stat.h>
 751 #if HAVE_UNISTD_H
 752 #  include <unistd.h>
 753 #endif
 754 ], [mkdir (".");],
 755 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 756 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 757   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 758             [Define if mkdir takes only one argument.])
 759 fi
 760 ])
 761
 762
 763 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 764 dnl (which may be a relative path, and need not refer to any existing
 765 dnl entity).
 766
 767 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 768 dnl native Win32 path name, (but with slashes, not backslashes).
 769
 770 dnl On any other system, it is simply the result which would be obtained
 771 dnl if PATHNAME represented an existing directory, and the pwd command was
 772 dnl executed in that directory.
 773 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 774 [ac_dir="$2"
 775  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 776     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 777  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 778  do
 779    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 780  done
 781  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 782  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 783  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 784    s?/*$[]??'`
 785 ])
 786
 787 dnl this is used by the macro blow to general a proper config.h.in entry
 788 m4_define([LYX_AH_CHECK_DECL],
 789 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 790   [Define if you have the prototype for function `$1'])])
 791
 792 dnl Check things are declared in headers to avoid errors or warnings.
 793 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 794 dnl Defines HAVE_DECL_{FUNCTION}
 795 AC_DEFUN([LYX_CHECK_DECL],
 796 [LYX_AH_CHECK_DECL($1)
 797 for ac_header in $2
 798 do
 799   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 800   AC_EGREP_HEADER($1, $ac_header,
 801       [AC_MSG_RESULT(yes)
 802        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 803        break],
 804       [AC_MSG_RESULT(no)])
 805 done])
 806
 807 dnl this is used by the macro below to generate a proper config.h.in entry
 808 m4_define([LYX_AH_CHECK_DEF],
 809 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 810   [Define to 1 if `$1' is defined in `$2'])])
 811
 812 dnl Check whether name is defined in header by using it in codesnippet.
 813 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 814 dnl Defines HAVE_DEF_{NAME}
 815 AC_DEFUN([LYX_CHECK_DEF],
 816 [LYX_AH_CHECK_DEF($1, $2)
 817  AC_MSG_CHECKING([whether $1 is defined by header $2])
 818  AC_TRY_COMPILE([#include <$2>], [$3],
 819      lyx_have_def_name=yes,
 820      lyx_have_def_name=no)
 821  AC_MSG_RESULT($lyx_have_def_name)
 822  if test "x$lyx_have_def_name" = xyes; then
 823    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 824  fi
 825 ])
 826
 827 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 828 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 829 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 830 AC_DEFUN([LYX_SET_VERSION_INFO],
 831 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 832  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 833  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 834  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 835  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 836  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 837  test "x$lyx_patch" = "x" && lyx_patch=0
 838  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 839  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 840  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 841  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 842  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 843  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 844  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 845  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 846 ])
 847
 848 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 849 # ---------------------------------------------------------------------------
 850 # Copied from autoconf 2.68, added a check that python version is < 3.0
 851 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 852 # Run ACTION-IF-FALSE otherwise.
 853 # This test uses sys.hexversion instead of the string equivalent (first
 854 # word of sys.version), in order to cope with versions such as 2.2c1.
 855 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 856 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 857  [prog="import sys
 858 # split strings by '.' and convert to numeric.  Append some zeros
 859 # because we need at least 4 digits for the hex conversion.
 860 # map returns an iterator in Python 3.0 and a list in 2.x
 861 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 862 minverhex = 0
 863 maxverhex = 50331648 # = 3.0.0.0
 864 # xrange is not present in Python 3.0 and range returns an iterator
 865 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 866 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 867   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])