config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6 dnl Compute the default build type from AC_PACKAGE_VERSION at autoconf time.
   7 m4_define([LYX_BUILD_TYPE], [m4_bmatch(AC_PACKAGE_VERSION,
   8     [dev], [development],
   9     [pre\|alpha\|beta\|rc], [prerelease],
  10     [release])])
  11
  12
  13 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
  14 dnl sets variable "build_type"
  15 AC_DEFUN([LYX_CHECK_VERSION],[
  16 echo "configuring LyX version" AC_PACKAGE_VERSION
  17
  18 AC_MSG_CHECKING([for build type])
  19 lyx_devel_version=no
  20 lyx_prerelease=no
  21 AC_ARG_ENABLE(build-type,
  22   AS_HELP_STRING([--enable-build-type=STR],[set build type to rel(ease), pre(release), dev(elopment), prof(iling), or gprof (default: LYX_BUILD_TYPE)]),
  23   [case $enableval in
  24     dev*) build_type=development;;
  25     pre*) build_type=prerelease;;
  26     prof*)  build_type=profiling;;
  27     gprof*) build_type=gprof;;
  28     rel*) build_type=release;;
  29     *) AC_MSG_ERROR([bad build type specification '$enableval'. Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  30    esac],
  31   [build_type=LYX_BUILD_TYPE])
  32 AC_MSG_RESULT([$build_type])
  33 lyx_flags="$lyx_flags build=$build_type"
  34 case $build_type in
  35     development) lyx_devel_version=yes
  36                  LYX_DATE="not released yet" ;;
  37     prerelease) lyx_prerelease=yes ;;
  38 esac
  39
  40 AC_SUBST(lyx_devel_version)
  41 ])
  42
  43
  44 dnl Define the option to set a LyX version on installed executables and directories
  45 dnl
  46 dnl
  47 AC_DEFUN([LYX_VERSION_SUFFIX],[
  48 AC_MSG_CHECKING([for version suffix])
  49 dnl We need the literal double quotes in the rpm spec file
  50 RPM_VERSION_SUFFIX='""'
  51 AC_ARG_WITH(version-suffix,
  52   [AS_HELP_STRING([--with-version-suffix@<:@=STR@:>@], install lyx files as lyxSTR (default STR: -AC_PACKAGE_VERSION))],
  53   [if test "x$withval" = "xyes";
  54    then
  55      withval="-"AC_PACKAGE_VERSION
  56      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  57    fi
  58    AC_SUBST(version_suffix,$withval)
  59    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  60 AC_SUBST(RPM_VERSION_SUFFIX)
  61 AC_SUBST(program_base_name,"lyx")
  62 AC_MSG_RESULT([$withval])
  63 ])
  64
  65
  66 dnl Check whether to configure for Qt5. Default is Qt4.
  67 dnl
  68 AC_DEFUN([LYX_CHECK_QT5],[
  69 AC_MSG_CHECKING([whether Qt5 is requested])
  70 AC_ARG_ENABLE([qt5],
  71   [  --disable-qt5           use Qt4 for building],
  72   USE_QT5=$enableval, USE_QT5=yes)
  73 AC_MSG_RESULT([$USE_QT5])
  74 AC_SUBST([USE_QT5])
  75 ])
  76
  77
  78 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  79 dnl flag lyx_warning to yes.
  80 AC_DEFUN([LYX_WARNING],[
  81 lyx_warning_txt="$lyx_warning_txt
  82 == $1
  83 "
  84 lyx_warning=yes])
  85
  86
  87 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  88 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  89 AC_DEFUN([LYX_LIB_ERROR],[
  90 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  91    is correctly installed on your system.])])
  92
  93
  94 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  95 dnl   has occurred previously.
  96 AC_DEFUN([LYX_CHECK_WARNINGS],[
  97 if test x$lyx_warning = xyes; then
  98 cat <<EOF
  99 === The following minor problems have been detected by configure.
 100 === Please check the messages below before running 'make'.
 101 === (see the section 'Problems' in the INSTALL file)
 102 $lyx_warning_txt
 103
 104 EOF
 105 fi])
 106
 107
 108 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 109 dnl
 110 define(LYX_SEARCH_PROG,[dnl
 111 for ac_prog in $2 ; do
 112 # Extract the first word of "$ac_prog", so it can be a program name with args.
 113   set dummy $ac_prog ; ac_word=$[2]
 114   if test -z "[$]$1"; then
 115     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 116     for ac_dir in $PATH; do
 117       test -z "$ac_dir" && ac_dir=.
 118       if test -f [$ac_dir/$ac_word]; then
 119         $1="$ac_prog"
 120         break
 121       fi
 122     done
 123     IFS="$ac_save_ifs"
 124   fi
 125
 126   if test -n "[$]$1"; then
 127     ac_result=yes
 128   else
 129     ac_result=no
 130   fi
 131   ifelse($3,,,[$3])
 132   test -n "[$]$1" && break
 133 done
 134 ])dnl
 135
 136
 137 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 138 AC_DEFUN([LYX_PROG_CLANG],
 139 [AC_CACHE_CHECK([whether the compiler is clang],
 140                [lyx_cv_prog_clang],
 141 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 142 #ifndef __clang__
 143             this is not clang
 144 #endif
 145 ]])],[lyx_cv_prog_clang=yes ; CLANG=yes],[lyx_cv_prog_clang=no ; CLANG=no])])
 146 if test $CLANG = yes ; then
 147   AC_CACHE_CHECK([for clang version],
 148     [lyx_cv_clang_version],
 149     [clang_noversion=no
 150      AC_COMPUTE_INT(clang_major,__clang_major__,,[clang_noversion_=yes])
 151      AC_COMPUTE_INT(clang_minor,__clang_minor__,,[clang_noversion_=yes])
 152      AC_COMPUTE_INT(clang_patchlevel,__clang_patchlevel__,,[clang_noversion_=yes])
 153      if test $clang_noversion = yes ; then
 154        clang_version=unknown
 155      else
 156        clang_version=$clang_major.$clang_minor.$clang_patchlevel
 157      fi
 158      lyx_cv_clang_version=$clang_version])
 159 fi
 160 ])
 161
 162
 163 dnl Usage: LYX_CXX_CXX11_FLAGS: add to AM_CXXFLAGS the best flag that
 164 selects C++11 mode; gives an error when C++11 mode is not found.
 165 AC_DEFUN([LYX_CXX_CXX11_FLAGS],
 166 [AC_CACHE_CHECK([for at least C++11 mode], [lyx_cv_cxx11_flags],
 167  [lyx_cv_cxx11_flags=none
 168   for flag in -std=c++14 -std=c++11 "" -std=c++0x -std=gnu++14 -std=gnu++11 -std=gnu++0x ; do
 169     save_CPPFLAGS=$CPPFLAGS
 170     CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 171     save_CXXFLAGS=$CXXFLAGS
 172     CXXFLAGS="$flag $AM_CXXFLAGS $CXXFLAGS"
 173     dnl sample openmp source code to test
 174     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 175        template <typename T>
 176        struct check
 177        {
 178            static_assert(sizeof(int) <= sizeof(T), "not big enough");
 179        };
 180
 181        typedef check<check<bool>> right_angle_brackets;
 182
 183        class TestDeleted
 184        {
 185        public:
 186            TestDeleted() = delete;
 187        };
 188
 189
 190        int a;
 191        decltype(a) b;
 192
 193        typedef check<int> check_type;
 194        check_type c;
 195        check_type&& cr = static_cast<check_type&&>(c);
 196
 197        auto d = a;]], [[]])],[lyx_cv_cxx11_flags=$flag; break],[])
 198    CXXFLAGS=$save_CXXFLAGS
 199    CPPFLAGS=$save_CPPFLAGS
 200   done])
 201   if test $lyx_cv_cxx11_flags = none ; then
 202     AC_MSG_ERROR(Cannot find suitable C++11 mode for compiler $CXX)
 203   fi
 204   AM_CXXFLAGS="$lyx_cv_cxx11_flags $AM_CXXFLAGS"
 205 ])
 206
 207
 208 dnl Usage: LYX_CXX_USE_REGEX
 209 dnl decide whether we want to use std::regex and set the
 210 dnl LYX_USE_STD_REGEX macro and conditional accordingly.
 211 AC_DEFUN([LYX_CXX_USE_REGEX],
 212 [AC_ARG_ENABLE(std-regex,
 213   AS_HELP_STRING([--enable-std-regex],[use std::regex instead of boost::regex (default is autodetected)]),
 214   [lyx_std_regex=$enableval],
 215   [AC_MSG_CHECKING([for correct regex implementation])
 216    save_CPPFLAGS=$CPPFLAGS
 217    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 218    save_CXXFLAGS=$CXXFLAGS
 219    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 220    # The following code snippet has been taken taken from example in
 221    #   http://stackoverflow.com/questions/8561850/compile-stdregex-iterator-with-gcc
 222    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 223         #include <regex>
 224         #include <iostream>
 225
 226         #include <string.h>
 227
 228         typedef std::regex_iterator<const char *> Myiter;
 229      ]], [[
 230         const char *pat = "axayaz";
 231         Myiter::regex_type rx("a");
 232         Myiter next(pat, pat + strlen(pat), rx);
 233         Myiter end;
 234    ]])],[lyx_std_regex=yes],[lyx_std_regex=no])
 235    CXXFLAGS=$save_CXXFLAGS
 236    CPPFLAGS=$save_CPPFLAGS
 237    AC_MSG_RESULT([$lyx_std_regex])
 238  ])
 239
 240  if test $lyx_std_regex = yes ; then
 241   lyx_flags="$lyx_flags std-regex"
 242   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 243  fi
 244  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 245 ])
 246
 247
 248 dnl Usage: LYX_CXX_USE_CALL_ONCE
 249 dnl check whether we can use std::call_once and set the
 250 dnl LYX_USE_STD_CALL_ONCE macro and conditional accordingly.
 251 AC_DEFUN([LYX_CXX_USE_CALL_ONCE],
 252 [AC_MSG_CHECKING([for std::call_once availability])
 253    save_CPPFLAGS=$CPPFLAGS
 254    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 255    save_CXXFLAGS=$CXXFLAGS
 256    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 257    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 258         #include <mutex>
 259         static std::once_flag flag;
 260      ]], [[
 261         std::call_once(flag, [](){ return; });
 262    ]])],[lyx_std_call_once=yes],[lyx_std_call_once=no])
 263    CXXFLAGS=$save_CXXFLAGS
 264    CPPFLAGS=$save_CPPFLAGS
 265    AC_MSG_RESULT([$lyx_std_call_once])
 266
 267  if test $lyx_std_call_once = yes ; then
 268   AC_DEFINE([LYX_USE_STD_CALL_ONCE], 1, [define to 1 if std::call_once is supported by the compiler])
 269  fi
 270  AM_CONDITIONAL([LYX_USE_STD_CALL_ONCE], test $lyx_std_call_once = yes)
 271 ])
 272
 273
 274 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 275 AC_DEFUN([LYX_LIB_STDCXX],
 276 [AC_CACHE_CHECK([whether STL is libstdc++],
 277                [lyx_cv_lib_stdcxx],
 278 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 279 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 280             this is not libstdc++
 281 #endif
 282 ]])],[lyx_cv_lib_stdcxx=yes],[lyx_cv_lib_stdcxx=no])])
 283 ])
 284
 285
 286 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 287 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 288 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 289 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 290                [lyx_cv_lib_stdcxx_cxx11_abi],
 291 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 292 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 293             this is not libstdc++ using the C++11 ABI
 294 #endif
 295 ]])],[lyx_cv_lib_stdcxx_cxx11_abi=yes],[lyx_cv_lib_stdcxx_cxx11_abi=no])])
 296 ])
 297
 298
 299 AC_DEFUN([LYX_PROG_CXX],
 300 [AC_REQUIRE([AC_PROG_CXX])
 301 AC_REQUIRE([AC_PROG_CXXCPP])
 302
 303 AC_LANG_PUSH(C++)
 304 LYX_PROG_CLANG
 305 LYX_CXX_CXX11_FLAGS
 306 LYX_LIB_STDCXX
 307 LYX_LIB_STDCXX_CXX11_ABI
 308 LYX_CXX_USE_REGEX
 309 LYX_CXX_USE_CALL_ONCE
 310 AC_LANG_POP(C++)
 311
 312 if test $lyx_cv_lib_stdcxx = "yes" ; then
 313   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 314     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 315   else
 316     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 317   fi
 318 else
 319   if test $lyx_cv_prog_clang = "yes" ; then
 320     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 321   fi
 322 fi
 323
 324 ### We might want to get or shut warnings.
 325 AC_ARG_ENABLE(warnings,
 326   AS_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 327   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_cxx_compiler_gnu = yes ; then
 328         enable_warnings=yes;
 329     else
 330         enable_warnings=no;
 331     fi;])
 332 if test x$enable_warnings = xyes ; then
 333   lyx_flags="$lyx_flags warnings"
 334 fi
 335
 336 ### We might want to disable debug
 337 AC_ARG_ENABLE(debug,
 338   AS_HELP_STRING([--enable-debug],[enable debug information]),,
 339   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 340 )
 341
 342 AC_ARG_ENABLE(stdlib-debug,
 343   AS_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 344   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 345           [enable_stdlib_debug=no])]
 346 )
 347
 348 ### set up optimization
 349 AC_ARG_ENABLE(optimization,
 350     AS_HELP_STRING([--enable-optimization@<:@=ARG@:>@],[enable compiler optimisation]),,
 351     enable_optimization=yes;)
 352 case $enable_optimization in
 353     yes)
 354         if test $lyx_devel_version = yes ; then
 355             lyx_optim=-O
 356         else
 357             lyx_optim=-O2
 358         fi;;
 359     no) lyx_optim=;;
 360     *) lyx_optim=${enable_optimization};;
 361 esac
 362
 363 AC_ARG_ENABLE(assertions,
 364   AS_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 365   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 366           [enable_assertions=no])]
 367 )
 368 if test "x$enable_assertions" = xyes ; then
 369    lyx_flags="$lyx_flags assertions"
 370    AC_DEFINE(ENABLE_ASSERTIONS,1,
 371     [Define if you want assertions to be enabled in the code])
 372 fi
 373
 374 # set the compiler options correctly.
 375 if test x$GXX = xyes; then
 376   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 377   if test x$CLANG = xno; then
 378     dnl Useful for global version info
 379     gxx_version=`${CXX} -dumpversion`
 380     case $gxx_version in
 381         *.*) ;;
 382         *) gxx_version=`${CXX} -dumpfullversion` ;;
 383     esac
 384     CXX_VERSION="($gxx_version)"
 385   else
 386     gxx_version=clang-$clang_version
 387     CXX_VERSION="($clang_version)"
 388   fi
 389
 390   AM_CXXFLAGS="$lyx_optim $AM_CXXFLAGS"
 391   if test x$enable_debug = xyes ; then
 392       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 393   fi
 394   if test $build_type = gprof ; then
 395     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 396     AM_LDFLAGS="$AM_LDFLAGS -pg"
 397   fi
 398   if test $build_type = profiling ; then
 399     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 400   fi
 401
 402   if test x$USE_QT5 = xyes ; then
 403       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 404   fi
 405   dnl Warnings are for preprocessor too
 406   if test x$enable_warnings = xyes ; then
 407       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 408       dnl Shut off warning -Wdeprecated-copy, which triggers too much
 409       dnl note that g++ always accepts -Wno-xxx, even when -Wxxx is an error.
 410       AC_LANG_PUSH(C++)
 411       AX_CHECK_COMPILE_FLAG([-Wdeprecated-copy],
 412         [AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-copy"], [], [-Werror])
 413       AC_LANG_POP(C++)
 414     fi
 415   case $gxx_version in
 416       2.*|3.*) AC_MSG_ERROR(gcc >= 4.6 is required);;
 417       4.0*|4.1*|4.2*|4.3*|4.4*|4.5*) AC_MSG_ERROR(gcc >= 4.6 is required);;
 418   esac
 419   if test x$enable_stdlib_debug = xyes ; then
 420     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 421     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 422     case $gxx_version in
 423       *)
 424         lyx_flags="$lyx_flags stdlib-debug"
 425         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 426         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 427         AC_SUBST(STDLIB_DEBUG, "-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 428         ;;
 429     esac
 430   fi
 431 fi
 432
 433 # Some additional flags may be needed
 434 if test x$GXX = xyes; then
 435     case $gxx_version in
 436       clang-3.0*|clang-3.1*|clang-3.2*|clang-3.3*)
 437         dnl boost contains pragmas that are annoying on older clang versions
 438         AM_CPPFLAGS="-Wno-unknown-pragmas $AM_CPPFLAGS";;
 439       clang*)
 440         dnl the more recent versions support the deprecated-register warning,
 441         dnl which  is very annoying with Qt4.x right now.
 442         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 443     esac
 444 fi
 445 ])
 446
 447 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 448 dnl        be used.
 449 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 450         AC_MSG_CHECKING([whether to use included boost library])
 451         AC_ARG_WITH(included-boost,
 452             [AS_HELP_STRING([--without-included-boost],[do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 453             [lyx_cv_with_included_boost=$withval],
 454             [lyx_cv_with_included_boost=yes])
 455         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 456         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 457         if test x$lyx_cv_with_included_boost = xyes ; then
 458             lyx_included_libs="$lyx_included_libs boost"
 459             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 460             if test $lyx_std_regex = yes ; then
 461               BOOST_LIBS=""
 462             else
 463               BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 464             fi
 465         else
 466             BOOST_INCLUDES=
 467             if test $lyx_std_regex = yes ; then
 468               BOOST_LIBS=""
 469             else
 470               AC_LANG_PUSH(C++)
 471               save_LIBS=$LIBS
 472
 473               AC_MSG_CHECKING([for multithreaded boost libraries])
 474               LIBS="$save_LIBS -lboost_regex-mt $LIBTHREAD"
 475               AC_LINK_IFELSE(
 476                 [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 477                         [boost::regex reg;])],
 478                 [AC_MSG_RESULT([yes])
 479                  BOOST_MT="-mt"],
 480                 [AC_MSG_RESULT([no])
 481                  AC_MSG_CHECKING([for plain boost libraries])
 482                  LIBS="$save_LIBS -lboost_regex"
 483                  AC_LINK_IFELSE(
 484                      [AC_LANG_PROGRAM([#include <boost/regex.hpp>],
 485                              [boost::regex reg;])],
 486                      [AC_MSG_RESULT([yes])
 487                       BOOST_MT=""],
 488                      [AC_MSG_RESULT([no])
 489                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 490                  ])
 491               ])
 492               LIBS=$save_LIBS
 493               AC_LANG_POP(C++)
 494
 495               dnl In general, system boost libraries are incompatible with
 496               dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 497               dnl details.
 498               if test $enable_stdlib_debug = "yes" ; then
 499                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 500    crashes. Consider using --disable-stdlib-debug or removing
 501    --without-included-boost.])
 502               fi
 503
 504               BOOST_LIBS="-lboost_regex${BOOST_MT}"
 505             fi
 506         fi
 507         AC_SUBST(BOOST_INCLUDES)
 508         AC_SUBST(BOOST_LIBS)
 509 ])
 510
 511
 512 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 513 dnl        be used.
 514 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 515   AC_MSG_CHECKING([whether to use included iconv library])
 516   AC_ARG_WITH(included-iconv,
 517     [AS_HELP_STRING([--with-included-iconv],[use the iconv lib supplied with LyX instead of the system one])],
 518     [lyx_cv_with_included_iconv=$withval],
 519     [lyx_cv_with_included_iconv=no])
 520   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 521   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 522   if test x$lyx_cv_with_included_iconv = xyes ; then
 523   lyx_included_libs="$lyx_included_libs iconv"
 524
 525 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 526     AC_EILSEQ
 527     AC_TYPE_MBSTATE_T
 528     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 529 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 530     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 531       USE_MBSTATE_T=1
 532     else
 533       USE_MBSTATE_T=0
 534     fi
 535     AC_SUBST([USE_MBSTATE_T])
 536     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 537       [gl_cv_header_wchar_h_standalone],
 538       [AC_COMPILE_IFELSE(
 539         [AC_LANG_PROGRAM(
 540           [[#include <wchar.h>
 541             wchar_t w;]],
 542           [[]])],
 543         [gl_cv_header_wchar_h_standalone=yes],
 544         [gl_cv_header_wchar_h_standalone=no])])
 545     if test $gl_cv_header_wchar_h_standalone = yes; then
 546       BROKEN_WCHAR_H=0
 547     else
 548       BROKEN_WCHAR_H=1
 549     fi
 550     AC_SUBST([BROKEN_WCHAR_H])
 551 dnl we want const correctness
 552     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 553       [Define as const if the declaration of iconv() needs const.])
 554     ICONV_CONST=const
 555     AC_SUBST([ICONV_CONST])
 556 dnl we build a static lib
 557     DLL_VARIABLE=
 558     AC_SUBST([DLL_VARIABLE])
 559     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 560     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 561     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 562   else
 563     ICONV_INCLUDES=
 564     AM_ICONV
 565     if test "$am_cv_func_iconv" = no; then
 566       AC_MSG_ERROR([cannot find required library iconv.])
 567     else
 568       ICONV_LIBS="$LIBICONV"
 569     fi
 570     ICONV_ICONV_H_IN=
 571   fi
 572   AC_SUBST(ICONV_INCLUDES)
 573   AC_SUBST(ICONV_LIBS)
 574   AC_SUBST(ICONV_ICONV_H_IN)
 575 ])
 576
 577
 578 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 579 dnl        be used.
 580 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 581   AC_MSG_CHECKING([whether to use included zlib library])
 582   AC_ARG_WITH(included-zlib,
 583     [AS_HELP_STRING([--with-included-zlib],[use the zlib lib supplied with LyX instead of the system one])],
 584     [lyx_cv_with_included_zlib=$withval],
 585     [lyx_cv_with_included_zlib=no])
 586   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 587   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 588   if test x$lyx_cv_with_included_zlib = xyes ; then
 589     lyx_included_libs="$lyx_included_libs zlib"
 590     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 591     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 592     mkdir -p 3rdparty/zlib
 593 dnl include standard config.h for HAVE_UNISTD_H
 594     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 595 dnl prevent clash with system zlib that might be dragged in by other libs
 596     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 597     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 598   else
 599     ZLIB_INCLUDES=
 600     AC_CHECK_HEADERS(zlib.h,
 601       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 602       [LYX_LIB_ERROR(zlib.h,zlib)])
 603   fi
 604   AC_SUBST(ZLIB_INCLUDES)
 605   AC_SUBST(ZLIB_LIBS)
 606 ])
 607
 608
 609 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 610 dnl        necessary APIs are available to print callstacks.
 611 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 612 [AC_CACHE_CHECK([whether printing callstack is possible],
 613                [lyx_cv_callstack_printing],
 614 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 615 #include <execinfo.h>
 616 #include <cxxabi.h>
 617 ]], [[
 618         void* array[200];
 619         size_t size = backtrace(array, 200);
 620         backtrace_symbols(array, size);
 621         int status = 0;
 622         abi::__cxa_demangle("abcd", 0, 0, &status);
 623 ]])],[lyx_cv_callstack_printing=yes],[lyx_cv_callstack_printing=no])])
 624 if test x"$lyx_cv_callstack_printing" = xyes; then
 625   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 626             [Define if callstack can be printed])
 627 fi
 628 ])
 629
 630
 631 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 632 dnl        be used.
 633 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 634   AC_ARG_WITH(included-mythes,
 635     [AS_HELP_STRING([--with-included-mythes],[force to use the MyThes lib supplied with LyX])],
 636     [use_included_mythes=$withval],
 637     [use_included_mythes=no])
 638   if test x$use_included_mythes != xyes ; then
 639     AC_LANG_PUSH(C++)
 640     use_included_mythes=yes
 641     AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
 642       [mythes_h_location="<$ac_header>"
 643        save_LIBS=$LIBS
 644        AC_MSG_CHECKING([checking for MyThes library])
 645        for ac_lib in mythes mythes-1.2 ; do
 646          LIBS="-l$ac_lib $save_LIBS"
 647          AC_LINK_IFELSE(
 648            [AC_LANG_PROGRAM([#include <cstdio>]
 649               [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
 650            [MYTHES_LIBS=-l$ac_lib
 651             AC_MSG_RESULT([$MYTHES_LIBS])
 652             use_included_mythes=no])
 653        done
 654        if test $use_included_mythes != no ; then
 655          AC_MSG_RESULT([not found])
 656        fi
 657        break])
 658     AC_LANG_POP(C++)
 659   fi
 660   if test $use_included_mythes = yes ; then
 661     mythes_h_location="<mythes.hxx>"
 662     MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
 663     MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
 664     lyx_included_libs="$lyx_included_libs mythes"
 665   fi
 666   AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
 667   AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
 668   AC_SUBST(MYTHES_INCLUDES)
 669   AC_SUBST(MYTHES_LIBS)
 670   AC_MSG_CHECKING([whether to use included MyThes library])
 671   AC_MSG_RESULT([$use_included_mythes])
 672 ])
 673
 674
 675 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 676 dnl                       [default-yes-value])
 677 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 678 dnl  resulting directory name in 'dir-var-name'.
 679 AC_DEFUN([LYX_WITH_DIR],[
 680   AC_ARG_WITH($1,[AS_HELP_STRING([--with-$1],[specify $2])])
 681   AC_MSG_CHECKING([for $2])
 682   if test -z "$with_$3"; then
 683      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 684   else
 685     test "x$with_$3" = xyes && with_$3=$5
 686     lyx_cv_$3="$with_$3"
 687   fi
 688   AC_MSG_RESULT($lyx_cv_$3)
 689 ])
 690
 691
 692 dnl Usage: LYX_LOOP_DIR(value,action)
 693 dnl Executes action for values of variable `dir' in `values'. `values' can
 694 dnl use ":" as a separator.
 695 AC_DEFUN([LYX_LOOP_DIR],[
 696 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 697 for dir in `eval "echo $1"`; do
 698   if test ! "$dir" = NONE; then
 699     test ! -d "$dir" && AC_MSG_ERROR(['$dir' is not a directory])
 700     $2
 701   fi
 702 done
 703 IFS=$ac_save_ifs
 704 ])
 705
 706
 707 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 708 dnl var-name.
 709 AC_DEFUN([LYX_ADD_LIB_DIR],[
 710 $1="${$1} -L$2"
 711 if test "`(uname) 2>/dev/null`" = SunOS &&
 712     uname -r | grep '^5' >/dev/null; then
 713   if test $ac_cv_cxx_compiler_gnu = yes ; then
 714     $1="${$1} -Wl[,]-R$2"
 715   else
 716     $1="${$1} -R$2"
 717   fi
 718 fi])
 719
 720
 721 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 722 dnl var-name.
 723 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 724
 725 ### Check for a headers existence and location iff it exists
 726 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 727 ## It almost works.  I've tried a few variations but they give errors
 728 ## of one sort or other: bad substitution or file not found etc.  The
 729 ## actual header _is_ found though and the cache variable is set however
 730 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 731 ## reason.
 732 ## Additionally, autoheader can't figure out what to use as the name in
 733 ## the config.h.in file so we need to write our own entries there -- one for
 734 ## each header in the form PATH_HEADER_NAME_H
 735 ##
 736 AC_DEFUN([LYX_PATH_HEADER],
 737 [ AC_CHECK_HEADER($1,[
 738   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 739 ### the only remaining problem is getting the second parameter to this
 740 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 741 ### of $ac_safe being printed.
 742   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 743   [ cat > conftest.$ac_ext <<EOF
 744 #line __oline__ "configure"
 745 #include "confdefs.h"
 746
 747 #include <$1>
 748 EOF
 749 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 750   grep $1  2>/dev/null | \
 751   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 752 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 753 rm -f conftest*])
 754   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 755 ])
 756 ### end of LYX_PATH_HEADER
 757
 758 ## Check what kind of packaging should be used at install time.
 759 ## The default is autodetected.
 760 AC_DEFUN([LYX_USE_PACKAGING],
 761 [AC_MSG_CHECKING([what packaging should be used])
 762 AC_ARG_WITH(packaging,
 763   [AS_HELP_STRING([--with-packaging=STR],[set packaging for installation among:
 764                             posix, windows, macosx, haiku (default is autodetected)])],
 765   [lyx_use_packaging="$withval"], [
 766   case $host in
 767     *-apple-darwin*) lyx_use_packaging=macosx ;;
 768     *-pc-mingw*) lyx_use_packaging=windows ;;
 769     *-mingw32*) lyx_use_packaging=windows ;;
 770     *haiku*) lyx_use_packaging=haiku ;;
 771     *) lyx_use_packaging=posix ;;
 772   esac])
 773 AC_MSG_RESULT($lyx_use_packaging)
 774 lyx_install_posix=false
 775 lyx_install_macosx=false
 776 lyx_install_cygwin=false
 777 lyx_install_windows=false
 778 case $lyx_use_packaging in
 779    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 780            PACKAGE=LyX${version_suffix}
 781            default_prefix="/Applications/${PACKAGE}.app"
 782            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 783            bindir='${prefix}/Contents/MacOS'
 784            libdir='${prefix}/Contents/Resources'
 785            datarootdir='${prefix}/Contents/Resources'
 786            pkgdatadir='${datadir}'
 787            mandir='${datadir}/man'
 788            lyx_install_macosx=true ;;
 789   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 790            PACKAGE=LyX${version_suffix}
 791            default_prefix="C:/Program Files/${PACKAGE}"
 792            bindir='${prefix}/bin'
 793            libdir='${prefix}/Resources'
 794            datarootdir='${prefix}/Resources'
 795            pkgdatadir='${datadir}'
 796            mandir='${prefix}/Resources/man'
 797            lyx_install_windows=true ;;
 798     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 799            PACKAGE=lyx${version_suffix}
 800            program_suffix=$version_suffix
 801            pkgdatadir='${datadir}/${PACKAGE}'
 802            default_prefix=$ac_default_prefix
 803            case ${host} in
 804              *cygwin*) lyx_install_cygwin=true ;;
 805              *apple-darwin*) lyx_install_macosx=true ;;
 806            esac
 807            lyx_install_posix=true ;;
 808         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 809            PACKAGE=lyx${version_suffix}
 810            program_suffix=$version_suffix
 811            pkgdatadir='${datadir}/${PACKAGE}'
 812            default_prefix=$ac_default_prefix
 813            lyx_install_posix=true ;;
 814     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 815 esac
 816 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 817 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 818 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 819 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 820 AC_SUBST(pkgdatadir)
 821 AC_SUBST(program_suffix)
 822 ])
 823
 824
 825 ## ------------------------------------------------------------------------
 826 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 827 ## one or two arguments.
 828 ##
 829 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 830 ## ------------------------------------------------------------------------
 831 ##
 832 AC_DEFUN([AC_FUNC_MKDIR],
 833 [AC_CHECK_FUNCS([mkdir _mkdir])
 834 AC_CACHE_CHECK([whether mkdir takes one argument],
 835                [ac_cv_mkdir_takes_one_arg],
 836 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 837 #include <sys/stat.h>
 838 #if HAVE_UNISTD_H
 839 #  include <unistd.h>
 840 #endif
 841 ]], [[mkdir (".");]])],[ac_cv_mkdir_takes_one_arg=yes],[ac_cv_mkdir_takes_one_arg=no])])
 842 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 843   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 844             [Define if mkdir takes only one argument.])
 845 fi
 846 ])
 847
 848
 849 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 850 dnl (which may be a relative path, and need not refer to any existing
 851 dnl entity).
 852
 853 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 854 dnl native Win32 path name, (but with slashes, not backslashes).
 855
 856 dnl On any other system, it is simply the result which would be obtained
 857 dnl if PATHNAME represented an existing directory, and the pwd command was
 858 dnl executed in that directory.
 859 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 860 [ac_dir="$2"
 861  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 862     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 863  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 864  do
 865    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 866  done
 867  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 868  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 869  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 870    s?/*$[]??'`
 871 ])
 872
 873 dnl this is used by the macro blow to general a proper config.h.in entry
 874 m4_define([LYX_AH_CHECK_DECL],
 875 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 876   [Define if you have the prototype for function `$1'])])dnl`
 877
 878 dnl Check things are declared in headers to avoid errors or warnings.
 879 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 880 dnl Defines HAVE_DECL_{FUNCTION}
 881 AC_DEFUN([LYX_CHECK_DECL],
 882 [LYX_AH_CHECK_DECL($1)
 883 for ac_header in $2
 884 do
 885   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 886   AC_EGREP_HEADER($1, $ac_header,
 887       [AC_MSG_RESULT(yes)
 888        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 889        break],
 890       [AC_MSG_RESULT(no)])
 891 done])
 892
 893 dnl this is used by the macro below to generate a proper config.h.in entry
 894 m4_define([LYX_AH_CHECK_DEF],
 895 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 896   [Define to 1 if `$1' is defined in `$2'])])dnl'
 897
 898 dnl Check whether name is defined in header by using it in codesnippet.
 899 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 900 dnl Defines HAVE_DEF_{NAME}
 901 AC_DEFUN([LYX_CHECK_DEF],
 902 [LYX_AH_CHECK_DEF($1, $2)
 903  AC_MSG_CHECKING([whether $1 is defined by header $2])
 904  save_CPPFLAGS=$CPPFLAGS
 905  CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 906  save_CXXFLAGS=$CXXFLAGS
 907  CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 908  AC_LANG_PUSH(C++)
 909  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <$2>]], [[$3]])],[lyx_have_def_name=yes],[lyx_have_def_name=no])
 910  AC_LANG_POP(C++)
 911  CXXFLAGS=$save_CXXFLAGS
 912  CPPFLAGS=$save_CPPFLAGS
 913  AC_MSG_RESULT($lyx_have_def_name)
 914  if test "x$lyx_have_def_name" = xyes; then
 915    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 916  fi
 917 ])
 918
 919 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 920 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 921 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 922 AC_DEFUN([LYX_SET_VERSION_INFO],
 923 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 924  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 925  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 926  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 927  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 928  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 929  test "x$lyx_patch" = "x" && lyx_patch=0
 930  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 931  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 932  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 933  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 934  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 935  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 936  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 937  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 938 ])
 939