config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN(LYX_CHECK_VERSION,[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN(LYX_VERSION_SUFFIX,[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN(LYX_ERROR,[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN(LYX_WARNING,[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN(LYX_LIB_ERROR,[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN(LYX_CHECK_ERRORS,[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 deleting cache $cache_file
  85 EOF
  86   rm -f $cache_file
  87 else
  88
  89 if test x$lyx_warning = xyes; then
  90 cat <<EOF
  91 === The following minor problems have been detected by configure.
  92 === Please check the messages below before running 'make'.
  93 === (see the section 'Problems' in the INSTALL file)
  94 $lyx_warning_txt
  95 EOF
  96 fi
  97 cat <<EOF
  98 Configuration of LyX was successful.
  99 Type 'make' to compile the program,
 100 and then 'make install' to install it.
 101 EOF
 102 fi])
 103
 104
 105 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 106 dnl
 107 define(LYX_SEARCH_PROG,[dnl
 108 for ac_prog in $2 ; do
 109 # Extract the first word of "$ac_prog", so it can be a program name with args.
 110   set dummy $ac_prog ; ac_word=$[2]
 111   if test -z "[$]$1"; then
 112     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 113     for ac_dir in $PATH; do
 114       test -z "$ac_dir" && ac_dir=.
 115       if test -f [$ac_dir/$ac_word]; then
 116         $1="$ac_prog"
 117         break
 118       fi
 119     done
 120     IFS="$ac_save_ifs"
 121   fi
 122
 123   if test -n "[$]$1"; then
 124     ac_result=yes
 125   else
 126     ac_result=no
 127   fi
 128   ifelse($3,,,[$3])
 129   test -n "[$]$1" && break
 130 done
 131 ])dnl
 132
 133
 134 AC_DEFUN([LYX_PROG_CXX_WORKS],
 135 [rm -f conftest.C
 136 cat >conftest.C <<EOF
 137 class foo {
 138    // we require the mutable keyword
 139    mutable int bar;
 140  };
 141  // we require namespace support
 142  namespace baz {
 143    int bar;
 144  }
 145  int main() {
 146    return(0);
 147  }
 148 EOF
 149 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 150 rm -f conftest.C conftest.o conftest.obj || true
 151 ])
 152
 153
 154 AC_DEFUN(LYX_PROG_CXX,
 155 [AC_MSG_CHECKING([for a good enough C++ compiler])
 156 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 157
 158 if test -z "$CXX" ; then
 159   AC_ERROR([Unable to find a good enough C++ compiler])
 160 fi
 161 AC_MSG_RESULT($CXX)
 162
 163 AC_PROG_CXX
 164
 165 ### We might want to get or shut warnings.
 166 AC_ARG_ENABLE(warnings,
 167   [  --enable-warnings       tell the compiler to display more warnings],,
 168   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 169         enable_warnings=yes;
 170     else
 171         enable_warnings=no;
 172     fi;])
 173 if test x$enable_warnings = xyes ; then
 174   lyx_flags="$lyx_flags warnings"
 175   AC_DEFINE(WITH_WARNINGS, 1,
 176   [Define this if you want to see the warning directives put here and
 177    there by the developpers to get attention])
 178 fi
 179
 180 ### We might want to disable debug
 181 AC_ARG_ENABLE(debug,
 182   [  --enable-debug          enable debug information],,
 183   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 184         enable_debug=yes;
 185     else
 186         enable_debug=no;
 187     fi;])
 188
 189 ### set up optimization
 190 AC_ARG_ENABLE(optimization,
 191   [  --enable-optimization[=value]   enable compiler optimisation],,
 192         enable_optimization=yes;)
 193 case $enable_optimization in
 194   yes) lyx_opt=-O;;
 195    no) lyx_opt=;;
 196     *) lyx_opt=${enable_optimization};;
 197 esac
 198
 199 # set the debug flags correctly.
 200 if test x$GXX = xyes; then
 201   dnl Useful for global version info
 202   gxx_version=`${CXX} -dumpversion`
 203   CXX_VERSION="($gxx_version)"
 204
 205   if test "$ac_test_CXXFLAGS" = set; then
 206     CXXFLAGS="$ac_save_CXXFLAGS"
 207   else
 208     case $gxx_version in
 209       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive";;
 210       2.95.2)  CXXFLAGS="$lyx_opt";;
 211       2.95.*)  CXXFLAGS="$lyx_opt";;
 212       2.96*)  CXXFLAGS="$lyx_opt";;
 213       3.0*)    CXXFLAGS="$lyx_opt";;
 214       3.1*)    CXXFLAGS="$lyx_opt";;
 215       3.2*)    CXXFLAGS="$lyx_opt";;
 216       *)       CXXFLAGS="$lyx_opt";;
 217     esac
 218     if test x$enable_debug = xyes ; then
 219         CXXFLAGS="-g $CXXFLAGS"
 220     fi
 221   fi
 222   if test x$enable_warnings = xyes ; then
 223     case $gxx_version in
 224         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 225         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 226         *)      CXXFLAGS="$CXXFLAGS -W -Wall";;
 227     esac
 228     if test $lyx_devel_version = yes ; then
 229       case $gxx_version in
 230           2.95.*) ;;
 231           2.96*) ;;
 232           *) CXXFLAGS="$CXXFLAGS -Winline";;
 233       esac
 234     fi
 235   fi
 236 fi])dnl
 237
 238
 239 dnl NOT USED CURRENTLY*************************************
 240 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 241 dnl   supports RTTI
 242 AC_DEFUN(LYX_CXX_RTTI,[
 243 ### Check whether the compiler supports runtime type information
 244 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 245  [AC_TRY_RUN([
 246 class rtti {
 247 public:
 248    virtual int tag() { return 0; }
 249 };
 250 class derived1 : public rtti {
 251 public:
 252     int tag() { return 1; }
 253 };
 254 class derived2 : public rtti {
 255 public:
 256     int tag() { return 2; }
 257 };
 258 int main() {
 259     derived1 * foo1 = new derived1();
 260     derived2 * foo2 = new derived2();
 261     rtti * bar = foo1;
 262     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 263     if (bar1 == 0)
 264         exit(1);
 265     bar = foo2;
 266     bar1 = dynamic_cast<derived1 *>(bar);
 267     if (bar1 != 0)
 268         exit(1);
 269     return 0;
 270 }
 271 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 272 ])
 273 if test x$lyx_cv_rtti = xyes ; then
 274   AC_DEFINE(HAVE_RTTI, 1,
 275    [Define to 1 if your compiler supports runtime type information])
 276 fi])
 277
 278
 279 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 280 dnl   understands the "explicit" directive.
 281 AC_DEFUN(LYX_CXX_EXPLICIT,[
 282 ### Check whether the compiler understands the keyword `explicit'
 283 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 284  [AC_TRY_COMPILE([
 285 class Expl {
 286 public:
 287         explicit Expl() {};
 288 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 289 ])
 290 if test $lyx_cv_explicit = no ; then
 291   AC_DEFINE(explicit,[ ],
 292    [Define to nothing if your compiler does not understand the
 293    'explicit' directive])
 294 fi])
 295
 296
 297 dnl NOT USED CURRENTLY*************************************
 298 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 299 dnl   has a working stl stack template
 300 AC_DEFUN(LYX_CXX_STL_STACK,[
 301 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 302  [AC_TRY_COMPILE([
 303 #include <stack>
 304 using std::stack;
 305 ],[
 306     stack<int> stakk;
 307     stakk.push(0);
 308 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 309 ])
 310 if test $lyx_cv_broken_stack = yes ; then
 311   AC_DEFINE(BROKEN_STL_STACK, 1,
 312    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 313    correctly])
 314 fi])
 315
 316
 317 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 318 dnl    count template, if not the old HP version is assumed.
 319 AC_DEFUN(LYX_STD_COUNT,[
 320 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 321  [AC_TRY_COMPILE([
 322 #include <algorithm>
 323 using std::count;
 324 int countChar(char * b, char * e, char const c)
 325 {
 326         return count(b, e, c);
 327 }
 328 ],[
 329     char a[] = "hello";
 330     int i = countChar(a, a + 5, 'l');
 331 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 332 ])
 333 if test $lyx_cv_std_count = yes ; then
 334     AC_DEFINE(HAVE_STD_COUNT, 1,
 335     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 336 fi])
 337
 338
 339 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 340 dnl   supports modern STL streams
 341 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 342 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 343  [AC_TRY_COMPILE([
 344 #include <iostream>
 345 ],[
 346  std::streambuf * test = std::cerr.rdbuf();
 347  test->pubsync();
 348 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 349 ])
 350 if test $lyx_cv_modern_streams = yes ; then
 351   AC_DEFINE(MODERN_STL_STREAMS, 1,
 352    [Define if you have modern standard-compliant STL streams])
 353 fi])
 354
 355
 356 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 357 dnl   has a std::string that is usable for LyX. LyX does not require this
 358 dnl   std::string to be standard.
 359 AC_DEFUN(LYX_CXX_STL_STRING,[
 360     AC_REQUIRE([AC_PROG_CXX])
 361     AC_MSG_CHECKING(whether the included std::string should be used)
 362     AC_ARG_WITH(included-string,
 363        [  --with-included-string  use LyX string class instead of STL string],
 364        [lyx_cv_with_included_string=$withval
 365         AC_MSG_RESULT([$with_included_string])],
 366        [AC_CACHE_CHECK([],lyx_cv_with_included_string,
 367         [AC_TRY_COMPILE([
 368             #include <string>
 369             using std::string;
 370         ],[
 371             // LyX has reduced its requirements on the basic_string
 372             // implementation so that the basic_string supplied
 373             // with gcc is usable. In particular this means that
 374             // lyx does not use std::string::clear and not the
 375             // strncmp version of std::string::compare. This is mainly
 376             // done so that LyX can use precompiled C++ libraries that
 377             // already uses the systems basic_string, e.g. gtk--
 378             string a("hello there");
 379             a.erase();
 380             a = "hey";
 381             //char s[] = "y";
 382             //int t = a.compare(a.length() - 1, 1, s);
 383             a.erase();
 384         ],[
 385             lyx_cv_with_included_string=no
 386         ],[
 387             lyx_cv_with_included_string=yes
 388         ])
 389         ])
 390     ])
 391     if test x$lyx_cv_with_included_string = xyes ; then
 392         AC_DEFINE(USE_INCLUDED_STRING, 1,
 393             [Define to use the lyxstring class bundled with LyX.])
 394             lyx_flags="$lyx_flags included-string"
 395     fi
 396     AM_CONDITIONAL(USE_LYXSTRING, test x$lyx_cv_with_included_string = xyes)
 397 dnl    AC_MSG_RESULT([$with_included_string])
 398 ])
 399
 400
 401 dnl Usage: LYX_CXX_GOOD_STD_STRING : checks whether the C++ compiler
 402 dnl   has a std::string that is close to the standard. So close that
 403 dnl   methods not found in "unstandard" std::strings are present here.
 404 AC_DEFUN(LYX_CXX_GOOD_STD_STRING,[
 405     AC_REQUIRE([AC_PROG_CXX])
 406     AC_CACHE_CHECK([whether the systems std::string is really good],
 407     [lyx_cv_std_string_good],
 408     [AC_TRY_COMPILE([
 409             #include <string>
 410             using std::string;
 411         ],[
 412             // From a std::string that is supposed to be close to the
 413             // standard we require at least three things:
 414             // - clear() and erase()
 415             // - the strncmp of compare()
 416             // - push_back()
 417             string a("hello there");
 418             a.erase();
 419             a = "hey";
 420             char s[] = "y";
 421             int t = a.compare(a.length() - 1, 1, s);
 422             a.push_back('g');
 423             a.clear();
 424         ],[
 425             lyx_cv_std_string_good=yes
 426         ],[
 427             lyx_cv_std_string_good=no
 428
 429         ])
 430     ])
 431     if test x$lyx_cv_std_string_good = xyes ; then
 432         AC_DEFINE(STD_STRING_IS_GOOD, 1,
 433             [Define if the systems std::string is really good.])
 434     fi
 435 ])
 436
 437
 438 dnl Usage: LYX_REGEX : checks if the header regex.h is available
 439 dnl   if it is not available the automake variable USE_REGEX will be
 440 dnl   defined and the regex.h and regex.c that we provide will be used.
 441 dnl AC_DEFUN(LYX_REGEX,[
 442 dnl     AC_CHECK_HEADERS(regex.h, lyx_regex=no, lyx_regex=yes)
 443 dnl     AM_CONDITIONAL(USE_REGEX, test x$lyx_regex = xyes)
 444 dnl ])
 445
 446 dnl NOT USED CURRENTLY*************************************
 447 dnl LYX_CXX_PARTIAL
 448 AC_DEFUN(LYX_CXX_PARTIAL, [
 449     AC_REQUIRE([AC_PROG_CXX])
 450     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 451         [lyx_cv_cxx_partial_specialization],
 452         [AC_TRY_COMPILE(
 453             [
 454             template<class T, class K>
 455             class k {
 456             public:
 457             };
 458             template<class T> class k<void,T> { };
 459             ],[
 460             k<float, float> b;
 461             k<void,void> a;
 462             ],[
 463             lyx_cv_cxx_partial_specialization=yes
 464             ],[
 465             lyx_cv_cxx_partial_specialization=no
 466             ])
 467         ])
 468     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 469         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 470         [Defined if your compiler supports partial specialization.])
 471     fi
 472 ])
 473
 474
 475 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 476 dnl   provides wrappers for C headers and use our alternate version otherwise.
 477 AC_DEFUN(LYX_CXX_CHEADERS,[
 478 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 479  [AC_TRY_CPP([
 480 #include <clocale>
 481 #include <cctype>
 482 #include <cerrno>
 483 #include <cmath>
 484 #include <csignal>
 485 #include <cstdio>
 486 #include <cstdlib>
 487 #include <cstring>
 488 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 489 if test $lyx_cv_cxx_cheaders = no ; then
 490   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 491 fi])
 492
 493 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 494 dnl   are already in the global namespace
 495 AC_DEFUN(LYX_CXX_GLOBAL_CSTD,[
 496     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 497     lyx_cv_cxx_global_cstd,
 498     [AC_TRY_COMPILE([
 499     #include <cctype>
 500     using std::tolower;
 501     ],[
 502     return 0;
 503     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 504     if test x$lyx_cv_cxx_global_cstd = xyes; then
 505         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 506         [Define if your C++ compiler puts C library functions in the global namespace])
 507     fi
 508 ])
 509
 510 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 511 AC_DEFUN(LYX_PATH_XPM,[
 512 ### Check for Xpm library
 513 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage,XPM_LIB="-lXpm",
 514         [LYX_LIB_ERROR(libXpm,Xpm)], $XPM_LIB)
 515 AC_SUBST(XPM_LIB)
 516 ### Check for Xpm headers
 517 lyx_cv_xpm_h_location="<xpm.h>"
 518 AC_CHECK_HEADER(X11/xpm.h,[
 519   ac_cv_header_xpm_h=yes
 520   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 521 AC_CHECK_HEADER(xpm.h,[],[
 522 LYX_LIB_ERROR(xpm.h,Xpm)])])
 523 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location)
 524
 525 ### Test for the header version
 526 if test $ac_cv_header_xpm_h = yes; then
 527   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 528   [ cat > conftest.$ac_ext <<EOF
 529 #line __oline__ "configure"
 530 #include "confdefs.h"
 531
 532 #include XPM_H_LOCATION
 533 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 534 EOF
 535     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 536       grep '^"%%%"'  2>/dev/null | \
 537       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 538     case "$lyx_cv_xpmr" in
 539 changequote(,)
 540      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 541             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 542 changequote([,])
 543          *) ;;
 544     esac
 545     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 546     rm -f conftest*])
 547   XPM_VERSION=${lyx_cv_xpmversion}
 548   case "$lyx_cv_xpmr" in
 549 changequote(,)
 550         [789]|[0-9][0-9]*) ;;
 551 changequote([,])
 552         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 553    If you experience strange crashes with LyX, try to upgrade
 554    to at least version 4.7 (aka 3.4g).
 555    If you have installed a newer version of the library, check whether you
 556    have an old xpm.h header file in your include path.]);;
 557   esac
 558 fi])
 559
 560
 561 dnl Usage: LYX_HPUX  Checks for HP-UX and update CXXFLAGS accordingly
 562 AC_DEFUN(LYX_HPUX,
 563 [#It seems that HPUX requires using -fpcc-struct-return with gcc.
 564 AC_CACHE_CHECK(for HP-UX,ac_cv_hpux,[
 565 os=`uname -s | tr '[A-Z]' '[a-z]'`
 566 ac_cv_hpux=no
 567 test "$os" = hp-ux && ac_cv_hpux=yes])
 568 if test "$ac_cv_hpux" = yes; then
 569  test "x$GXX" = xyes && CXXFLAGS="$CXXFLAGS -fpcc-struct-return"
 570 fi])
 571
 572
 573 dnl Usage: LYX_SUNOS4 Checks for SunOS 4.x and sets the flag lyx_broken_headers
 574 dnl   if necessary
 575 AC_DEFUN(LYX_SUNOS4,
 576 [#The headers are not correct under SunOS4
 577 AC_CACHE_CHECK(for SunOS 4.x,ac_cv_sunos4,[
 578 changequote(, ) dnl
 579 os=`uname -a | sed -e 's/^\([^ ]*\) [^ ]* \([0-9]\)\..*/\1\2/'`
 580 changequote([, ]) dnl
 581 ac_cv_sunos4=no
 582 test "$os" = SunOS4 && ac_cv_sunos4=yes])
 583 if test "$ac_cv_sunos4" = yes; then
 584  test "x$GXX" = xyes && lyx_broken_headers=yes
 585 fi])
 586
 587
 588 dnl Usage: LYX_SCO Checks for SCO and sets the flag lyx_broken_headers
 589 dnl   if necessary
 590 AC_DEFUN(LYX_SCO,
 591 [AC_CACHE_CHECK(for SCO 3.2v4,ac_cv_sco,[
 592 ac_cv_sco=no
 593 if test `uname -s` != "SCO_SV"; then
 594   lyx_machine_rel=`uname -m`:`uname -r`
 595   if test $lyx_machine_rel = i386:3.2 || test $lyx_machine_rel = i486:3.2;
 596   then
 597     if test -f /usr/options/cb.name; then
 598       ac_cv_sco=no
 599     elif /bin/uname -X 2>/dev/null >/dev/null ; then
 600       ac_cv_sco=yes
 601     fi
 602   fi
 603 fi])
 604 if test "$ac_cv_sco" = yes; then
 605  test "x$GXX" = xyes && lyx_broken_headers=yes
 606 fi])
 607
 608 dnl Usage: LYX_FUNC_PUTENV_ARGTYPE
 609 dnl Checks whether putenv() takes 'char const *' or 'char *' as
 610 dnl argument. This is needed because Solaris 7 (wrongly?) uses 'char *',
 611 dnl while everybody else uses the former...
 612 AC_DEFUN(LYX_FUNC_PUTENV_ARGTYPE,
 613 [AC_MSG_CHECKING([type of argument for putenv()])
 614  AC_CACHE_VAL(lyx_cv_func_putenv_arg,dnl
 615   [AC_TRY_COMPILE(dnl
 616 [#include <cstdlib>],
 617 [char const * foo = "bar";
 618  putenv(foo);],dnl
 619    [lyx_cv_func_putenv_arg='char const *'],[lyx_cv_func_putenv_arg='char *'])])
 620  AC_MSG_RESULT($lyx_cv_func_putenv_arg)
 621  AC_DEFINE_UNQUOTED(PUTENV_TYPE_ARG,$lyx_cv_func_putenv_arg,dnl
 622    [Define to the type of the argument of putenv(). Needed on Solaris 7.])])
 623
 624
 625 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 626 dnl                       [default-yes-value])
 627 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 628 dnl  resulting directory name in 'dir-var-name'.
 629 AC_DEFUN(LYX_WITH_DIR,[
 630   AC_ARG_WITH($1,[  --with-$1        specify $2])
 631   AC_MSG_CHECKING([for $2])
 632   if test -z "$with_$3"; then
 633      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 634   else
 635     test "x$with_$3" = xyes && with_$3=$5
 636     lyx_cv_$3="$with_$3"
 637   fi
 638   AC_MSG_RESULT($lyx_cv_$3)])
 639
 640
 641 dnl Usage: LYX_LOOP_DIR(value,action)
 642 dnl Executes action for values of variable `dir' in `values'. `values' can
 643 dnl use ":" as a separator.
 644 AC_DEFUN(LYX_LOOP_DIR,[
 645 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 646 for dir in `eval "echo $1"`; do
 647   if test ! "$dir" = NONE; then
 648     test ! -d "$dir" && AC_ERROR([\"$dir\" is not a directory])
 649     $2
 650   fi
 651 done
 652 IFS=$ac_save_ifs
 653 ])
 654
 655
 656 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 657 dnl var-name.
 658 AC_DEFUN(LYX_ADD_LIB_DIR,[
 659 $1="${$1} -L$2"
 660 if test "`(uname) 2>/dev/null`" = SunOS &&
 661     uname -r | grep '^5' >/dev/null; then
 662   if test $ac_cv_prog_gxx = yes ; then
 663     $1="${$1} -Wl[,]-R$2"
 664   else
 665     $1="${$1} -R$2"
 666   fi
 667 fi])
 668
 669
 670 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 671 dnl var-name.
 672 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 673
 674 ### Check for a headers existence and location iff it exists
 675 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 676 ## It almost works.  I've tried a few variations but they give errors
 677 ## of one sort or other: bad substitution or file not found etc.  The
 678 ## actual header _is_ found though and the cache variable is set however
 679 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 680 ## reason.
 681 ## Additionally, autoheader can't figure out what to use as the name in
 682 ## the config.h.in file so we need to write our own entries there -- one for
 683 ## each header in the form PATH_HEADER_NAME_H
 684 ##
 685 AC_DEFUN(LYX_PATH_HEADER,
 686 [ AC_CHECK_HEADER($1,[
 687   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 688 ### the only remaining problem is getting the second parameter to this
 689 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 690 ### of $ac_safe being printed.
 691   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 692   [ cat > conftest.$ac_ext <<EOF
 693 #line __oline__ "configure"
 694 #include "confdefs.h"
 695
 696 #include <$1>
 697 EOF
 698 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 699   grep $1  2>/dev/null | \
 700   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 701 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 702 rm -f conftest*])
 703   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path)])
 704 ])
 705 ### end of LYX_PATH_HEADER
 706
 707 ### Check for stl_string_fwd.h existence and location if it exists
 708 AC_DEFUN(LYX_STL_STRING_FWD,
 709 [ AC_CHECK_HEADER(stl_string_fwd.h,[
 710   AC_CACHE_CHECK([path to stl_string_fwd.h],lyx_cv_path_stl_string_fwd_h,
 711   [ cat > conftest.$ac_ext <<EOF
 712 #line __oline__ "configure"
 713 #include "confdefs.h"
 714
 715 #include <stl_string_fwd.h>
 716 EOF
 717 lyx_cv_path_stl_string_fwd_h=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 718   grep 'stl_string_fwd.h'  2>/dev/null | \
 719   sed -e 's/.*\(".*stl_string_fwd.h"\).*/\1/' -e "1q"`
 720 rm -f conftest*])
 721   AC_DEFINE_UNQUOTED(STL_STRING_FWD_H_LOCATION,$lyx_cv_path_stl_string_fwd_h,
 722 [define this to the location of stl_string_fwd.h to be used with #include,
 723   NOTE: Do not set it to <stl_string_fwd.h> as that will find the LyX
 724         supplied version of the header.
 725   e.g. <../include/stl_string_fwd.h> or better yet use an absolute path])])
 726 ])
 727
 728
 729 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
 730 dnl if the cache file is inconsistent with the current host,
 731 dnl target and build system types, execute CMD or print a default
 732 dnl error message.
 733 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
 734     AC_REQUIRE([AC_CANONICAL_SYSTEM])
 735     AC_MSG_CHECKING([config.cache system type])
 736     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
 737          test x"$ac_cv_host_system_type" != x"$host"; } ||
 738        { test x"${ac_cv_build_system_type+set}" = x"set" &&
 739          test x"$ac_cv_build_system_type" != x"$build"; } ||
 740        { test x"${ac_cv_target_system_type+set}" = x"set" &&
 741          test x"$ac_cv_target_system_type" != x"$target"; }; then
 742         AC_MSG_RESULT([different])
 743         ifelse($#, 1, [$1],
 744                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
 745     else
 746         AC_MSG_RESULT([same])
 747     fi
 748     ac_cv_host_system_type="$host"
 749     ac_cv_build_system_type="$build"
 750     ac_cv_target_system_type="$target"
 751 ])
 752
 753 dnl We use this until autoconf fixes its version.
 754 AC_DEFUN(LYX_FUNC_SELECT_ARGTYPES,
 755 [AC_MSG_CHECKING([types of arguments for select()])
 756  AC_CACHE_VAL(ac_cv_func_select_arg234,dnl
 757  [AC_CACHE_VAL(ac_cv_func_select_arg1,dnl
 758   [AC_CACHE_VAL(ac_cv_func_select_arg5,dnl
 759    [for ac_cv_func_select_arg234 in 'fd_set *' 'int *' 'void *'; do
 760      for ac_cv_func_select_arg1 in 'int' 'size_t' 'unsigned long' 'unsigned'; do      for ac_cv_func_select_arg5 in 'struct timeval *' 'const struct timeval *'; do
 761        AC_TRY_COMPILE(dnl
 762 [#ifdef HAVE_SYS_TYPES_H
 763 #include <sys/types.h>
 764 #endif
 765 #ifdef HAVE_SYS_TIME_H
 766 #include <sys/time.h>
 767 #endif
 768 #ifdef HAVE_SYS_SELECT_H
 769 #include <sys/select.h>
 770 #endif
 771 #ifdef HAVE_SYS_SOCKET_H
 772 #include <sys/socket.h>
 773 #endif
 774 extern int select ($ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5);],,dnl
 775         [ac_not_found=no ; break 3],ac_not_found=yes)
 776       done
 777      done
 778     done
 779    ])dnl AC_CACHE_VAL
 780   ])dnl AC_CACHE_VAL
 781  ])dnl AC_CACHE_VAL
 782  if test "$ac_not_found" = yes; then
 783   ac_cv_func_select_arg1=int
 784   ac_cv_func_select_arg234='int *'
 785   ac_cv_func_select_arg5='struct timeval *'
 786  fi
 787  AC_MSG_RESULT([$ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5])
 788  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG1,$ac_cv_func_select_arg1,
 789                     [Define to the type of arg1 for select().])
 790  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG234,($ac_cv_func_select_arg234),
 791                     [Define to the type of args 2, 3 and 4 for select().])
 792  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG5,($ac_cv_func_select_arg5),
 793                     [Define to the type of arg5 for select().])
 794 ])
 795
 796 ### Check which frontend we want to use. The default is XForms
 797 ###
 798 AC_DEFUN(LYX_USE_FRONTEND,
 799 [AC_MSG_CHECKING([what frontend should be used as main GUI])
 800 AC_ARG_WITH(frontend,
 801   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 802                             Possible values: xforms, qt2, gnome],
 803   [lyx_use_frontend="$withval"], [lyx_use_frontend="xforms"])
 804 AC_MSG_RESULT($lyx_use_frontend)
 805 AC_SUBST(FRONTEND)
 806 AC_SUBST(FRONTEND_GUILIB)
 807 AC_SUBST(FRONTEND_LDFLAGS)
 808 AC_SUBST(FRONTEND_INCLUDES)
 809 AC_SUBST(FRONTEND_LIBS)
 810 ])
 811
 812
 813 dnl Check things are declared in headers to avoid errors or warnings.
 814 dnl Called like LYX_CHECK_DECL(function, headerfile)
 815 dnl Defines HAVE_DECL_{FUNCTION}
 816 AC_DEFUN(LYX_CHECK_DECL,
 817 [AC_MSG_CHECKING(if $1 is declared by header $2)
 818 tr_func=`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 819
 820 tr_hdr=`echo $2 | tr . _`
 821 AC_CACHE_VAL([lyx_cv_declare_${tr_hdr}_$1],
 822 [AC_EGREP_HEADER($1, $2, [eval "lyx_cv_declare_${tr_hdr}_$1=yes"], [eval "lyx_cv_declare_${tr_hdr}_$1=no"])])
 823 if eval "test \"\${lyx_cv_declare_${tr_hdr}_$1}\" = \"yes\""; then
 824         AC_DEFINE_UNQUOTED(HAVE_DECL_${tr_func})
 825         AC_MSG_RESULT(yes)
 826 else
 827         AC_MSG_RESULT(no)
 828 fi])
 829
 830 dnl This is the multiple headers version of the LYX_CHECK_DECL macro above.
 831 dnl Called like LYX_CHECK_DECL_HDRS(function, file1 file2 file3)
 832 AC_DEFUN(LYX_CHECK_DECL_HDRS,
 833 [ got="no"
 834 for I in $2; do
 835 tr_hdr=`echo $I | tr . _`
 836 if test "${got}" = "no"; then
 837     LYX_CHECK_DECL($1, $I)
 838 fi
 839 if eval "test \"\${lyx_cv_declare_${tr_hdr}_$1}\" = \"yes\""; then
 840      got="yes"
 841 fi
 842 done])
 843
 844
 845 ## ------------------------------------------------------------------------
 846 ## Find a file (or one of more files in a list of dirs)
 847 ## ------------------------------------------------------------------------
 848 ##
 849 AC_DEFUN(AC_FIND_FILE,
 850 [
 851 $3=NO
 852 for i in $2;
 853 do
 854   for j in $1;
 855   do
 856     if test -r "$i/$j"; then
 857       $3=$i
 858       break 2
 859     fi
 860   done
 861 done
 862 ])
 863
 864 dnl just a wrapper to clean up configure.in
 865 AC_DEFUN(LYX_PROG_LIBTOOL,
 866 [
 867 AC_REQUIRE([AC_ENABLE_SHARED])
 868 AC_REQUIRE([AC_ENABLE_STATIC])
 869 dnl libtool is only for C, so I must force him
 870 dnl to find the correct flags for C++
 871 ac_save_cc=$CC
 872 ac_save_cflags="$CFLAGS"
 873 CC=$CXX
 874 CFLAGS="$CXXFLAGS"
 875 AM_PROG_LIBTOOL dnl for libraries
 876 CC=$ac_save_cc
 877 CFLAGS="$ac_save_cflags"
 878 ])