config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  66 dnl flag lyx_warning to yes.
  67 AC_DEFUN([LYX_WARNING],[
  68 lyx_warning_txt="$lyx_warning_txt
  69 == $1
  70 "
  71 lyx_warning=yes])
  72
  73
  74 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  75 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  76 AC_DEFUN([LYX_LIB_ERROR],[
  77 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  78    is correctly installed on your system.])])
  79
  80
  81 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  82 dnl   has occured previously.
  83 AC_DEFUN([LYX_CHECK_WARNINGS],[
  84 if test x$lyx_warning = xyes; then
  85 cat <<EOF
  86 === The following minor problems have been detected by configure.
  87 === Please check the messages below before running 'make'.
  88 === (see the section 'Problems' in the INSTALL file)
  89 $lyx_warning_txt
  90
  91 EOF
  92 fi])
  93
  94
  95 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
  96 dnl
  97 define(LYX_SEARCH_PROG,[dnl
  98 for ac_prog in $2 ; do
  99 # Extract the first word of "$ac_prog", so it can be a program name with args.
 100   set dummy $ac_prog ; ac_word=$[2]
 101   if test -z "[$]$1"; then
 102     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 103     for ac_dir in $PATH; do
 104       test -z "$ac_dir" && ac_dir=.
 105       if test -f [$ac_dir/$ac_word]; then
 106         $1="$ac_prog"
 107         break
 108       fi
 109     done
 110     IFS="$ac_save_ifs"
 111   fi
 112
 113   if test -n "[$]$1"; then
 114     ac_result=yes
 115   else
 116     ac_result=no
 117   fi
 118   ifelse($3,,,[$3])
 119   test -n "[$]$1" && break
 120 done
 121 ])dnl
 122
 123
 124 AC_DEFUN([LYX_PROG_CXX_WORKS],
 125 [rm -f conftest.C
 126 cat >conftest.C <<EOF
 127 class foo {
 128    // we require the mutable keyword
 129    mutable int bar;
 130  };
 131  // we require namespace support
 132  namespace baz {
 133    int bar;
 134  }
 135  int main() {
 136    return(0);
 137  }
 138 EOF
 139 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 140 rm -f conftest.C conftest.o conftest.obj || true
 141 ])
 142
 143
 144 dnl Usage: LYX_PROG_CLANG: set lyx_cv_prog_clang to yes if the compiler is clang.
 145 AC_DEFUN([LYX_PROG_CLANG],
 146 [AC_CACHE_CHECK([for clang],
 147                [lyx_cv_prog_clang],
 148 [AC_TRY_COMPILE([], [
 149 #ifndef __clang__
 150             this is not clang
 151 #endif
 152 ],
 153 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 154 ])
 155
 156
 157 AC_DEFUN([LYX_PROG_CXX],
 158 [AC_MSG_CHECKING([for a good enough C++ compiler])
 159 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 160
 161 if test -z "$CXX" ; then
 162   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 163 fi
 164 AC_MSG_RESULT($CXX)
 165
 166 AC_REQUIRE([AC_PROG_CXX])
 167 AC_REQUIRE([AC_PROG_CXXCPP])
 168 AC_LANG_PUSH(C++)
 169 LYX_PROG_CLANG
 170 AC_LANG_POP(C++)
 171
 172 ### We might want to get or shut warnings.
 173 AC_ARG_ENABLE(warnings,
 174   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 175   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 176         enable_warnings=yes;
 177     else
 178         enable_warnings=no;
 179     fi;])
 180 if test x$enable_warnings = xyes ; then
 181   lyx_flags="$lyx_flags warnings"
 182 fi
 183
 184 ### We might want to disable debug
 185 AC_ARG_ENABLE(debug,
 186   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 187   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 188 )
 189
 190 AC_ARG_ENABLE(stdlib-debug,
 191   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 192   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 193           [enable_stdlib_debug=no])]
 194 )
 195
 196 AC_ARG_ENABLE(concept-checks,
 197   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 198   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 199           [enable_concept_checks=no])]
 200 )
 201
 202 ### set up optimization
 203 AC_ARG_ENABLE(optimization,
 204     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 205     enable_optimization=yes;)
 206 case $enable_optimization in
 207     yes)
 208         if test $lyx_devel_version = yes ; then
 209             lyx_opt=-O
 210         else
 211             lyx_opt=-O2
 212         fi;;
 213     no) lyx_opt=;;
 214     *) lyx_opt=${enable_optimization};;
 215 esac
 216
 217 AC_ARG_ENABLE(pch,
 218   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 219         enable_pch=no;)
 220 lyx_pch_comp=no
 221
 222 AC_ARG_ENABLE(cxx11,
 223   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode]),,
 224   enable_cxx11=no;)
 225
 226 AC_ARG_ENABLE(assertions,
 227   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 228   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 229           [enable_assertions=no])]
 230 )
 231 if test "x$enable_assertions" = xyes ; then
 232    lyx_flags="$lyx_flags assertions"
 233    AC_DEFINE(ENABLE_ASSERTIONS,1,
 234     [Define if you want assertions to be enabled in the code])
 235 fi
 236
 237 # set the compiler options correctly.
 238 if test x$GXX = xyes; then
 239   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 240   if test x$CLANG = xno; then
 241     dnl Useful for global version info
 242     gxx_version=`${CXX} -dumpversion`
 243     CXX_VERSION="($gxx_version)"
 244   fi
 245
 246   if test "$ac_test_CXXFLAGS" = set; then
 247     CXXFLAGS="$ac_save_CXXFLAGS"
 248   else
 249     CFLAGS="$lyx_opt"
 250     CXXFLAGS="$lyx_opt"
 251     if test x$enable_debug = xyes ; then
 252       CFLAGS="-g $CFLAGS"
 253       CXXFLAGS="-g $CXXFLAGS"
 254     fi
 255     if test $build_type = gprof ; then
 256       CFLAGS="-pg $CFLAGS"
 257       CXXFLAGS="-pg $CXXFLAGS"
 258       LDFLAGS="-pg $LDFLAGS"
 259     fi
 260     if test $build_type = profiling ; then
 261       CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 262       CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 263     fi
 264   fi
 265   if test "$ac_env_CPPFLAGS_set" != set; then
 266     if test x$enable_warnings = xyes ; then
 267         case $gxx_version in
 268             3.1*|3.2*|3.3*)
 269                 CPPFLAGS="-W -Wall $CPPFLAGS"
 270                 ;;
 271             *)
 272                 CPPFLAGS="-Wextra -Wall $CPPFLAGS "
 273                 ;;
 274         esac
 275     fi
 276   fi
 277   case $gxx_version in
 278       3.1*)    AM_CXXFLAGS="-finline-limit=500 ";;
 279       3.2*|3.3*)    AM_CXXFLAGS="";;
 280       3.4*|4.*)
 281           AM_CXXFLAGS=""
 282           test $enable_pch = yes && lyx_pch_comp=yes
 283           ;;
 284       *)       AM_CXXFLAGS="";;
 285   esac
 286   if test x$enable_stdlib_debug = xyes ; then
 287     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 288     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 289     case $gxx_version in
 290       3.4*|4.*)
 291         lyx_flags="$lyx_flags stdlib-debug"
 292         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 293         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 294         ;;
 295     esac
 296   fi
 297   if test x$enable_concept_checks = xyes ; then
 298     case $gxx_version in
 299       3.3*)
 300         lyx_flags="$lyx_flags concept-checks"
 301         dnl FIXME check whether this makes sense with clang/libc++
 302         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 303         ;;
 304       3.4*|4.*)
 305         lyx_flags="$lyx_flags concept-checks"
 306         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 307         ;;
 308     esac
 309   fi
 310   if test x$enable_cxx11 = xyes ; then
 311       dnl FIXME: check what to do with clang (is anything needed at all?)
 312       case $gxx_version in
 313           4.3*|4.4*|4.5*|4.6*)
 314               lyx_flags="$lyx_flags c++11-mode"
 315               CXXFLAGS="-std=gnu++0x $CXXFLAGS"
 316               ;;
 317           4.7*|4.8*)
 318               lyx_flags="$lyx_flags c++11-mode"
 319               CXXFLAGS="-std=gnu++11 $CXXFLAGS"
 320               ;;
 321       esac
 322   fi
 323   dnl FIXME: this should be conditional to the use of libstdc++
 324   AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 325 fi
 326 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 327 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 328 ])dnl
 329
 330 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 331 dnl        be used.
 332 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 333         AC_MSG_CHECKING([whether to use included boost library])
 334         AC_ARG_WITH(included-boost,
 335             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 336             [lyx_cv_with_included_boost=$withval],
 337             [lyx_cv_with_included_boost=yes])
 338         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 339         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 340         if test x$lyx_cv_with_included_boost = xyes ; then
 341             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 342             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 343         else
 344             AC_LANG_PUSH(C++)
 345             save_LIBS=$LIBS
 346
 347             AC_MSG_CHECKING([for multithreaded boost libraries])
 348             LIBS="$save_LIBS -lboost_signals-mt -lm $LIBTHREAD"
 349             AC_LINK_IFELSE(
 350                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 351                         [boost::signal<void ()> s;])],
 352                 [AC_MSG_RESULT([yes])
 353                  BOOST_MT="-mt"],
 354                 [AC_MSG_RESULT([no])
 355                  AC_MSG_CHECKING([for plain boost libraries])
 356                  LIBS="$save_LIBS -lboost_signals -lm"
 357                  AC_LINK_IFELSE(
 358                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 359                              [boost::signal<void ()> s;])],
 360                      [AC_MSG_RESULT([yes])
 361                       BOOST_MT=""],
 362                      [AC_MSG_RESULT([no])
 363                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 364                  ])
 365             ])
 366             LIBS=$save_LIBS
 367             AC_LANG_POP(C++)
 368             BOOST_INCLUDES=
 369             BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 370         fi
 371         AC_SUBST(BOOST_INCLUDES)
 372         AC_SUBST(BOOST_LIBS)
 373 ])
 374
 375
 376 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 377 dnl        necessary APIs are available to print callstacks.
 378 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 379 [AC_CACHE_CHECK([whether printing callstack is possible],
 380                [lyx_cv_callstack_printing],
 381 [AC_TRY_COMPILE([
 382 #include <execinfo.h>
 383 #include <cxxabi.h>
 384 ], [
 385         void* array[200];
 386         size_t size = backtrace(array, 200);
 387         backtrace_symbols(array, size);
 388         int status = 0;
 389         abi::__cxa_demangle("abcd", 0, 0, &status);
 390 ],
 391 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 392 if test x"$lyx_cv_callstack_printing" = xyes; then
 393   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 394             [Define if callstack can be printed])
 395 fi
 396 ])
 397
 398
 399 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 400 dnl        be used.
 401 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 402         AC_MSG_CHECKING([whether to use included MyThes library])
 403         AC_ARG_WITH(included-mythes,
 404             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 405             [lyx_cv_with_included_mythes=$withval],
 406             [lyx_cv_with_included_mythes=yes])
 407         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 408         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 409         if test x$lyx_cv_with_included_mythes != xyes ; then
 410                 AC_LANG_PUSH(C++)
 411                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 412                 if test x$ac_cv_header_mythes_h != xyes; then
 413                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 414                 fi
 415                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 416                 if test x$lyx_mythes != xyes; then
 417                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 418                 fi
 419                 AC_LANG_POP(C++)
 420                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 421                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 422                 fi
 423                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 424                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 425                 AC_SUBST(MYTHES_LIBS)
 426         fi
 427 ])
 428
 429
 430 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 431 dnl                       [default-yes-value])
 432 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 433 dnl  resulting directory name in 'dir-var-name'.
 434 AC_DEFUN([LYX_WITH_DIR],[
 435   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 436   AC_MSG_CHECKING([for $2])
 437   if test -z "$with_$3"; then
 438      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 439   else
 440     test "x$with_$3" = xyes && with_$3=$5
 441     lyx_cv_$3="$with_$3"
 442   fi
 443   AC_MSG_RESULT($lyx_cv_$3)])
 444
 445
 446 dnl Usage: LYX_LOOP_DIR(value,action)
 447 dnl Executes action for values of variable `dir' in `values'. `values' can
 448 dnl use ":" as a separator.
 449 AC_DEFUN([LYX_LOOP_DIR],[
 450 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 451 for dir in `eval "echo $1"`; do
 452   if test ! "$dir" = NONE; then
 453     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 454     $2
 455   fi
 456 done
 457 IFS=$ac_save_ifs
 458 ])
 459
 460
 461 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 462 dnl var-name.
 463 AC_DEFUN([LYX_ADD_LIB_DIR],[
 464 $1="${$1} -L$2"
 465 if test "`(uname) 2>/dev/null`" = SunOS &&
 466     uname -r | grep '^5' >/dev/null; then
 467   if test $ac_cv_prog_gxx = yes ; then
 468     $1="${$1} -Wl[,]-R$2"
 469   else
 470     $1="${$1} -R$2"
 471   fi
 472 fi])
 473
 474
 475 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 476 dnl var-name.
 477 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 478
 479 ### Check for a headers existence and location iff it exists
 480 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 481 ## It almost works.  I've tried a few variations but they give errors
 482 ## of one sort or other: bad substitution or file not found etc.  The
 483 ## actual header _is_ found though and the cache variable is set however
 484 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 485 ## reason.
 486 ## Additionally, autoheader can't figure out what to use as the name in
 487 ## the config.h.in file so we need to write our own entries there -- one for
 488 ## each header in the form PATH_HEADER_NAME_H
 489 ##
 490 AC_DEFUN([LYX_PATH_HEADER],
 491 [ AC_CHECK_HEADER($1,[
 492   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 493 ### the only remaining problem is getting the second parameter to this
 494 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 495 ### of $ac_safe being printed.
 496   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 497   [ cat > conftest.$ac_ext <<EOF
 498 #line __oline__ "configure"
 499 #include "confdefs.h"
 500
 501 #include <$1>
 502 EOF
 503 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 504   grep $1  2>/dev/null | \
 505   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 506 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 507 rm -f conftest*])
 508   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 509 ])
 510 ### end of LYX_PATH_HEADER
 511
 512 ## Check what kind of packaging should be used at install time.
 513 ## The default is autodetected.
 514 AC_DEFUN([LYX_USE_PACKAGING],
 515 [AC_MSG_CHECKING([what packaging should be used])
 516 AC_ARG_WITH(packaging,
 517   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 518                             Possible values: posix, windows, macosx])],
 519   [lyx_use_packaging="$withval"], [
 520   case $host in
 521     *-apple-darwin*) lyx_use_packaging=macosx ;;
 522      *-pc-mingw32*) lyx_use_packaging=windows;;
 523                   *) lyx_use_packaging=posix;;
 524   esac])
 525 AC_MSG_RESULT($lyx_use_packaging)
 526 lyx_install_posix=false
 527 lyx_install_macosx=false
 528 lyx_install_cygwin=false
 529 lyx_install_windows=false
 530 case $lyx_use_packaging in
 531    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 532            PACKAGE=LyX${version_suffix}
 533            default_prefix="/Applications/${PACKAGE}.app"
 534            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 535            bindir='${prefix}/Contents/MacOS'
 536            libdir='${prefix}/Contents/Resources'
 537            datarootdir='${prefix}/Contents/Resources'
 538            pkgdatadir='${datadir}'
 539            mandir='${datadir}/man'
 540            lyx_install_macosx=true ;;
 541   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 542            PACKAGE=LyX${version_suffix}
 543            default_prefix="C:/Program Files/${PACKAGE}"
 544            bindir='${prefix}/bin'
 545            libdir='${prefix}/Resources'
 546            datarootdir='${prefix}/Resources'
 547            pkgdatadir='${datadir}'
 548            mandir='${prefix}/Resources/man'
 549            lyx_install_windows=true ;;
 550     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 551            PACKAGE=lyx${version_suffix}
 552            program_suffix=$version_suffix
 553            pkgdatadir='${datadir}/${PACKAGE}'
 554            default_prefix=$ac_default_prefix
 555            case ${host} in
 556            *cygwin*) lyx_install_cygwin=true ;;
 557                 *apple-darwin*) lyx_install_macosx=true ;;
 558            esac
 559            lyx_install_posix=true ;;
 560     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 561 esac
 562 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 563 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 564 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 565 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 566 AC_SUBST(pkgdatadir)
 567 AC_SUBST(program_suffix)
 568 ])
 569
 570
 571 ## ------------------------------------------------------------------------
 572 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 573 ## one or two arguments.
 574 ##
 575 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 576 ## ------------------------------------------------------------------------
 577 ##
 578 AC_DEFUN([AC_FUNC_MKDIR],
 579 [AC_CHECK_FUNCS([mkdir _mkdir])
 580 AC_CACHE_CHECK([whether mkdir takes one argument],
 581                [ac_cv_mkdir_takes_one_arg],
 582 [AC_TRY_COMPILE([
 583 #include <sys/stat.h>
 584 #if HAVE_UNISTD_H
 585 #  include <unistd.h>
 586 #endif
 587 ], [mkdir (".");],
 588 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 589 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 590   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 591             [Define if mkdir takes only one argument.])
 592 fi
 593 ])
 594
 595
 596 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 597 dnl (which may be a relative path, and need not refer to any existing
 598 dnl entity).
 599
 600 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 601 dnl native Win32 path name, (but with slashes, not backslashes).
 602
 603 dnl On any other system, it is simply the result which would be obtained
 604 dnl if PATHNAME represented an existing directory, and the pwd command was
 605 dnl executed in that directory.
 606 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 607 [ac_dir="$2"
 608  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 609     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 610  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 611  do
 612    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 613  done
 614  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 615  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 616  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 617    s?/*$[]??'`
 618 ])
 619
 620 dnl this is used by the macro blow to general a proper config.h.in entry
 621 m4_define([LYX_AH_CHECK_DECL],
 622 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 623   [Define if you have the prototype for function `$1'])])
 624
 625 dnl Check things are declared in headers to avoid errors or warnings.
 626 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 627 dnl Defines HAVE_DECL_{FUNCTION}
 628 AC_DEFUN([LYX_CHECK_DECL],
 629 [LYX_AH_CHECK_DECL($1)
 630 for ac_header in $2
 631 do
 632   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 633   AC_EGREP_HEADER($1, $ac_header,
 634       [AC_MSG_RESULT(yes)
 635        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 636        break],
 637       [AC_MSG_RESULT(no)])
 638 done])
 639
 640 dnl this is used by the macro below to generate a proper config.h.in entry
 641 m4_define([LYX_AH_CHECK_DEF],
 642 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 643   [Define to 1 if `$1' is defined in `$2'])])
 644
 645 dnl Check whether name is defined in header by using it in codesnippet.
 646 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 647 dnl Defines HAVE_DEF_{NAME}
 648 AC_DEFUN([LYX_CHECK_DEF],
 649 [LYX_AH_CHECK_DEF($1, $2)
 650  AC_MSG_CHECKING([whether $1 is defined by header $2])
 651  AC_TRY_COMPILE([#include <$2>], [$3],
 652      lyx_have_def_name=yes,
 653      lyx_have_def_name=no)
 654  AC_MSG_RESULT($lyx_have_def_name)
 655  if test "x$lyx_have_def_name" = xyes; then
 656    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 657  fi
 658 ])
 659
 660 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 661 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 662 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 663 AC_DEFUN([LYX_SET_VERSION_INFO],
 664 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 665  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 666  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 667  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 668  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 669  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 670  test "x$lyx_patch" = "x" && lyx_patch=0
 671  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 672  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 673  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 674  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 675  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 676  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 677  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 678  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 679 ])
 680
 681 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 682 # ---------------------------------------------------------------------------
 683 # Copied from autoconf 2.68, added a check that python version is < 3.0
 684 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 685 # Run ACTION-IF-FALSE otherwise.
 686 # This test uses sys.hexversion instead of the string equivalent (first
 687 # word of sys.version), in order to cope with versions such as 2.2c1.
 688 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 689 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 690  [prog="import sys
 691 # split strings by '.' and convert to numeric.  Append some zeros
 692 # because we need at least 4 digits for the hex conversion.
 693 # map returns an iterator in Python 3.0 and a list in 2.x
 694 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 695 minverhex = 0
 696 maxverhex = 50331648 # = 3.0.0.0
 697 # xrange is not present in Python 3.0 and range returns an iterator
 698 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 699 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 700   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])