config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version $VERSION"
  11 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  12   lyx_devel_version=yes
  13   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 AC_SUBST(lyx_devel_version)])
  25
  26
  27 dnl Define the option to set a LyX version on installed executables and directories
  28 dnl
  29 dnl
  30 AC_DEFUN([LYX_VERSION_SUFFIX],[
  31 AC_MSG_CHECKING([for install target ... ])
  32 AC_ARG_WITH(version-suffix,
  33   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  34   [if test "x$withval" = "xyes";
  35    then
  36      withval="-$VERSION"
  37      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  38    fi
  39    lyxname="lyx$withval"
  40    program_suffix=$withval],
  41   [lyxname=lyx])
  42 AC_MSG_RESULT([$lyxname])
  43 ])
  44
  45
  46 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  47 dnl flag lyx_error to yes.
  48 AC_DEFUN([LYX_ERROR],[
  49 lyx_error_txt="$lyx_error_txt
  50 ** $1
  51 "
  52 lyx_error=yes])
  53
  54
  55 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  56 dnl flag lyx_warning to yes.
  57 AC_DEFUN([LYX_WARNING],[
  58 lyx_warning_txt="$lyx_warning_txt
  59 == $1
  60 "
  61 lyx_warning=yes])
  62
  63
  64 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  65 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  66 AC_DEFUN([LYX_LIB_ERROR],[
  67 LYX_ERROR([Cannot find $1. Please check that the $2 library
  68    is correctly installed on your system.])])
  69
  70
  71 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  72 dnl   has occured previously.
  73 AC_DEFUN([LYX_CHECK_ERRORS],[
  74 if test x$lyx_error = xyes; then
  75 cat <<EOF
  76 **** The following problems have been detected by configure.
  77 **** Please check the messages below before running 'make'.
  78 **** (see the section 'Problems' in the INSTALL file)
  79 $lyx_error_txt
  80 $lyx_warning_txt
  81 EOF
  82 else
  83
  84 if test x$lyx_warning = xyes; then
  85 cat <<EOF
  86 === The following minor problems have been detected by configure.
  87 === Please check the messages below before running 'make'.
  88 === (see the section 'Problems' in the INSTALL file)
  89 $lyx_warning_txt
  90 EOF
  91 fi
  92 cat <<EOF
  93 Configuration of LyX was successful.
  94 Type 'make' to compile the program,
  95 and then 'make install' to install it.
  96 EOF
  97 fi])
  98
  99
 100 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 101 dnl
 102 define(LYX_SEARCH_PROG,[dnl
 103 for ac_prog in $2 ; do
 104 # Extract the first word of "$ac_prog", so it can be a program name with args.
 105   set dummy $ac_prog ; ac_word=$[2]
 106   if test -z "[$]$1"; then
 107     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 108     for ac_dir in $PATH; do
 109       test -z "$ac_dir" && ac_dir=.
 110       if test -f [$ac_dir/$ac_word]; then
 111         $1="$ac_prog"
 112         break
 113       fi
 114     done
 115     IFS="$ac_save_ifs"
 116   fi
 117
 118   if test -n "[$]$1"; then
 119     ac_result=yes
 120   else
 121     ac_result=no
 122   fi
 123   ifelse($3,,,[$3])
 124   test -n "[$]$1" && break
 125 done
 126 ])dnl
 127
 128
 129 AC_DEFUN([LYX_PROG_CXX_WORKS],
 130 [rm -f conftest.C
 131 cat >conftest.C <<EOF
 132 class foo {
 133    // we require the mutable keyword
 134    mutable int bar;
 135  };
 136  // we require namespace support
 137  namespace baz {
 138    int bar;
 139  }
 140  int main() {
 141    return(0);
 142  }
 143 EOF
 144 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 145 rm -f conftest.C conftest.o conftest.obj || true
 146 ])
 147
 148
 149 AC_DEFUN([LYX_PROG_CXX],
 150 [AC_MSG_CHECKING([for a good enough C++ compiler])
 151 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 152
 153 if test -z "$CXX" ; then
 154   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 155 fi
 156 AC_MSG_RESULT($CXX)
 157
 158 AC_PROG_CXX
 159
 160 ### We might want to get or shut warnings.
 161 AC_ARG_ENABLE(warnings,
 162   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 163   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 164         enable_warnings=yes;
 165     else
 166         enable_warnings=no;
 167     fi;])
 168 if test x$enable_warnings = xyes ; then
 169   lyx_flags="$lyx_flags warnings"
 170   AC_DEFINE(WITH_WARNINGS, 1,
 171   [Define this if you want to see the warning directives put here and
 172    there by the developpers to get attention])
 173 fi
 174
 175 ### We might want to disable debug
 176 AC_ARG_ENABLE(debug,
 177   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 178   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 179         enable_debug=yes;
 180     else
 181         enable_debug=no;
 182     fi;])
 183
 184 ### set up optimization
 185 AC_ARG_ENABLE(optimization,
 186   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 187         enable_optimization=yes;)
 188 case $enable_optimization in
 189   yes) lyx_opt=-O;;
 190    no) lyx_opt=;;
 191     *) lyx_opt=${enable_optimization};;
 192 esac
 193
 194 lyx_pch_comp=no
 195
 196 # set the debug flags correctly.
 197 if test x$GXX = xyes; then
 198   dnl Useful for global version info
 199   gxx_version=`${CXX} -dumpversion`
 200   CXX_VERSION="($gxx_version)"
 201
 202   if test "$ac_test_CXXFLAGS" = set; then
 203     CXXFLAGS="$ac_save_CXXFLAGS"
 204   else
 205     case $gxx_version in
 206       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 207       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 208       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 209       3.0*)    CXXFLAGS="$lyx_opt";;
 210       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 211       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 212       3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 213       3.4*|3.5*)
 214             CXXFLAGS="$lyx_opt -fno-exceptions"
 215             lyx_pch_comp=yes;;
 216       *)       CXXFLAGS="$lyx_opt";;
 217     esac
 218     if test x$enable_debug = xyes ; then
 219         case $gxx_version in
 220             3.4*|3.5*) CXXFLAGS="-g $CXXFLAGS"
 221                 AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 222                 AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 223                 ;;
 224             *)    CXXFLAGS="-g $CXXFLAGS";;
 225         esac
 226     fi
 227   fi
 228   if test x$enable_warnings = xyes ; then
 229     case $gxx_version in
 230         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 231         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 232         3.1*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 233         3.2*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 234         3.3*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 235         *)    CXXFLAGS="$CXXFLAGS -Wextra -Wall";;
 236     esac
 237   fi
 238 fi
 239 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 240 ])dnl
 241
 242
 243 dnl NOT USED CURRENTLY*************************************
 244 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 245 dnl   supports RTTI
 246 AC_DEFUN([LYX_CXX_RTTI],[
 247 ### Check whether the compiler supports runtime type information
 248 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 249  [AC_TRY_RUN([
 250 class rtti {
 251 public:
 252    virtual int tag() { return 0; }
 253 };
 254 class derived1 : public rtti {
 255 public:
 256     int tag() { return 1; }
 257 };
 258 class derived2 : public rtti {
 259 public:
 260     int tag() { return 2; }
 261 };
 262 int main() {
 263     derived1 * foo1 = new derived1();
 264     derived2 * foo2 = new derived2();
 265     rtti * bar = foo1;
 266     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 267     if (bar1 == 0)
 268         exit(1);
 269     bar = foo2;
 270     bar1 = dynamic_cast<derived1 *>(bar);
 271     if (bar1 != 0)
 272         exit(1);
 273     return 0;
 274 }
 275 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 276 ])
 277 if test x$lyx_cv_rtti = xyes ; then
 278   AC_DEFINE(HAVE_RTTI, 1,
 279    [Define to 1 if your compiler supports runtime type information])
 280 fi])
 281
 282
 283 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 284 dnl   understands the "explicit" directive.
 285 AC_DEFUN([LYX_CXX_EXPLICIT],[
 286 ### Check whether the compiler understands the keyword `explicit'
 287 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 288  [AC_TRY_COMPILE([
 289 class Expl {
 290 public:
 291         explicit Expl() {}
 292 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 293 ])
 294 if test $lyx_cv_explicit = no ; then
 295   AC_DEFINE(explicit,[ ],
 296    [Define to nothing if your compiler does not understand the
 297    'explicit' directive])
 298 fi])
 299
 300
 301 dnl NOT USED CURRENTLY*************************************
 302 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 303 dnl   has a working stl stack template
 304 AC_DEFUN([LYX_CXX_STL_STACK],[
 305 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 306  [AC_TRY_COMPILE([
 307 #include <stack>
 308 using std::stack;
 309 ],[
 310     stack<int> stakk;
 311     stakk.push(0);
 312 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 313 ])
 314 if test $lyx_cv_broken_stack = yes ; then
 315   AC_DEFINE(BROKEN_STL_STACK, 1,
 316    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 317    correctly])
 318 fi])
 319
 320
 321 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 322 dnl    count template, if not the old HP version is assumed.
 323 AC_DEFUN([LYX_STD_COUNT],[
 324 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 325  [AC_TRY_COMPILE([
 326 #include <algorithm>
 327 using std::count;
 328 int countChar(char * b, char * e, char const c)
 329 {
 330         return count(b, e, c);
 331 }
 332 ],[
 333     char a[] = "hello";
 334     int i = countChar(a, a + 5, 'l');
 335 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 336 ])
 337 if test $lyx_cv_std_count = yes ; then
 338     AC_DEFINE(HAVE_STD_COUNT, 1,
 339     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 340 fi])
 341
 342
 343 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 344 dnl   supports modern STL streams
 345 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 346 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 347  [AC_TRY_COMPILE([
 348 #include <iostream>
 349 ],[
 350  std::streambuf * test = std::cerr.rdbuf();
 351  test->pubsync();
 352 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 353 ])
 354 if test $lyx_cv_modern_streams = yes ; then
 355   AC_DEFINE(MODERN_STL_STREAMS, 1,
 356    [Define if you have modern standard-compliant STL streams])
 357 fi])
 358
 359
 360 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 361 dnl        be used.
 362 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 363         AC_ARG_WITH(included-boost,
 364             [  --with-included-boost  use the boost lib supplied with LyX],
 365             [lyx_cv_with_included_boost=$withval
 366                 AC_MSG_RESULT([$with_included_boost])],
 367             [lyx_cv_with_included_boost=yes])
 368         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 369 ])
 370
 371
 372 dnl NOT USED CURRENTLY*************************************
 373 dnl LYX_CXX_PARTIAL
 374 AC_DEFUN([LYX_CXX_PARTIAL], [
 375     AC_REQUIRE([AC_PROG_CXX])
 376     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 377         [lyx_cv_cxx_partial_specialization],
 378         [AC_TRY_COMPILE(
 379             [
 380             template<class T, class K>
 381             class k {
 382             public:
 383             };
 384             template<class T> class k<void,T> { };
 385             ],[
 386             k<float, float> b;
 387             k<void,void> a;
 388             ],[
 389             lyx_cv_cxx_partial_specialization=yes
 390             ],[
 391             lyx_cv_cxx_partial_specialization=no
 392             ])
 393         ])
 394     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 395         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 396         [Defined if your compiler supports partial specialization.])
 397     fi
 398 ])
 399
 400
 401 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 402 dnl   provides wrappers for C headers and use our alternate version otherwise.
 403 AC_DEFUN([LYX_CXX_CHEADERS],[
 404 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 405  [AC_TRY_CPP([
 406 #include <clocale>
 407 #include <cctype>
 408 #include <cerrno>
 409 #include <cmath>
 410 #include <csignal>
 411 #include <cstdio>
 412 #include <cstdlib>
 413 #include <cstring>
 414 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 415 if test $lyx_cv_cxx_cheaders = no ; then
 416   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 417 fi])
 418
 419
 420 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 421 dnl   are already in the global namespace
 422 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 423     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 424     lyx_cv_cxx_global_cstd,
 425     [AC_TRY_COMPILE([
 426     #include <cctype>
 427     using std::tolower;
 428     ],[
 429     return 0;
 430     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 431     if test x$lyx_cv_cxx_global_cstd = xyes; then
 432         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 433         [Define if your C++ compiler puts C library functions in the global namespace])
 434     fi
 435 ])
 436
 437
 438 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 439 dnl                       [default-yes-value])
 440 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 441 dnl  resulting directory name in 'dir-var-name'.
 442 AC_DEFUN([LYX_WITH_DIR],[
 443   AC_ARG_WITH($1,[  --with-$1        specify $2])
 444   AC_MSG_CHECKING([for $2])
 445   if test -z "$with_$3"; then
 446      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 447   else
 448     test "x$with_$3" = xyes && with_$3=$5
 449     lyx_cv_$3="$with_$3"
 450   fi
 451   AC_MSG_RESULT($lyx_cv_$3)])
 452
 453
 454 dnl Usage: LYX_LOOP_DIR(value,action)
 455 dnl Executes action for values of variable `dir' in `values'. `values' can
 456 dnl use ":" as a separator.
 457 AC_DEFUN([LYX_LOOP_DIR],[
 458 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 459 for dir in `eval "echo $1"`; do
 460   if test ! "$dir" = NONE; then
 461     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 462     $2
 463   fi
 464 done
 465 IFS=$ac_save_ifs
 466 ])
 467
 468
 469 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 470 dnl var-name.
 471 AC_DEFUN([LYX_ADD_LIB_DIR],[
 472 $1="${$1} -L$2"
 473 if test "`(uname) 2>/dev/null`" = SunOS &&
 474     uname -r | grep '^5' >/dev/null; then
 475   if test $ac_cv_prog_gxx = yes ; then
 476     $1="${$1} -Wl[,]-R$2"
 477   else
 478     $1="${$1} -R$2"
 479   fi
 480 fi])
 481
 482
 483 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 484 dnl var-name.
 485 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 486
 487 ### Check for a headers existence and location iff it exists
 488 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 489 ## It almost works.  I've tried a few variations but they give errors
 490 ## of one sort or other: bad substitution or file not found etc.  The
 491 ## actual header _is_ found though and the cache variable is set however
 492 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 493 ## reason.
 494 ## Additionally, autoheader can't figure out what to use as the name in
 495 ## the config.h.in file so we need to write our own entries there -- one for
 496 ## each header in the form PATH_HEADER_NAME_H
 497 ##
 498 AC_DEFUN([LYX_PATH_HEADER],
 499 [ AC_CHECK_HEADER($1,[
 500   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 501 ### the only remaining problem is getting the second parameter to this
 502 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 503 ### of $ac_safe being printed.
 504   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 505   [ cat > conftest.$ac_ext <<EOF
 506 #line __oline__ "configure"
 507 #include "confdefs.h"
 508
 509 #include <$1>
 510 EOF
 511 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 512   grep $1  2>/dev/null | \
 513   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 514 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 515 rm -f conftest*])
 516   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 517 ])
 518 ### end of LYX_PATH_HEADER
 519
 520 ### Check which frontends we want to use. The default is XForms only
 521 ###
 522 AC_DEFUN([LYX_USE_FRONTENDS],
 523 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 524 AC_ARG_WITH(frontend,
 525   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 526                             Possible values: xforms, qt, gtk(EXPERIMENTAL)],
 527   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 528 AC_MSG_RESULT($FRONTENDS)
 529 AC_SUBST(FRONTENDS)
 530 AC_SUBST(FRONTENDS_SUBDIRS)
 531 AC_SUBST(FRONTENDS_PROGS)
 532 ])
 533
 534
 535
 536 ## ------------------------------------------------------------------------
 537 ## Find a file (or one of more files in a list of dirs)
 538 ## ------------------------------------------------------------------------
 539 ##
 540 AC_DEFUN([AC_FIND_FILE],
 541 [
 542 $3=NO
 543 for i in $2;
 544 do
 545   for j in $1;
 546   do
 547     if test -r "$i/$j"; then
 548       $3=$i
 549       break 2
 550     fi
 551   done
 552 done
 553 ])
 554
 555 dnl just a wrapper to clean up configure.in
 556 AC_DEFUN([LYX_PROG_LIBTOOL],
 557 [
 558 AC_REQUIRE([AC_ENABLE_SHARED])
 559 AC_REQUIRE([AC_ENABLE_STATIC])
 560 dnl libtool is only for C, so I must force him
 561 dnl to find the correct flags for C++
 562 ac_save_cc=$CC
 563 ac_save_cflags="$CFLAGS"
 564 CC=$CXX
 565 CFLAGS="$CXXFLAGS"
 566 AM_PROG_LIBTOOL dnl for libraries
 567 CC=$ac_save_cc
 568 CFLAGS="$ac_save_cflags"
 569 ])