config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171
 172 dnl Usage: LYX_CXX_USE_REGEX(cxx11_flags)
 173 dnl decide whether we want to use std::regex and set the
 174 dnl LYX_USE_STD_REGEX accordingly.
 175 dnl the extra cxx11 flags have to be passed to the preprocessor. They are
 176 dnl not plainly added to AM_CPPFLAGS because then the objc compiler (mac)
 177 dnl would fail.
 178 AC_DEFUN([LYX_CXX_USE_REGEX],
 179 [lyx_std_regex=no
 180    save_CPPFLAGS=$CPPFLAGS
 181    # we want to pass -std=c++11 to clang/cpp if necessary
 182    CPPFLAGS="$AM_CPPFLAGS $1 $CPPFLAGS"
 183    save_CXXFLAGS=$CXXFLAGS
 184    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 185    AC_LANG_PUSH(C++)
 186    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 187    AC_LANG_POP(C++)
 188    CXXFLAGS=$save_CXXFLAGS
 189    CPPFLAGS=$save_CPPFLAGS
 190    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 191      AC_MSG_CHECKING([for correct regex implementation])
 192      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 193        dnl <regex> in gcc is unusable in versions less than 4.9.0
 194        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 195        case $gxx_version in
 196          4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 197          *) ;;
 198        esac
 199      fi
 200    fi
 201    AC_MSG_RESULT([$lyx_std_regex])
 202
 203  if test $lyx_std_regex = yes ; then
 204   lyx_flags="$lyx_flags std-regex"
 205   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 206  fi
 207  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 208 ])
 209
 210
 211 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 212 AC_DEFUN([LYX_LIB_STDCXX],
 213 [AC_CACHE_CHECK([whether STL is libstdc++],
 214                [lyx_cv_lib_stdcxx],
 215 [AC_TRY_COMPILE([#include<vector>], [
 216 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 217             this is not libstdc++
 218 #endif
 219 ],
 220 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 221 ])
 222
 223
 224 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 225 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 226 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 227 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 228                [lyx_cv_lib_stdcxx_cxx11_abi],
 229 [AC_TRY_COMPILE([#include<vector>], [
 230 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 231             this is not libstdc++ using the C++11 ABI
 232 #endif
 233 ],
 234 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 235 ])
 236
 237
 238 AC_DEFUN([LYX_PROG_CXX],
 239 [AC_REQUIRE([AC_PROG_CXX])
 240 AC_REQUIRE([AC_PROG_CXXCPP])
 241
 242 AC_LANG_PUSH(C++)
 243 LYX_PROG_CLANG
 244 LYX_LIB_STDCXX
 245 LYX_LIB_STDCXX_CXX11_ABI
 246 AC_LANG_POP(C++)
 247
 248 if test $lyx_cv_lib_stdcxx = "yes" ; then
 249   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 250     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 251   else
 252     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 253   fi
 254 else
 255   if test $lyx_cv_prog_clang = "yes" ; then
 256     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 257   fi
 258 fi
 259
 260 ### We might want to get or shut warnings.
 261 AC_ARG_ENABLE(warnings,
 262   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 263   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 264         enable_warnings=yes;
 265     else
 266         enable_warnings=no;
 267     fi;])
 268 if test x$enable_warnings = xyes ; then
 269   lyx_flags="$lyx_flags warnings"
 270 fi
 271
 272 ### We might want to disable debug
 273 AC_ARG_ENABLE(debug,
 274   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 275   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 276 )
 277
 278 AC_ARG_ENABLE(stdlib-debug,
 279   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 280   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 281           [enable_stdlib_debug=no])]
 282 )
 283
 284 ### set up optimization
 285 AC_ARG_ENABLE(optimization,
 286     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 287     enable_optimization=yes;)
 288 case $enable_optimization in
 289     yes)
 290         if test $lyx_devel_version = yes ; then
 291             lyx_optim=-O
 292         else
 293             lyx_optim=-O2
 294         fi;;
 295     no) lyx_optim=;;
 296     *) lyx_optim=${enable_optimization};;
 297 esac
 298
 299 AC_ARG_ENABLE(assertions,
 300   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 301   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 302           [enable_assertions=no])]
 303 )
 304 if test "x$enable_assertions" = xyes ; then
 305    lyx_flags="$lyx_flags assertions"
 306    AC_DEFINE(ENABLE_ASSERTIONS,1,
 307     [Define if you want assertions to be enabled in the code])
 308 fi
 309
 310 # set the compiler options correctly.
 311 if test x$GXX = xyes; then
 312   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 313   if test x$CLANG = xno; then
 314     dnl Useful for global version info
 315     gxx_version=`${CXX} -dumpversion`
 316     CXX_VERSION="($gxx_version)"
 317   else
 318     gxx_version=clang
 319   fi
 320
 321   AM_CXXFLAGS="$lyx_optim"
 322   if test x$enable_debug = xyes ; then
 323       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 324   fi
 325   if test $build_type = gprof ; then
 326     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 327     AM_LDFLAGS="$AM_LDFLAGS -pg"
 328   fi
 329   if test $build_type = profiling ; then
 330     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 331   fi
 332
 333   if test x$USE_QT5 = xyes ; then
 334       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 335   fi
 336   dnl Warnings are for preprocessor too
 337   if test x$enable_warnings = xyes ; then
 338       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 339   fi
 340   case $gxx_version in
 341       2.*|3.*) AC_ERROR([gcc >= 4.3 is required]);;
 342       4.0*|4.1*|4.2*) AC_ERROR([gcc >= 4.3 is required]);;
 343   esac
 344   if test x$enable_stdlib_debug = xyes ; then
 345     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 346     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 347     case $gxx_version in
 348       *)
 349         lyx_flags="$lyx_flags stdlib-debug"
 350         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 351         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 352         ;;
 353     esac
 354   fi
 355     case $gxx_version in
 356       4.3*|4.4*|4.5*|4.6*)
 357         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 358         dnl The source code relies on that.
 359         cxx11_flags="-std=c++0x";;
 360       clang)
 361         dnl presumably all clang versions support c++11.
 362         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 363         cxx11_flags="-std=c++11"
 364         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 365       *)
 366         AS_CASE([$host], [*cygwin*],
 367                 [cxx11_flags="-std=gnu++11"],
 368                 [cxx11_flags="-std=c++11"]);;
 369     esac
 370     # cxx11_flags is useful when running preprocessor alone
 371     # (see detection of regex).
 372     AM_CXXFLAGS="$cxx11_flags $AM_CXXFLAGS"
 373 fi
 374
 375 LYX_CXX_CXX11
 376 if test $lyx_use_cxx11 = yes; then
 377   if test x$GXX = xyes; then
 378     dnl We still use auto_ptr, which is obsoleted. Shut off the warnings.
 379     AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-declarations"
 380   fi
 381 else
 382   AC_ERROR([A C++11 compatible compiler is required])
 383 fi
 384 LYX_CXX_USE_REGEX([$cxx11_flags])
 385 ])
 386
 387 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 388 dnl        be used.
 389 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 390         AC_MSG_CHECKING([whether to use included boost library])
 391         AC_ARG_WITH(included-boost,
 392             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 393             [lyx_cv_with_included_boost=$withval],
 394             [lyx_cv_with_included_boost=yes])
 395         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 396         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 397         if test x$lyx_cv_with_included_boost = xyes ; then
 398             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 399             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 400         else
 401             AC_LANG_PUSH(C++)
 402             save_LIBS=$LIBS
 403
 404             AC_MSG_CHECKING([for multithreaded boost libraries])
 405             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 406             AC_LINK_IFELSE(
 407                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 408                         [boost::signal<void ()> s;])],
 409                 [AC_MSG_RESULT([yes])
 410                  BOOST_MT="-mt"],
 411                 [AC_MSG_RESULT([no])
 412                  AC_MSG_CHECKING([for plain boost libraries])
 413                  LIBS="$save_LIBS -lboost_signals"
 414                  AC_LINK_IFELSE(
 415                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 416                              [boost::signal<void ()> s;])],
 417                      [AC_MSG_RESULT([yes])
 418                       BOOST_MT=""],
 419                      [AC_MSG_RESULT([no])
 420                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 421                  ])
 422             ])
 423             LIBS=$save_LIBS
 424             AC_LANG_POP(C++)
 425             BOOST_INCLUDES=
 426             if test $lyx_std_regex = yes ; then
 427               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 428             else
 429               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 430             fi
 431
 432             dnl In general, system boost libraries are incompatible with
 433             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 434             dnl details.
 435             if test $enable_stdlib_debug = "yes" ; then
 436                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 437    crashes. Consider using --disable-stdlib-debug or removing
 438    --without-included-boost.])
 439             fi
 440         fi
 441         AC_SUBST(BOOST_INCLUDES)
 442         AC_SUBST(BOOST_LIBS)
 443 ])
 444
 445
 446 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 447 dnl        be used.
 448 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 449   AC_MSG_CHECKING([whether to use included iconv library])
 450   AC_ARG_WITH(included-iconv,
 451     [AC_HELP_STRING([--without-included-iconv], [do not use the iconv lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 452     [lyx_cv_with_included_iconv=$withval],
 453     [lyx_cv_with_included_iconv=no])
 454   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 455   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 456   if test x$lyx_cv_with_included_iconv = xyes ; then
 457 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 458     AC_EILSEQ
 459     AC_TYPE_MBSTATE_T
 460     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 461 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 462     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 463       USE_MBSTATE_T=1
 464     else
 465       USE_MBSTATE_T=0
 466     fi
 467     AC_SUBST([USE_MBSTATE_T])
 468     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 469       [gl_cv_header_wchar_h_standalone],
 470       [AC_COMPILE_IFELSE(
 471         [AC_LANG_PROGRAM(
 472           [[#include <wchar.h>
 473             wchar_t w;]],
 474           [[]])],
 475         [gl_cv_header_wchar_h_standalone=yes],
 476         [gl_cv_header_wchar_h_standalone=no])])
 477     if test $gl_cv_header_wchar_h_standalone = yes; then
 478       BROKEN_WCHAR_H=0
 479     else
 480       BROKEN_WCHAR_H=1
 481     fi
 482     AC_SUBST([BROKEN_WCHAR_H])
 483 dnl we want const correctness
 484     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 485       [Define as const if the declaration of iconv() needs const.])
 486     ICONV_CONST=const
 487     AC_SUBST([ICONV_CONST])
 488 dnl we build a static lib
 489     DLL_VARIABLE=
 490     AC_SUBST([DLL_VARIABLE])
 491     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 492     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 493     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 494   else
 495     ICONV_INCLUDES=
 496     AM_ICONV
 497     if test "$am_cv_func_iconv" = no; then
 498       AC_MSG_ERROR([cannot find required library iconv.])
 499     else
 500       ICONV_LIBS="$LIBICONV"
 501     fi
 502     ICONV_ICONV_H_IN=
 503   fi
 504   AC_SUBST(ICONV_INCLUDES)
 505   AC_SUBST(ICONV_LIBS)
 506   AC_SUBST(ICONV_ICONV_H_IN)
 507 ])
 508
 509
 510 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 511 dnl        be used.
 512 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 513   AC_MSG_CHECKING([whether to use included zlib library])
 514   AC_ARG_WITH(included-zlib,
 515     [AC_HELP_STRING([--without-included-zlib], [do not use the zlib lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 516     [lyx_cv_with_included_zlib=$withval],
 517     [lyx_cv_with_included_zlib=no])
 518   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 519   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 520   if test x$lyx_cv_with_included_zlib = xyes ; then
 521     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 522     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 523     mkdir -p 3rdparty/zlib
 524 dnl include standard config.h for HAVE_UNISTD_H
 525     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 526 dnl prevent clash with system zlib that might be dragged in by other libs
 527     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 528     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 529   else
 530     ZLIB_INCLUDES=
 531     AC_CHECK_HEADERS(zlib.h,
 532       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 533       [LYX_LIB_ERROR(zlib.h,zlib)])
 534   fi
 535   AC_SUBST(ZLIB_INCLUDES)
 536   AC_SUBST(ZLIB_LIBS)
 537 ])
 538
 539
 540 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 541 dnl        necessary APIs are available to print callstacks.
 542 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 543 [AC_CACHE_CHECK([whether printing callstack is possible],
 544                [lyx_cv_callstack_printing],
 545 [AC_TRY_COMPILE([
 546 #include <execinfo.h>
 547 #include <cxxabi.h>
 548 ], [
 549         void* array[200];
 550         size_t size = backtrace(array, 200);
 551         backtrace_symbols(array, size);
 552         int status = 0;
 553         abi::__cxa_demangle("abcd", 0, 0, &status);
 554 ],
 555 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 556 if test x"$lyx_cv_callstack_printing" = xyes; then
 557   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 558             [Define if callstack can be printed])
 559 fi
 560 ])
 561
 562
 563 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 564 dnl        be used.
 565 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 566         AC_MSG_CHECKING([whether to use included MyThes library])
 567         AC_ARG_WITH(included-mythes,
 568             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 569             [lyx_cv_with_included_mythes=$withval],
 570             [lyx_cv_with_included_mythes=yes])
 571         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 572         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 573         if test x$lyx_cv_with_included_mythes != xyes ; then
 574                 AC_LANG_PUSH(C++)
 575                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 576                 if test x$ac_cv_header_mythes_h != xyes; then
 577                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 578                 fi
 579                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 580                 if test x$lyx_mythes != xyes; then
 581                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 582                 fi
 583                 AC_LANG_POP(C++)
 584                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 585                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 586                 fi
 587                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 588                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 589                 AC_SUBST(MYTHES_LIBS)
 590         fi
 591 ])
 592
 593
 594 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 595 dnl                       [default-yes-value])
 596 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 597 dnl  resulting directory name in 'dir-var-name'.
 598 AC_DEFUN([LYX_WITH_DIR],[
 599   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 600   AC_MSG_CHECKING([for $2])
 601   if test -z "$with_$3"; then
 602      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 603   else
 604     test "x$with_$3" = xyes && with_$3=$5
 605     lyx_cv_$3="$with_$3"
 606   fi
 607   AC_MSG_RESULT($lyx_cv_$3)])
 608
 609
 610 dnl Usage: LYX_LOOP_DIR(value,action)
 611 dnl Executes action for values of variable `dir' in `values'. `values' can
 612 dnl use ":" as a separator.
 613 AC_DEFUN([LYX_LOOP_DIR],[
 614 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 615 for dir in `eval "echo $1"`; do
 616   if test ! "$dir" = NONE; then
 617     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 618     $2
 619   fi
 620 done
 621 IFS=$ac_save_ifs
 622 ])
 623
 624
 625 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 626 dnl var-name.
 627 AC_DEFUN([LYX_ADD_LIB_DIR],[
 628 $1="${$1} -L$2"
 629 if test "`(uname) 2>/dev/null`" = SunOS &&
 630     uname -r | grep '^5' >/dev/null; then
 631   if test $ac_cv_prog_gxx = yes ; then
 632     $1="${$1} -Wl[,]-R$2"
 633   else
 634     $1="${$1} -R$2"
 635   fi
 636 fi])
 637
 638
 639 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 640 dnl var-name.
 641 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 642
 643 ### Check for a headers existence and location iff it exists
 644 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 645 ## It almost works.  I've tried a few variations but they give errors
 646 ## of one sort or other: bad substitution or file not found etc.  The
 647 ## actual header _is_ found though and the cache variable is set however
 648 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 649 ## reason.
 650 ## Additionally, autoheader can't figure out what to use as the name in
 651 ## the config.h.in file so we need to write our own entries there -- one for
 652 ## each header in the form PATH_HEADER_NAME_H
 653 ##
 654 AC_DEFUN([LYX_PATH_HEADER],
 655 [ AC_CHECK_HEADER($1,[
 656   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 657 ### the only remaining problem is getting the second parameter to this
 658 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 659 ### of $ac_safe being printed.
 660   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 661   [ cat > conftest.$ac_ext <<EOF
 662 #line __oline__ "configure"
 663 #include "confdefs.h"
 664
 665 #include <$1>
 666 EOF
 667 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 668   grep $1  2>/dev/null | \
 669   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 670 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 671 rm -f conftest*])
 672   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 673 ])
 674 ### end of LYX_PATH_HEADER
 675
 676 ## Check what kind of packaging should be used at install time.
 677 ## The default is autodetected.
 678 AC_DEFUN([LYX_USE_PACKAGING],
 679 [AC_MSG_CHECKING([what packaging should be used])
 680 AC_ARG_WITH(packaging,
 681   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 682                             Possible values: posix, windows, macosx, haiku])],
 683   [lyx_use_packaging="$withval"], [
 684   case $host in
 685     *-apple-darwin*) lyx_use_packaging=macosx ;;
 686     *-pc-mingw*) lyx_use_packaging=windows ;;
 687     *-mingw32*) lyx_use_packaging=windows ;;
 688     *haiku*) lyx_use_packaging=haiku ;;
 689     *) lyx_use_packaging=posix ;;
 690   esac])
 691 AC_MSG_RESULT($lyx_use_packaging)
 692 lyx_install_posix=false
 693 lyx_install_macosx=false
 694 lyx_install_cygwin=false
 695 lyx_install_windows=false
 696 case $lyx_use_packaging in
 697    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 698            PACKAGE=LyX${version_suffix}
 699            default_prefix="/Applications/${PACKAGE}.app"
 700            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 701            bindir='${prefix}/Contents/MacOS'
 702            libdir='${prefix}/Contents/Resources'
 703            datarootdir='${prefix}/Contents/Resources'
 704            pkgdatadir='${datadir}'
 705            mandir='${datadir}/man'
 706            lyx_install_macosx=true ;;
 707   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 708            PACKAGE=LyX${version_suffix}
 709            default_prefix="C:/Program Files/${PACKAGE}"
 710            bindir='${prefix}/bin'
 711            libdir='${prefix}/Resources'
 712            datarootdir='${prefix}/Resources'
 713            pkgdatadir='${datadir}'
 714            mandir='${prefix}/Resources/man'
 715            lyx_install_windows=true ;;
 716     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 717            PACKAGE=lyx${version_suffix}
 718            program_suffix=$version_suffix
 719            pkgdatadir='${datadir}/${PACKAGE}'
 720            default_prefix=$ac_default_prefix
 721            case ${host} in
 722              *cygwin*) lyx_install_cygwin=true ;;
 723              *apple-darwin*) lyx_install_macosx=true ;;
 724            esac
 725            lyx_install_posix=true ;;
 726         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 727            PACKAGE=lyx${version_suffix}
 728            program_suffix=$version_suffix
 729            pkgdatadir='${datadir}/${PACKAGE}'
 730            default_prefix=$ac_default_prefix
 731            lyx_install_posix=true ;;
 732     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 733 esac
 734 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 735 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 736 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 737 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 738 AC_SUBST(pkgdatadir)
 739 AC_SUBST(program_suffix)
 740 ])
 741
 742
 743 ## ------------------------------------------------------------------------
 744 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 745 ## one or two arguments.
 746 ##
 747 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 748 ## ------------------------------------------------------------------------
 749 ##
 750 AC_DEFUN([AC_FUNC_MKDIR],
 751 [AC_CHECK_FUNCS([mkdir _mkdir])
 752 AC_CACHE_CHECK([whether mkdir takes one argument],
 753                [ac_cv_mkdir_takes_one_arg],
 754 [AC_TRY_COMPILE([
 755 #include <sys/stat.h>
 756 #if HAVE_UNISTD_H
 757 #  include <unistd.h>
 758 #endif
 759 ], [mkdir (".");],
 760 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 761 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 762   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 763             [Define if mkdir takes only one argument.])
 764 fi
 765 ])
 766
 767
 768 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 769 dnl (which may be a relative path, and need not refer to any existing
 770 dnl entity).
 771
 772 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 773 dnl native Win32 path name, (but with slashes, not backslashes).
 774
 775 dnl On any other system, it is simply the result which would be obtained
 776 dnl if PATHNAME represented an existing directory, and the pwd command was
 777 dnl executed in that directory.
 778 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 779 [ac_dir="$2"
 780  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 781     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 782  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 783  do
 784    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 785  done
 786  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 787  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 788  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 789    s?/*$[]??'`
 790 ])
 791
 792 dnl this is used by the macro blow to general a proper config.h.in entry
 793 m4_define([LYX_AH_CHECK_DECL],
 794 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 795   [Define if you have the prototype for function `$1'])])
 796
 797 dnl Check things are declared in headers to avoid errors or warnings.
 798 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 799 dnl Defines HAVE_DECL_{FUNCTION}
 800 AC_DEFUN([LYX_CHECK_DECL],
 801 [LYX_AH_CHECK_DECL($1)
 802 for ac_header in $2
 803 do
 804   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 805   AC_EGREP_HEADER($1, $ac_header,
 806       [AC_MSG_RESULT(yes)
 807        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 808        break],
 809       [AC_MSG_RESULT(no)])
 810 done])
 811
 812 dnl this is used by the macro below to generate a proper config.h.in entry
 813 m4_define([LYX_AH_CHECK_DEF],
 814 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 815   [Define to 1 if `$1' is defined in `$2'])])
 816
 817 dnl Check whether name is defined in header by using it in codesnippet.
 818 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 819 dnl Defines HAVE_DEF_{NAME}
 820 AC_DEFUN([LYX_CHECK_DEF],
 821 [LYX_AH_CHECK_DEF($1, $2)
 822  AC_MSG_CHECKING([whether $1 is defined by header $2])
 823  AC_TRY_COMPILE([#include <$2>], [$3],
 824      lyx_have_def_name=yes,
 825      lyx_have_def_name=no)
 826  AC_MSG_RESULT($lyx_have_def_name)
 827  if test "x$lyx_have_def_name" = xyes; then
 828    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 829  fi
 830 ])
 831
 832 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 833 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 834 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 835 AC_DEFUN([LYX_SET_VERSION_INFO],
 836 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 837  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 838  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 839  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 840  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 841  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 842  test "x$lyx_patch" = "x" && lyx_patch=0
 843  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 844  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 845  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 846  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 847  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 848  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 849  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 850  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 851 ])
 852
 853 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 854 # ---------------------------------------------------------------------------
 855 # Copied from autoconf 2.68, added a check that python version is < 3.0
 856 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 857 # Run ACTION-IF-FALSE otherwise.
 858 # This test uses sys.hexversion instead of the string equivalent (first
 859 # word of sys.version), in order to cope with versions such as 2.2c1.
 860 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 861 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 862  [prog="import sys
 863 # split strings by '.' and convert to numeric.  Append some zeros
 864 # because we need at least 4 digits for the hex conversion.
 865 # map returns an iterator in Python 3.0 and a list in 2.x
 866 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 867 minverhex = 0
 868 maxverhex = 50331648 # = 3.0.0.0
 869 # xrange is not present in Python 3.0 and range returns an iterator
 870 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 871 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 872   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])