config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN(LYX_CHECK_VERSION,[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN(LYX_VERSION_SUFFIX,[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN(LYX_ERROR,[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN(LYX_WARNING,[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN(LYX_LIB_ERROR,[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN(LYX_CHECK_ERRORS,[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 deleting cache $cache_file
  85 EOF
  86   rm -f $cache_file
  87 else
  88
  89 if test x$lyx_warning = xyes; then
  90 cat <<EOF
  91 === The following minor problems have been detected by configure.
  92 === Please check the messages below before running 'make'.
  93 === (see the section 'Problems' in the INSTALL file)
  94 $lyx_warning_txt
  95 EOF
  96 fi
  97 cat <<EOF
  98 Configuration of LyX was successful.
  99 Type 'make' to compile the program,
 100 and then 'make install' to install it.
 101 EOF
 102 fi])
 103
 104
 105 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 106 dnl
 107 define(LYX_SEARCH_PROG,[dnl
 108 for ac_prog in $2 ; do
 109 # Extract the first word of "$ac_prog", so it can be a program name with args.
 110   set dummy $ac_prog ; ac_word=$[2]
 111   if test -z "[$]$1"; then
 112     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 113     for ac_dir in $PATH; do
 114       test -z "$ac_dir" && ac_dir=.
 115       if test -f [$ac_dir/$ac_word]; then
 116         $1="$ac_prog"
 117         break
 118       fi
 119     done
 120     IFS="$ac_save_ifs"
 121   fi
 122
 123   if test -n "[$]$1"; then
 124     ac_result=yes
 125   else
 126     ac_result=no
 127   fi
 128   ifelse($3,,,[$3])
 129   test -n "[$]$1" && break
 130 done
 131 ])dnl
 132
 133
 134 AC_DEFUN([LYX_PROG_CXX_WORKS],
 135 [rm -f conftest.C
 136 cat >conftest.C <<EOF
 137 class foo {
 138    // we require the mutable keyword
 139    mutable int bar;
 140  };
 141  // we require namespace support
 142  namespace baz {
 143    int bar;
 144  }
 145  int main() {
 146    return(0);
 147  }
 148 EOF
 149 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 150 rm -f conftest.C conftest.o conftest.obj || true
 151 ])
 152
 153
 154 AC_DEFUN(LYX_PROG_CXX,
 155 [AC_MSG_CHECKING([for a good enough C++ compiler])
 156 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 157
 158 if test -z "$CXX" ; then
 159   AC_ERROR([Unable to find a good enough C++ compiler])
 160 fi
 161 AC_MSG_RESULT($CXX)
 162
 163 AC_PROG_CXX
 164
 165 ### We might want to get or shut warnings.
 166 AC_ARG_ENABLE(warnings,
 167   [  --enable-warnings       tell the compiler to display more warnings],,
 168   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 169         enable_warnings=yes;
 170     else
 171         enable_warnings=no;
 172     fi;])
 173 if test x$enable_warnings = xyes ; then
 174   lyx_flags="$lyx_flags warnings"
 175   AC_DEFINE(WITH_WARNINGS, 1,
 176   [Define this if you want to see the warning directives put here and
 177    there by the developpers to get attention])
 178 fi
 179
 180 ### We might want to disable debug
 181 AC_ARG_ENABLE(debug,
 182   [  --enable-debug          enable debug information],,
 183   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 184         enable_debug=yes;
 185     else
 186         enable_debug=no;
 187     fi;])
 188
 189 ### set up optimization
 190 AC_ARG_ENABLE(optimization,
 191   [  --enable-optimization[=value]   enable compiler optimisation],,
 192         enable_optimization=yes;)
 193 case $enable_optimization in
 194   yes) lyx_opt=-O;;
 195    no) lyx_opt=;;
 196     *) lyx_opt=${enable_optimization};;
 197 esac
 198
 199 # set the debug flags correctly.
 200 if test x$GXX = xyes; then
 201   dnl Useful for global version info
 202   gxx_version=`${CXX} -dumpversion`
 203   CXX_VERSION="($gxx_version)"
 204
 205   if test "$ac_test_CXXFLAGS" = set; then
 206     CXXFLAGS="$ac_save_CXXFLAGS"
 207   else
 208     case $gxx_version in
 209       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive";;
 210       2.95.2)  CXXFLAGS="$lyx_opt";;
 211       2.95.*)  CXXFLAGS="$lyx_opt";;
 212       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions";;
 213       3.0*)    CXXFLAGS="$lyx_opt";;
 214       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 215       3.2*)    CXXFLAGS="$lyx_opt";;
 216       *)       CXXFLAGS="$lyx_opt";;
 217     esac
 218     if test x$enable_debug = xyes ; then
 219         CXXFLAGS="-g $CXXFLAGS"
 220     fi
 221   fi
 222   if test x$enable_warnings = xyes ; then
 223     case $gxx_version in
 224         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 225         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 226         3.1*)  CXXFLAGS="$CXXFLAGS -W -Wall -Winline";;
 227         *)      CXXFLAGS="$CXXFLAGS -W -Wall";;
 228     esac
 229     if test $lyx_devel_version = yes ; then
 230       case $gxx_version in
 231           2.95.*) ;;
 232           2.96*) ;;
 233           *) CXXFLAGS="$CXXFLAGS -Winline";;
 234       esac
 235     fi
 236   fi
 237 fi])dnl
 238
 239
 240 dnl NOT USED CURRENTLY*************************************
 241 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 242 dnl   supports RTTI
 243 AC_DEFUN(LYX_CXX_RTTI,[
 244 ### Check whether the compiler supports runtime type information
 245 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 246  [AC_TRY_RUN([
 247 class rtti {
 248 public:
 249    virtual int tag() { return 0; }
 250 };
 251 class derived1 : public rtti {
 252 public:
 253     int tag() { return 1; }
 254 };
 255 class derived2 : public rtti {
 256 public:
 257     int tag() { return 2; }
 258 };
 259 int main() {
 260     derived1 * foo1 = new derived1();
 261     derived2 * foo2 = new derived2();
 262     rtti * bar = foo1;
 263     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 264     if (bar1 == 0)
 265         exit(1);
 266     bar = foo2;
 267     bar1 = dynamic_cast<derived1 *>(bar);
 268     if (bar1 != 0)
 269         exit(1);
 270     return 0;
 271 }
 272 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 273 ])
 274 if test x$lyx_cv_rtti = xyes ; then
 275   AC_DEFINE(HAVE_RTTI, 1,
 276    [Define to 1 if your compiler supports runtime type information])
 277 fi])
 278
 279
 280 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 281 dnl   understands the "explicit" directive.
 282 AC_DEFUN(LYX_CXX_EXPLICIT,[
 283 ### Check whether the compiler understands the keyword `explicit'
 284 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 285  [AC_TRY_COMPILE([
 286 class Expl {
 287 public:
 288         explicit Expl() {};
 289 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 290 ])
 291 if test $lyx_cv_explicit = no ; then
 292   AC_DEFINE(explicit,[ ],
 293    [Define to nothing if your compiler does not understand the
 294    'explicit' directive])
 295 fi])
 296
 297
 298 dnl NOT USED CURRENTLY*************************************
 299 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 300 dnl   has a working stl stack template
 301 AC_DEFUN(LYX_CXX_STL_STACK,[
 302 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 303  [AC_TRY_COMPILE([
 304 #include <stack>
 305 using std::stack;
 306 ],[
 307     stack<int> stakk;
 308     stakk.push(0);
 309 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 310 ])
 311 if test $lyx_cv_broken_stack = yes ; then
 312   AC_DEFINE(BROKEN_STL_STACK, 1,
 313    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 314    correctly])
 315 fi])
 316
 317
 318 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 319 dnl    count template, if not the old HP version is assumed.
 320 AC_DEFUN(LYX_STD_COUNT,[
 321 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 322  [AC_TRY_COMPILE([
 323 #include <algorithm>
 324 using std::count;
 325 int countChar(char * b, char * e, char const c)
 326 {
 327         return count(b, e, c);
 328 }
 329 ],[
 330     char a[] = "hello";
 331     int i = countChar(a, a + 5, 'l');
 332 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 333 ])
 334 if test $lyx_cv_std_count = yes ; then
 335     AC_DEFINE(HAVE_STD_COUNT, 1,
 336     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 337 fi])
 338
 339
 340 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 341 dnl   supports modern STL streams
 342 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 343 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 344  [AC_TRY_COMPILE([
 345 #include <iostream>
 346 ],[
 347  std::streambuf * test = std::cerr.rdbuf();
 348  test->pubsync();
 349 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 350 ])
 351 if test $lyx_cv_modern_streams = yes ; then
 352   AC_DEFINE(MODERN_STL_STREAMS, 1,
 353    [Define if you have modern standard-compliant STL streams])
 354 fi])
 355
 356
 357 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 358 dnl   has a std::string that is usable for LyX. LyX does not require this
 359 dnl   std::string to be standard.
 360 AC_DEFUN(LYX_CXX_STL_STRING,[
 361     AC_REQUIRE([AC_PROG_CXX])
 362     AC_MSG_CHECKING(whether the included std::string should be used)
 363     AC_ARG_WITH(included-string,
 364        [  --with-included-string  use LyX string class instead of STL string],
 365        [lyx_cv_with_included_string=$withval
 366         AC_MSG_RESULT([$with_included_string])],
 367        [AC_CACHE_CHECK([],lyx_cv_with_included_string,
 368         [AC_TRY_COMPILE([
 369             #include <string>
 370             using std::string;
 371         ],[
 372             // LyX has reduced its requirements on the basic_string
 373             // implementation so that the basic_string supplied
 374             // with gcc is usable. In particular this means that
 375             // lyx does not use std::string::clear and not the
 376             // strncmp version of std::string::compare. This is mainly
 377             // done so that LyX can use precompiled C++ libraries that
 378             // already uses the systems basic_string, e.g. gtk--
 379             string a("hello there");
 380             a.erase();
 381             a = "hey";
 382             //char s[] = "y";
 383             //int t = a.compare(a.length() - 1, 1, s);
 384             a.erase();
 385         ],[
 386             lyx_cv_with_included_string=no
 387         ],[
 388             lyx_cv_with_included_string=yes
 389         ])
 390         ])
 391     ])
 392     if test x$lyx_cv_with_included_string = xyes ; then
 393         AC_DEFINE(USE_INCLUDED_STRING, 1,
 394             [Define to use the lyxstring class bundled with LyX.])
 395             lyx_flags="$lyx_flags included-string"
 396     fi
 397     AM_CONDITIONAL(USE_LYXSTRING, test x$lyx_cv_with_included_string = xyes)
 398 dnl    AC_MSG_RESULT([$with_included_string])
 399 ])
 400
 401
 402 dnl Usage: LYX_CXX_GOOD_STD_STRING : checks whether the C++ compiler
 403 dnl   has a std::string that is close to the standard. So close that
 404 dnl   methods not found in "unstandard" std::strings are present here.
 405 AC_DEFUN(LYX_CXX_GOOD_STD_STRING,[
 406     AC_REQUIRE([AC_PROG_CXX])
 407     AC_CACHE_CHECK([whether the systems std::string is really good],
 408     [lyx_cv_std_string_good],
 409     [AC_TRY_COMPILE([
 410             #include <string>
 411             using std::string;
 412         ],[
 413             // From a std::string that is supposed to be close to the
 414             // standard we require at least three things:
 415             // - clear() and erase()
 416             // - the strncmp of compare()
 417             // - push_back()
 418             string a("hello there");
 419             a.erase();
 420             a = "hey";
 421             char s[] = "y";
 422             int t = a.compare(a.length() - 1, 1, s);
 423             a.push_back('g');
 424             a.clear();
 425         ],[
 426             lyx_cv_std_string_good=yes
 427         ],[
 428             lyx_cv_std_string_good=no
 429
 430         ])
 431     ])
 432     if test x$lyx_cv_std_string_good = xyes ; then
 433         AC_DEFINE(STD_STRING_IS_GOOD, 1,
 434             [Define if the systems std::string is really good.])
 435     fi
 436 ])
 437
 438
 439 dnl Usage: LYX_REGEX : checks if the header regex.h is available
 440 dnl   if it is not available the automake variable USE_REGEX will be
 441 dnl   defined and the regex.h and regex.c that we provide will be used.
 442 dnl AC_DEFUN(LYX_REGEX,[
 443 dnl     AC_CHECK_HEADERS(regex.h, lyx_regex=no, lyx_regex=yes)
 444 dnl     AM_CONDITIONAL(USE_REGEX, test x$lyx_regex = xyes)
 445 dnl ])
 446
 447 dnl NOT USED CURRENTLY*************************************
 448 dnl LYX_CXX_PARTIAL
 449 AC_DEFUN(LYX_CXX_PARTIAL, [
 450     AC_REQUIRE([AC_PROG_CXX])
 451     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 452         [lyx_cv_cxx_partial_specialization],
 453         [AC_TRY_COMPILE(
 454             [
 455             template<class T, class K>
 456             class k {
 457             public:
 458             };
 459             template<class T> class k<void,T> { };
 460             ],[
 461             k<float, float> b;
 462             k<void,void> a;
 463             ],[
 464             lyx_cv_cxx_partial_specialization=yes
 465             ],[
 466             lyx_cv_cxx_partial_specialization=no
 467             ])
 468         ])
 469     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 470         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 471         [Defined if your compiler supports partial specialization.])
 472     fi
 473 ])
 474
 475
 476 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 477 dnl   provides wrappers for C headers and use our alternate version otherwise.
 478 AC_DEFUN(LYX_CXX_CHEADERS,[
 479 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 480  [AC_TRY_CPP([
 481 #include <clocale>
 482 #include <cctype>
 483 #include <cerrno>
 484 #include <cmath>
 485 #include <csignal>
 486 #include <cstdio>
 487 #include <cstdlib>
 488 #include <cstring>
 489 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 490 if test $lyx_cv_cxx_cheaders = no ; then
 491   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 492 fi])
 493
 494 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 495 dnl   are already in the global namespace
 496 AC_DEFUN(LYX_CXX_GLOBAL_CSTD,[
 497     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 498     lyx_cv_cxx_global_cstd,
 499     [AC_TRY_COMPILE([
 500     #include <cctype>
 501     using std::tolower;
 502     ],[
 503     return 0;
 504     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 505     if test x$lyx_cv_cxx_global_cstd = xyes; then
 506         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 507         [Define if your C++ compiler puts C library functions in the global namespace])
 508     fi
 509 ])
 510
 511 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 512 AC_DEFUN(LYX_PATH_XPM,[
 513 ### Check for Xpm library
 514 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage,XPM_LIB="-lXpm",
 515         [LYX_LIB_ERROR(libXpm,Xpm)], $XPM_LIB)
 516 AC_SUBST(XPM_LIB)
 517 ### Check for Xpm headers
 518 lyx_cv_xpm_h_location="<xpm.h>"
 519 AC_CHECK_HEADER(X11/xpm.h,[
 520   ac_cv_header_xpm_h=yes
 521   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 522 AC_CHECK_HEADER(xpm.h,[],[
 523 LYX_LIB_ERROR(xpm.h,Xpm)])])
 524 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location)
 525
 526 ### Test for the header version
 527 if test $ac_cv_header_xpm_h = yes; then
 528   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 529   [ cat > conftest.$ac_ext <<EOF
 530 #line __oline__ "configure"
 531 #include "confdefs.h"
 532
 533 #include XPM_H_LOCATION
 534 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 535 EOF
 536     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 537       grep '^"%%%"'  2>/dev/null | \
 538       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 539     case "$lyx_cv_xpmr" in
 540 changequote(,)
 541      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 542             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 543 changequote([,])
 544          *) ;;
 545     esac
 546     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 547     rm -f conftest*])
 548   XPM_VERSION=${lyx_cv_xpmversion}
 549   case "$lyx_cv_xpmr" in
 550 changequote(,)
 551         [789]|[0-9][0-9]*) ;;
 552 changequote([,])
 553         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 554    If you experience strange crashes with LyX, try to upgrade
 555    to at least version 4.7 (aka 3.4g).
 556    If you have installed a newer version of the library, check whether you
 557    have an old xpm.h header file in your include path.]);;
 558   esac
 559 fi])
 560
 561
 562 dnl Usage: LYX_HPUX  Checks for HP-UX and update CXXFLAGS accordingly
 563 AC_DEFUN(LYX_HPUX,
 564 [#It seems that HPUX requires using -fpcc-struct-return with gcc.
 565 AC_CACHE_CHECK(for HP-UX,ac_cv_hpux,[
 566 os=`uname -s | tr '[A-Z]' '[a-z]'`
 567 ac_cv_hpux=no
 568 test "$os" = hp-ux && ac_cv_hpux=yes])
 569 if test "$ac_cv_hpux" = yes; then
 570  test "x$GXX" = xyes && CXXFLAGS="$CXXFLAGS -fpcc-struct-return"
 571 fi])
 572
 573
 574 dnl Usage: LYX_SUNOS4 Checks for SunOS 4.x and sets the flag lyx_broken_headers
 575 dnl   if necessary
 576 AC_DEFUN(LYX_SUNOS4,
 577 [#The headers are not correct under SunOS4
 578 AC_CACHE_CHECK(for SunOS 4.x,ac_cv_sunos4,[
 579 changequote(, ) dnl
 580 os=`uname -a | sed -e 's/^\([^ ]*\) [^ ]* \([0-9]\)\..*/\1\2/'`
 581 changequote([, ]) dnl
 582 ac_cv_sunos4=no
 583 test "$os" = SunOS4 && ac_cv_sunos4=yes])
 584 if test "$ac_cv_sunos4" = yes; then
 585  test "x$GXX" = xyes && lyx_broken_headers=yes
 586 fi])
 587
 588
 589 dnl Usage: LYX_SCO Checks for SCO and sets the flag lyx_broken_headers
 590 dnl   if necessary
 591 AC_DEFUN(LYX_SCO,
 592 [AC_CACHE_CHECK(for SCO 3.2v4,ac_cv_sco,[
 593 ac_cv_sco=no
 594 if test `uname -s` != "SCO_SV"; then
 595   lyx_machine_rel=`uname -m`:`uname -r`
 596   if test $lyx_machine_rel = i386:3.2 || test $lyx_machine_rel = i486:3.2;
 597   then
 598     if test -f /usr/options/cb.name; then
 599       ac_cv_sco=no
 600     elif /bin/uname -X 2>/dev/null >/dev/null ; then
 601       ac_cv_sco=yes
 602     fi
 603   fi
 604 fi])
 605 if test "$ac_cv_sco" = yes; then
 606  test "x$GXX" = xyes && lyx_broken_headers=yes
 607 fi])
 608
 609 dnl Usage: LYX_FUNC_PUTENV_ARGTYPE
 610 dnl Checks whether putenv() takes 'char const *' or 'char *' as
 611 dnl argument. This is needed because Solaris 7 (wrongly?) uses 'char *',
 612 dnl while everybody else uses the former...
 613 AC_DEFUN(LYX_FUNC_PUTENV_ARGTYPE,
 614 [AC_MSG_CHECKING([type of argument for putenv()])
 615  AC_CACHE_VAL(lyx_cv_func_putenv_arg,dnl
 616   [AC_TRY_COMPILE(dnl
 617 [#include <cstdlib>],
 618 [char const * foo = "bar";
 619  putenv(foo);],dnl
 620    [lyx_cv_func_putenv_arg='char const *'],[lyx_cv_func_putenv_arg='char *'])])
 621  AC_MSG_RESULT($lyx_cv_func_putenv_arg)
 622  AC_DEFINE_UNQUOTED(PUTENV_TYPE_ARG,$lyx_cv_func_putenv_arg,dnl
 623    [Define to the type of the argument of putenv(). Needed on Solaris 7.])])
 624
 625
 626 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 627 dnl                       [default-yes-value])
 628 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 629 dnl  resulting directory name in 'dir-var-name'.
 630 AC_DEFUN(LYX_WITH_DIR,[
 631   AC_ARG_WITH($1,[  --with-$1        specify $2])
 632   AC_MSG_CHECKING([for $2])
 633   if test -z "$with_$3"; then
 634      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 635   else
 636     test "x$with_$3" = xyes && with_$3=$5
 637     lyx_cv_$3="$with_$3"
 638   fi
 639   AC_MSG_RESULT($lyx_cv_$3)])
 640
 641
 642 dnl Usage: LYX_LOOP_DIR(value,action)
 643 dnl Executes action for values of variable `dir' in `values'. `values' can
 644 dnl use ":" as a separator.
 645 AC_DEFUN(LYX_LOOP_DIR,[
 646 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 647 for dir in `eval "echo $1"`; do
 648   if test ! "$dir" = NONE; then
 649     test ! -d "$dir" && AC_ERROR([\"$dir\" is not a directory])
 650     $2
 651   fi
 652 done
 653 IFS=$ac_save_ifs
 654 ])
 655
 656
 657 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 658 dnl var-name.
 659 AC_DEFUN(LYX_ADD_LIB_DIR,[
 660 $1="${$1} -L$2"
 661 if test "`(uname) 2>/dev/null`" = SunOS &&
 662     uname -r | grep '^5' >/dev/null; then
 663   if test $ac_cv_prog_gxx = yes ; then
 664     $1="${$1} -Wl[,]-R$2"
 665   else
 666     $1="${$1} -R$2"
 667   fi
 668 fi])
 669
 670
 671 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 672 dnl var-name.
 673 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 674
 675 ### Check for a headers existence and location iff it exists
 676 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 677 ## It almost works.  I've tried a few variations but they give errors
 678 ## of one sort or other: bad substitution or file not found etc.  The
 679 ## actual header _is_ found though and the cache variable is set however
 680 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 681 ## reason.
 682 ## Additionally, autoheader can't figure out what to use as the name in
 683 ## the config.h.in file so we need to write our own entries there -- one for
 684 ## each header in the form PATH_HEADER_NAME_H
 685 ##
 686 AC_DEFUN(LYX_PATH_HEADER,
 687 [ AC_CHECK_HEADER($1,[
 688   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 689 ### the only remaining problem is getting the second parameter to this
 690 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 691 ### of $ac_safe being printed.
 692   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 693   [ cat > conftest.$ac_ext <<EOF
 694 #line __oline__ "configure"
 695 #include "confdefs.h"
 696
 697 #include <$1>
 698 EOF
 699 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 700   grep $1  2>/dev/null | \
 701   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 702 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 703 rm -f conftest*])
 704   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path)])
 705 ])
 706 ### end of LYX_PATH_HEADER
 707
 708 ### Check for stl_string_fwd.h existence and location if it exists
 709 AC_DEFUN(LYX_STL_STRING_FWD,
 710 [ AC_CHECK_HEADER(stl_string_fwd.h,[
 711   AC_CACHE_CHECK([path to stl_string_fwd.h],lyx_cv_path_stl_string_fwd_h,
 712   [ cat > conftest.$ac_ext <<EOF
 713 #line __oline__ "configure"
 714 #include "confdefs.h"
 715
 716 #include <stl_string_fwd.h>
 717 EOF
 718 lyx_cv_path_stl_string_fwd_h=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 719   grep 'stl_string_fwd.h'  2>/dev/null | \
 720   sed -e 's/.*\(".*stl_string_fwd.h"\).*/\1/' -e "1q"`
 721 rm -f conftest*])
 722   AC_DEFINE_UNQUOTED(STL_STRING_FWD_H_LOCATION,$lyx_cv_path_stl_string_fwd_h,
 723 [define this to the location of stl_string_fwd.h to be used with #include,
 724   NOTE: Do not set it to <stl_string_fwd.h> as that will find the LyX
 725         supplied version of the header.
 726   e.g. <../include/stl_string_fwd.h> or better yet use an absolute path])])
 727 ])
 728
 729
 730 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
 731 dnl if the cache file is inconsistent with the current host,
 732 dnl target and build system types, execute CMD or print a default
 733 dnl error message.
 734 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
 735     AC_REQUIRE([AC_CANONICAL_SYSTEM])
 736     AC_MSG_CHECKING([config.cache system type])
 737     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
 738          test x"$ac_cv_host_system_type" != x"$host"; } ||
 739        { test x"${ac_cv_build_system_type+set}" = x"set" &&
 740          test x"$ac_cv_build_system_type" != x"$build"; } ||
 741        { test x"${ac_cv_target_system_type+set}" = x"set" &&
 742          test x"$ac_cv_target_system_type" != x"$target"; }; then
 743         AC_MSG_RESULT([different])
 744         ifelse($#, 1, [$1],
 745                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
 746     else
 747         AC_MSG_RESULT([same])
 748     fi
 749     ac_cv_host_system_type="$host"
 750     ac_cv_build_system_type="$build"
 751     ac_cv_target_system_type="$target"
 752 ])
 753
 754 dnl We use this until autoconf fixes its version.
 755 AC_DEFUN(LYX_FUNC_SELECT_ARGTYPES,
 756 [AC_MSG_CHECKING([types of arguments for select()])
 757  AC_CACHE_VAL(ac_cv_func_select_arg234,dnl
 758  [AC_CACHE_VAL(ac_cv_func_select_arg1,dnl
 759   [AC_CACHE_VAL(ac_cv_func_select_arg5,dnl
 760    [for ac_cv_func_select_arg234 in 'fd_set *' 'int *' 'void *'; do
 761      for ac_cv_func_select_arg1 in 'int' 'size_t' 'unsigned long' 'unsigned'; do      for ac_cv_func_select_arg5 in 'struct timeval *' 'const struct timeval *'; do
 762        AC_TRY_COMPILE(dnl
 763 [#ifdef HAVE_SYS_TYPES_H
 764 #include <sys/types.h>
 765 #endif
 766 #ifdef HAVE_SYS_TIME_H
 767 #include <sys/time.h>
 768 #endif
 769 #ifdef HAVE_SYS_SELECT_H
 770 #include <sys/select.h>
 771 #endif
 772 #ifdef HAVE_SYS_SOCKET_H
 773 #include <sys/socket.h>
 774 #endif
 775 extern int select ($ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5);],,dnl
 776         [ac_not_found=no ; break 3],ac_not_found=yes)
 777       done
 778      done
 779     done
 780    ])dnl AC_CACHE_VAL
 781   ])dnl AC_CACHE_VAL
 782  ])dnl AC_CACHE_VAL
 783  if test "$ac_not_found" = yes; then
 784   ac_cv_func_select_arg1=int
 785   ac_cv_func_select_arg234='int *'
 786   ac_cv_func_select_arg5='struct timeval *'
 787  fi
 788  AC_MSG_RESULT([$ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5])
 789  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG1,$ac_cv_func_select_arg1,
 790                     [Define to the type of arg1 for select().])
 791  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG234,($ac_cv_func_select_arg234),
 792                     [Define to the type of args 2, 3 and 4 for select().])
 793  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG5,($ac_cv_func_select_arg5),
 794                     [Define to the type of arg5 for select().])
 795 ])
 796
 797 ### Check which frontend we want to use. The default is XForms
 798 ###
 799 AC_DEFUN(LYX_USE_FRONTEND,
 800 [AC_MSG_CHECKING([what frontend should be used as main GUI])
 801 AC_ARG_WITH(frontend,
 802   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 803                             Possible values: xforms, qt2, gnome],
 804   [lyx_use_frontend="$withval"], [lyx_use_frontend="xforms"])
 805 AC_MSG_RESULT($lyx_use_frontend)
 806 AC_SUBST(FRONTEND)
 807 AC_SUBST(FRONTEND_GUILIB)
 808 AC_SUBST(FRONTEND_LDFLAGS)
 809 AC_SUBST(FRONTEND_INCLUDES)
 810 AC_SUBST(FRONTEND_LIBS)
 811 ])
 812
 813
 814 dnl Check things are declared in headers to avoid errors or warnings.
 815 dnl Called like LYX_CHECK_DECL(function, headerfile)
 816 dnl Defines HAVE_DECL_{FUNCTION}
 817 AC_DEFUN(LYX_CHECK_DECL,
 818 [AC_MSG_CHECKING(if $1 is declared by header $2)
 819 tr_func=`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 820
 821 tr_hdr=`echo $2 | tr . _`
 822 AC_CACHE_VAL([lyx_cv_declare_${tr_hdr}_$1],
 823 [AC_EGREP_HEADER($1, $2, [eval "lyx_cv_declare_${tr_hdr}_$1=yes"], [eval "lyx_cv_declare_${tr_hdr}_$1=no"])])
 824 if eval "test \"\${lyx_cv_declare_${tr_hdr}_$1}\" = \"yes\""; then
 825         AC_DEFINE_UNQUOTED(HAVE_DECL_${tr_func})
 826         AC_MSG_RESULT(yes)
 827 else
 828         AC_MSG_RESULT(no)
 829 fi])
 830
 831 dnl This is the multiple headers version of the LYX_CHECK_DECL macro above.
 832 dnl Called like LYX_CHECK_DECL_HDRS(function, file1 file2 file3)
 833 AC_DEFUN(LYX_CHECK_DECL_HDRS,
 834 [ got="no"
 835 for I in $2; do
 836 tr_hdr=`echo $I | tr . _`
 837 if test "${got}" = "no"; then
 838     LYX_CHECK_DECL($1, $I)
 839 fi
 840 if eval "test \"\${lyx_cv_declare_${tr_hdr}_$1}\" = \"yes\""; then
 841      got="yes"
 842 fi
 843 done])
 844
 845
 846 ## ------------------------------------------------------------------------
 847 ## Find a file (or one of more files in a list of dirs)
 848 ## ------------------------------------------------------------------------
 849 ##
 850 AC_DEFUN(AC_FIND_FILE,
 851 [
 852 $3=NO
 853 for i in $2;
 854 do
 855   for j in $1;
 856   do
 857     if test -r "$i/$j"; then
 858       $3=$i
 859       break 2
 860     fi
 861   done
 862 done
 863 ])
 864
 865 dnl just a wrapper to clean up configure.in
 866 AC_DEFUN(LYX_PROG_LIBTOOL,
 867 [
 868 AC_REQUIRE([AC_ENABLE_SHARED])
 869 AC_REQUIRE([AC_ENABLE_STATIC])
 870 dnl libtool is only for C, so I must force him
 871 dnl to find the correct flags for C++
 872 ac_save_cc=$CC
 873 ac_save_cflags="$CFLAGS"
 874 CC=$CXX
 875 CFLAGS="$CXXFLAGS"
 876 AM_PROG_LIBTOOL dnl for libraries
 877 CC=$ac_save_cc
 878 CFLAGS="$ac_save_cflags"
 879 ])