config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171
 172 dnl Usage: LYX_CXX_USE_REGEX(cxx11_flags)
 173 dnl decide whether we want to use std::regex and set the
 174 dnl LYX_USE_STD_REGEX accordingly.
 175 dnl the extra cxx11 flags have to be passed to the preprocessor. They are
 176 dnl not plainly added to AM_CPPFLAGS because then the objc compiler (mac)
 177 dnl would fail.
 178 AC_DEFUN([LYX_CXX_USE_REGEX],
 179 [lyx_std_regex=no
 180  if test $lyx_use_cxx11 = yes; then
 181    save_CPPFLAGS=$CPPFLAGS
 182    # we want to pass -std=c++11 to clang/cpp if necessary
 183    CPPFLAGS="$AM_CPPFLAGS $1 $CPPFLAGS"
 184    save_CXXFLAGS=$CXXFLAGS
 185    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 186    AC_LANG_PUSH(C++)
 187    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 188    AC_LANG_POP(C++)
 189    CXXFLAGS=$save_CXXFLAGS
 190    CPPFLAGS=$save_CPPFLAGS
 191    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 192      AC_MSG_CHECKING([for correct regex implementation])
 193      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 194        dnl <regex> in gcc is unusable in versions less than 4.9.0
 195        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 196        case $gxx_version in
 197          4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 198          *) ;;
 199        esac
 200      fi
 201    fi
 202    AC_MSG_RESULT([$lyx_std_regex])
 203  fi
 204
 205  if test $lyx_std_regex = yes ; then
 206   lyx_flags="$lyx_flags std-regex"
 207   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 208  fi
 209  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 210 ])
 211
 212
 213 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 214 AC_DEFUN([LYX_LIB_STDCXX],
 215 [AC_CACHE_CHECK([whether STL is libstdc++],
 216                [lyx_cv_lib_stdcxx],
 217 [AC_TRY_COMPILE([#include<vector>], [
 218 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 219             this is not libstdc++
 220 #endif
 221 ],
 222 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 223 ])
 224
 225
 226 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 227 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 228 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 229 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 230                [lyx_cv_lib_stdcxx_cxx11_abi],
 231 [AC_TRY_COMPILE([#include<vector>], [
 232 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 233             this is not libstdc++ using the C++11 ABI
 234 #endif
 235 ],
 236 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 237 ])
 238
 239
 240 AC_DEFUN([LYX_PROG_CXX],
 241 [AC_REQUIRE([AC_PROG_CXX])
 242 AC_REQUIRE([AC_PROG_CXXCPP])
 243
 244 AC_LANG_PUSH(C++)
 245 LYX_PROG_CLANG
 246 LYX_LIB_STDCXX
 247 LYX_LIB_STDCXX_CXX11_ABI
 248 AC_LANG_POP(C++)
 249
 250 if test $lyx_cv_lib_stdcxx = "yes" ; then
 251   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 252     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 253   else
 254     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 255   fi
 256 else
 257   if test $lyx_cv_prog_clang = "yes" ; then
 258     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 259   fi
 260 fi
 261
 262 ### We might want to get or shut warnings.
 263 AC_ARG_ENABLE(warnings,
 264   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 265   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 266         enable_warnings=yes;
 267     else
 268         enable_warnings=no;
 269     fi;])
 270 if test x$enable_warnings = xyes ; then
 271   lyx_flags="$lyx_flags warnings"
 272 fi
 273
 274 ### We might want to disable debug
 275 AC_ARG_ENABLE(debug,
 276   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 277   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 278 )
 279
 280 AC_ARG_ENABLE(stdlib-debug,
 281   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 282   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 283           [enable_stdlib_debug=no])]
 284 )
 285
 286 ### set up optimization
 287 AC_ARG_ENABLE(optimization,
 288     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 289     enable_optimization=yes;)
 290 case $enable_optimization in
 291     yes)
 292         if test $lyx_devel_version = yes ; then
 293             lyx_optim=-O
 294         else
 295             lyx_optim=-O2
 296         fi;;
 297     no) lyx_optim=;;
 298     *) lyx_optim=${enable_optimization};;
 299 esac
 300
 301 AC_ARG_ENABLE(cxx11,
 302   AC_HELP_STRING([--disable-cxx11],[disable C++11 mode (default: enabled for known good compilers)]),,
 303   enable_cxx11=auto;)
 304
 305 AC_ARG_ENABLE(assertions,
 306   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 307   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 308           [enable_assertions=no])]
 309 )
 310 if test "x$enable_assertions" = xyes ; then
 311    lyx_flags="$lyx_flags assertions"
 312    AC_DEFINE(ENABLE_ASSERTIONS,1,
 313     [Define if you want assertions to be enabled in the code])
 314 fi
 315
 316 # set the compiler options correctly.
 317 if test x$GXX = xyes; then
 318   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 319   if test x$CLANG = xno; then
 320     dnl Useful for global version info
 321     gxx_version=`${CXX} -dumpversion`
 322     CXX_VERSION="($gxx_version)"
 323   else
 324     gxx_version=clang
 325   fi
 326
 327   AM_CXXFLAGS="$lyx_optim"
 328   if test x$enable_debug = xyes ; then
 329       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 330   fi
 331   if test $build_type = gprof ; then
 332     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 333     AM_LDFLAGS="$AM_LDFLAGS -pg"
 334   fi
 335   if test $build_type = profiling ; then
 336     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 337   fi
 338
 339   if test x$USE_QT5 = xyes ; then
 340       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 341   fi
 342   dnl Warnings are for preprocessor too
 343   if test x$enable_warnings = xyes ; then
 344       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 345   fi
 346   case $gxx_version in
 347       2.*|3.*) AC_ERROR([gcc >= 4.3 is required]);;
 348       4.0*|4.1*|4.2*) AC_ERROR([gcc >= 4.3 is required]);;
 349   esac
 350   if test x$enable_stdlib_debug = xyes ; then
 351     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 352     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 353     case $gxx_version in
 354       *)
 355         lyx_flags="$lyx_flags stdlib-debug"
 356         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 357         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 358         ;;
 359     esac
 360   fi
 361   dnl enable_cxx11 can be yes/no/auto.
 362   dnl By default, it is auto and we enable C++11 when possible
 363   if test x$enable_cxx11 != xno ; then
 364     case $gxx_version in
 365       4.3*|4.4*|4.5*|4.6*)
 366         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 367         dnl The source code relies on that.
 368         cxx11_flags="-std=c++0x";;
 369       clang)
 370         dnl presumably all clang versions support c++11.
 371         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 372         cxx11_flags="-std=c++11"
 373         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 374       *)
 375         AS_CASE([$host], [*cygwin*],
 376                 [cxx11_flags="-std=gnu++11"],
 377                 [cxx11_flags="-std=c++11"]);;
 378     esac
 379     # cxx11_flags is useful when running preprocessor alone
 380     # (see detection of regex).
 381     AM_CXXFLAGS="$cxx11_flags $AM_CXXFLAGS"
 382   fi
 383 fi
 384
 385 LYX_CXX_CXX11
 386 if test $lyx_use_cxx11 = yes; then
 387   if test x$GXX = xyes; then
 388     dnl We still use auto_ptr, which is obsoleted. Shut off the warnings.
 389     AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-declarations"
 390   fi
 391 fi
 392 LYX_CXX_USE_REGEX([$cxx11_flags])
 393 ])
 394
 395 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 396 dnl        be used.
 397 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 398         AC_MSG_CHECKING([whether to use included boost library])
 399         AC_ARG_WITH(included-boost,
 400             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 401             [lyx_cv_with_included_boost=$withval],
 402             [lyx_cv_with_included_boost=yes])
 403         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 404         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 405         if test x$lyx_cv_with_included_boost = xyes ; then
 406             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 407             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 408         else
 409             AC_LANG_PUSH(C++)
 410             save_LIBS=$LIBS
 411
 412             AC_MSG_CHECKING([for multithreaded boost libraries])
 413             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 414             AC_LINK_IFELSE(
 415                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 416                         [boost::signal<void ()> s;])],
 417                 [AC_MSG_RESULT([yes])
 418                  BOOST_MT="-mt"],
 419                 [AC_MSG_RESULT([no])
 420                  AC_MSG_CHECKING([for plain boost libraries])
 421                  LIBS="$save_LIBS -lboost_signals"
 422                  AC_LINK_IFELSE(
 423                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 424                              [boost::signal<void ()> s;])],
 425                      [AC_MSG_RESULT([yes])
 426                       BOOST_MT=""],
 427                      [AC_MSG_RESULT([no])
 428                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 429                  ])
 430             ])
 431             LIBS=$save_LIBS
 432             AC_LANG_POP(C++)
 433             BOOST_INCLUDES=
 434             if test $lyx_std_regex = yes ; then
 435               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 436             else
 437               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 438             fi
 439
 440             dnl In general, system boost libraries are incompatible with
 441             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 442             dnl details.
 443             if test $enable_stdlib_debug = "yes" ; then
 444                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 445    crashes. Consider using --disable-stdlib-debug or removing
 446    --without-included-boost.])
 447             fi
 448         fi
 449         AC_SUBST(BOOST_INCLUDES)
 450         AC_SUBST(BOOST_LIBS)
 451 ])
 452
 453
 454 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 455 dnl        be used.
 456 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 457   AC_MSG_CHECKING([whether to use included iconv library])
 458   AC_ARG_WITH(included-iconv,
 459     [AC_HELP_STRING([--without-included-iconv], [do not use the iconv lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 460     [lyx_cv_with_included_iconv=$withval],
 461     [lyx_cv_with_included_iconv=no])
 462   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 463   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 464   if test x$lyx_cv_with_included_iconv = xyes ; then
 465 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 466     AC_EILSEQ
 467     AC_TYPE_MBSTATE_T
 468     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 469 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.14/lib/loop_wchar.h.
 470     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 471       USE_MBSTATE_T=1
 472     else
 473       USE_MBSTATE_T=0
 474     fi
 475     AC_SUBST([USE_MBSTATE_T])
 476     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 477       [gl_cv_header_wchar_h_standalone],
 478       [AC_COMPILE_IFELSE(
 479         [AC_LANG_PROGRAM(
 480           [[#include <wchar.h>
 481             wchar_t w;]],
 482           [[]])],
 483         [gl_cv_header_wchar_h_standalone=yes],
 484         [gl_cv_header_wchar_h_standalone=no])])
 485     if test $gl_cv_header_wchar_h_standalone = yes; then
 486       BROKEN_WCHAR_H=0
 487     else
 488       BROKEN_WCHAR_H=1
 489     fi
 490     AC_SUBST([BROKEN_WCHAR_H])
 491 dnl we want const correctness
 492     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 493       [Define as const if the declaration of iconv() needs const.])
 494     ICONV_CONST=const
 495     AC_SUBST([ICONV_CONST])
 496 dnl we build a static lib
 497     DLL_VARIABLE=
 498     AC_SUBST([DLL_VARIABLE])
 499     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.14 -I$(top_builddir)/3rdparty/libiconv'
 500     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 501     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.14/include/iconv.h.in
 502   else
 503     ICONV_INCLUDES=
 504     AM_ICONV
 505     if test "$am_cv_func_iconv" = no; then
 506       AC_MSG_ERROR([cannot find required library iconv.])
 507     else
 508       ICONV_LIBS="$LIBICONV"
 509     fi
 510     ICONV_ICONV_H_IN=
 511   fi
 512   AC_SUBST(ICONV_INCLUDES)
 513   AC_SUBST(ICONV_LIBS)
 514   AC_SUBST(ICONV_ICONV_H_IN)
 515 ])
 516
 517
 518 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 519 dnl        be used.
 520 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 521   AC_MSG_CHECKING([whether to use included zlib library])
 522   AC_ARG_WITH(included-zlib,
 523     [AC_HELP_STRING([--without-included-zlib], [do not use the zlib lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 524     [lyx_cv_with_included_zlib=$withval],
 525     [lyx_cv_with_included_zlib=no])
 526   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 527   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 528   if test x$lyx_cv_with_included_zlib = xyes ; then
 529     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 530     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 531     mkdir -p 3rdparty/zlib
 532 dnl include standard config.h for HAVE_UNISTD_H
 533     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 534 dnl prevent clash with system zlib that might be dragged in by other libs
 535     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 536     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 537   else
 538     ZLIB_INCLUDES=
 539     AC_CHECK_HEADERS(zlib.h,
 540       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 541       [LYX_LIB_ERROR(zlib.h,zlib)])
 542   fi
 543   AC_SUBST(ZLIB_INCLUDES)
 544   AC_SUBST(ZLIB_LIBS)
 545 ])
 546
 547
 548 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 549 dnl        necessary APIs are available to print callstacks.
 550 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 551 [AC_CACHE_CHECK([whether printing callstack is possible],
 552                [lyx_cv_callstack_printing],
 553 [AC_TRY_COMPILE([
 554 #include <execinfo.h>
 555 #include <cxxabi.h>
 556 ], [
 557         void* array[200];
 558         size_t size = backtrace(array, 200);
 559         backtrace_symbols(array, size);
 560         int status = 0;
 561         abi::__cxa_demangle("abcd", 0, 0, &status);
 562 ],
 563 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 564 if test x"$lyx_cv_callstack_printing" = xyes; then
 565   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 566             [Define if callstack can be printed])
 567 fi
 568 ])
 569
 570
 571 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 572 dnl        be used.
 573 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 574         AC_MSG_CHECKING([whether to use included MyThes library])
 575         AC_ARG_WITH(included-mythes,
 576             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 577             [lyx_cv_with_included_mythes=$withval],
 578             [lyx_cv_with_included_mythes=yes])
 579         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 580         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 581         if test x$lyx_cv_with_included_mythes != xyes ; then
 582                 AC_LANG_PUSH(C++)
 583                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 584                 if test x$ac_cv_header_mythes_h != xyes; then
 585                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 586                 fi
 587                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 588                 if test x$lyx_mythes != xyes; then
 589                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 590                 fi
 591                 AC_LANG_POP(C++)
 592                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 593                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 594                 fi
 595                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 596                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 597                 AC_SUBST(MYTHES_LIBS)
 598         fi
 599 ])
 600
 601
 602 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 603 dnl                       [default-yes-value])
 604 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 605 dnl  resulting directory name in 'dir-var-name'.
 606 AC_DEFUN([LYX_WITH_DIR],[
 607   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 608   AC_MSG_CHECKING([for $2])
 609   if test -z "$with_$3"; then
 610      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 611   else
 612     test "x$with_$3" = xyes && with_$3=$5
 613     lyx_cv_$3="$with_$3"
 614   fi
 615   AC_MSG_RESULT($lyx_cv_$3)])
 616
 617
 618 dnl Usage: LYX_LOOP_DIR(value,action)
 619 dnl Executes action for values of variable `dir' in `values'. `values' can
 620 dnl use ":" as a separator.
 621 AC_DEFUN([LYX_LOOP_DIR],[
 622 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 623 for dir in `eval "echo $1"`; do
 624   if test ! "$dir" = NONE; then
 625     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 626     $2
 627   fi
 628 done
 629 IFS=$ac_save_ifs
 630 ])
 631
 632
 633 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 634 dnl var-name.
 635 AC_DEFUN([LYX_ADD_LIB_DIR],[
 636 $1="${$1} -L$2"
 637 if test "`(uname) 2>/dev/null`" = SunOS &&
 638     uname -r | grep '^5' >/dev/null; then
 639   if test $ac_cv_prog_gxx = yes ; then
 640     $1="${$1} -Wl[,]-R$2"
 641   else
 642     $1="${$1} -R$2"
 643   fi
 644 fi])
 645
 646
 647 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 648 dnl var-name.
 649 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 650
 651 ### Check for a headers existence and location iff it exists
 652 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 653 ## It almost works.  I've tried a few variations but they give errors
 654 ## of one sort or other: bad substitution or file not found etc.  The
 655 ## actual header _is_ found though and the cache variable is set however
 656 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 657 ## reason.
 658 ## Additionally, autoheader can't figure out what to use as the name in
 659 ## the config.h.in file so we need to write our own entries there -- one for
 660 ## each header in the form PATH_HEADER_NAME_H
 661 ##
 662 AC_DEFUN([LYX_PATH_HEADER],
 663 [ AC_CHECK_HEADER($1,[
 664   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 665 ### the only remaining problem is getting the second parameter to this
 666 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 667 ### of $ac_safe being printed.
 668   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 669   [ cat > conftest.$ac_ext <<EOF
 670 #line __oline__ "configure"
 671 #include "confdefs.h"
 672
 673 #include <$1>
 674 EOF
 675 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 676   grep $1  2>/dev/null | \
 677   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 678 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 679 rm -f conftest*])
 680   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 681 ])
 682 ### end of LYX_PATH_HEADER
 683
 684 ## Check what kind of packaging should be used at install time.
 685 ## The default is autodetected.
 686 AC_DEFUN([LYX_USE_PACKAGING],
 687 [AC_MSG_CHECKING([what packaging should be used])
 688 AC_ARG_WITH(packaging,
 689   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 690                             Possible values: posix, windows, macosx, haiku])],
 691   [lyx_use_packaging="$withval"], [
 692   case $host in
 693     *-apple-darwin*) lyx_use_packaging=macosx ;;
 694     *-pc-mingw*) lyx_use_packaging=windows ;;
 695     *-mingw32*) lyx_use_packaging=windows ;;
 696     *haiku*) lyx_use_packaging=haiku ;;
 697     *) lyx_use_packaging=posix ;;
 698   esac])
 699 AC_MSG_RESULT($lyx_use_packaging)
 700 lyx_install_posix=false
 701 lyx_install_macosx=false
 702 lyx_install_cygwin=false
 703 lyx_install_windows=false
 704 case $lyx_use_packaging in
 705    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 706            PACKAGE=LyX${version_suffix}
 707            default_prefix="/Applications/${PACKAGE}.app"
 708            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 709            bindir='${prefix}/Contents/MacOS'
 710            libdir='${prefix}/Contents/Resources'
 711            datarootdir='${prefix}/Contents/Resources'
 712            pkgdatadir='${datadir}'
 713            mandir='${datadir}/man'
 714            lyx_install_macosx=true ;;
 715   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 716            PACKAGE=LyX${version_suffix}
 717            default_prefix="C:/Program Files/${PACKAGE}"
 718            bindir='${prefix}/bin'
 719            libdir='${prefix}/Resources'
 720            datarootdir='${prefix}/Resources'
 721            pkgdatadir='${datadir}'
 722            mandir='${prefix}/Resources/man'
 723            lyx_install_windows=true ;;
 724     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 725            PACKAGE=lyx${version_suffix}
 726            program_suffix=$version_suffix
 727            pkgdatadir='${datadir}/${PACKAGE}'
 728            default_prefix=$ac_default_prefix
 729            case ${host} in
 730              *cygwin*) lyx_install_cygwin=true ;;
 731              *apple-darwin*) lyx_install_macosx=true ;;
 732            esac
 733            lyx_install_posix=true ;;
 734         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 735            PACKAGE=lyx${version_suffix}
 736            program_suffix=$version_suffix
 737            pkgdatadir='${datadir}/${PACKAGE}'
 738            default_prefix=$ac_default_prefix
 739            lyx_install_posix=true ;;
 740     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 741 esac
 742 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 743 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 744 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 745 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 746 AC_SUBST(pkgdatadir)
 747 AC_SUBST(program_suffix)
 748 ])
 749
 750
 751 ## ------------------------------------------------------------------------
 752 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 753 ## one or two arguments.
 754 ##
 755 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 756 ## ------------------------------------------------------------------------
 757 ##
 758 AC_DEFUN([AC_FUNC_MKDIR],
 759 [AC_CHECK_FUNCS([mkdir _mkdir])
 760 AC_CACHE_CHECK([whether mkdir takes one argument],
 761                [ac_cv_mkdir_takes_one_arg],
 762 [AC_TRY_COMPILE([
 763 #include <sys/stat.h>
 764 #if HAVE_UNISTD_H
 765 #  include <unistd.h>
 766 #endif
 767 ], [mkdir (".");],
 768 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 769 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 770   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 771             [Define if mkdir takes only one argument.])
 772 fi
 773 ])
 774
 775
 776 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 777 dnl (which may be a relative path, and need not refer to any existing
 778 dnl entity).
 779
 780 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 781 dnl native Win32 path name, (but with slashes, not backslashes).
 782
 783 dnl On any other system, it is simply the result which would be obtained
 784 dnl if PATHNAME represented an existing directory, and the pwd command was
 785 dnl executed in that directory.
 786 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 787 [ac_dir="$2"
 788  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 789     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 790  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 791  do
 792    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 793  done
 794  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 795  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 796  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 797    s?/*$[]??'`
 798 ])
 799
 800 dnl this is used by the macro blow to general a proper config.h.in entry
 801 m4_define([LYX_AH_CHECK_DECL],
 802 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 803   [Define if you have the prototype for function `$1'])])
 804
 805 dnl Check things are declared in headers to avoid errors or warnings.
 806 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 807 dnl Defines HAVE_DECL_{FUNCTION}
 808 AC_DEFUN([LYX_CHECK_DECL],
 809 [LYX_AH_CHECK_DECL($1)
 810 for ac_header in $2
 811 do
 812   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 813   AC_EGREP_HEADER($1, $ac_header,
 814       [AC_MSG_RESULT(yes)
 815        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 816        break],
 817       [AC_MSG_RESULT(no)])
 818 done])
 819
 820 dnl this is used by the macro below to generate a proper config.h.in entry
 821 m4_define([LYX_AH_CHECK_DEF],
 822 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 823   [Define to 1 if `$1' is defined in `$2'])])
 824
 825 dnl Check whether name is defined in header by using it in codesnippet.
 826 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 827 dnl Defines HAVE_DEF_{NAME}
 828 AC_DEFUN([LYX_CHECK_DEF],
 829 [LYX_AH_CHECK_DEF($1, $2)
 830  AC_MSG_CHECKING([whether $1 is defined by header $2])
 831  AC_TRY_COMPILE([#include <$2>], [$3],
 832      lyx_have_def_name=yes,
 833      lyx_have_def_name=no)
 834  AC_MSG_RESULT($lyx_have_def_name)
 835  if test "x$lyx_have_def_name" = xyes; then
 836    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 837  fi
 838 ])
 839
 840 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 841 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 842 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 843 AC_DEFUN([LYX_SET_VERSION_INFO],
 844 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 845  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 846  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 847  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 848  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 849  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 850  test "x$lyx_patch" = "x" && lyx_patch=0
 851  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 852  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 853  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 854  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 855  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 856  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 857  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 858  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 859 ])
 860
 861 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 862 # ---------------------------------------------------------------------------
 863 # Copied from autoconf 2.68, added a check that python version is < 3.0
 864 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 865 # Run ACTION-IF-FALSE otherwise.
 866 # This test uses sys.hexversion instead of the string equivalent (first
 867 # word of sys.version), in order to cope with versions such as 2.2c1.
 868 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 869 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 870  [prog="import sys
 871 # split strings by '.' and convert to numeric.  Append some zeros
 872 # because we need at least 4 digits for the hex conversion.
 873 # map returns an iterator in Python 3.0 and a list in 2.x
 874 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 875 minverhex = 0
 876 maxverhex = 50331648 # = 3.0.0.0
 877 # xrange is not present in Python 3.0 and range returns an iterator
 878 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 879 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 880   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])