config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set lyx_cv_prog_clang to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 150 AC_DEFUN([LYX_LIB_STDCXX],
 151 [AC_CACHE_CHECK([whether STL is libstdc++],
 152                [lyx_cv_lib_stdcxx],
 153 [AC_TRY_COMPILE([#include<vector>], [
 154 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 155             this is not libstdc++
 156 #endif
 157 ],
 158 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 159 ])
 160
 161
 162 AC_DEFUN([LYX_PROG_CXX],
 163 [AC_REQUIRE([AC_PROG_CXX])
 164 AC_REQUIRE([AC_PROG_CXXCPP])
 165
 166 AC_LANG_PUSH(C++)
 167 LYX_PROG_CLANG
 168 LYX_LIB_STDCXX
 169 AC_LANG_POP(C++)
 170
 171 if test $lyx_cv_lib_stdcxx = "yes" ; then
 172   AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 173 else
 174   if test $lyx_cv_prog_clang = "yes" ; then
 175     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 176   fi
 177 fi
 178
 179 ### We might want to get or shut warnings.
 180 AC_ARG_ENABLE(warnings,
 181   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 182   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 183         enable_warnings=yes;
 184     else
 185         enable_warnings=no;
 186     fi;])
 187 if test x$enable_warnings = xyes ; then
 188   lyx_flags="$lyx_flags warnings"
 189 fi
 190
 191 ### We might want to disable debug
 192 AC_ARG_ENABLE(debug,
 193   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 194   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 195 )
 196
 197 AC_ARG_ENABLE(stdlib-debug,
 198   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 199   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 200           [enable_stdlib_debug=no])]
 201 )
 202
 203 AC_ARG_ENABLE(concept-checks,
 204   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 205   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 206           [enable_concept_checks=no])]
 207   if test x$USE_QT5 = xyes ; then
 208       enable_concept_checks=no
 209   fi
 210 )
 211
 212 ### set up optimization
 213 AC_ARG_ENABLE(optimization,
 214     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 215     enable_optimization=yes;)
 216 case $enable_optimization in
 217     yes)
 218         if test $lyx_devel_version = yes ; then
 219             lyx_optim=-O
 220         else
 221             lyx_optim=-O2
 222         fi;;
 223     no) lyx_optim=;;
 224     *) lyx_optim=${enable_optimization};;
 225 esac
 226
 227 AC_ARG_ENABLE(pch,
 228   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 229         enable_pch=no;)
 230 lyx_pch_comp=no
 231
 232 AC_ARG_ENABLE(cxx11,
 233   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode]),,
 234   enable_cxx11=no;)
 235
 236 AC_ARG_ENABLE(assertions,
 237   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 238   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 239           [enable_assertions=no])]
 240 )
 241 if test "x$enable_assertions" = xyes ; then
 242    lyx_flags="$lyx_flags assertions"
 243    AC_DEFINE(ENABLE_ASSERTIONS,1,
 244     [Define if you want assertions to be enabled in the code])
 245 fi
 246
 247 # set the compiler options correctly.
 248 lyx_std_regex=no
 249 if test x$GXX = xyes; then
 250   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 251   if test x$CLANG = xno; then
 252     dnl Useful for global version info
 253     gxx_version=`${CXX} -dumpversion`
 254     CXX_VERSION="($gxx_version)"
 255   else
 256     gxx_version=clang
 257   fi
 258
 259   AM_CXXFLAGS="$lyx_optim"
 260   if test x$enable_debug = xyes ; then
 261       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 262   fi
 263   if test $build_type = gprof ; then
 264     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 265     AM_LDFLAGS="$AM_LDFLAGS -pg"
 266   fi
 267   if test $build_type = profiling ; then
 268     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 269   fi
 270
 271   if test x$USE_QT5 = xyes ; then
 272       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 273   fi
 274   dnl Warnings are for preprocessor too
 275   if test x$enable_warnings = xyes ; then
 276       case $gxx_version in
 277           3.1*|3.2*|3.3*)
 278               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -W"
 279               ;;
 280           3.4*|4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*|clang)
 281               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 282               ;;
 283           *)
 284               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra -Wfloat-conversion"
 285               ;;
 286       esac
 287   fi
 288   case $gxx_version in
 289       3.1*)    AM_CXXFLAGS="$AM_CXXFLAGS -finline-limit=500";;
 290       3.2*|3.3*) ;;
 291       *)  test $enable_pch = yes && lyx_pch_comp=yes ;;
 292   esac
 293   if test x$enable_stdlib_debug = xyes ; then
 294     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 295     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 296     case $gxx_version in
 297       3.1*|3.2*|3.3*) ;;
 298       *)
 299         lyx_flags="$lyx_flags stdlib-debug"
 300         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 301         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 302         ;;
 303     esac
 304   fi
 305   if test x$enable_concept_checks = xyes ; then
 306     case $gxx_version in
 307       3.3*)
 308         lyx_flags="$lyx_flags concept-checks"
 309         dnl FIXME check whether this makes sense with clang/libc++
 310         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 311         ;;
 312       3.4*|4.*)
 313         lyx_flags="$lyx_flags concept-checks"
 314         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 315         ;;
 316     esac
 317   fi
 318   if test x$enable_cxx11 = xyes ; then
 319     case $gxx_version in
 320       3.*|4.0*|4.1*|4.2*) AC_ERROR([There is no C++11 support in gcc 3.x]);;
 321       4.3*|4.4*|4.5*|4.6*)
 322         lyx_flags="$lyx_flags c++11-mode"
 323         AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++0x";;
 324       clang)
 325         dnl presumably all clang version support c++11.
 326         lyx_flags="$lyx_flags c++11-mode"
 327         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 328         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11 -Wno-deprecated-register";;
 329       *)
 330         lyx_flags="$lyx_flags c++11-mode"
 331         AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++11"
 332         ;;
 333     esac
 334     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 335       dnl <regex> in gcc is unusable in versions less than 4.9.0
 336       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 337       case $gxx_version in
 338         3.*|4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 339         *) lyx_flags="$lyx_flags stdregex"
 340            lyx_std_regex=yes
 341            ;;
 342       esac
 343     else
 344       lyx_flags="$lyx_flags stdregex"
 345       lyx_std_regex=yes
 346     fi
 347
 348     if test $lyx_std_regex = yes ; then
 349       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 350     fi
 351   fi
 352 fi
 353 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 354 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 355 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 356 ])dnl
 357
 358 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 359 dnl        be used.
 360 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 361         AC_MSG_CHECKING([whether to use included boost library])
 362         AC_ARG_WITH(included-boost,
 363             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 364             [lyx_cv_with_included_boost=$withval],
 365             [lyx_cv_with_included_boost=yes])
 366         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 367         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 368         if test x$lyx_cv_with_included_boost = xyes ; then
 369             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 370             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 371         else
 372             AC_LANG_PUSH(C++)
 373             save_LIBS=$LIBS
 374
 375             AC_MSG_CHECKING([for multithreaded boost libraries])
 376             LIBS="$save_LIBS -lboost_signals-mt -lm $LIBTHREAD"
 377             AC_LINK_IFELSE(
 378                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 379                         [boost::signal<void ()> s;])],
 380                 [AC_MSG_RESULT([yes])
 381                  BOOST_MT="-mt"],
 382                 [AC_MSG_RESULT([no])
 383                  AC_MSG_CHECKING([for plain boost libraries])
 384                  LIBS="$save_LIBS -lboost_signals -lm"
 385                  AC_LINK_IFELSE(
 386                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 387                              [boost::signal<void ()> s;])],
 388                      [AC_MSG_RESULT([yes])
 389                       BOOST_MT=""],
 390                      [AC_MSG_RESULT([no])
 391                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 392                  ])
 393             ])
 394             LIBS=$save_LIBS
 395             AC_LANG_POP(C++)
 396             BOOST_INCLUDES=
 397             if test $lyx_std_regex = yes ; then
 398               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 399             else
 400               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 401             fi
 402         fi
 403         AC_SUBST(BOOST_INCLUDES)
 404         AC_SUBST(BOOST_LIBS)
 405 ])
 406
 407
 408 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 409 dnl        necessary APIs are available to print callstacks.
 410 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 411 [AC_CACHE_CHECK([whether printing callstack is possible],
 412                [lyx_cv_callstack_printing],
 413 [AC_TRY_COMPILE([
 414 #include <execinfo.h>
 415 #include <cxxabi.h>
 416 ], [
 417         void* array[200];
 418         size_t size = backtrace(array, 200);
 419         backtrace_symbols(array, size);
 420         int status = 0;
 421         abi::__cxa_demangle("abcd", 0, 0, &status);
 422 ],
 423 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 424 if test x"$lyx_cv_callstack_printing" = xyes; then
 425   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 426             [Define if callstack can be printed])
 427 fi
 428 ])
 429
 430
 431 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 432 dnl        be used.
 433 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 434         AC_MSG_CHECKING([whether to use included MyThes library])
 435         AC_ARG_WITH(included-mythes,
 436             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 437             [lyx_cv_with_included_mythes=$withval],
 438             [lyx_cv_with_included_mythes=yes])
 439         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 440         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 441         if test x$lyx_cv_with_included_mythes != xyes ; then
 442                 AC_LANG_PUSH(C++)
 443                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 444                 if test x$ac_cv_header_mythes_h != xyes; then
 445                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 446                 fi
 447                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 448                 if test x$lyx_mythes != xyes; then
 449                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 450                 fi
 451                 AC_LANG_POP(C++)
 452                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 453                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 454                 fi
 455                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 456                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 457                 AC_SUBST(MYTHES_LIBS)
 458         fi
 459 ])
 460
 461
 462 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 463 dnl                       [default-yes-value])
 464 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 465 dnl  resulting directory name in 'dir-var-name'.
 466 AC_DEFUN([LYX_WITH_DIR],[
 467   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 468   AC_MSG_CHECKING([for $2])
 469   if test -z "$with_$3"; then
 470      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 471   else
 472     test "x$with_$3" = xyes && with_$3=$5
 473     lyx_cv_$3="$with_$3"
 474   fi
 475   AC_MSG_RESULT($lyx_cv_$3)])
 476
 477
 478 dnl Usage: LYX_LOOP_DIR(value,action)
 479 dnl Executes action for values of variable `dir' in `values'. `values' can
 480 dnl use ":" as a separator.
 481 AC_DEFUN([LYX_LOOP_DIR],[
 482 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 483 for dir in `eval "echo $1"`; do
 484   if test ! "$dir" = NONE; then
 485     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 486     $2
 487   fi
 488 done
 489 IFS=$ac_save_ifs
 490 ])
 491
 492
 493 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 494 dnl var-name.
 495 AC_DEFUN([LYX_ADD_LIB_DIR],[
 496 $1="${$1} -L$2"
 497 if test "`(uname) 2>/dev/null`" = SunOS &&
 498     uname -r | grep '^5' >/dev/null; then
 499   if test $ac_cv_prog_gxx = yes ; then
 500     $1="${$1} -Wl[,]-R$2"
 501   else
 502     $1="${$1} -R$2"
 503   fi
 504 fi])
 505
 506
 507 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 508 dnl var-name.
 509 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 510
 511 ### Check for a headers existence and location iff it exists
 512 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 513 ## It almost works.  I've tried a few variations but they give errors
 514 ## of one sort or other: bad substitution or file not found etc.  The
 515 ## actual header _is_ found though and the cache variable is set however
 516 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 517 ## reason.
 518 ## Additionally, autoheader can't figure out what to use as the name in
 519 ## the config.h.in file so we need to write our own entries there -- one for
 520 ## each header in the form PATH_HEADER_NAME_H
 521 ##
 522 AC_DEFUN([LYX_PATH_HEADER],
 523 [ AC_CHECK_HEADER($1,[
 524   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 525 ### the only remaining problem is getting the second parameter to this
 526 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 527 ### of $ac_safe being printed.
 528   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 529   [ cat > conftest.$ac_ext <<EOF
 530 #line __oline__ "configure"
 531 #include "confdefs.h"
 532
 533 #include <$1>
 534 EOF
 535 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 536   grep $1  2>/dev/null | \
 537   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 538 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 539 rm -f conftest*])
 540   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 541 ])
 542 ### end of LYX_PATH_HEADER
 543
 544 ## Check what kind of packaging should be used at install time.
 545 ## The default is autodetected.
 546 AC_DEFUN([LYX_USE_PACKAGING],
 547 [AC_MSG_CHECKING([what packaging should be used])
 548 AC_ARG_WITH(packaging,
 549   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 550                             Possible values: posix, windows, macosx])],
 551   [lyx_use_packaging="$withval"], [
 552   case $host in
 553     *-apple-darwin*) lyx_use_packaging=macosx ;;
 554      *-pc-mingw32*) lyx_use_packaging=windows;;
 555                   *) lyx_use_packaging=posix;;
 556   esac])
 557 AC_MSG_RESULT($lyx_use_packaging)
 558 lyx_install_posix=false
 559 lyx_install_macosx=false
 560 lyx_install_cygwin=false
 561 lyx_install_windows=false
 562 case $lyx_use_packaging in
 563    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 564            PACKAGE=LyX${version_suffix}
 565            default_prefix="/Applications/${PACKAGE}.app"
 566            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 567            bindir='${prefix}/Contents/MacOS'
 568            libdir='${prefix}/Contents/Resources'
 569            datarootdir='${prefix}/Contents/Resources'
 570            pkgdatadir='${datadir}'
 571            mandir='${datadir}/man'
 572            lyx_install_macosx=true ;;
 573   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 574            PACKAGE=LyX${version_suffix}
 575            default_prefix="C:/Program Files/${PACKAGE}"
 576            bindir='${prefix}/bin'
 577            libdir='${prefix}/Resources'
 578            datarootdir='${prefix}/Resources'
 579            pkgdatadir='${datadir}'
 580            mandir='${prefix}/Resources/man'
 581            lyx_install_windows=true ;;
 582     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 583            PACKAGE=lyx${version_suffix}
 584            program_suffix=$version_suffix
 585            pkgdatadir='${datadir}/${PACKAGE}'
 586            default_prefix=$ac_default_prefix
 587            case ${host} in
 588            *cygwin*) lyx_install_cygwin=true ;;
 589                 *apple-darwin*) lyx_install_macosx=true ;;
 590            esac
 591            lyx_install_posix=true ;;
 592     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 593 esac
 594 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 595 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 596 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 597 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 598 AC_SUBST(pkgdatadir)
 599 AC_SUBST(program_suffix)
 600 ])
 601
 602
 603 ## ------------------------------------------------------------------------
 604 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 605 ## one or two arguments.
 606 ##
 607 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 608 ## ------------------------------------------------------------------------
 609 ##
 610 AC_DEFUN([AC_FUNC_MKDIR],
 611 [AC_CHECK_FUNCS([mkdir _mkdir])
 612 AC_CACHE_CHECK([whether mkdir takes one argument],
 613                [ac_cv_mkdir_takes_one_arg],
 614 [AC_TRY_COMPILE([
 615 #include <sys/stat.h>
 616 #if HAVE_UNISTD_H
 617 #  include <unistd.h>
 618 #endif
 619 ], [mkdir (".");],
 620 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 621 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 622   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 623             [Define if mkdir takes only one argument.])
 624 fi
 625 ])
 626
 627
 628 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 629 dnl (which may be a relative path, and need not refer to any existing
 630 dnl entity).
 631
 632 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 633 dnl native Win32 path name, (but with slashes, not backslashes).
 634
 635 dnl On any other system, it is simply the result which would be obtained
 636 dnl if PATHNAME represented an existing directory, and the pwd command was
 637 dnl executed in that directory.
 638 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 639 [ac_dir="$2"
 640  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 641     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 642  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 643  do
 644    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 645  done
 646  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 647  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 648  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 649    s?/*$[]??'`
 650 ])
 651
 652 dnl this is used by the macro blow to general a proper config.h.in entry
 653 m4_define([LYX_AH_CHECK_DECL],
 654 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 655   [Define if you have the prototype for function `$1'])])
 656
 657 dnl Check things are declared in headers to avoid errors or warnings.
 658 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 659 dnl Defines HAVE_DECL_{FUNCTION}
 660 AC_DEFUN([LYX_CHECK_DECL],
 661 [LYX_AH_CHECK_DECL($1)
 662 for ac_header in $2
 663 do
 664   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 665   AC_EGREP_HEADER($1, $ac_header,
 666       [AC_MSG_RESULT(yes)
 667        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 668        break],
 669       [AC_MSG_RESULT(no)])
 670 done])
 671
 672 dnl this is used by the macro below to generate a proper config.h.in entry
 673 m4_define([LYX_AH_CHECK_DEF],
 674 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 675   [Define to 1 if `$1' is defined in `$2'])])
 676
 677 dnl Check whether name is defined in header by using it in codesnippet.
 678 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 679 dnl Defines HAVE_DEF_{NAME}
 680 AC_DEFUN([LYX_CHECK_DEF],
 681 [LYX_AH_CHECK_DEF($1, $2)
 682  AC_MSG_CHECKING([whether $1 is defined by header $2])
 683  AC_TRY_COMPILE([#include <$2>], [$3],
 684      lyx_have_def_name=yes,
 685      lyx_have_def_name=no)
 686  AC_MSG_RESULT($lyx_have_def_name)
 687  if test "x$lyx_have_def_name" = xyes; then
 688    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 689  fi
 690 ])
 691
 692 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 693 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 694 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 695 AC_DEFUN([LYX_SET_VERSION_INFO],
 696 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 697  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 698  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 699  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 700  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 701  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 702  test "x$lyx_patch" = "x" && lyx_patch=0
 703  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 704  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 705  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 706  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 707  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 708  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 709  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 710  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 711 ])
 712
 713 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 714 # ---------------------------------------------------------------------------
 715 # Copied from autoconf 2.68, added a check that python version is < 3.0
 716 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 717 # Run ACTION-IF-FALSE otherwise.
 718 # This test uses sys.hexversion instead of the string equivalent (first
 719 # word of sys.version), in order to cope with versions such as 2.2c1.
 720 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 721 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 722  [prog="import sys
 723 # split strings by '.' and convert to numeric.  Append some zeros
 724 # because we need at least 4 digits for the hex conversion.
 725 # map returns an iterator in Python 3.0 and a list in 2.x
 726 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 727 minverhex = 0
 728 maxverhex = 50331648 # = 3.0.0.0
 729 # xrange is not present in Python 3.0 and range returns an iterator
 730 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 731 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 732   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])