config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version $VERSION"
  11 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  12   lyx_devel_version=yes
  13   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 AC_SUBST(lyx_devel_version)])
  25
  26
  27 dnl Define the option to set a LyX version on installed executables and directories
  28 dnl
  29 dnl
  30 AC_DEFUN([LYX_VERSION_SUFFIX],[
  31 AC_MSG_CHECKING([for install target ... ])
  32 RPM_VERSION_SUFFIX='""'
  33 AC_ARG_WITH(version-suffix,
  34   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  35   [if test "x$withval" = "xyes";
  36    then
  37      withval="-$VERSION"
  38      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  39    fi
  40    lyxname="lyx$withval"
  41    program_suffix=$withval
  42    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"],
  43   [lyxname=lyx])
  44 AC_SUBST(RPM_VERSION_SUFFIX)
  45 AC_MSG_RESULT([$lyxname])
  46 ])
  47
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN([LYX_ERROR],[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN([LYX_WARNING],[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN([LYX_LIB_ERROR],[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN([LYX_CHECK_ERRORS],[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 EOF
  85 else
  86
  87 if test x$lyx_warning = xyes; then
  88 cat <<EOF
  89 === The following minor problems have been detected by configure.
  90 === Please check the messages below before running 'make'.
  91 === (see the section 'Problems' in the INSTALL file)
  92 $lyx_warning_txt
  93 EOF
  94 fi
  95 cat <<EOF
  96 Configuration of LyX was successful.
  97 Type 'make' to compile the program,
  98 and then 'make install' to install it.
  99 EOF
 100 fi])
 101
 102
 103 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 104 dnl
 105 define(LYX_SEARCH_PROG,[dnl
 106 for ac_prog in $2 ; do
 107 # Extract the first word of "$ac_prog", so it can be a program name with args.
 108   set dummy $ac_prog ; ac_word=$[2]
 109   if test -z "[$]$1"; then
 110     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 111     for ac_dir in $PATH; do
 112       test -z "$ac_dir" && ac_dir=.
 113       if test -f [$ac_dir/$ac_word]; then
 114         $1="$ac_prog"
 115         break
 116       fi
 117     done
 118     IFS="$ac_save_ifs"
 119   fi
 120
 121   if test -n "[$]$1"; then
 122     ac_result=yes
 123   else
 124     ac_result=no
 125   fi
 126   ifelse($3,,,[$3])
 127   test -n "[$]$1" && break
 128 done
 129 ])dnl
 130
 131
 132 AC_DEFUN([LYX_PROG_CXX_WORKS],
 133 [rm -f conftest.C
 134 cat >conftest.C <<EOF
 135 class foo {
 136    // we require the mutable keyword
 137    mutable int bar;
 138  };
 139  // we require namespace support
 140  namespace baz {
 141    int bar;
 142  }
 143  int main() {
 144    return(0);
 145  }
 146 EOF
 147 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 148 rm -f conftest.C conftest.o conftest.obj || true
 149 ])
 150
 151
 152 AC_DEFUN([LYX_PROG_CXX],
 153 [AC_MSG_CHECKING([for a good enough C++ compiler])
 154 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 155
 156 if test -z "$CXX" ; then
 157   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 158 fi
 159 AC_MSG_RESULT($CXX)
 160
 161 AC_PROG_CXX
 162
 163 ### We might want to get or shut warnings.
 164 AC_ARG_ENABLE(warnings,
 165   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 166   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 167         enable_warnings=yes;
 168     else
 169         enable_warnings=no;
 170     fi;])
 171 if test x$enable_warnings = xyes ; then
 172   lyx_flags="warnings $lyx_flags"
 173   AC_DEFINE(WITH_WARNINGS, 1,
 174   [Define this if you want to see the warning directives put here and
 175    there by the developpers to get attention])
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 181   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 182         enable_debug=yes;
 183     else
 184         enable_debug=no;
 185     fi;])
 186
 187 AC_ARG_ENABLE(stdlib-debug,
 188   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 189   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 190       enable_stdlib_debug=yes;
 191     else
 192       enable_stdlib_debug=no;
 193     fi;])
 194
 195 AC_ARG_ENABLE(concept-checks,
 196   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 197   [ if test $lyx_devel_version = yes -o $lyx-prerelease = yes ; then
 198         enable_concept_checks=yes;
 199     else
 200         enable_concept_checks=no;
 201     fi;])
 202
 203 ### set up optimization
 204 AC_ARG_ENABLE(optimization,
 205   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 206         enable_optimization=yes;)
 207 case $enable_optimization in
 208   yes) lyx_opt=-O;;
 209    no) lyx_opt=;;
 210     *) lyx_opt=${enable_optimization};;
 211 esac
 212
 213 AC_ARG_ENABLE(pch,
 214   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 215         enable_pch=yes;)
 216 lyx_pch_comp=no
 217
 218 # set the compiler options correctly.
 219 if test x$GXX = xyes; then
 220   dnl Useful for global version info
 221   gxx_version=`${CXX} -dumpversion`
 222   CXX_VERSION="($gxx_version)"
 223
 224   if test "$ac_test_CXXFLAGS" = set; then
 225     CXXFLAGS="$ac_save_CXXFLAGS"
 226   else
 227       CFLAGS="$lyx_opt"
 228       CXXFLAGS="$lyx_opt"
 229     if test x$enable_debug = xyes ; then
 230         CFLAGS="-g $CFLAGS"
 231         CXXFLAGS="-g $CXXFLAGS"
 232     fi
 233     if test x$enable_warnings = xyes ; then
 234         case $gxx_version in
 235             2.*|3.1*|3.2*|3.3*)
 236                 CPPFLAGS="-W -Wall $CPPFLAGS"
 237                 ;;
 238             *)
 239                 CPPFLAGS="-Wextra -Wall $CPPFLAGS "
 240                 ;;
 241         esac
 242     fi
 243   fi
 244   case $gxx_version in
 245       2.95.1)  AM_CXXFLAGS="-fpermissive -ftemplate-depth-30";;
 246       2.95.*)  AM_CXXFLAGS="-Wno-non-template-friend -ftemplate-depth-30";;
 247       2.96*)  AM_CXXFLAGS="-fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 248       3.1*)    AM_CXXFLAGS="-finline-limit=500 -fno-exceptions";;
 249       3.2*|3.3*)    AM_CXXFLAGS="-fno-exceptions";;
 250       3.4*|4.0*)
 251           AM_CXXFLAGS="-fno-exceptions"
 252           test $enable_pch = yes && lyx_pch_comp=yes
 253           ;;
 254       *)       AM_CXXFLAGS="";;
 255   esac
 256   if test x$enable_stdlib_debug = xyes ; then
 257     case $gxx_version in
 258       3.4*|4.0*)
 259         lyx_flags="stdlib-debug $lyx_flags"
 260         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 261         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 262         ;;
 263     esac
 264   fi
 265   if test x$enable_concept_checks = xyes ; then
 266     case $gxx_version in
 267       3.3*)
 268         lyx_flags="concept-checks $lyx_flags"
 269         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 270         ;;
 271       3.4*|4.0*)
 272         lyx_flags="concept-checks $lyx_flags"
 273         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 274         ;;
 275     esac
 276   fi
 277 fi
 278 test "$lyx_pch_comp" = yes && lyx_flags="pch $lyx_flags"
 279 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 280 ])dnl
 281
 282
 283 dnl NOT USED CURRENTLY*************************************
 284 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 285 dnl   supports RTTI
 286 AC_DEFUN([LYX_CXX_RTTI],[
 287 ### Check whether the compiler supports runtime type information
 288 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 289  [AC_TRY_RUN([
 290 class rtti {
 291 public:
 292    virtual int tag() { return 0; }
 293 };
 294 class derived1 : public rtti {
 295 public:
 296     int tag() { return 1; }
 297 };
 298 class derived2 : public rtti {
 299 public:
 300     int tag() { return 2; }
 301 };
 302 int main() {
 303     derived1 * foo1 = new derived1();
 304     derived2 * foo2 = new derived2();
 305     rtti * bar = foo1;
 306     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 307     if (bar1 == 0)
 308         exit(1);
 309     bar = foo2;
 310     bar1 = dynamic_cast<derived1 *>(bar);
 311     if (bar1 != 0)
 312         exit(1);
 313     return 0;
 314 }
 315 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 316 ])
 317 if test x$lyx_cv_rtti = xyes ; then
 318   AC_DEFINE(HAVE_RTTI, 1,
 319    [Define to 1 if your compiler supports runtime type information])
 320 fi])
 321
 322
 323 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 324 dnl   understands the "explicit" directive.
 325 AC_DEFUN([LYX_CXX_EXPLICIT],[
 326 ### Check whether the compiler understands the keyword `explicit'
 327 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 328  [AC_TRY_COMPILE([
 329 class Expl {
 330 public:
 331         explicit Expl() {}
 332 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 333 ])
 334 if test $lyx_cv_explicit = no ; then
 335   AC_DEFINE(explicit,[ ],
 336    [Define to nothing if your compiler does not understand the
 337    'explicit' directive])
 338 fi])
 339
 340
 341 dnl NOT USED CURRENTLY*************************************
 342 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 343 dnl   has a working stl stack template
 344 AC_DEFUN([LYX_CXX_STL_STACK],[
 345 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 346  [AC_TRY_COMPILE([
 347 #include <stack>
 348 using std::stack;
 349 ],[
 350     stack<int> stakk;
 351     stakk.push(0);
 352 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 353 ])
 354 if test $lyx_cv_broken_stack = yes ; then
 355   AC_DEFINE(BROKEN_STL_STACK, 1,
 356    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 357    correctly])
 358 fi])
 359
 360
 361 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 362 dnl    count template, if not the old HP version is assumed.
 363 AC_DEFUN([LYX_STD_COUNT],[
 364 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 365  [AC_TRY_COMPILE([
 366 #include <algorithm>
 367 using std::count;
 368 int countChar(char * b, char * e, char const c)
 369 {
 370         return count(b, e, c);
 371 }
 372 ],[
 373     char a[] = "hello";
 374     int i = countChar(a, a + 5, 'l');
 375 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 376 ])
 377 if test $lyx_cv_std_count = yes ; then
 378     AC_DEFINE(HAVE_STD_COUNT, 1,
 379     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 380 fi])
 381
 382
 383 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 384 dnl   supports modern STL streams
 385 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 386 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 387  [AC_TRY_COMPILE([
 388 #include <iostream>
 389 ],[
 390  std::streambuf * test = std::cerr.rdbuf();
 391  test->pubsync();
 392 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 393 ])
 394 if test $lyx_cv_modern_streams = yes ; then
 395   AC_DEFINE(MODERN_STL_STREAMS, 1,
 396    [Define if you have modern standard-compliant STL streams])
 397 fi])
 398
 399
 400 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 401 dnl        be used.
 402 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 403         AC_ARG_WITH(included-boost,
 404             [  --with-included-boost  use the boost lib supplied with LyX],
 405             [lyx_cv_with_included_boost=$withval
 406                 AC_MSG_RESULT([$with_included_boost])],
 407             [lyx_cv_with_included_boost=yes])
 408         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 409 ])
 410
 411
 412 dnl NOT USED CURRENTLY*************************************
 413 dnl LYX_CXX_PARTIAL
 414 AC_DEFUN([LYX_CXX_PARTIAL], [
 415     AC_REQUIRE([AC_PROG_CXX])
 416     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 417         [lyx_cv_cxx_partial_specialization],
 418         [AC_TRY_COMPILE(
 419             [
 420             template<class T, class K>
 421             class k {
 422             public:
 423             };
 424             template<class T> class k<void,T> { };
 425             ],[
 426             k<float, float> b;
 427             k<void,void> a;
 428             ],[
 429             lyx_cv_cxx_partial_specialization=yes
 430             ],[
 431             lyx_cv_cxx_partial_specialization=no
 432             ])
 433         ])
 434     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 435         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 436         [Defined if your compiler supports partial specialization.])
 437     fi
 438 ])
 439
 440
 441 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 442 dnl   are already in the global namespace
 443 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 444     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 445     lyx_cv_cxx_global_cstd,
 446     [AC_TRY_COMPILE([
 447     #include <cctype>
 448     using std::tolower;
 449     ],[
 450     return 0;
 451     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 452     if test x$lyx_cv_cxx_global_cstd = xyes; then
 453         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 454         [Define if your C++ compiler puts C library functions in the global namespace])
 455     fi
 456 ])
 457
 458
 459 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 460 dnl                       [default-yes-value])
 461 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 462 dnl  resulting directory name in 'dir-var-name'.
 463 AC_DEFUN([LYX_WITH_DIR],[
 464   AC_ARG_WITH($1,[  --with-$1        specify $2])
 465   AC_MSG_CHECKING([for $2])
 466   if test -z "$with_$3"; then
 467      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 468   else
 469     test "x$with_$3" = xyes && with_$3=$5
 470     lyx_cv_$3="$with_$3"
 471   fi
 472   AC_MSG_RESULT($lyx_cv_$3)])
 473
 474
 475 dnl Usage: LYX_LOOP_DIR(value,action)
 476 dnl Executes action for values of variable `dir' in `values'. `values' can
 477 dnl use ":" as a separator.
 478 AC_DEFUN([LYX_LOOP_DIR],[
 479 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 480 for dir in `eval "echo $1"`; do
 481   if test ! "$dir" = NONE; then
 482     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 483     $2
 484   fi
 485 done
 486 IFS=$ac_save_ifs
 487 ])
 488
 489
 490 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 491 dnl var-name.
 492 AC_DEFUN([LYX_ADD_LIB_DIR],[
 493 $1="${$1} -L$2"
 494 if test "`(uname) 2>/dev/null`" = SunOS &&
 495     uname -r | grep '^5' >/dev/null; then
 496   if test $ac_cv_prog_gxx = yes ; then
 497     $1="${$1} -Wl[,]-R$2"
 498   else
 499     $1="${$1} -R$2"
 500   fi
 501 fi])
 502
 503
 504 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 505 dnl var-name.
 506 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 507
 508 ### Check for a headers existence and location iff it exists
 509 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 510 ## It almost works.  I've tried a few variations but they give errors
 511 ## of one sort or other: bad substitution or file not found etc.  The
 512 ## actual header _is_ found though and the cache variable is set however
 513 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 514 ## reason.
 515 ## Additionally, autoheader can't figure out what to use as the name in
 516 ## the config.h.in file so we need to write our own entries there -- one for
 517 ## each header in the form PATH_HEADER_NAME_H
 518 ##
 519 AC_DEFUN([LYX_PATH_HEADER],
 520 [ AC_CHECK_HEADER($1,[
 521   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 522 ### the only remaining problem is getting the second parameter to this
 523 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 524 ### of $ac_safe being printed.
 525   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 526   [ cat > conftest.$ac_ext <<EOF
 527 #line __oline__ "configure"
 528 #include "confdefs.h"
 529
 530 #include <$1>
 531 EOF
 532 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 533   grep $1  2>/dev/null | \
 534   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 535 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 536 rm -f conftest*])
 537   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 538 ])
 539 ### end of LYX_PATH_HEADER
 540
 541 ### Check which frontends we want to use. The default is XForms only
 542 ###
 543 AC_DEFUN([LYX_USE_FRONTENDS],
 544 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 545 AC_ARG_WITH(frontend,
 546   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 547                             Possible values: xforms, qt, gtk(EXPERIMENTAL)],
 548   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 549 AC_MSG_RESULT($FRONTENDS)
 550 AC_SUBST(FRONTENDS)
 551 AC_SUBST(FRONTENDS_SUBDIRS)
 552 AC_SUBST(FRONTENDS_PROGS)
 553 ])
 554
 555
 556 ## Check what kind of packaging should be used at install time.
 557 ## The default is autodetected.
 558 AC_DEFUN([LYX_USE_PACKAGING],
 559 [AC_MSG_CHECKING([what packaging should be used])
 560 AC_ARG_WITH(packaging,
 561   [  --with-packaging=THIS   Use THIS packaging for installation:
 562                             Possible values: posix, windows, macosx],
 563   [lyx_use_packaging="$withval"], [
 564   case $host in
 565     *-apple-darwin*) lyx_use_packaging=macosx ;;
 566      *-pc-mingw32*) lyx_use_packaging=windows;;
 567                   *) lyx_use_packaging=posix;;
 568   esac])
 569 AC_MSG_RESULT($lyx_use_packaging)
 570 case $lyx_use_packaging in
 571    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 572            default_prefix="/Applications/LyX.app"
 573            bindir='${prefix}/Contents/MacOS'
 574            libdir='${prefix}/Contents/Resources'
 575            datadir='${prefix}/Contents/Resources'
 576            mandir='${prefix}/Contents/Resources/man' ;;
 577   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 578            default_prefix="C:/Program Files/LyX"
 579            bindir='${prefix}/bin'
 580            libdir='${prefix}/Resources'
 581            datadir='${prefix}/Resources'
 582            mandir='${prefix}/Resources/man' ;;
 583     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 584            default_prefix=$ac_default_prefix ;;
 585     *) LYX_ERROR([Unknown packaging type $lyx_use_packaging]) ;;
 586 esac
 587 ])
 588
 589
 590 ## ------------------------------------------------------------------------
 591 ## Find a file (or one of more files in a list of dirs)
 592 ## ------------------------------------------------------------------------
 593 ##
 594 AC_DEFUN([AC_FIND_FILE],
 595 [
 596 $3=NO
 597 for i in $2;
 598 do
 599   for j in $1;
 600   do
 601     if test -r "$i/$j"; then
 602       $3=$i
 603       break 2
 604     fi
 605   done
 606 done
 607 ])
 608
 609 dnl just a wrapper to clean up configure.in
 610 AC_DEFUN([LYX_PROG_LIBTOOL],
 611 [
 612 AC_REQUIRE([AC_ENABLE_SHARED])
 613 AC_REQUIRE([AC_ENABLE_STATIC])
 614 dnl libtool is only for C, so I must force him
 615 dnl to find the correct flags for C++
 616 ac_save_cc=$CC
 617 ac_save_cflags="$CFLAGS"
 618 CC=$CXX
 619 CFLAGS="$CXXFLAGS"
 620 AM_PROG_LIBTOOL dnl for libraries
 621 CC=$ac_save_cc
 622 CFLAGS="$ac_save_cflags"
 623 ])
 624
 625
 626 ## ------------------------------------------------------------------------
 627 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 628 ## one or two arguments.
 629 ##
 630 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 631 ## ------------------------------------------------------------------------
 632 ##
 633 AC_DEFUN([AC_FUNC_MKDIR],
 634 [AC_CHECK_FUNCS([mkdir _mkdir])
 635 AC_CACHE_CHECK([whether mkdir takes one argument],
 636                [ac_cv_mkdir_takes_one_arg],
 637 [AC_TRY_COMPILE([
 638 #include <sys/stat.h>
 639 #if HAVE_UNISTD_H
 640 #  include <unistd.h>
 641 #endif
 642 ], [mkdir (".");],
 643 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 644 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 645   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 646             [Define if mkdir takes only one argument.])
 647 fi
 648 ])