config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version $VERSION"
  11 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  12   lyx_devel_version=yes
  13   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 AC_SUBST(lyx_devel_version)])
  25
  26
  27 dnl Define the option to set a LyX version on installed executables and directories
  28 dnl
  29 dnl
  30 AC_DEFUN([LYX_VERSION_SUFFIX],[
  31 AC_MSG_CHECKING([for install target ... ])
  32 RPM_VERSION_SUFFIX='""'
  33 AC_ARG_WITH(version-suffix,
  34   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  35   [if test "x$withval" = "xyes";
  36    then
  37      withval="-$VERSION"
  38      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  39    fi
  40    lyxname="lyx$withval"
  41    program_suffix=$withval
  42    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"],
  43   [lyxname=lyx])
  44 AC_SUBST(RPM_VERSION_SUFFIX)
  45 AC_MSG_RESULT([$lyxname])
  46 ])
  47
  48
  49 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  50 dnl flag lyx_error to yes.
  51 AC_DEFUN([LYX_ERROR],[
  52 lyx_error_txt="$lyx_error_txt
  53 ** $1
  54 "
  55 lyx_error=yes])
  56
  57
  58 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  59 dnl flag lyx_warning to yes.
  60 AC_DEFUN([LYX_WARNING],[
  61 lyx_warning_txt="$lyx_warning_txt
  62 == $1
  63 "
  64 lyx_warning=yes])
  65
  66
  67 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  68 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  69 AC_DEFUN([LYX_LIB_ERROR],[
  70 LYX_ERROR([Cannot find $1. Please check that the $2 library
  71    is correctly installed on your system.])])
  72
  73
  74 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  75 dnl   has occured previously.
  76 AC_DEFUN([LYX_CHECK_ERRORS],[
  77 if test x$lyx_error = xyes; then
  78 cat <<EOF
  79 **** The following problems have been detected by configure.
  80 **** Please check the messages below before running 'make'.
  81 **** (see the section 'Problems' in the INSTALL file)
  82 $lyx_error_txt
  83 $lyx_warning_txt
  84 EOF
  85 else
  86
  87 if test x$lyx_warning = xyes; then
  88 cat <<EOF
  89 === The following minor problems have been detected by configure.
  90 === Please check the messages below before running 'make'.
  91 === (see the section 'Problems' in the INSTALL file)
  92 $lyx_warning_txt
  93 EOF
  94 fi
  95 cat <<EOF
  96 Configuration of LyX was successful.
  97 Type 'make' to compile the program,
  98 and then 'make install' to install it.
  99 EOF
 100 fi])
 101
 102
 103 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 104 dnl
 105 define(LYX_SEARCH_PROG,[dnl
 106 for ac_prog in $2 ; do
 107 # Extract the first word of "$ac_prog", so it can be a program name with args.
 108   set dummy $ac_prog ; ac_word=$[2]
 109   if test -z "[$]$1"; then
 110     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 111     for ac_dir in $PATH; do
 112       test -z "$ac_dir" && ac_dir=.
 113       if test -f [$ac_dir/$ac_word]; then
 114         $1="$ac_prog"
 115         break
 116       fi
 117     done
 118     IFS="$ac_save_ifs"
 119   fi
 120
 121   if test -n "[$]$1"; then
 122     ac_result=yes
 123   else
 124     ac_result=no
 125   fi
 126   ifelse($3,,,[$3])
 127   test -n "[$]$1" && break
 128 done
 129 ])dnl
 130
 131
 132 AC_DEFUN([LYX_PROG_CXX_WORKS],
 133 [rm -f conftest.C
 134 cat >conftest.C <<EOF
 135 class foo {
 136    // we require the mutable keyword
 137    mutable int bar;
 138  };
 139  // we require namespace support
 140  namespace baz {
 141    int bar;
 142  }
 143  int main() {
 144    return(0);
 145  }
 146 EOF
 147 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 148 rm -f conftest.C conftest.o conftest.obj || true
 149 ])
 150
 151
 152 AC_DEFUN([LYX_PROG_CXX],
 153 [AC_MSG_CHECKING([for a good enough C++ compiler])
 154 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 155
 156 if test -z "$CXX" ; then
 157   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 158 fi
 159 AC_MSG_RESULT($CXX)
 160
 161 AC_PROG_CXX
 162
 163 ### We might want to get or shut warnings.
 164 AC_ARG_ENABLE(warnings,
 165   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 166   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 167         enable_warnings=yes;
 168     else
 169         enable_warnings=no;
 170     fi;])
 171 if test x$enable_warnings = xyes ; then
 172   lyx_flags="$lyx_flags warnings"
 173   AC_DEFINE(WITH_WARNINGS, 1,
 174   [Define this if you want to see the warning directives put here and
 175    there by the developpers to get attention])
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 181   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 182         enable_debug=yes;
 183     else
 184         enable_debug=no;
 185     fi;])
 186
 187 ### set up optimization
 188 AC_ARG_ENABLE(optimization,
 189   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 190         enable_optimization=yes;)
 191 case $enable_optimization in
 192   yes) lyx_opt=-O;;
 193    no) lyx_opt=;;
 194     *) lyx_opt=${enable_optimization};;
 195 esac
 196
 197 lyx_pch_comp=no
 198
 199 # set the debug flags correctly.
 200 if test x$GXX = xyes; then
 201   dnl Useful for global version info
 202   gxx_version=`${CXX} -dumpversion`
 203   CXX_VERSION="($gxx_version)"
 204
 205   if test "$ac_test_CXXFLAGS" = set; then
 206     CXXFLAGS="$ac_save_CXXFLAGS"
 207   else
 208     case $gxx_version in
 209       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 210       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 211       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 212       3.0*)    CXXFLAGS="$lyx_opt";;
 213       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 214       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 215       3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 216       3.4*|4.0*)
 217             CXXFLAGS="$lyx_opt -fno-exceptions"
 218             lyx_pch_comp=yes;;
 219       *)       CXXFLAGS="$lyx_opt";;
 220     esac
 221     if test x$enable_debug = xyes ; then
 222         case $gxx_version in
 223             3.3*) CXXFLAGS="-g $CXXFLAGS"
 224                 AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 225                 ;;
 226             3.4*|4.0*) CXXFLAGS="-g $CXXFLAGS"
 227                 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 228                 AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 229                 AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 230                 ;;
 231             *)    CXXFLAGS="-g $CXXFLAGS";;
 232         esac
 233     fi
 234   fi
 235   if test x$enable_warnings = xyes ; then
 236     case $gxx_version in
 237         2.95.*) CPPFLAGS="$CPPFLAGS -W -Wall";;
 238         2.96*)  CPPFLAGS="$CPPFLAGS -W -Wall";;
 239         3.1*) CPPFLAGS="$CPPFLAGS -W -Wall";;
 240         3.2*) CPPFLAGS="$CPPFLAGS -W -Wall";;
 241         3.3*) CPPFLAGS="$CPPFLAGS -W -Wall";;
 242         *)    CPPFLAGS="$CPPFLAGS -Wextra -Wall";;
 243     esac
 244   fi
 245 fi
 246 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 247 ])dnl
 248
 249
 250 dnl NOT USED CURRENTLY*************************************
 251 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 252 dnl   supports RTTI
 253 AC_DEFUN([LYX_CXX_RTTI],[
 254 ### Check whether the compiler supports runtime type information
 255 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 256  [AC_TRY_RUN([
 257 class rtti {
 258 public:
 259    virtual int tag() { return 0; }
 260 };
 261 class derived1 : public rtti {
 262 public:
 263     int tag() { return 1; }
 264 };
 265 class derived2 : public rtti {
 266 public:
 267     int tag() { return 2; }
 268 };
 269 int main() {
 270     derived1 * foo1 = new derived1();
 271     derived2 * foo2 = new derived2();
 272     rtti * bar = foo1;
 273     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 274     if (bar1 == 0)
 275         exit(1);
 276     bar = foo2;
 277     bar1 = dynamic_cast<derived1 *>(bar);
 278     if (bar1 != 0)
 279         exit(1);
 280     return 0;
 281 }
 282 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 283 ])
 284 if test x$lyx_cv_rtti = xyes ; then
 285   AC_DEFINE(HAVE_RTTI, 1,
 286    [Define to 1 if your compiler supports runtime type information])
 287 fi])
 288
 289
 290 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 291 dnl   understands the "explicit" directive.
 292 AC_DEFUN([LYX_CXX_EXPLICIT],[
 293 ### Check whether the compiler understands the keyword `explicit'
 294 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 295  [AC_TRY_COMPILE([
 296 class Expl {
 297 public:
 298         explicit Expl() {}
 299 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 300 ])
 301 if test $lyx_cv_explicit = no ; then
 302   AC_DEFINE(explicit,[ ],
 303    [Define to nothing if your compiler does not understand the
 304    'explicit' directive])
 305 fi])
 306
 307
 308 dnl NOT USED CURRENTLY*************************************
 309 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 310 dnl   has a working stl stack template
 311 AC_DEFUN([LYX_CXX_STL_STACK],[
 312 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 313  [AC_TRY_COMPILE([
 314 #include <stack>
 315 using std::stack;
 316 ],[
 317     stack<int> stakk;
 318     stakk.push(0);
 319 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 320 ])
 321 if test $lyx_cv_broken_stack = yes ; then
 322   AC_DEFINE(BROKEN_STL_STACK, 1,
 323    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 324    correctly])
 325 fi])
 326
 327
 328 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 329 dnl    count template, if not the old HP version is assumed.
 330 AC_DEFUN([LYX_STD_COUNT],[
 331 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 332  [AC_TRY_COMPILE([
 333 #include <algorithm>
 334 using std::count;
 335 int countChar(char * b, char * e, char const c)
 336 {
 337         return count(b, e, c);
 338 }
 339 ],[
 340     char a[] = "hello";
 341     int i = countChar(a, a + 5, 'l');
 342 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 343 ])
 344 if test $lyx_cv_std_count = yes ; then
 345     AC_DEFINE(HAVE_STD_COUNT, 1,
 346     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 347 fi])
 348
 349
 350 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 351 dnl   supports modern STL streams
 352 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 353 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 354  [AC_TRY_COMPILE([
 355 #include <iostream>
 356 ],[
 357  std::streambuf * test = std::cerr.rdbuf();
 358  test->pubsync();
 359 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 360 ])
 361 if test $lyx_cv_modern_streams = yes ; then
 362   AC_DEFINE(MODERN_STL_STREAMS, 1,
 363    [Define if you have modern standard-compliant STL streams])
 364 fi])
 365
 366
 367 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 368 dnl        be used.
 369 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 370         AC_ARG_WITH(included-boost,
 371             [  --with-included-boost  use the boost lib supplied with LyX],
 372             [lyx_cv_with_included_boost=$withval
 373                 AC_MSG_RESULT([$with_included_boost])],
 374             [lyx_cv_with_included_boost=yes])
 375         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 376 ])
 377
 378
 379 dnl NOT USED CURRENTLY*************************************
 380 dnl LYX_CXX_PARTIAL
 381 AC_DEFUN([LYX_CXX_PARTIAL], [
 382     AC_REQUIRE([AC_PROG_CXX])
 383     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 384         [lyx_cv_cxx_partial_specialization],
 385         [AC_TRY_COMPILE(
 386             [
 387             template<class T, class K>
 388             class k {
 389             public:
 390             };
 391             template<class T> class k<void,T> { };
 392             ],[
 393             k<float, float> b;
 394             k<void,void> a;
 395             ],[
 396             lyx_cv_cxx_partial_specialization=yes
 397             ],[
 398             lyx_cv_cxx_partial_specialization=no
 399             ])
 400         ])
 401     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 402         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 403         [Defined if your compiler supports partial specialization.])
 404     fi
 405 ])
 406
 407
 408 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 409 dnl   provides wrappers for C headers and use our alternate version otherwise.
 410 AC_DEFUN([LYX_CXX_CHEADERS],[
 411 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 412  [AC_TRY_CPP([
 413 #include <clocale>
 414 #include <cctype>
 415 #include <cerrno>
 416 #include <cmath>
 417 #include <csignal>
 418 #include <cstdio>
 419 #include <cstdlib>
 420 #include <cstring>
 421 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 422 if test $lyx_cv_cxx_cheaders = no ; then
 423   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 424 fi])
 425
 426
 427 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 428 dnl   are already in the global namespace
 429 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 430     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 431     lyx_cv_cxx_global_cstd,
 432     [AC_TRY_COMPILE([
 433     #include <cctype>
 434     using std::tolower;
 435     ],[
 436     return 0;
 437     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 438     if test x$lyx_cv_cxx_global_cstd = xyes; then
 439         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 440         [Define if your C++ compiler puts C library functions in the global namespace])
 441     fi
 442 ])
 443
 444
 445 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 446 dnl                       [default-yes-value])
 447 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 448 dnl  resulting directory name in 'dir-var-name'.
 449 AC_DEFUN([LYX_WITH_DIR],[
 450   AC_ARG_WITH($1,[  --with-$1        specify $2])
 451   AC_MSG_CHECKING([for $2])
 452   if test -z "$with_$3"; then
 453      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 454   else
 455     test "x$with_$3" = xyes && with_$3=$5
 456     lyx_cv_$3="$with_$3"
 457   fi
 458   AC_MSG_RESULT($lyx_cv_$3)])
 459
 460
 461 dnl Usage: LYX_LOOP_DIR(value,action)
 462 dnl Executes action for values of variable `dir' in `values'. `values' can
 463 dnl use ":" as a separator.
 464 AC_DEFUN([LYX_LOOP_DIR],[
 465 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 466 for dir in `eval "echo $1"`; do
 467   if test ! "$dir" = NONE; then
 468     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 469     $2
 470   fi
 471 done
 472 IFS=$ac_save_ifs
 473 ])
 474
 475
 476 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 477 dnl var-name.
 478 AC_DEFUN([LYX_ADD_LIB_DIR],[
 479 $1="${$1} -L$2"
 480 if test "`(uname) 2>/dev/null`" = SunOS &&
 481     uname -r | grep '^5' >/dev/null; then
 482   if test $ac_cv_prog_gxx = yes ; then
 483     $1="${$1} -Wl[,]-R$2"
 484   else
 485     $1="${$1} -R$2"
 486   fi
 487 fi])
 488
 489
 490 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 491 dnl var-name.
 492 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 493
 494 ### Check for a headers existence and location iff it exists
 495 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 496 ## It almost works.  I've tried a few variations but they give errors
 497 ## of one sort or other: bad substitution or file not found etc.  The
 498 ## actual header _is_ found though and the cache variable is set however
 499 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 500 ## reason.
 501 ## Additionally, autoheader can't figure out what to use as the name in
 502 ## the config.h.in file so we need to write our own entries there -- one for
 503 ## each header in the form PATH_HEADER_NAME_H
 504 ##
 505 AC_DEFUN([LYX_PATH_HEADER],
 506 [ AC_CHECK_HEADER($1,[
 507   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 508 ### the only remaining problem is getting the second parameter to this
 509 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 510 ### of $ac_safe being printed.
 511   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 512   [ cat > conftest.$ac_ext <<EOF
 513 #line __oline__ "configure"
 514 #include "confdefs.h"
 515
 516 #include <$1>
 517 EOF
 518 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 519   grep $1  2>/dev/null | \
 520   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 521 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 522 rm -f conftest*])
 523   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 524 ])
 525 ### end of LYX_PATH_HEADER
 526
 527 ### Check which frontends we want to use. The default is XForms only
 528 ###
 529 AC_DEFUN([LYX_USE_FRONTENDS],
 530 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 531 AC_ARG_WITH(frontend,
 532   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 533                             Possible values: xforms, qt, gtk(EXPERIMENTAL)],
 534   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 535 AC_MSG_RESULT($FRONTENDS)
 536 AC_SUBST(FRONTENDS)
 537 AC_SUBST(FRONTENDS_SUBDIRS)
 538 AC_SUBST(FRONTENDS_PROGS)
 539 ])
 540
 541
 542
 543 ## ------------------------------------------------------------------------
 544 ## Find a file (or one of more files in a list of dirs)
 545 ## ------------------------------------------------------------------------
 546 ##
 547 AC_DEFUN([AC_FIND_FILE],
 548 [
 549 $3=NO
 550 for i in $2;
 551 do
 552   for j in $1;
 553   do
 554     if test -r "$i/$j"; then
 555       $3=$i
 556       break 2
 557     fi
 558   done
 559 done
 560 ])
 561
 562 dnl just a wrapper to clean up configure.in
 563 AC_DEFUN([LYX_PROG_LIBTOOL],
 564 [
 565 AC_REQUIRE([AC_ENABLE_SHARED])
 566 AC_REQUIRE([AC_ENABLE_STATIC])
 567 dnl libtool is only for C, so I must force him
 568 dnl to find the correct flags for C++
 569 ac_save_cc=$CC
 570 ac_save_cflags="$CFLAGS"
 571 CC=$CXX
 572 CFLAGS="$CXXFLAGS"
 573 AM_PROG_LIBTOOL dnl for libraries
 574 CC=$ac_save_cc
 575 CFLAGS="$ac_save_cflags"
 576 ])
 577
 578
 579 ## ------------------------------------------------------------------------
 580 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 581 ## one or two arguments.
 582 ##
 583 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 584 ## ------------------------------------------------------------------------
 585 ##
 586 AC_DEFUN([AC_FUNC_MKDIR],
 587 [AC_CHECK_FUNCS([mkdir _mkdir])
 588 AC_CACHE_CHECK([whether mkdir takes one argument],
 589                [ac_cv_mkdir_takes_one_arg],
 590 [AC_TRY_COMPILE([
 591 #include <sys/stat.h>
 592 #if HAVE_UNISTD_H
 593 #  include <unistd.h>
 594 #endif
 595 ], [mkdir (".");],
 596 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 597 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 598   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 599             [Define if mkdir takes only one argument.])
 600 fi
 601 ])