config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version $VERSION"
  11 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  12   lyx_devel_version=yes
  13   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 AC_SUBST(lyx_devel_version)])
  25
  26
  27 dnl Define the option to set a LyX version on installed executables and directories
  28 dnl
  29 dnl
  30 AC_DEFUN([LYX_VERSION_SUFFIX],[
  31 AC_MSG_CHECKING([for install target ... ])
  32 RPM_VERSION_SUFFIX='""'
  33 AC_ARG_WITH(version-suffix,
  34   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  35   [if test "x$withval" = "xyes";
  36    then
  37      withval="-$VERSION"
  38      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  39    fi
  40    lyxname="lyx$withval"
  41    program_suffix=$withval
  42    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"],
  43   [lyxname=lyx])
  44 AC_SUBST(RPM_VERSION_SUFFIX)
  45 AC_MSG_RESULT([$lyxname])
  46 ])
  47
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN([LYX_ERROR],[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN([LYX_WARNING],[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN([LYX_LIB_ERROR],[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN([LYX_CHECK_ERRORS],[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 EOF
  85 else
  86
  87 if test x$lyx_warning = xyes; then
  88 cat <<EOF
  89 === The following minor problems have been detected by configure.
  90 === Please check the messages below before running 'make'.
  91 === (see the section 'Problems' in the INSTALL file)
  92 $lyx_warning_txt
  93 EOF
  94 fi
  95 cat <<EOF
  96 Configuration of LyX was successful.
  97 Type 'make' to compile the program,
  98 and then 'make install' to install it.
  99 EOF
 100 fi])
 101
 102
 103 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 104 dnl
 105 define(LYX_SEARCH_PROG,[dnl
 106 for ac_prog in $2 ; do
 107 # Extract the first word of "$ac_prog", so it can be a program name with args.
 108   set dummy $ac_prog ; ac_word=$[2]
 109   if test -z "[$]$1"; then
 110     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 111     for ac_dir in $PATH; do
 112       test -z "$ac_dir" && ac_dir=.
 113       if test -f [$ac_dir/$ac_word]; then
 114         $1="$ac_prog"
 115         break
 116       fi
 117     done
 118     IFS="$ac_save_ifs"
 119   fi
 120
 121   if test -n "[$]$1"; then
 122     ac_result=yes
 123   else
 124     ac_result=no
 125   fi
 126   ifelse($3,,,[$3])
 127   test -n "[$]$1" && break
 128 done
 129 ])dnl
 130
 131
 132 AC_DEFUN([LYX_PROG_CXX_WORKS],
 133 [rm -f conftest.C
 134 cat >conftest.C <<EOF
 135 class foo {
 136    // we require the mutable keyword
 137    mutable int bar;
 138  };
 139  // we require namespace support
 140  namespace baz {
 141    int bar;
 142  }
 143  int main() {
 144    return(0);
 145  }
 146 EOF
 147 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 148 rm -f conftest.C conftest.o conftest.obj || true
 149 ])
 150
 151
 152 AC_DEFUN([LYX_PROG_CXX],
 153 [AC_MSG_CHECKING([for a good enough C++ compiler])
 154 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 155
 156 if test -z "$CXX" ; then
 157   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 158 fi
 159 AC_MSG_RESULT($CXX)
 160
 161 AC_PROG_CXX
 162
 163 ### We might want to get or shut warnings.
 164 AC_ARG_ENABLE(warnings,
 165   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 166   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 167         enable_warnings=yes;
 168     else
 169         enable_warnings=no;
 170     fi;])
 171 if test x$enable_warnings = xyes ; then
 172   lyx_flags="$lyx_flags warnings"
 173   AC_DEFINE(WITH_WARNINGS, 1,
 174   [Define this if you want to see the warning directives put here and
 175    there by the developpers to get attention])
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 181   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 182         enable_debug=yes;
 183     else
 184         enable_debug=no;
 185     fi;])
 186
 187 ### set up optimization
 188 AC_ARG_ENABLE(optimization,
 189   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 190         enable_optimization=yes;)
 191 case $enable_optimization in
 192   yes) lyx_opt=-O;;
 193    no) lyx_opt=;;
 194     *) lyx_opt=${enable_optimization};;
 195 esac
 196
 197 lyx_pch_comp=no
 198
 199 # set the debug flags correctly.
 200 if test x$GXX = xyes; then
 201   dnl Useful for global version info
 202   gxx_version=`${CXX} -dumpversion`
 203   CXX_VERSION="($gxx_version)"
 204
 205   if test "$ac_test_CXXFLAGS" = set; then
 206     CXXFLAGS="$ac_save_CXXFLAGS"
 207   else
 208     case $gxx_version in
 209       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 210       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 211       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 212       3.0*)    CXXFLAGS="$lyx_opt";;
 213       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 214       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 215       3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 216       3.4*|3.5*)
 217             CXXFLAGS="$lyx_opt -fno-exceptions"
 218             lyx_pch_comp=yes;;
 219       *)       CXXFLAGS="$lyx_opt";;
 220     esac
 221     if test x$enable_debug = xyes ; then
 222         case $gxx_version in
 223             3.4*|3.5*) CXXFLAGS="-g $CXXFLAGS"
 224                 AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 225                 AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 226                 ;;
 227             *)    CXXFLAGS="-g $CXXFLAGS";;
 228         esac
 229     fi
 230   fi
 231   if test x$enable_warnings = xyes ; then
 232     case $gxx_version in
 233         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 234         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 235         3.1*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 236         3.2*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 237         3.3*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 238         *)    CXXFLAGS="$CXXFLAGS -Wextra -Wall";;
 239     esac
 240   fi
 241 fi
 242 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 243 ])dnl
 244
 245
 246 dnl NOT USED CURRENTLY*************************************
 247 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 248 dnl   supports RTTI
 249 AC_DEFUN([LYX_CXX_RTTI],[
 250 ### Check whether the compiler supports runtime type information
 251 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 252  [AC_TRY_RUN([
 253 class rtti {
 254 public:
 255    virtual int tag() { return 0; }
 256 };
 257 class derived1 : public rtti {
 258 public:
 259     int tag() { return 1; }
 260 };
 261 class derived2 : public rtti {
 262 public:
 263     int tag() { return 2; }
 264 };
 265 int main() {
 266     derived1 * foo1 = new derived1();
 267     derived2 * foo2 = new derived2();
 268     rtti * bar = foo1;
 269     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 270     if (bar1 == 0)
 271         exit(1);
 272     bar = foo2;
 273     bar1 = dynamic_cast<derived1 *>(bar);
 274     if (bar1 != 0)
 275         exit(1);
 276     return 0;
 277 }
 278 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 279 ])
 280 if test x$lyx_cv_rtti = xyes ; then
 281   AC_DEFINE(HAVE_RTTI, 1,
 282    [Define to 1 if your compiler supports runtime type information])
 283 fi])
 284
 285
 286 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 287 dnl   understands the "explicit" directive.
 288 AC_DEFUN([LYX_CXX_EXPLICIT],[
 289 ### Check whether the compiler understands the keyword `explicit'
 290 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 291  [AC_TRY_COMPILE([
 292 class Expl {
 293 public:
 294         explicit Expl() {}
 295 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 296 ])
 297 if test $lyx_cv_explicit = no ; then
 298   AC_DEFINE(explicit,[ ],
 299    [Define to nothing if your compiler does not understand the
 300    'explicit' directive])
 301 fi])
 302
 303
 304 dnl NOT USED CURRENTLY*************************************
 305 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 306 dnl   has a working stl stack template
 307 AC_DEFUN([LYX_CXX_STL_STACK],[
 308 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 309  [AC_TRY_COMPILE([
 310 #include <stack>
 311 using std::stack;
 312 ],[
 313     stack<int> stakk;
 314     stakk.push(0);
 315 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 316 ])
 317 if test $lyx_cv_broken_stack = yes ; then
 318   AC_DEFINE(BROKEN_STL_STACK, 1,
 319    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 320    correctly])
 321 fi])
 322
 323
 324 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 325 dnl    count template, if not the old HP version is assumed.
 326 AC_DEFUN([LYX_STD_COUNT],[
 327 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 328  [AC_TRY_COMPILE([
 329 #include <algorithm>
 330 using std::count;
 331 int countChar(char * b, char * e, char const c)
 332 {
 333         return count(b, e, c);
 334 }
 335 ],[
 336     char a[] = "hello";
 337     int i = countChar(a, a + 5, 'l');
 338 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 339 ])
 340 if test $lyx_cv_std_count = yes ; then
 341     AC_DEFINE(HAVE_STD_COUNT, 1,
 342     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 343 fi])
 344
 345
 346 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 347 dnl   supports modern STL streams
 348 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 349 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 350  [AC_TRY_COMPILE([
 351 #include <iostream>
 352 ],[
 353  std::streambuf * test = std::cerr.rdbuf();
 354  test->pubsync();
 355 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 356 ])
 357 if test $lyx_cv_modern_streams = yes ; then
 358   AC_DEFINE(MODERN_STL_STREAMS, 1,
 359    [Define if you have modern standard-compliant STL streams])
 360 fi])
 361
 362
 363 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 364 dnl        be used.
 365 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 366         AC_ARG_WITH(included-boost,
 367             [  --with-included-boost  use the boost lib supplied with LyX],
 368             [lyx_cv_with_included_boost=$withval
 369                 AC_MSG_RESULT([$with_included_boost])],
 370             [lyx_cv_with_included_boost=yes])
 371         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 372 ])
 373
 374
 375 dnl NOT USED CURRENTLY*************************************
 376 dnl LYX_CXX_PARTIAL
 377 AC_DEFUN([LYX_CXX_PARTIAL], [
 378     AC_REQUIRE([AC_PROG_CXX])
 379     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 380         [lyx_cv_cxx_partial_specialization],
 381         [AC_TRY_COMPILE(
 382             [
 383             template<class T, class K>
 384             class k {
 385             public:
 386             };
 387             template<class T> class k<void,T> { };
 388             ],[
 389             k<float, float> b;
 390             k<void,void> a;
 391             ],[
 392             lyx_cv_cxx_partial_specialization=yes
 393             ],[
 394             lyx_cv_cxx_partial_specialization=no
 395             ])
 396         ])
 397     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 398         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 399         [Defined if your compiler supports partial specialization.])
 400     fi
 401 ])
 402
 403
 404 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 405 dnl   provides wrappers for C headers and use our alternate version otherwise.
 406 AC_DEFUN([LYX_CXX_CHEADERS],[
 407 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 408  [AC_TRY_CPP([
 409 #include <clocale>
 410 #include <cctype>
 411 #include <cerrno>
 412 #include <cmath>
 413 #include <csignal>
 414 #include <cstdio>
 415 #include <cstdlib>
 416 #include <cstring>
 417 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 418 if test $lyx_cv_cxx_cheaders = no ; then
 419   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 420 fi])
 421
 422
 423 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 424 dnl   are already in the global namespace
 425 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 426     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 427     lyx_cv_cxx_global_cstd,
 428     [AC_TRY_COMPILE([
 429     #include <cctype>
 430     using std::tolower;
 431     ],[
 432     return 0;
 433     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 434     if test x$lyx_cv_cxx_global_cstd = xyes; then
 435         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 436         [Define if your C++ compiler puts C library functions in the global namespace])
 437     fi
 438 ])
 439
 440
 441 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 442 dnl                       [default-yes-value])
 443 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 444 dnl  resulting directory name in 'dir-var-name'.
 445 AC_DEFUN([LYX_WITH_DIR],[
 446   AC_ARG_WITH($1,[  --with-$1        specify $2])
 447   AC_MSG_CHECKING([for $2])
 448   if test -z "$with_$3"; then
 449      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 450   else
 451     test "x$with_$3" = xyes && with_$3=$5
 452     lyx_cv_$3="$with_$3"
 453   fi
 454   AC_MSG_RESULT($lyx_cv_$3)])
 455
 456
 457 dnl Usage: LYX_LOOP_DIR(value,action)
 458 dnl Executes action for values of variable `dir' in `values'. `values' can
 459 dnl use ":" as a separator.
 460 AC_DEFUN([LYX_LOOP_DIR],[
 461 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 462 for dir in `eval "echo $1"`; do
 463   if test ! "$dir" = NONE; then
 464     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 465     $2
 466   fi
 467 done
 468 IFS=$ac_save_ifs
 469 ])
 470
 471
 472 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 473 dnl var-name.
 474 AC_DEFUN([LYX_ADD_LIB_DIR],[
 475 $1="${$1} -L$2"
 476 if test "`(uname) 2>/dev/null`" = SunOS &&
 477     uname -r | grep '^5' >/dev/null; then
 478   if test $ac_cv_prog_gxx = yes ; then
 479     $1="${$1} -Wl[,]-R$2"
 480   else
 481     $1="${$1} -R$2"
 482   fi
 483 fi])
 484
 485
 486 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 487 dnl var-name.
 488 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 489
 490 ### Check for a headers existence and location iff it exists
 491 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 492 ## It almost works.  I've tried a few variations but they give errors
 493 ## of one sort or other: bad substitution or file not found etc.  The
 494 ## actual header _is_ found though and the cache variable is set however
 495 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 496 ## reason.
 497 ## Additionally, autoheader can't figure out what to use as the name in
 498 ## the config.h.in file so we need to write our own entries there -- one for
 499 ## each header in the form PATH_HEADER_NAME_H
 500 ##
 501 AC_DEFUN([LYX_PATH_HEADER],
 502 [ AC_CHECK_HEADER($1,[
 503   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 504 ### the only remaining problem is getting the second parameter to this
 505 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 506 ### of $ac_safe being printed.
 507   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 508   [ cat > conftest.$ac_ext <<EOF
 509 #line __oline__ "configure"
 510 #include "confdefs.h"
 511
 512 #include <$1>
 513 EOF
 514 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 515   grep $1  2>/dev/null | \
 516   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 517 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 518 rm -f conftest*])
 519   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 520 ])
 521 ### end of LYX_PATH_HEADER
 522
 523 ### Check which frontends we want to use. The default is XForms only
 524 ###
 525 AC_DEFUN([LYX_USE_FRONTENDS],
 526 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 527 AC_ARG_WITH(frontend,
 528   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 529                             Possible values: xforms, qt, gtk(EXPERIMENTAL)],
 530   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 531 AC_MSG_RESULT($FRONTENDS)
 532 AC_SUBST(FRONTENDS)
 533 AC_SUBST(FRONTENDS_SUBDIRS)
 534 AC_SUBST(FRONTENDS_PROGS)
 535 ])
 536
 537
 538
 539 ## ------------------------------------------------------------------------
 540 ## Find a file (or one of more files in a list of dirs)
 541 ## ------------------------------------------------------------------------
 542 ##
 543 AC_DEFUN([AC_FIND_FILE],
 544 [
 545 $3=NO
 546 for i in $2;
 547 do
 548   for j in $1;
 549   do
 550     if test -r "$i/$j"; then
 551       $3=$i
 552       break 2
 553     fi
 554   done
 555 done
 556 ])
 557
 558 dnl just a wrapper to clean up configure.in
 559 AC_DEFUN([LYX_PROG_LIBTOOL],
 560 [
 561 AC_REQUIRE([AC_ENABLE_SHARED])
 562 AC_REQUIRE([AC_ENABLE_STATIC])
 563 dnl libtool is only for C, so I must force him
 564 dnl to find the correct flags for C++
 565 ac_save_cc=$CC
 566 ac_save_cflags="$CFLAGS"
 567 CC=$CXX
 568 CFLAGS="$CXXFLAGS"
 569 AM_PROG_LIBTOOL dnl for libraries
 570 CC=$ac_save_cc
 571 CFLAGS="$ac_save_cflags"
 572 ])