config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set lyx_cv_prog_clang to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 150 AC_DEFUN([LYX_LIB_STDCXX],
 151 [AC_CACHE_CHECK([whether STL is libstdc++],
 152                [lyx_cv_lib_stdcxx],
 153 [AC_TRY_COMPILE([#include<vector>], [
 154 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 155             this is not libstdc++
 156 #endif
 157 ],
 158 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 159 ])
 160
 161
 162 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 163 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 164 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 165 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 166                [lyx_cv_lib_stdcxx_cxx11_abi],
 167 [AC_TRY_COMPILE([#include<vector>], [
 168 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 169             this is not libstdc++ using the C++11 ABI
 170 #endif
 171 ],
 172 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 173 ])
 174
 175
 176 AC_DEFUN([LYX_PROG_CXX],
 177 [AC_REQUIRE([AC_PROG_CXX])
 178 AC_REQUIRE([AC_PROG_CXXCPP])
 179
 180 AC_LANG_PUSH(C++)
 181 LYX_PROG_CLANG
 182 LYX_LIB_STDCXX
 183 LYX_LIB_STDCXX_CXX11_ABI
 184 AC_LANG_POP(C++)
 185
 186 if test $lyx_cv_lib_stdcxx = "yes" ; then
 187   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 188     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 189   else
 190     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 191   fi
 192 else
 193   if test $lyx_cv_prog_clang = "yes" ; then
 194     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 195   fi
 196 fi
 197
 198 ### We might want to get or shut warnings.
 199 AC_ARG_ENABLE(warnings,
 200   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 201   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 202         enable_warnings=yes;
 203     else
 204         enable_warnings=no;
 205     fi;])
 206 if test x$enable_warnings = xyes ; then
 207   lyx_flags="$lyx_flags warnings"
 208 fi
 209
 210 ### We might want to disable debug
 211 AC_ARG_ENABLE(debug,
 212   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 213   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 214 )
 215
 216 AC_ARG_ENABLE(stdlib-debug,
 217   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 218   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 219           [enable_stdlib_debug=no])]
 220 )
 221
 222 AC_ARG_ENABLE(concept-checks,
 223   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 224   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 225           [enable_concept_checks=no])]
 226   if test x$USE_QT5 = xyes ; then
 227       enable_concept_checks=no
 228   fi
 229 )
 230
 231 ### set up optimization
 232 AC_ARG_ENABLE(optimization,
 233     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 234     enable_optimization=yes;)
 235 case $enable_optimization in
 236     yes)
 237         if test $lyx_devel_version = yes ; then
 238             lyx_optim=-O
 239         else
 240             lyx_optim=-O2
 241         fi;;
 242     no) lyx_optim=;;
 243     *) lyx_optim=${enable_optimization};;
 244 esac
 245
 246 AC_ARG_ENABLE(pch,
 247   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 248         enable_pch=no;)
 249 lyx_pch_comp=no
 250
 251 AC_ARG_ENABLE(cxx11,
 252   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode]),,
 253   enable_cxx11=no;)
 254
 255 AC_ARG_ENABLE(assertions,
 256   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 257   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 258           [enable_assertions=no])]
 259 )
 260 if test "x$enable_assertions" = xyes ; then
 261    lyx_flags="$lyx_flags assertions"
 262    AC_DEFINE(ENABLE_ASSERTIONS,1,
 263     [Define if you want assertions to be enabled in the code])
 264 fi
 265
 266 # set the compiler options correctly.
 267 lyx_std_regex=no
 268 if test x$GXX = xyes; then
 269   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 270   if test x$CLANG = xno; then
 271     dnl Useful for global version info
 272     gxx_version=`${CXX} -dumpversion`
 273     CXX_VERSION="($gxx_version)"
 274   else
 275     gxx_version=clang
 276   fi
 277
 278   AM_CXXFLAGS="$lyx_optim"
 279   if test x$enable_debug = xyes ; then
 280       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 281   fi
 282   if test $build_type = gprof ; then
 283     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 284     AM_LDFLAGS="$AM_LDFLAGS -pg"
 285   fi
 286   if test $build_type = profiling ; then
 287     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 288   fi
 289
 290   if test x$USE_QT5 = xyes ; then
 291       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 292   fi
 293   dnl Warnings are for preprocessor too
 294   if test x$enable_warnings = xyes ; then
 295       case $gxx_version in
 296           4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*|clang)
 297               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 298               ;;
 299           *)
 300               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra -Wfloat-conversion"
 301               ;;
 302       esac
 303   fi
 304   case $gxx_version in
 305       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 306       *)  test $enable_pch = yes && lyx_pch_comp=yes ;;
 307   esac
 308   if test x$enable_stdlib_debug = xyes ; then
 309     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 310     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 311     case $gxx_version in
 312       *)
 313         lyx_flags="$lyx_flags stdlib-debug"
 314         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 315         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 316         ;;
 317     esac
 318   fi
 319   if test x$enable_concept_checks = xyes ; then
 320     case $gxx_version in
 321       4.*)
 322         lyx_flags="$lyx_flags concept-checks"
 323         dnl FIXME check whether this makes sense with clang/libc++
 324         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 325         ;;
 326     esac
 327   fi
 328   if test x$enable_cxx11 = xyes ; then
 329     case $gxx_version in
 330       4.0*|4.1*|4.2*) AC_ERROR([There is no C++11 support in gcc 4.2 or older]);;
 331       4.3*|4.4*|4.5*|4.6*)
 332         lyx_flags="$lyx_flags c++11-mode"
 333         AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++0x";;
 334       clang)
 335         dnl presumably all clang version support c++11.
 336         lyx_flags="$lyx_flags c++11-mode"
 337         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 338         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11 -Wno-deprecated-register";;
 339       *)
 340         lyx_flags="$lyx_flags c++11-mode"
 341         AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++11"
 342         ;;
 343     esac
 344     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 345       dnl <regex> in gcc is unusable in versions less than 4.9.0
 346       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 347       case $gxx_version in
 348         4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 349         *) lyx_flags="$lyx_flags stdregex"
 350            lyx_std_regex=yes
 351            ;;
 352       esac
 353     else
 354       lyx_flags="$lyx_flags stdregex"
 355       lyx_std_regex=yes
 356     fi
 357
 358     if test $lyx_std_regex = yes ; then
 359       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 360     fi
 361   fi
 362 fi
 363 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 364 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 365 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 366 ])dnl
 367
 368 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 369 dnl        be used.
 370 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 371         AC_MSG_CHECKING([whether to use included boost library])
 372         AC_ARG_WITH(included-boost,
 373             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 374             [lyx_cv_with_included_boost=$withval],
 375             [lyx_cv_with_included_boost=yes])
 376         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 377         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 378         if test x$lyx_cv_with_included_boost = xyes ; then
 379             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 380             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 381         else
 382             AC_LANG_PUSH(C++)
 383             save_LIBS=$LIBS
 384
 385             AC_MSG_CHECKING([for multithreaded boost libraries])
 386             LIBS="$save_LIBS -lboost_signals-mt -lm $LIBTHREAD"
 387             AC_LINK_IFELSE(
 388                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 389                         [boost::signal<void ()> s;])],
 390                 [AC_MSG_RESULT([yes])
 391                  BOOST_MT="-mt"],
 392                 [AC_MSG_RESULT([no])
 393                  AC_MSG_CHECKING([for plain boost libraries])
 394                  LIBS="$save_LIBS -lboost_signals -lm"
 395                  AC_LINK_IFELSE(
 396                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 397                              [boost::signal<void ()> s;])],
 398                      [AC_MSG_RESULT([yes])
 399                       BOOST_MT=""],
 400                      [AC_MSG_RESULT([no])
 401                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 402                  ])
 403             ])
 404             LIBS=$save_LIBS
 405             AC_LANG_POP(C++)
 406             BOOST_INCLUDES=
 407             if test $lyx_std_regex = yes ; then
 408               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 409             else
 410               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 411             fi
 412         fi
 413         AC_SUBST(BOOST_INCLUDES)
 414         AC_SUBST(BOOST_LIBS)
 415 ])
 416
 417
 418 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 419 dnl        necessary APIs are available to print callstacks.
 420 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 421 [AC_CACHE_CHECK([whether printing callstack is possible],
 422                [lyx_cv_callstack_printing],
 423 [AC_TRY_COMPILE([
 424 #include <execinfo.h>
 425 #include <cxxabi.h>
 426 ], [
 427         void* array[200];
 428         size_t size = backtrace(array, 200);
 429         backtrace_symbols(array, size);
 430         int status = 0;
 431         abi::__cxa_demangle("abcd", 0, 0, &status);
 432 ],
 433 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 434 if test x"$lyx_cv_callstack_printing" = xyes; then
 435   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 436             [Define if callstack can be printed])
 437 fi
 438 ])
 439
 440
 441 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 442 dnl        be used.
 443 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 444         AC_MSG_CHECKING([whether to use included MyThes library])
 445         AC_ARG_WITH(included-mythes,
 446             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 447             [lyx_cv_with_included_mythes=$withval],
 448             [lyx_cv_with_included_mythes=yes])
 449         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 450         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 451         if test x$lyx_cv_with_included_mythes != xyes ; then
 452                 AC_LANG_PUSH(C++)
 453                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 454                 if test x$ac_cv_header_mythes_h != xyes; then
 455                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 456                 fi
 457                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 458                 if test x$lyx_mythes != xyes; then
 459                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 460                 fi
 461                 AC_LANG_POP(C++)
 462                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 463                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 464                 fi
 465                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 466                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 467                 AC_SUBST(MYTHES_LIBS)
 468         fi
 469 ])
 470
 471
 472 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 473 dnl                       [default-yes-value])
 474 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 475 dnl  resulting directory name in 'dir-var-name'.
 476 AC_DEFUN([LYX_WITH_DIR],[
 477   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 478   AC_MSG_CHECKING([for $2])
 479   if test -z "$with_$3"; then
 480      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 481   else
 482     test "x$with_$3" = xyes && with_$3=$5
 483     lyx_cv_$3="$with_$3"
 484   fi
 485   AC_MSG_RESULT($lyx_cv_$3)])
 486
 487
 488 dnl Usage: LYX_LOOP_DIR(value,action)
 489 dnl Executes action for values of variable `dir' in `values'. `values' can
 490 dnl use ":" as a separator.
 491 AC_DEFUN([LYX_LOOP_DIR],[
 492 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 493 for dir in `eval "echo $1"`; do
 494   if test ! "$dir" = NONE; then
 495     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 496     $2
 497   fi
 498 done
 499 IFS=$ac_save_ifs
 500 ])
 501
 502
 503 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 504 dnl var-name.
 505 AC_DEFUN([LYX_ADD_LIB_DIR],[
 506 $1="${$1} -L$2"
 507 if test "`(uname) 2>/dev/null`" = SunOS &&
 508     uname -r | grep '^5' >/dev/null; then
 509   if test $ac_cv_prog_gxx = yes ; then
 510     $1="${$1} -Wl[,]-R$2"
 511   else
 512     $1="${$1} -R$2"
 513   fi
 514 fi])
 515
 516
 517 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 518 dnl var-name.
 519 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 520
 521 ### Check for a headers existence and location iff it exists
 522 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 523 ## It almost works.  I've tried a few variations but they give errors
 524 ## of one sort or other: bad substitution or file not found etc.  The
 525 ## actual header _is_ found though and the cache variable is set however
 526 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 527 ## reason.
 528 ## Additionally, autoheader can't figure out what to use as the name in
 529 ## the config.h.in file so we need to write our own entries there -- one for
 530 ## each header in the form PATH_HEADER_NAME_H
 531 ##
 532 AC_DEFUN([LYX_PATH_HEADER],
 533 [ AC_CHECK_HEADER($1,[
 534   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 535 ### the only remaining problem is getting the second parameter to this
 536 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 537 ### of $ac_safe being printed.
 538   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 539   [ cat > conftest.$ac_ext <<EOF
 540 #line __oline__ "configure"
 541 #include "confdefs.h"
 542
 543 #include <$1>
 544 EOF
 545 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 546   grep $1  2>/dev/null | \
 547   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 548 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 549 rm -f conftest*])
 550   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 551 ])
 552 ### end of LYX_PATH_HEADER
 553
 554 ## Check what kind of packaging should be used at install time.
 555 ## The default is autodetected.
 556 AC_DEFUN([LYX_USE_PACKAGING],
 557 [AC_MSG_CHECKING([what packaging should be used])
 558 AC_ARG_WITH(packaging,
 559   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 560                             Possible values: posix, windows, macosx])],
 561   [lyx_use_packaging="$withval"], [
 562   case $host in
 563     *-apple-darwin*) lyx_use_packaging=macosx ;;
 564      *-pc-mingw32*) lyx_use_packaging=windows;;
 565                   *) lyx_use_packaging=posix;;
 566   esac])
 567 AC_MSG_RESULT($lyx_use_packaging)
 568 lyx_install_posix=false
 569 lyx_install_macosx=false
 570 lyx_install_cygwin=false
 571 lyx_install_windows=false
 572 case $lyx_use_packaging in
 573    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 574            PACKAGE=LyX${version_suffix}
 575            default_prefix="/Applications/${PACKAGE}.app"
 576            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 577            bindir='${prefix}/Contents/MacOS'
 578            libdir='${prefix}/Contents/Resources'
 579            datarootdir='${prefix}/Contents/Resources'
 580            pkgdatadir='${datadir}'
 581            mandir='${datadir}/man'
 582            lyx_install_macosx=true ;;
 583   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 584            PACKAGE=LyX${version_suffix}
 585            default_prefix="C:/Program Files/${PACKAGE}"
 586            bindir='${prefix}/bin'
 587            libdir='${prefix}/Resources'
 588            datarootdir='${prefix}/Resources'
 589            pkgdatadir='${datadir}'
 590            mandir='${prefix}/Resources/man'
 591            lyx_install_windows=true ;;
 592     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 593            PACKAGE=lyx${version_suffix}
 594            program_suffix=$version_suffix
 595            pkgdatadir='${datadir}/${PACKAGE}'
 596            default_prefix=$ac_default_prefix
 597            case ${host} in
 598            *cygwin*) lyx_install_cygwin=true ;;
 599                 *apple-darwin*) lyx_install_macosx=true ;;
 600            esac
 601            lyx_install_posix=true ;;
 602     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 603 esac
 604 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 605 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 606 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 607 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 608 AC_SUBST(pkgdatadir)
 609 AC_SUBST(program_suffix)
 610 ])
 611
 612
 613 ## ------------------------------------------------------------------------
 614 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 615 ## one or two arguments.
 616 ##
 617 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 618 ## ------------------------------------------------------------------------
 619 ##
 620 AC_DEFUN([AC_FUNC_MKDIR],
 621 [AC_CHECK_FUNCS([mkdir _mkdir])
 622 AC_CACHE_CHECK([whether mkdir takes one argument],
 623                [ac_cv_mkdir_takes_one_arg],
 624 [AC_TRY_COMPILE([
 625 #include <sys/stat.h>
 626 #if HAVE_UNISTD_H
 627 #  include <unistd.h>
 628 #endif
 629 ], [mkdir (".");],
 630 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 631 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 632   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 633             [Define if mkdir takes only one argument.])
 634 fi
 635 ])
 636
 637
 638 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 639 dnl (which may be a relative path, and need not refer to any existing
 640 dnl entity).
 641
 642 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 643 dnl native Win32 path name, (but with slashes, not backslashes).
 644
 645 dnl On any other system, it is simply the result which would be obtained
 646 dnl if PATHNAME represented an existing directory, and the pwd command was
 647 dnl executed in that directory.
 648 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 649 [ac_dir="$2"
 650  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 651     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 652  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 653  do
 654    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 655  done
 656  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 657  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 658  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 659    s?/*$[]??'`
 660 ])
 661
 662 dnl this is used by the macro blow to general a proper config.h.in entry
 663 m4_define([LYX_AH_CHECK_DECL],
 664 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 665   [Define if you have the prototype for function `$1'])])
 666
 667 dnl Check things are declared in headers to avoid errors or warnings.
 668 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 669 dnl Defines HAVE_DECL_{FUNCTION}
 670 AC_DEFUN([LYX_CHECK_DECL],
 671 [LYX_AH_CHECK_DECL($1)
 672 for ac_header in $2
 673 do
 674   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 675   AC_EGREP_HEADER($1, $ac_header,
 676       [AC_MSG_RESULT(yes)
 677        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 678        break],
 679       [AC_MSG_RESULT(no)])
 680 done])
 681
 682 dnl this is used by the macro below to generate a proper config.h.in entry
 683 m4_define([LYX_AH_CHECK_DEF],
 684 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 685   [Define to 1 if `$1' is defined in `$2'])])
 686
 687 dnl Check whether name is defined in header by using it in codesnippet.
 688 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 689 dnl Defines HAVE_DEF_{NAME}
 690 AC_DEFUN([LYX_CHECK_DEF],
 691 [LYX_AH_CHECK_DEF($1, $2)
 692  AC_MSG_CHECKING([whether $1 is defined by header $2])
 693  AC_TRY_COMPILE([#include <$2>], [$3],
 694      lyx_have_def_name=yes,
 695      lyx_have_def_name=no)
 696  AC_MSG_RESULT($lyx_have_def_name)
 697  if test "x$lyx_have_def_name" = xyes; then
 698    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 699  fi
 700 ])
 701
 702 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 703 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 704 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 705 AC_DEFUN([LYX_SET_VERSION_INFO],
 706 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 707  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 708  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 709  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 710  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 711  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 712  test "x$lyx_patch" = "x" && lyx_patch=0
 713  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 714  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 715  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 716  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 717  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 718  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 719  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 720  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 721 ])
 722
 723 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 724 # ---------------------------------------------------------------------------
 725 # Copied from autoconf 2.68, added a check that python version is < 3.0
 726 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 727 # Run ACTION-IF-FALSE otherwise.
 728 # This test uses sys.hexversion instead of the string equivalent (first
 729 # word of sys.version), in order to cope with versions such as 2.2c1.
 730 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 731 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 732  [prog="import sys
 733 # split strings by '.' and convert to numeric.  Append some zeros
 734 # because we need at least 4 digits for the hex conversion.
 735 # map returns an iterator in Python 3.0 and a list in 2.x
 736 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 737 minverhex = 0
 738 maxverhex = 50331648 # = 3.0.0.0
 739 # xrange is not present in Python 3.0 and range returns an iterator
 740 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 741 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 742   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])