config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN(LYX_CHECK_VERSION,[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN(LYX_VERSION_SUFFIX,[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN(LYX_ERROR,[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN(LYX_WARNING,[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN(LYX_LIB_ERROR,[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN(LYX_CHECK_ERRORS,[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 deleting cache $cache_file
  85 EOF
  86   rm -f $cache_file
  87 else
  88
  89 if test x$lyx_warning = xyes; then
  90 cat <<EOF
  91 === The following minor problems have been detected by configure.
  92 === Please check the messages below before running 'make'.
  93 === (see the section 'Problems' in the INSTALL file)
  94 $lyx_warning_txt
  95 EOF
  96 fi
  97 cat <<EOF
  98 Configuration of LyX was successful.
  99 Type 'make' to compile the program,
 100 and then 'make install' to install it.
 101 EOF
 102 fi])
 103
 104
 105 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 106 dnl
 107 define(LYX_SEARCH_PROG,[dnl
 108 for ac_prog in $2 ; do
 109 # Extract the first word of "$ac_prog", so it can be a program name with args.
 110   set dummy $ac_prog ; ac_word=$[2]
 111   if test -z "[$]$1"; then
 112     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 113     for ac_dir in $PATH; do
 114       test -z "$ac_dir" && ac_dir=.
 115       if test -f [$ac_dir/$ac_word]; then
 116         $1="$ac_prog"
 117         break
 118       fi
 119     done
 120     IFS="$ac_save_ifs"
 121   fi
 122
 123   if test -n "[$]$1"; then
 124     ac_result=yes
 125   else
 126     ac_result=no
 127   fi
 128   ifelse($3,,,[$3])
 129   test -n "[$]$1" && break
 130 done
 131 ])dnl
 132
 133
 134 AC_DEFUN([LYX_PROG_CXX_WORKS],
 135 [rm -f conftest.C
 136 cat >conftest.C <<EOF
 137 class foo {
 138    // we require the mutable keyword
 139    mutable int bar;
 140  };
 141  // we require namespace support
 142  namespace baz {
 143    int bar;
 144  }
 145  int main() {
 146    return(0);
 147  }
 148 EOF
 149 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 150 rm -f conftest.C conftest.o conftest.obj || true
 151 ])
 152
 153
 154 AC_DEFUN(LYX_PROG_CXX,
 155 [AC_MSG_CHECKING([for a good enough C++ compiler])
 156 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 157
 158 if test -z "$CXX" ; then
 159   AC_ERROR([Unable to find a good enough C++ compiler])
 160 fi
 161 AC_MSG_RESULT($CXX)
 162
 163 AC_PROG_CXX
 164
 165 ### We might want to get or shut warnings.
 166 AC_ARG_ENABLE(warnings,
 167   [  --enable-warnings       tell the compiler to display more warnings],,
 168   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 169         enable_warnings=yes;
 170     else
 171         enable_warnings=no;
 172     fi;])
 173 if test x$enable_warnings = xyes ; then
 174   lyx_flags="$lyx_flags warnings"
 175   AC_DEFINE(WITH_WARNINGS, 1,
 176   [Define this if you want to see the warning directives put here and
 177    there by the developpers to get attention])
 178 fi
 179
 180 ### We might want to disable debug
 181 AC_ARG_ENABLE(debug,
 182   [  --enable-debug          enable debug information],,
 183   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 184         enable_debug=yes;
 185     else
 186         enable_debug=no;
 187     fi;])
 188
 189 ### set up optimization
 190 AC_ARG_ENABLE(optimization,
 191   [  --enable-optimization[=value]   enable compiler optimisation],,
 192         enable_optimization=yes;)
 193 case $enable_optimization in
 194   yes) lyx_opt=-O;;
 195    no) lyx_opt=;;
 196     *) lyx_opt=${enable_optimization};;
 197 esac
 198
 199 # set the debug flags correctly.
 200 if test x$GXX = xyes; then
 201   dnl Useful for global version info
 202   gxx_version=`${CXX} -dumpversion`
 203   CXX_VERSION="($gxx_version)"
 204
 205   if test "$ac_test_CXXFLAGS" = set; then
 206     CXXFLAGS="$ac_save_CXXFLAGS"
 207   else
 208     case $gxx_version in
 209       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive";;
 210       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend";;
 211       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -Wno-non-template-friend";;
 212       3.0*)    CXXFLAGS="$lyx_opt";;
 213       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 214       3.2*)    CXXFLAGS="$lyx_opt";;
 215       *)       CXXFLAGS="$lyx_opt";;
 216     esac
 217     if test x$enable_debug = xyes ; then
 218         CXXFLAGS="-g $CXXFLAGS"
 219     fi
 220   fi
 221   if test x$enable_warnings = xyes ; then
 222     case $gxx_version in
 223         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 224         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 225         3.1*)  CXXFLAGS="$CXXFLAGS -W -Wall -Winline";;
 226         *)      CXXFLAGS="$CXXFLAGS -W -Wall";;
 227     esac
 228     if test $lyx_devel_version = yes ; then
 229       case $gxx_version in
 230           2.95.*) ;;
 231           2.96*) ;;
 232           *) CXXFLAGS="$CXXFLAGS -Winline";;
 233       esac
 234     fi
 235   fi
 236 fi])dnl
 237
 238
 239 dnl NOT USED CURRENTLY*************************************
 240 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 241 dnl   supports RTTI
 242 AC_DEFUN(LYX_CXX_RTTI,[
 243 ### Check whether the compiler supports runtime type information
 244 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 245  [AC_TRY_RUN([
 246 class rtti {
 247 public:
 248    virtual int tag() { return 0; }
 249 };
 250 class derived1 : public rtti {
 251 public:
 252     int tag() { return 1; }
 253 };
 254 class derived2 : public rtti {
 255 public:
 256     int tag() { return 2; }
 257 };
 258 int main() {
 259     derived1 * foo1 = new derived1();
 260     derived2 * foo2 = new derived2();
 261     rtti * bar = foo1;
 262     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 263     if (bar1 == 0)
 264         exit(1);
 265     bar = foo2;
 266     bar1 = dynamic_cast<derived1 *>(bar);
 267     if (bar1 != 0)
 268         exit(1);
 269     return 0;
 270 }
 271 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 272 ])
 273 if test x$lyx_cv_rtti = xyes ; then
 274   AC_DEFINE(HAVE_RTTI, 1,
 275    [Define to 1 if your compiler supports runtime type information])
 276 fi])
 277
 278
 279 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 280 dnl   understands the "explicit" directive.
 281 AC_DEFUN(LYX_CXX_EXPLICIT,[
 282 ### Check whether the compiler understands the keyword `explicit'
 283 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 284  [AC_TRY_COMPILE([
 285 class Expl {
 286 public:
 287         explicit Expl() {};
 288 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 289 ])
 290 if test $lyx_cv_explicit = no ; then
 291   AC_DEFINE(explicit,[ ],
 292    [Define to nothing if your compiler does not understand the
 293    'explicit' directive])
 294 fi])
 295
 296
 297 dnl NOT USED CURRENTLY*************************************
 298 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 299 dnl   has a working stl stack template
 300 AC_DEFUN(LYX_CXX_STL_STACK,[
 301 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 302  [AC_TRY_COMPILE([
 303 #include <stack>
 304 using std::stack;
 305 ],[
 306     stack<int> stakk;
 307     stakk.push(0);
 308 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 309 ])
 310 if test $lyx_cv_broken_stack = yes ; then
 311   AC_DEFINE(BROKEN_STL_STACK, 1,
 312    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 313    correctly])
 314 fi])
 315
 316
 317 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 318 dnl    count template, if not the old HP version is assumed.
 319 AC_DEFUN(LYX_STD_COUNT,[
 320 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 321  [AC_TRY_COMPILE([
 322 #include <algorithm>
 323 using std::count;
 324 int countChar(char * b, char * e, char const c)
 325 {
 326         return count(b, e, c);
 327 }
 328 ],[
 329     char a[] = "hello";
 330     int i = countChar(a, a + 5, 'l');
 331 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 332 ])
 333 if test $lyx_cv_std_count = yes ; then
 334     AC_DEFINE(HAVE_STD_COUNT, 1,
 335     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 336 fi])
 337
 338
 339 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 340 dnl   supports modern STL streams
 341 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 342 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 343  [AC_TRY_COMPILE([
 344 #include <iostream>
 345 ],[
 346  std::streambuf * test = std::cerr.rdbuf();
 347  test->pubsync();
 348 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 349 ])
 350 if test $lyx_cv_modern_streams = yes ; then
 351   AC_DEFINE(MODERN_STL_STREAMS, 1,
 352    [Define if you have modern standard-compliant STL streams])
 353 fi])
 354
 355
 356 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 357 dnl   has a std::string that is usable for LyX. LyX does not require this
 358 dnl   std::string to be standard.
 359 AC_DEFUN(LYX_CXX_STL_STRING,[
 360     AC_REQUIRE([AC_PROG_CXX])
 361     AC_MSG_CHECKING(whether the included std::string should be used)
 362     AC_ARG_WITH(included-string,
 363        [  --with-included-string  use LyX string class instead of STL string],
 364        [lyx_cv_with_included_string=$withval
 365         AC_MSG_RESULT([$with_included_string])],
 366        [AC_CACHE_CHECK([],lyx_cv_with_included_string,
 367         [AC_TRY_COMPILE([
 368             #include <string>
 369             using std::string;
 370         ],[
 371             // LyX has reduced its requirements on the basic_string
 372             // implementation so that the basic_string supplied
 373             // with gcc is usable. In particular this means that
 374             // lyx does not use std::string::clear and not the
 375             // strncmp version of std::string::compare. This is mainly
 376             // done so that LyX can use precompiled C++ libraries that
 377             // already uses the systems basic_string, e.g. gtk--
 378             string a("hello there");
 379             a.erase();
 380             a = "hey";
 381             //char s[] = "y";
 382             //int t = a.compare(a.length() - 1, 1, s);
 383             a.erase();
 384         ],[
 385             lyx_cv_with_included_string=no
 386         ],[
 387             lyx_cv_with_included_string=yes
 388         ])
 389         ])
 390     ])
 391     if test x$lyx_cv_with_included_string = xyes ; then
 392         AC_DEFINE(USE_INCLUDED_STRING, 1,
 393             [Define to use the lyxstring class bundled with LyX.])
 394             lyx_flags="$lyx_flags included-string"
 395     fi
 396     AM_CONDITIONAL(USE_LYXSTRING, test x$lyx_cv_with_included_string = xyes)
 397 dnl    AC_MSG_RESULT([$with_included_string])
 398 ])
 399
 400
 401 dnl Usage: LYX_CXX_GOOD_STD_STRING : checks whether the C++ compiler
 402 dnl   has a std::string that is close to the standard. So close that
 403 dnl   methods not found in "unstandard" std::strings are present here.
 404 AC_DEFUN(LYX_CXX_GOOD_STD_STRING,[
 405     AC_REQUIRE([AC_PROG_CXX])
 406     AC_CACHE_CHECK([whether the systems std::string is really good],
 407     [lyx_cv_std_string_good],
 408     [AC_TRY_COMPILE([
 409             #include <string>
 410             using std::string;
 411         ],[
 412             // From a std::string that is supposed to be close to the
 413             // standard we require at least three things:
 414             // - clear() and erase()
 415             // - the strncmp of compare()
 416             // - push_back()
 417             string a("hello there");
 418             a.erase();
 419             a = "hey";
 420             char s[] = "y";
 421             int t = a.compare(a.length() - 1, 1, s);
 422             a.push_back('g');
 423             a.clear();
 424         ],[
 425             lyx_cv_std_string_good=yes
 426         ],[
 427             lyx_cv_std_string_good=no
 428
 429         ])
 430     ])
 431     if test x$lyx_cv_std_string_good = xyes ; then
 432         AC_DEFINE(STD_STRING_IS_GOOD, 1,
 433             [Define if the systems std::string is really good.])
 434     fi
 435 ])
 436
 437
 438 dnl NOT USED CURRENTLY*************************************
 439 dnl LYX_CXX_PARTIAL
 440 AC_DEFUN(LYX_CXX_PARTIAL, [
 441     AC_REQUIRE([AC_PROG_CXX])
 442     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 443         [lyx_cv_cxx_partial_specialization],
 444         [AC_TRY_COMPILE(
 445             [
 446             template<class T, class K>
 447             class k {
 448             public:
 449             };
 450             template<class T> class k<void,T> { };
 451             ],[
 452             k<float, float> b;
 453             k<void,void> a;
 454             ],[
 455             lyx_cv_cxx_partial_specialization=yes
 456             ],[
 457             lyx_cv_cxx_partial_specialization=no
 458             ])
 459         ])
 460     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 461         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 462         [Defined if your compiler supports partial specialization.])
 463     fi
 464 ])
 465
 466
 467 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 468 dnl   provides wrappers for C headers and use our alternate version otherwise.
 469 AC_DEFUN(LYX_CXX_CHEADERS,[
 470 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 471  [AC_TRY_CPP([
 472 #include <clocale>
 473 #include <cctype>
 474 #include <cerrno>
 475 #include <cmath>
 476 #include <csignal>
 477 #include <cstdio>
 478 #include <cstdlib>
 479 #include <cstring>
 480 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 481 if test $lyx_cv_cxx_cheaders = no ; then
 482   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 483 fi])
 484
 485 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 486 dnl   are already in the global namespace
 487 AC_DEFUN(LYX_CXX_GLOBAL_CSTD,[
 488     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 489     lyx_cv_cxx_global_cstd,
 490     [AC_TRY_COMPILE([
 491     #include <cctype>
 492     using std::tolower;
 493     ],[
 494     return 0;
 495     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 496     if test x$lyx_cv_cxx_global_cstd = xyes; then
 497         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 498         [Define if your C++ compiler puts C library functions in the global namespace])
 499     fi
 500 ])
 501
 502 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 503 AC_DEFUN(LYX_PATH_XPM,[
 504 ### Check for Xpm library
 505 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage,XPM_LIB="-lXpm",
 506         [LYX_LIB_ERROR(libXpm,Xpm)], $XPM_LIB)
 507 AC_SUBST(XPM_LIB)
 508 ### Check for Xpm headers
 509 lyx_cv_xpm_h_location="<xpm.h>"
 510 AC_CHECK_HEADER(X11/xpm.h,[
 511   ac_cv_header_xpm_h=yes
 512   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 513 AC_CHECK_HEADER(xpm.h,[],[
 514 LYX_LIB_ERROR(xpm.h,Xpm)])])
 515 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location)
 516
 517 ### Test for the header version
 518 if test $ac_cv_header_xpm_h = yes; then
 519   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 520   [ cat > conftest.$ac_ext <<EOF
 521 #line __oline__ "configure"
 522 #include "confdefs.h"
 523
 524 #include XPM_H_LOCATION
 525 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 526 EOF
 527     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 528       grep '^"%%%"'  2>/dev/null | \
 529       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 530     case "$lyx_cv_xpmr" in
 531 changequote(,)
 532      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 533             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 534 changequote([,])
 535          *) ;;
 536     esac
 537     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 538     rm -f conftest*])
 539   XPM_VERSION=${lyx_cv_xpmversion}
 540   case "$lyx_cv_xpmr" in
 541 changequote(,)
 542         [789]|[0-9][0-9]*) ;;
 543 changequote([,])
 544         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 545    If you experience strange crashes with LyX, try to upgrade
 546    to at least version 4.7 (aka 3.4g).
 547    If you have installed a newer version of the library, check whether you
 548    have an old xpm.h header file in your include path.]);;
 549   esac
 550 fi])
 551
 552
 553 dnl Usage: LYX_HPUX  Checks for HP-UX and update CXXFLAGS accordingly
 554 AC_DEFUN(LYX_HPUX,
 555 [#It seems that HPUX requires using -fpcc-struct-return with gcc.
 556 AC_CACHE_CHECK(for HP-UX,ac_cv_hpux,[
 557 os=`uname -s | tr '[A-Z]' '[a-z]'`
 558 ac_cv_hpux=no
 559 test "$os" = hp-ux && ac_cv_hpux=yes])
 560 if test "$ac_cv_hpux" = yes; then
 561  test "x$GXX" = xyes && CXXFLAGS="$CXXFLAGS -fpcc-struct-return"
 562 fi])
 563
 564
 565 dnl Usage: LYX_SUNOS4 Checks for SunOS 4.x and sets the flag lyx_broken_headers
 566 dnl   if necessary
 567 AC_DEFUN(LYX_SUNOS4,
 568 [#The headers are not correct under SunOS4
 569 AC_CACHE_CHECK(for SunOS 4.x,ac_cv_sunos4,[
 570 changequote(, ) dnl
 571 os=`uname -a | sed -e 's/^\([^ ]*\) [^ ]* \([0-9]\)\..*/\1\2/'`
 572 changequote([, ]) dnl
 573 ac_cv_sunos4=no
 574 test "$os" = SunOS4 && ac_cv_sunos4=yes])
 575 if test "$ac_cv_sunos4" = yes; then
 576  test "x$GXX" = xyes && lyx_broken_headers=yes
 577 fi])
 578
 579
 580 dnl Usage: LYX_SCO Checks for SCO and sets the flag lyx_broken_headers
 581 dnl   if necessary
 582 AC_DEFUN(LYX_SCO,
 583 [AC_CACHE_CHECK(for SCO 3.2v4,ac_cv_sco,[
 584 ac_cv_sco=no
 585 if test `uname -s` != "SCO_SV"; then
 586   lyx_machine_rel=`uname -m`:`uname -r`
 587   if test $lyx_machine_rel = i386:3.2 || test $lyx_machine_rel = i486:3.2;
 588   then
 589     if test -f /usr/options/cb.name; then
 590       ac_cv_sco=no
 591     elif /bin/uname -X 2>/dev/null >/dev/null ; then
 592       ac_cv_sco=yes
 593     fi
 594   fi
 595 fi])
 596 if test "$ac_cv_sco" = yes; then
 597  test "x$GXX" = xyes && lyx_broken_headers=yes
 598 fi])
 599
 600 dnl Usage: LYX_FUNC_PUTENV_ARGTYPE
 601 dnl Checks whether putenv() takes 'char const *' or 'char *' as
 602 dnl argument. This is needed because Solaris 7 (wrongly?) uses 'char *',
 603 dnl while everybody else uses the former...
 604 AC_DEFUN(LYX_FUNC_PUTENV_ARGTYPE,
 605 [AC_MSG_CHECKING([type of argument for putenv()])
 606  AC_CACHE_VAL(lyx_cv_func_putenv_arg,dnl
 607   [AC_TRY_COMPILE(dnl
 608 [#include <cstdlib>],
 609 [char const * foo = "bar";
 610  putenv(foo);],dnl
 611    [lyx_cv_func_putenv_arg='char const *'],[lyx_cv_func_putenv_arg='char *'])])
 612  AC_MSG_RESULT($lyx_cv_func_putenv_arg)
 613  AC_DEFINE_UNQUOTED(PUTENV_TYPE_ARG,$lyx_cv_func_putenv_arg,dnl
 614    [Define to the type of the argument of putenv(). Needed on Solaris 7.])])
 615
 616
 617 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 618 dnl                       [default-yes-value])
 619 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 620 dnl  resulting directory name in 'dir-var-name'.
 621 AC_DEFUN(LYX_WITH_DIR,[
 622   AC_ARG_WITH($1,[  --with-$1        specify $2])
 623   AC_MSG_CHECKING([for $2])
 624   if test -z "$with_$3"; then
 625      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 626   else
 627     test "x$with_$3" = xyes && with_$3=$5
 628     lyx_cv_$3="$with_$3"
 629   fi
 630   AC_MSG_RESULT($lyx_cv_$3)])
 631
 632
 633 dnl Usage: LYX_LOOP_DIR(value,action)
 634 dnl Executes action for values of variable `dir' in `values'. `values' can
 635 dnl use ":" as a separator.
 636 AC_DEFUN(LYX_LOOP_DIR,[
 637 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 638 for dir in `eval "echo $1"`; do
 639   if test ! "$dir" = NONE; then
 640     test ! -d "$dir" && AC_ERROR([\"$dir\" is not a directory])
 641     $2
 642   fi
 643 done
 644 IFS=$ac_save_ifs
 645 ])
 646
 647
 648 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 649 dnl var-name.
 650 AC_DEFUN(LYX_ADD_LIB_DIR,[
 651 $1="${$1} -L$2"
 652 if test "`(uname) 2>/dev/null`" = SunOS &&
 653     uname -r | grep '^5' >/dev/null; then
 654   if test $ac_cv_prog_gxx = yes ; then
 655     $1="${$1} -Wl[,]-R$2"
 656   else
 657     $1="${$1} -R$2"
 658   fi
 659 fi])
 660
 661
 662 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 663 dnl var-name.
 664 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 665
 666 ### Check for a headers existence and location iff it exists
 667 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 668 ## It almost works.  I've tried a few variations but they give errors
 669 ## of one sort or other: bad substitution or file not found etc.  The
 670 ## actual header _is_ found though and the cache variable is set however
 671 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 672 ## reason.
 673 ## Additionally, autoheader can't figure out what to use as the name in
 674 ## the config.h.in file so we need to write our own entries there -- one for
 675 ## each header in the form PATH_HEADER_NAME_H
 676 ##
 677 AC_DEFUN(LYX_PATH_HEADER,
 678 [ AC_CHECK_HEADER($1,[
 679   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 680 ### the only remaining problem is getting the second parameter to this
 681 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 682 ### of $ac_safe being printed.
 683   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 684   [ cat > conftest.$ac_ext <<EOF
 685 #line __oline__ "configure"
 686 #include "confdefs.h"
 687
 688 #include <$1>
 689 EOF
 690 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 691   grep $1  2>/dev/null | \
 692   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 693 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 694 rm -f conftest*])
 695   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path)])
 696 ])
 697 ### end of LYX_PATH_HEADER
 698
 699 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
 700 dnl if the cache file is inconsistent with the current host,
 701 dnl target and build system types, execute CMD or print a default
 702 dnl error message.
 703 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
 704     AC_REQUIRE([AC_CANONICAL_SYSTEM])
 705     AC_MSG_CHECKING([config.cache system type])
 706     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
 707          test x"$ac_cv_host_system_type" != x"$host"; } ||
 708        { test x"${ac_cv_build_system_type+set}" = x"set" &&
 709          test x"$ac_cv_build_system_type" != x"$build"; } ||
 710        { test x"${ac_cv_target_system_type+set}" = x"set" &&
 711          test x"$ac_cv_target_system_type" != x"$target"; }; then
 712         AC_MSG_RESULT([different])
 713         ifelse($#, 1, [$1],
 714                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
 715     else
 716         AC_MSG_RESULT([same])
 717     fi
 718     ac_cv_host_system_type="$host"
 719     ac_cv_build_system_type="$build"
 720     ac_cv_target_system_type="$target"
 721 ])
 722
 723 dnl We use this until autoconf fixes its version.
 724 AC_DEFUN(LYX_FUNC_SELECT_ARGTYPES,
 725 [AC_MSG_CHECKING([types of arguments for select()])
 726  AC_CACHE_VAL(ac_cv_func_select_arg234,dnl
 727  [AC_CACHE_VAL(ac_cv_func_select_arg1,dnl
 728   [AC_CACHE_VAL(ac_cv_func_select_arg5,dnl
 729    [for ac_cv_func_select_arg234 in 'fd_set *' 'int *' 'void *'; do
 730      for ac_cv_func_select_arg1 in 'int' 'size_t' 'unsigned long' 'unsigned'; do      for ac_cv_func_select_arg5 in 'struct timeval *' 'const struct timeval *'; do
 731        AC_TRY_COMPILE(dnl
 732 [#ifdef HAVE_SYS_TYPES_H
 733 #include <sys/types.h>
 734 #endif
 735 #ifdef HAVE_SYS_TIME_H
 736 #include <sys/time.h>
 737 #endif
 738 #ifdef HAVE_SYS_SELECT_H
 739 #include <sys/select.h>
 740 #endif
 741 #ifdef HAVE_SYS_SOCKET_H
 742 #include <sys/socket.h>
 743 #endif
 744 extern int select ($ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5);],,dnl
 745         [ac_not_found=no ; break 3],ac_not_found=yes)
 746       done
 747      done
 748     done
 749    ])dnl AC_CACHE_VAL
 750   ])dnl AC_CACHE_VAL
 751  ])dnl AC_CACHE_VAL
 752  if test "$ac_not_found" = yes; then
 753   ac_cv_func_select_arg1=int
 754   ac_cv_func_select_arg234='int *'
 755   ac_cv_func_select_arg5='struct timeval *'
 756  fi
 757  AC_MSG_RESULT([$ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5])
 758  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG1,$ac_cv_func_select_arg1,
 759                     [Define to the type of arg1 for select().])
 760  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG234,($ac_cv_func_select_arg234),
 761                     [Define to the type of args 2, 3 and 4 for select().])
 762  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG5,($ac_cv_func_select_arg5),
 763                     [Define to the type of arg5 for select().])
 764 ])
 765
 766 ### Check which frontend we want to use. The default is XForms
 767 ###
 768 AC_DEFUN(LYX_USE_FRONTEND,
 769 [AC_MSG_CHECKING([what frontend should be used as main GUI])
 770 AC_ARG_WITH(frontend,
 771   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 772                             Possible values: xforms, qt2, gnome],
 773   [lyx_use_frontend="$withval"], [lyx_use_frontend="xforms"])
 774 AC_MSG_RESULT($lyx_use_frontend)
 775 AC_SUBST(FRONTEND)
 776 AC_SUBST(FRONTEND_GUILIB)
 777 AC_SUBST(FRONTEND_LDFLAGS)
 778 AC_SUBST(FRONTEND_INCLUDES)
 779 AC_SUBST(FRONTEND_LIBS)
 780 ])
 781
 782
 783 dnl Check things are declared in headers to avoid errors or warnings.
 784 dnl Called like LYX_CHECK_DECL(function, headerfile)
 785 dnl Defines HAVE_DECL_{FUNCTION}
 786 AC_DEFUN(LYX_CHECK_DECL,
 787 [AC_MSG_CHECKING(if $1 is declared by header $2)
 788 tr_func=`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 789
 790 tr_hdr=`echo $2 | tr . _`
 791 AC_CACHE_VAL([lyx_cv_declare_${tr_hdr}_$1],
 792 [AC_EGREP_HEADER($1, $2, [eval "lyx_cv_declare_${tr_hdr}_$1=yes"], [eval "lyx_cv_declare_${tr_hdr}_$1=no"])])
 793 if eval "test \"\${lyx_cv_declare_${tr_hdr}_$1}\" = \"yes\""; then
 794         AC_DEFINE_UNQUOTED(HAVE_DECL_${tr_func})
 795         AC_MSG_RESULT(yes)
 796 else
 797         AC_MSG_RESULT(no)
 798 fi])
 799
 800 dnl This is the multiple headers version of the LYX_CHECK_DECL macro above.
 801 dnl Called like LYX_CHECK_DECL_HDRS(function, file1 file2 file3)
 802 AC_DEFUN(LYX_CHECK_DECL_HDRS,
 803 [ got="no"
 804 for I in $2; do
 805 tr_hdr=`echo $I | tr . _`
 806 if test "${got}" = "no"; then
 807     LYX_CHECK_DECL($1, $I)
 808 fi
 809 if eval "test \"\${lyx_cv_declare_${tr_hdr}_$1}\" = \"yes\""; then
 810      got="yes"
 811 fi
 812 done])
 813
 814
 815 ## ------------------------------------------------------------------------
 816 ## Find a file (or one of more files in a list of dirs)
 817 ## ------------------------------------------------------------------------
 818 ##
 819 AC_DEFUN(AC_FIND_FILE,
 820 [
 821 $3=NO
 822 for i in $2;
 823 do
 824   for j in $1;
 825   do
 826     if test -r "$i/$j"; then
 827       $3=$i
 828       break 2
 829     fi
 830   done
 831 done
 832 ])
 833
 834 dnl just a wrapper to clean up configure.in
 835 AC_DEFUN(LYX_PROG_LIBTOOL,
 836 [
 837 AC_REQUIRE([AC_ENABLE_SHARED])
 838 AC_REQUIRE([AC_ENABLE_STATIC])
 839 dnl libtool is only for C, so I must force him
 840 dnl to find the correct flags for C++
 841 ac_save_cc=$CC
 842 ac_save_cflags="$CFLAGS"
 843 CC=$CXX
 844 CFLAGS="$CXXFLAGS"
 845 AM_PROG_LIBTOOL dnl for libraries
 846 CC=$ac_save_cc
 847 CFLAGS="$ac_save_cflags"
 848 ])