config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11 lyx_devel_version=no
  12 lyx_prerelease=no
  13 AC_MSG_CHECKING([for build type])
  14 AC_ARG_ENABLE(build-type,
  15   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  16   [case $enableval in
  17     dev*) build_type=development;;
  18     pre*) build_type=prerelease;;
  19     prof*)  build_type=profiling;;
  20     gprof*) build_type=gprof;;
  21     rel*) build_type=release;;
  22     *) AC_ERROR([Bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  23    esac],
  24   [case AC_PACKAGE_VERSION in
  25     *svn*) build_type=development;;
  26     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  27     *) build_type=release ;;
  28    esac])
  29 AC_MSG_RESULT([$build_type])
  30 lyx_flags="$lyx_flags build=$build_type"
  31 case $build_type in
  32     development) lyx_devel_version=yes
  33                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  34                  LYX_DATE="not released yet" ;;
  35     prerelease) lyx_prerelease=yes ;;
  36 esac
  37
  38 AC_SUBST(lyx_devel_version)
  39 ])
  40
  41
  42 dnl Define the option to set a LyX version on installed executables and directories
  43 dnl
  44 dnl
  45 AC_DEFUN([LYX_VERSION_SUFFIX],[
  46 AC_MSG_CHECKING([for version suffix])
  47 dnl We need the literal double quotes in the rpm spec file
  48 RPM_VERSION_SUFFIX='""'
  49 AC_ARG_WITH(version-suffix,
  50   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  51   [if test "x$withval" = "xyes";
  52    then
  53      withval="-"AC_PACKAGE_VERSION
  54      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  55    fi
  56    AC_SUBST(version_suffix,$withval)
  57    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  58 AC_SUBST(RPM_VERSION_SUFFIX)
  59 AC_MSG_RESULT([$withval])
  60 ])
  61
  62
  63 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  64 dnl flag lyx_error to yes.
  65 AC_DEFUN([LYX_ERROR],[
  66 lyx_error_txt="$lyx_error_txt
  67 ** $1
  68 "
  69 lyx_error=yes])
  70
  71
  72 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  73 dnl flag lyx_warning to yes.
  74 AC_DEFUN([LYX_WARNING],[
  75 lyx_warning_txt="$lyx_warning_txt
  76 == $1
  77 "
  78 lyx_warning=yes])
  79
  80
  81 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  82 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  83 AC_DEFUN([LYX_LIB_ERROR],[
  84 LYX_ERROR([Cannot find $1. Please check that the $2 library
  85    is correctly installed on your system.])])
  86
  87
  88 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  89 dnl   has occured previously.
  90 AC_DEFUN([LYX_CHECK_ERRORS],[
  91 if test x$lyx_warning = xyes; then
  92 cat <<EOF
  93 === The following minor problems have been detected by configure.
  94 === Please check the messages below before running 'make'.
  95 === (see the section 'Problems' in the INSTALL file)
  96 $lyx_warning_txt
  97 EOF
  98 fi
  99 if test x$lyx_error = xyes; then
 100 cat <<EOF
 101 **** The following problems have been detected by configure.
 102 **** Please check the messages below before running 'make'.
 103 **** (see the section 'Problems' in the INSTALL file)
 104 $lyx_error_txt
 105 $lyx_warning_txt
 106 EOF
 107 exit 1
 108 else
 109
 110 cat <<EOF
 111 Configuration of LyX was successful.
 112 Type 'make' to compile the program,
 113 and then 'make install' to install it.
 114 EOF
 115 fi])
 116
 117
 118 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 119 dnl
 120 define(LYX_SEARCH_PROG,[dnl
 121 for ac_prog in $2 ; do
 122 # Extract the first word of "$ac_prog", so it can be a program name with args.
 123   set dummy $ac_prog ; ac_word=$[2]
 124   if test -z "[$]$1"; then
 125     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 126     for ac_dir in $PATH; do
 127       test -z "$ac_dir" && ac_dir=.
 128       if test -f [$ac_dir/$ac_word]; then
 129         $1="$ac_prog"
 130         break
 131       fi
 132     done
 133     IFS="$ac_save_ifs"
 134   fi
 135
 136   if test -n "[$]$1"; then
 137     ac_result=yes
 138   else
 139     ac_result=no
 140   fi
 141   ifelse($3,,,[$3])
 142   test -n "[$]$1" && break
 143 done
 144 ])dnl
 145
 146
 147 AC_DEFUN([LYX_PROG_CXX_WORKS],
 148 [rm -f conftest.C
 149 cat >conftest.C <<EOF
 150 class foo {
 151    // we require the mutable keyword
 152    mutable int bar;
 153  };
 154  // we require namespace support
 155  namespace baz {
 156    int bar;
 157  }
 158  int main() {
 159    return(0);
 160  }
 161 EOF
 162 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 163 rm -f conftest.C conftest.o conftest.obj || true
 164 ])
 165
 166
 167 AC_DEFUN([LYX_PROG_CXX],
 168 [AC_MSG_CHECKING([for a good enough C++ compiler])
 169 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 170
 171 if test -z "$CXX" ; then
 172   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 173 fi
 174 AC_MSG_RESULT($CXX)
 175
 176 AC_PROG_CXX
 177 AC_PROG_CXXCPP
 178
 179 ### We might want to get or shut warnings.
 180 AC_ARG_ENABLE(warnings,
 181   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 182   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 183         enable_warnings=yes;
 184     else
 185         enable_warnings=no;
 186     fi;])
 187 if test x$enable_warnings = xyes ; then
 188   lyx_flags="$lyx_flags warnings"
 189 fi
 190
 191 ### We might want to disable debug
 192 AC_ARG_ENABLE(debug,
 193   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 194   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 195 )
 196
 197 AC_ARG_ENABLE(stdlib-debug,
 198   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 199   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 200           [enable_stdlib_debug=no])]
 201 )
 202
 203 AC_ARG_ENABLE(concept-checks,
 204   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 205   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 206           [enable_concept_checks=no])]
 207 )
 208
 209 AC_ARG_ENABLE(gprof,
 210   AC_HELP_STRING([--enable-gprof],[enable profiling using gprof]),,
 211   [AS_CASE([$build_type], [gprof], [enable_gprof=yes], [enable_gprof=no])]
 212 )
 213
 214 ### set up optimization
 215 AC_ARG_ENABLE(optimization,
 216     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 217     enable_optimization=yes;)
 218 case $enable_optimization in
 219     yes)
 220         if test $lyx_devel_version = yes ; then
 221             lyx_opt=-O
 222         else
 223             lyx_opt=-O2
 224         fi;;
 225     no) lyx_opt=;;
 226     *) lyx_opt=${enable_optimization};;
 227 esac
 228
 229 AC_ARG_ENABLE(pch,
 230   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 231         enable_pch=no;)
 232 lyx_pch_comp=no
 233
 234 AC_ARG_ENABLE(assertions,
 235   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 236   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 237           [enable_assertions=no])]
 238 )
 239 if test "x$enable_assertions" = xyes ; then
 240    lyx_flags="$lyx_flags assertions"
 241    AC_DEFINE(ENABLE_ASSERTIONS,1,
 242     [Define if you want assertions to be enabled in the code])
 243 fi
 244
 245 # set the compiler options correctly.
 246 if test x$GXX = xyes; then
 247   dnl Useful for global version info
 248   gxx_version=`${CXX} -dumpversion`
 249   CXX_VERSION="($gxx_version)"
 250
 251   if test "$ac_test_CXXFLAGS" = set; then
 252     CXXFLAGS="$ac_save_CXXFLAGS"
 253   else
 254       CFLAGS="$lyx_opt"
 255       CXXFLAGS="$lyx_opt"
 256     if test x$enable_debug = xyes ; then
 257         CFLAGS="-g $CFLAGS"
 258         CXXFLAGS="-g $CXXFLAGS"
 259     fi
 260     if test x$enable_gprof = xyes ; then
 261         CFLAGS="-pg $CFLAGS"
 262         CXXFLAGS="-pg $CXXFLAGS"
 263         LDFLAGS="-pg $LDFLAGS"
 264     fi
 265   fi
 266   if test "$ac_env_CPPFLAGS_set" != set; then
 267     if test x$enable_warnings = xyes ; then
 268         case $gxx_version in
 269             3.1*|3.2*|3.3*)
 270                 CPPFLAGS="-W -Wall $CPPFLAGS"
 271                 ;;
 272             *)
 273                 CPPFLAGS="-Wextra -Wall $CPPFLAGS "
 274                 ;;
 275         esac
 276     fi
 277   fi
 278   case $gxx_version in
 279       3.1*)    AM_CXXFLAGS="-finline-limit=500 ";;
 280       3.2*|3.3*)    AM_CXXFLAGS="";;
 281       3.4*|4.*)
 282           AM_CXXFLAGS=""
 283           test $enable_pch = yes && lyx_pch_comp=yes
 284           ;;
 285       *)       AM_CXXFLAGS="";;
 286   esac
 287   if test x$enable_stdlib_debug = xyes ; then
 288     case $gxx_version in
 289       3.4*|4.*)
 290         lyx_flags="$lyx_flags stdlib-debug"
 291         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 292         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 293         ;;
 294     esac
 295   fi
 296   if test x$enable_concept_checks = xyes ; then
 297     case $gxx_version in
 298       3.3*)
 299         lyx_flags="$lyx_flags concept-checks"
 300         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 301         ;;
 302       3.4*|4.*)
 303         lyx_flags="$lyx_flags concept-checks"
 304         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 305         ;;
 306     esac
 307   fi
 308 fi
 309 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 310 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 311 ])dnl
 312
 313 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 314 dnl        be used.
 315 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 316         AC_MSG_CHECKING([whether to use included boost library])
 317         AC_ARG_WITH(included-boost,
 318             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 319             [lyx_cv_with_included_boost=$withval],
 320             [lyx_cv_with_included_boost=yes])
 321         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 322         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 323         if test x$lyx_cv_with_included_boost != xyes ; then
 324                 AC_CHECK_LIB(boost_signals, main, [lyx_boost_underscore=yes], [], [-lm])
 325                 AC_CHECK_LIB(boost_signals-mt, main, [lyx_boost_underscore_mt=yes], [], [-lm $LIBTHREAD])
 326                 if test x$lyx_boost_underscore_mt = xyes ; then
 327                         BOOST_MT="-mt"
 328                 else
 329                         BOOST_MT=""
 330                         if test x$lyx_boost_plain != xyes -a x$lyx_boost_underscore != xyes ; then
 331                                 LYX_ERROR([No suitable boost library found (do not use --without-included-boost)])
 332                         fi
 333                 fi
 334                 AC_SUBST(BOOST_SEP)
 335                 AC_SUBST(BOOST_MT)
 336         fi
 337 ])
 338
 339
 340 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 341 dnl        be used.
 342 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 343         AC_MSG_CHECKING([whether to use included MyThes library])
 344         AC_ARG_WITH(included-mythes,
 345             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 346             [lyx_cv_with_included_mythes=$withval],
 347             [lyx_cv_with_included_mythes=yes])
 348         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 349         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 350         if test x$lyx_cv_with_included_mythes != xyes ; then
 351                 AC_LANG_PUSH(C++)
 352                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 353                 if test x$ac_cv_header_mythes_h != xyes; then
 354                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 355                 fi
 356                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 357                 if test x$lyx_mythes != xyes; then
 358                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 359                 fi
 360                 AC_LANG_POP(C++)
 361                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 362                         LYX_ERROR([No suitable MyThes library found (do not use --without-included-mythes)])
 363                 fi
 364                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 365                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 366                 AC_SUBST(MYTHES_LIBS)
 367         fi
 368 ])
 369
 370
 371 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 372 dnl                       [default-yes-value])
 373 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 374 dnl  resulting directory name in 'dir-var-name'.
 375 AC_DEFUN([LYX_WITH_DIR],[
 376   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 377   AC_MSG_CHECKING([for $2])
 378   if test -z "$with_$3"; then
 379      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 380   else
 381     test "x$with_$3" = xyes && with_$3=$5
 382     lyx_cv_$3="$with_$3"
 383   fi
 384   AC_MSG_RESULT($lyx_cv_$3)])
 385
 386
 387 dnl Usage: LYX_LOOP_DIR(value,action)
 388 dnl Executes action for values of variable `dir' in `values'. `values' can
 389 dnl use ":" as a separator.
 390 AC_DEFUN([LYX_LOOP_DIR],[
 391 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 392 for dir in `eval "echo $1"`; do
 393   if test ! "$dir" = NONE; then
 394     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 395     $2
 396   fi
 397 done
 398 IFS=$ac_save_ifs
 399 ])
 400
 401
 402 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 403 dnl var-name.
 404 AC_DEFUN([LYX_ADD_LIB_DIR],[
 405 $1="${$1} -L$2"
 406 if test "`(uname) 2>/dev/null`" = SunOS &&
 407     uname -r | grep '^5' >/dev/null; then
 408   if test $ac_cv_prog_gxx = yes ; then
 409     $1="${$1} -Wl[,]-R$2"
 410   else
 411     $1="${$1} -R$2"
 412   fi
 413 fi])
 414
 415
 416 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 417 dnl var-name.
 418 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 419
 420 ### Check for a headers existence and location iff it exists
 421 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 422 ## It almost works.  I've tried a few variations but they give errors
 423 ## of one sort or other: bad substitution or file not found etc.  The
 424 ## actual header _is_ found though and the cache variable is set however
 425 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 426 ## reason.
 427 ## Additionally, autoheader can't figure out what to use as the name in
 428 ## the config.h.in file so we need to write our own entries there -- one for
 429 ## each header in the form PATH_HEADER_NAME_H
 430 ##
 431 AC_DEFUN([LYX_PATH_HEADER],
 432 [ AC_CHECK_HEADER($1,[
 433   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 434 ### the only remaining problem is getting the second parameter to this
 435 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 436 ### of $ac_safe being printed.
 437   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 438   [ cat > conftest.$ac_ext <<EOF
 439 #line __oline__ "configure"
 440 #include "confdefs.h"
 441
 442 #include <$1>
 443 EOF
 444 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 445   grep $1  2>/dev/null | \
 446   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 447 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 448 rm -f conftest*])
 449   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 450 ])
 451 ### end of LYX_PATH_HEADER
 452
 453 ### Check which frontends we want to use.
 454 ###
 455 AC_DEFUN([LYX_USE_FRONTENDS],
 456 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 457 AC_ARG_WITH(frontend,
 458   [AC_HELP_STRING([--with-frontend=THIS], [use THIS frontend as main GUI:
 459                             Possible values: qt4])],
 460   [FRONTENDS="$withval"],[FRONTENDS="qt4"])
 461 if test "x$FRONTENDS" = x ; then
 462   AC_MSG_RESULT(none)
 463   AC_ERROR("Please select a frontend using --with-frontend")
 464 fi
 465 AC_MSG_RESULT($FRONTENDS)
 466 AC_SUBST(FRONTENDS)
 467 AC_SUBST(FRONTENDS_SUBDIRS)
 468 AC_SUBST(FRONTENDS_PROGS)
 469 ])
 470
 471
 472 ## Check what kind of packaging should be used at install time.
 473 ## The default is autodetected.
 474 AC_DEFUN([LYX_USE_PACKAGING],
 475 [AC_MSG_CHECKING([what packaging should be used])
 476 AC_ARG_WITH(packaging,
 477   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 478                             Possible values: posix, windows, macosx])],
 479   [lyx_use_packaging="$withval"], [
 480   case $host in
 481     *-apple-darwin*) lyx_use_packaging=macosx ;;
 482      *-pc-mingw32*) lyx_use_packaging=windows;;
 483                   *) lyx_use_packaging=posix;;
 484   esac])
 485 AC_MSG_RESULT($lyx_use_packaging)
 486 lyx_install_macosx=false
 487 lyx_install_cygwin=false
 488 lyx_install_windows=false
 489 case $lyx_use_packaging in
 490    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 491            PACKAGE=LyX${version_suffix}
 492            default_prefix="/Applications/${PACKAGE}.app"
 493            bindir='${prefix}/Contents/MacOS'
 494            libdir='${prefix}/Contents/Resources'
 495            datarootdir='${prefix}/Contents/Resources'
 496            pkgdatadir='${datadir}'
 497            mandir='${datadir}/man'
 498            lyx_install_macosx=true ;;
 499   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 500            PACKAGE=LyX${version_suffix}
 501            default_prefix="C:/Program Files/${PACKAGE}"
 502            bindir='${prefix}/bin'
 503            libdir='${prefix}/Resources'
 504            datarootdir='${prefix}/Resources'
 505            pkgdatadir='${datadir}'
 506            mandir='${prefix}/Resources/man'
 507            lyx_install_windows=true ;;
 508     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 509            PACKAGE=lyx${version_suffix}
 510            program_suffix=$version_suffix
 511            pkgdatadir='${datadir}/${PACKAGE}'
 512            default_prefix=$ac_default_prefix
 513            case ${host} in
 514            *cygwin*) lyx_install_cygwin=true ;;
 515            esac ;;
 516     *) LYX_ERROR([Unknown packaging type $lyx_use_packaging]) ;;
 517 esac
 518 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 519 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 520 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 521 dnl Next two lines are only for autoconf <= 2.59
 522 datadir='${datarootdir}'
 523 AC_SUBST(datarootdir)
 524 AC_SUBST(pkgdatadir)
 525 AC_SUBST(program_suffix)
 526 ])
 527
 528
 529 ## ------------------------------------------------------------------------
 530 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 531 ## one or two arguments.
 532 ##
 533 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 534 ## ------------------------------------------------------------------------
 535 ##
 536 AC_DEFUN([AC_FUNC_MKDIR],
 537 [AC_CHECK_FUNCS([mkdir _mkdir])
 538 AC_CACHE_CHECK([whether mkdir takes one argument],
 539                [ac_cv_mkdir_takes_one_arg],
 540 [AC_TRY_COMPILE([
 541 #include <sys/stat.h>
 542 #if HAVE_UNISTD_H
 543 #  include <unistd.h>
 544 #endif
 545 ], [mkdir (".");],
 546 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 547 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 548   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 549             [Define if mkdir takes only one argument.])
 550 fi
 551 ])
 552
 553
 554 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 555 dnl (which may be a relative path, and need not refer to any existing
 556 dnl entity).
 557
 558 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 559 dnl native Win32 path name, (but with slashes, not backslashes).
 560
 561 dnl On any other system, it is simply the result which would be obtained
 562 dnl if PATHNAME represented an existing directory, and the pwd command was
 563 dnl executed in that directory.
 564 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 565 [ac_dir="$2"
 566  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 567     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 568  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 569  do
 570    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 571  done
 572  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 573  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 574  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 575    s?/*$[]??'`
 576 ])
 577
 578 dnl this is used by the macro blow to general a proper config.h.in entry
 579 m4_define([LYX_AH_CHECK_DECL],
 580 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 581   [Define if you have the prototype for function `$1'])])
 582
 583 dnl Check things are declared in headers to avoid errors or warnings.
 584 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 585 dnl Defines HAVE_DECL_{FUNCTION}
 586 AC_DEFUN([LYX_CHECK_DECL],
 587 [LYX_AH_CHECK_DECL($1)
 588 for ac_header in $2
 589 do
 590   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 591   AC_EGREP_HEADER($1, $ac_header,
 592       [AC_MSG_RESULT(yes)
 593        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 594        break],
 595       [AC_MSG_RESULT(no)])
 596 done])
 597
 598 dnl this is used by the macro below to generate a proper config.h.in entry
 599 m4_define([LYX_AH_CHECK_DEF],
 600 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 601   [Define to 1 if `$1' is defined in `$2'])])
 602
 603 dnl Check whether name is defined in header by using it in codesnippet.
 604 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 605 dnl Defines HAVE_DEF_{NAME}
 606 AC_DEFUN([LYX_CHECK_DEF],
 607 [LYX_AH_CHECK_DEF($1, $2)
 608  AC_MSG_CHECKING([whether $1 is defined by header $2])
 609  AC_TRY_COMPILE([#include <$2>], [$3],
 610      lyx_have_def_name=yes,
 611      lyx_have_def_name=no)
 612  AC_MSG_RESULT($lyx_have_def_name)
 613  if test "x$lyx_have_def_name" = xyes; then
 614    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 615  fi
 616 ])
 617
 618 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 619 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 620 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 621 AC_DEFUN([LYX_SET_VERSION_INFO],
 622 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 623  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 624  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 625  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 626  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 627  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 628  test "x$lyx_patch" = "x" && lyx_patch=0
 629  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 630  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 631  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 632  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 633  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 634  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 635  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 636  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 637 ])