config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN([LYX_VERSION_SUFFIX],[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49
  50 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  51 dnl flag lyx_error to yes.
  52 AC_DEFUN([LYX_ERROR],[
  53 lyx_error_txt="$lyx_error_txt
  54 ** $1
  55 "
  56 lyx_error=yes])
  57
  58
  59 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  60 dnl flag lyx_warning to yes.
  61 AC_DEFUN([LYX_WARNING],[
  62 lyx_warning_txt="$lyx_warning_txt
  63 == $1
  64 "
  65 lyx_warning=yes])
  66
  67
  68 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  69 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  70 AC_DEFUN([LYX_LIB_ERROR],[
  71 LYX_ERROR([Cannot find $1. Please check that the $2 library
  72    is correctly installed on your system.])])
  73
  74
  75 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  76 dnl   has occured previously.
  77 AC_DEFUN([LYX_CHECK_ERRORS],[
  78 if test x$lyx_error = xyes; then
  79 cat <<EOF
  80 **** The following problems have been detected by configure.
  81 **** Please check the messages below before running 'make'.
  82 **** (see the section 'Problems' in the INSTALL file)
  83 $lyx_error_txt
  84 $lyx_warning_txt
  85 EOF
  86 else
  87
  88 if test x$lyx_warning = xyes; then
  89 cat <<EOF
  90 === The following minor problems have been detected by configure.
  91 === Please check the messages below before running 'make'.
  92 === (see the section 'Problems' in the INSTALL file)
  93 $lyx_warning_txt
  94 EOF
  95 fi
  96 cat <<EOF
  97 Configuration of LyX was successful.
  98 Type 'make' to compile the program,
  99 and then 'make install' to install it.
 100 EOF
 101 fi])
 102
 103
 104 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 105 dnl
 106 define(LYX_SEARCH_PROG,[dnl
 107 for ac_prog in $2 ; do
 108 # Extract the first word of "$ac_prog", so it can be a program name with args.
 109   set dummy $ac_prog ; ac_word=$[2]
 110   if test -z "[$]$1"; then
 111     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 112     for ac_dir in $PATH; do
 113       test -z "$ac_dir" && ac_dir=.
 114       if test -f [$ac_dir/$ac_word]; then
 115         $1="$ac_prog"
 116         break
 117       fi
 118     done
 119     IFS="$ac_save_ifs"
 120   fi
 121
 122   if test -n "[$]$1"; then
 123     ac_result=yes
 124   else
 125     ac_result=no
 126   fi
 127   ifelse($3,,,[$3])
 128   test -n "[$]$1" && break
 129 done
 130 ])dnl
 131
 132
 133 AC_DEFUN([LYX_PROG_CXX_WORKS],
 134 [rm -f conftest.C
 135 cat >conftest.C <<EOF
 136 class foo {
 137    // we require the mutable keyword
 138    mutable int bar;
 139  };
 140  // we require namespace support
 141  namespace baz {
 142    int bar;
 143  }
 144  int main() {
 145    return(0);
 146  }
 147 EOF
 148 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 149 rm -f conftest.C conftest.o conftest.obj || true
 150 ])
 151
 152
 153 AC_DEFUN([LYX_PROG_CXX],
 154 [AC_MSG_CHECKING([for a good enough C++ compiler])
 155 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 156
 157 if test -z "$CXX" ; then
 158   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 159 fi
 160 AC_MSG_RESULT($CXX)
 161
 162 AC_PROG_CXX
 163
 164 ### We might want to get or shut warnings.
 165 AC_ARG_ENABLE(warnings,
 166   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 167   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 168         enable_warnings=yes;
 169     else
 170         enable_warnings=no;
 171     fi;])
 172 if test x$enable_warnings = xyes ; then
 173   lyx_flags="$lyx_flags warnings"
 174   AC_DEFINE(WITH_WARNINGS, 1,
 175   [Define this if you want to see the warning directives put here and
 176    there by the developpers to get attention])
 177 fi
 178
 179 ### We might want to disable debug
 180 AC_ARG_ENABLE(debug,
 181   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 182   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 183         enable_debug=yes;
 184     else
 185         enable_debug=no;
 186     fi;])
 187
 188 ### set up optimization
 189 AC_ARG_ENABLE(optimization,
 190   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 191         enable_optimization=yes;)
 192 case $enable_optimization in
 193   yes) lyx_opt=-O;;
 194    no) lyx_opt=;;
 195     *) lyx_opt=${enable_optimization};;
 196 esac
 197
 198 lyx_pch_comp=no
 199
 200 # set the debug flags correctly.
 201 if test x$GXX = xyes; then
 202   dnl Useful for global version info
 203   gxx_version=`${CXX} -dumpversion`
 204   CXX_VERSION="($gxx_version)"
 205
 206   if test "$ac_test_CXXFLAGS" = set; then
 207     CXXFLAGS="$ac_save_CXXFLAGS"
 208   else
 209     case $gxx_version in
 210       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 211       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 212       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 213       3.0*)    CXXFLAGS="$lyx_opt";;
 214       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 215       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 216       3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 217       3.4*|3.5*)
 218             CXXFLAGS="$lyx_opt -fno-exceptions"
 219             lyx_pch_comp=yes;;
 220       *)       CXXFLAGS="$lyx_opt";;
 221     esac
 222     if test x$enable_debug = xyes ; then
 223         case $gxx_version in
 224             3.4*|3.5*) CXXFLAGS="-g $CXXFLAGS"
 225                 AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 226                 AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 227                 ;;
 228             *)    CXXFLAGS="-g $CXXFLAGS";;
 229         esac
 230     fi
 231   fi
 232   if test x$enable_warnings = xyes ; then
 233     case $gxx_version in
 234         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 235         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 236         3.1*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 237         3.2*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 238         3.3*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 239         *)    CXXFLAGS="$CXXFLAGS -Wextra -Wall";;
 240     esac
 241   fi
 242 fi
 243 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 244 ])dnl
 245
 246
 247 dnl NOT USED CURRENTLY*************************************
 248 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 249 dnl   supports RTTI
 250 AC_DEFUN([LYX_CXX_RTTI],[
 251 ### Check whether the compiler supports runtime type information
 252 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 253  [AC_TRY_RUN([
 254 class rtti {
 255 public:
 256    virtual int tag() { return 0; }
 257 };
 258 class derived1 : public rtti {
 259 public:
 260     int tag() { return 1; }
 261 };
 262 class derived2 : public rtti {
 263 public:
 264     int tag() { return 2; }
 265 };
 266 int main() {
 267     derived1 * foo1 = new derived1();
 268     derived2 * foo2 = new derived2();
 269     rtti * bar = foo1;
 270     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 271     if (bar1 == 0)
 272         exit(1);
 273     bar = foo2;
 274     bar1 = dynamic_cast<derived1 *>(bar);
 275     if (bar1 != 0)
 276         exit(1);
 277     return 0;
 278 }
 279 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 280 ])
 281 if test x$lyx_cv_rtti = xyes ; then
 282   AC_DEFINE(HAVE_RTTI, 1,
 283    [Define to 1 if your compiler supports runtime type information])
 284 fi])
 285
 286
 287 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 288 dnl   understands the "explicit" directive.
 289 AC_DEFUN([LYX_CXX_EXPLICIT],[
 290 ### Check whether the compiler understands the keyword `explicit'
 291 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 292  [AC_TRY_COMPILE([
 293 class Expl {
 294 public:
 295         explicit Expl() {}
 296 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 297 ])
 298 if test $lyx_cv_explicit = no ; then
 299   AC_DEFINE(explicit,[ ],
 300    [Define to nothing if your compiler does not understand the
 301    'explicit' directive])
 302 fi])
 303
 304
 305 dnl NOT USED CURRENTLY*************************************
 306 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 307 dnl   has a working stl stack template
 308 AC_DEFUN([LYX_CXX_STL_STACK],[
 309 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 310  [AC_TRY_COMPILE([
 311 #include <stack>
 312 using std::stack;
 313 ],[
 314     stack<int> stakk;
 315     stakk.push(0);
 316 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 317 ])
 318 if test $lyx_cv_broken_stack = yes ; then
 319   AC_DEFINE(BROKEN_STL_STACK, 1,
 320    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 321    correctly])
 322 fi])
 323
 324
 325 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 326 dnl    count template, if not the old HP version is assumed.
 327 AC_DEFUN([LYX_STD_COUNT],[
 328 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 329  [AC_TRY_COMPILE([
 330 #include <algorithm>
 331 using std::count;
 332 int countChar(char * b, char * e, char const c)
 333 {
 334         return count(b, e, c);
 335 }
 336 ],[
 337     char a[] = "hello";
 338     int i = countChar(a, a + 5, 'l');
 339 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 340 ])
 341 if test $lyx_cv_std_count = yes ; then
 342     AC_DEFINE(HAVE_STD_COUNT, 1,
 343     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 344 fi])
 345
 346
 347 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 348 dnl   supports modern STL streams
 349 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 350 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 351  [AC_TRY_COMPILE([
 352 #include <iostream>
 353 ],[
 354  std::streambuf * test = std::cerr.rdbuf();
 355  test->pubsync();
 356 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 357 ])
 358 if test $lyx_cv_modern_streams = yes ; then
 359   AC_DEFINE(MODERN_STL_STREAMS, 1,
 360    [Define if you have modern standard-compliant STL streams])
 361 fi])
 362
 363
 364 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 365 dnl        be used.
 366 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 367         AC_ARG_WITH(included-boost,
 368             [  --with-included-boost  use the boost lib supplied with LyX],
 369             [lyx_cv_with_included_boost=$withval
 370                 AC_MSG_RESULT([$with_included_boost])],
 371             [lyx_cv_with_included_boost=yes])
 372         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 373 ])
 374
 375
 376 dnl NOT USED CURRENTLY*************************************
 377 dnl LYX_CXX_PARTIAL
 378 AC_DEFUN([LYX_CXX_PARTIAL], [
 379     AC_REQUIRE([AC_PROG_CXX])
 380     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 381         [lyx_cv_cxx_partial_specialization],
 382         [AC_TRY_COMPILE(
 383             [
 384             template<class T, class K>
 385             class k {
 386             public:
 387             };
 388             template<class T> class k<void,T> { };
 389             ],[
 390             k<float, float> b;
 391             k<void,void> a;
 392             ],[
 393             lyx_cv_cxx_partial_specialization=yes
 394             ],[
 395             lyx_cv_cxx_partial_specialization=no
 396             ])
 397         ])
 398     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 399         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 400         [Defined if your compiler supports partial specialization.])
 401     fi
 402 ])
 403
 404
 405 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 406 dnl   provides wrappers for C headers and use our alternate version otherwise.
 407 AC_DEFUN([LYX_CXX_CHEADERS],[
 408 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 409  [AC_TRY_CPP([
 410 #include <clocale>
 411 #include <cctype>
 412 #include <cerrno>
 413 #include <cmath>
 414 #include <csignal>
 415 #include <cstdio>
 416 #include <cstdlib>
 417 #include <cstring>
 418 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 419 if test $lyx_cv_cxx_cheaders = no ; then
 420   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 421 fi])
 422
 423
 424 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 425 dnl   are already in the global namespace
 426 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 427     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 428     lyx_cv_cxx_global_cstd,
 429     [AC_TRY_COMPILE([
 430     #include <cctype>
 431     using std::tolower;
 432     ],[
 433     return 0;
 434     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 435     if test x$lyx_cv_cxx_global_cstd = xyes; then
 436         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 437         [Define if your C++ compiler puts C library functions in the global namespace])
 438     fi
 439 ])
 440
 441
 442 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 443 dnl                       [default-yes-value])
 444 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 445 dnl  resulting directory name in 'dir-var-name'.
 446 AC_DEFUN([LYX_WITH_DIR],[
 447   AC_ARG_WITH($1,[  --with-$1        specify $2])
 448   AC_MSG_CHECKING([for $2])
 449   if test -z "$with_$3"; then
 450      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 451   else
 452     test "x$with_$3" = xyes && with_$3=$5
 453     lyx_cv_$3="$with_$3"
 454   fi
 455   AC_MSG_RESULT($lyx_cv_$3)])
 456
 457
 458 dnl Usage: LYX_LOOP_DIR(value,action)
 459 dnl Executes action for values of variable `dir' in `values'. `values' can
 460 dnl use ":" as a separator.
 461 AC_DEFUN([LYX_LOOP_DIR],[
 462 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 463 for dir in `eval "echo $1"`; do
 464   if test ! "$dir" = NONE; then
 465     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 466     $2
 467   fi
 468 done
 469 IFS=$ac_save_ifs
 470 ])
 471
 472
 473 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 474 dnl var-name.
 475 AC_DEFUN([LYX_ADD_LIB_DIR],[
 476 $1="${$1} -L$2"
 477 if test "`(uname) 2>/dev/null`" = SunOS &&
 478     uname -r | grep '^5' >/dev/null; then
 479   if test $ac_cv_prog_gxx = yes ; then
 480     $1="${$1} -Wl[,]-R$2"
 481   else
 482     $1="${$1} -R$2"
 483   fi
 484 fi])
 485
 486
 487 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 488 dnl var-name.
 489 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 490
 491 ### Check for a headers existence and location iff it exists
 492 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 493 ## It almost works.  I've tried a few variations but they give errors
 494 ## of one sort or other: bad substitution or file not found etc.  The
 495 ## actual header _is_ found though and the cache variable is set however
 496 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 497 ## reason.
 498 ## Additionally, autoheader can't figure out what to use as the name in
 499 ## the config.h.in file so we need to write our own entries there -- one for
 500 ## each header in the form PATH_HEADER_NAME_H
 501 ##
 502 AC_DEFUN([LYX_PATH_HEADER],
 503 [ AC_CHECK_HEADER($1,[
 504   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 505 ### the only remaining problem is getting the second parameter to this
 506 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 507 ### of $ac_safe being printed.
 508   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 509   [ cat > conftest.$ac_ext <<EOF
 510 #line __oline__ "configure"
 511 #include "confdefs.h"
 512
 513 #include <$1>
 514 EOF
 515 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 516   grep $1  2>/dev/null | \
 517   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 518 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 519 rm -f conftest*])
 520   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 521 ])
 522 ### end of LYX_PATH_HEADER
 523
 524 ### Check which frontends we want to use. The default is XForms only
 525 ###
 526 AC_DEFUN([LYX_USE_FRONTENDS],
 527 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 528 AC_ARG_WITH(frontend,
 529   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 530                             Possible values: xforms, qt],
 531   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 532 AC_MSG_RESULT($FRONTENDS)
 533 AC_SUBST(FRONTENDS)
 534 AC_SUBST(FRONTENDS_SUBDIRS)
 535 AC_SUBST(FRONTENDS_PROGS)
 536 ])
 537
 538
 539
 540 ## ------------------------------------------------------------------------
 541 ## Find a file (or one of more files in a list of dirs)
 542 ## ------------------------------------------------------------------------
 543 ##
 544 AC_DEFUN([AC_FIND_FILE],
 545 [
 546 $3=NO
 547 for i in $2;
 548 do
 549   for j in $1;
 550   do
 551     if test -r "$i/$j"; then
 552       $3=$i
 553       break 2
 554     fi
 555   done
 556 done
 557 ])
 558
 559 dnl just a wrapper to clean up configure.in
 560 AC_DEFUN([LYX_PROG_LIBTOOL],
 561 [
 562 AC_REQUIRE([AC_ENABLE_SHARED])
 563 AC_REQUIRE([AC_ENABLE_STATIC])
 564 dnl libtool is only for C, so I must force him
 565 dnl to find the correct flags for C++
 566 ac_save_cc=$CC
 567 ac_save_cflags="$CFLAGS"
 568 CC=$CXX
 569 CFLAGS="$CXXFLAGS"
 570 AM_PROG_LIBTOOL dnl for libraries
 571 CC=$ac_save_cc
 572 CFLAGS="$ac_save_cflags"
 573 ])