config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set lyx_cv_prog_clang to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 150 AC_DEFUN([LYX_LIB_STDCXX],
 151 [AC_CACHE_CHECK([whether STL is libstdc++],
 152                [lyx_cv_lib_stdcxx],
 153 [AC_TRY_COMPILE([#include<vector>], [
 154 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 155             this is not libstdc++
 156 #endif
 157 ],
 158 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 159 ])
 160
 161
 162 dnl Usage: LYX_CXX_USE_CXX11(STD): pass option -std=STD to the C++ compiler
 163 dnl        and update lyxflags
 164 AC_DEFUN([LYX_CXX_USE_CXX11],
 165 [lyx_flags="$lyx_flags c++11"
 166  AM_CXXFLAGS="$AM_CXXFLAGS -std=$1"
 167 ])
 168
 169
 170 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 171 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 172 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 173 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 174                [lyx_cv_lib_stdcxx_cxx11_abi],
 175 [AC_TRY_COMPILE([#include<vector>], [
 176 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 177             this is not libstdc++ using the C++11 ABI
 178 #endif
 179 ],
 180 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 181 ])
 182
 183
 184 AC_DEFUN([LYX_PROG_CXX],
 185 [AC_REQUIRE([AC_PROG_CXX])
 186 AC_REQUIRE([AC_PROG_CXXCPP])
 187
 188 AC_LANG_PUSH(C++)
 189 LYX_PROG_CLANG
 190 LYX_LIB_STDCXX
 191 LYX_LIB_STDCXX_CXX11_ABI
 192 AC_LANG_POP(C++)
 193
 194 if test $lyx_cv_lib_stdcxx = "yes" ; then
 195   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 196     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 197   else
 198     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 199   fi
 200 else
 201   if test $lyx_cv_prog_clang = "yes" ; then
 202     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 203   fi
 204 fi
 205
 206 ### We might want to get or shut warnings.
 207 AC_ARG_ENABLE(warnings,
 208   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 209   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 210         enable_warnings=yes;
 211     else
 212         enable_warnings=no;
 213     fi;])
 214 if test x$enable_warnings = xyes ; then
 215   lyx_flags="$lyx_flags warnings"
 216 fi
 217
 218 ### We might want to disable debug
 219 AC_ARG_ENABLE(debug,
 220   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 221   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 222 )
 223
 224 AC_ARG_ENABLE(stdlib-debug,
 225   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 226   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 227           [enable_stdlib_debug=no])]
 228 )
 229
 230 AC_ARG_ENABLE(concept-checks,
 231   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 232   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 233           [enable_concept_checks=no])]
 234   if test x$USE_QT5 = xyes ; then
 235       enable_concept_checks=no
 236   fi
 237 )
 238
 239 ### set up optimization
 240 AC_ARG_ENABLE(optimization,
 241     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 242     enable_optimization=yes;)
 243 case $enable_optimization in
 244     yes)
 245         if test $lyx_devel_version = yes ; then
 246             lyx_optim=-O
 247         else
 248             lyx_optim=-O2
 249         fi;;
 250     no) lyx_optim=;;
 251     *) lyx_optim=${enable_optimization};;
 252 esac
 253
 254 AC_ARG_ENABLE(pch,
 255   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 256         enable_pch=no;)
 257 lyx_pch_comp=no
 258
 259 AC_ARG_ENABLE(cxx11,
 260   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode]),,
 261   enable_cxx11=no;)
 262
 263 AC_ARG_ENABLE(assertions,
 264   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 265   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 266           [enable_assertions=no])]
 267 )
 268 if test "x$enable_assertions" = xyes ; then
 269    lyx_flags="$lyx_flags assertions"
 270    AC_DEFINE(ENABLE_ASSERTIONS,1,
 271     [Define if you want assertions to be enabled in the code])
 272 fi
 273
 274 # set the compiler options correctly.
 275 lyx_std_regex=no
 276 if test x$GXX = xyes; then
 277   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 278   if test x$CLANG = xno; then
 279     dnl Useful for global version info
 280     gxx_version=`${CXX} -dumpversion`
 281     CXX_VERSION="($gxx_version)"
 282   else
 283     gxx_version=clang
 284   fi
 285
 286   AM_CXXFLAGS="$lyx_optim"
 287   if test x$enable_debug = xyes ; then
 288       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 289   fi
 290   if test $build_type = gprof ; then
 291     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 292     AM_LDFLAGS="$AM_LDFLAGS -pg"
 293   fi
 294   if test $build_type = profiling ; then
 295     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 296   fi
 297
 298   if test x$USE_QT5 = xyes ; then
 299       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 300   fi
 301   dnl Warnings are for preprocessor too
 302   if test x$enable_warnings = xyes ; then
 303       case $gxx_version in
 304           4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*|clang)
 305               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 306               ;;
 307           *)
 308               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra -Wfloat-conversion"
 309               ;;
 310       esac
 311   fi
 312   case $gxx_version in
 313       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 314       *)  test $enable_pch = yes && lyx_pch_comp=yes ;;
 315   esac
 316   if test x$enable_stdlib_debug = xyes ; then
 317     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 318     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 319     case $gxx_version in
 320       *)
 321         lyx_flags="$lyx_flags stdlib-debug"
 322         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 323         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 324         ;;
 325     esac
 326   fi
 327   if test x$enable_concept_checks = xyes ; then
 328     case $gxx_version in
 329       4.*)
 330         lyx_flags="$lyx_flags concept-checks"
 331         dnl FIXME check whether this makes sense with clang/libc++
 332         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 333         ;;
 334     esac
 335   fi
 336   if test x$enable_cxx11 = xyes ; then
 337     case $gxx_version in
 338       4.0*|4.1*|4.2*) AC_ERROR([There is no C++11 support in gcc 4.2 or older]);;
 339       4.3*|4.4*|4.5*|4.6*)
 340         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 341         dnl The source code relies on that.
 342         LYX_CXX_USE_CXX11(c++0x);;
 343       clang)
 344         dnl presumably all clang version support c++11.
 345         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 346         LYX_CXX_USE_CXX11(c++11 -Wno-deprecated-register);;
 347       *)
 348         LYX_CXX_USE_CXX11(c++11);;
 349     esac
 350     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 351       dnl <regex> in gcc is unusable in versions less than 4.9.0
 352       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 353       case $gxx_version in
 354         4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 355         *) lyx_flags="$lyx_flags stdregex"
 356            lyx_std_regex=yes
 357            ;;
 358       esac
 359     else
 360       lyx_flags="$lyx_flags stdregex"
 361       lyx_std_regex=yes
 362     fi
 363
 364     if test $lyx_std_regex = yes ; then
 365       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 366     fi
 367   fi
 368 fi
 369 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 370 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 371 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 372 ])dnl
 373
 374 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 375 dnl        be used.
 376 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 377         AC_MSG_CHECKING([whether to use included boost library])
 378         AC_ARG_WITH(included-boost,
 379             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 380             [lyx_cv_with_included_boost=$withval],
 381             [lyx_cv_with_included_boost=yes])
 382         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 383         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 384         if test x$lyx_cv_with_included_boost = xyes ; then
 385             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 386             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 387         else
 388             AC_LANG_PUSH(C++)
 389             save_LIBS=$LIBS
 390
 391             AC_MSG_CHECKING([for multithreaded boost libraries])
 392             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 393             AC_LINK_IFELSE(
 394                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 395                         [boost::signal<void ()> s;])],
 396                 [AC_MSG_RESULT([yes])
 397                  BOOST_MT="-mt"],
 398                 [AC_MSG_RESULT([no])
 399                  AC_MSG_CHECKING([for plain boost libraries])
 400                  LIBS="$save_LIBS -lboost_signals"
 401                  AC_LINK_IFELSE(
 402                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 403                              [boost::signal<void ()> s;])],
 404                      [AC_MSG_RESULT([yes])
 405                       BOOST_MT=""],
 406                      [AC_MSG_RESULT([no])
 407                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 408                  ])
 409             ])
 410             LIBS=$save_LIBS
 411             AC_LANG_POP(C++)
 412             BOOST_INCLUDES=
 413             if test $lyx_std_regex = yes ; then
 414               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 415             else
 416               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 417             fi
 418         fi
 419         AC_SUBST(BOOST_INCLUDES)
 420         AC_SUBST(BOOST_LIBS)
 421 ])
 422
 423
 424 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 425 dnl        necessary APIs are available to print callstacks.
 426 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 427 [AC_CACHE_CHECK([whether printing callstack is possible],
 428                [lyx_cv_callstack_printing],
 429 [AC_TRY_COMPILE([
 430 #include <execinfo.h>
 431 #include <cxxabi.h>
 432 ], [
 433         void* array[200];
 434         size_t size = backtrace(array, 200);
 435         backtrace_symbols(array, size);
 436         int status = 0;
 437         abi::__cxa_demangle("abcd", 0, 0, &status);
 438 ],
 439 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 440 if test x"$lyx_cv_callstack_printing" = xyes; then
 441   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 442             [Define if callstack can be printed])
 443 fi
 444 ])
 445
 446
 447 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 448 dnl        be used.
 449 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 450         AC_MSG_CHECKING([whether to use included MyThes library])
 451         AC_ARG_WITH(included-mythes,
 452             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 453             [lyx_cv_with_included_mythes=$withval],
 454             [lyx_cv_with_included_mythes=yes])
 455         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 456         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 457         if test x$lyx_cv_with_included_mythes != xyes ; then
 458                 AC_LANG_PUSH(C++)
 459                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 460                 if test x$ac_cv_header_mythes_h != xyes; then
 461                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 462                 fi
 463                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 464                 if test x$lyx_mythes != xyes; then
 465                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 466                 fi
 467                 AC_LANG_POP(C++)
 468                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 469                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 470                 fi
 471                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 472                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 473                 AC_SUBST(MYTHES_LIBS)
 474         fi
 475 ])
 476
 477
 478 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 479 dnl                       [default-yes-value])
 480 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 481 dnl  resulting directory name in 'dir-var-name'.
 482 AC_DEFUN([LYX_WITH_DIR],[
 483   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 484   AC_MSG_CHECKING([for $2])
 485   if test -z "$with_$3"; then
 486      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 487   else
 488     test "x$with_$3" = xyes && with_$3=$5
 489     lyx_cv_$3="$with_$3"
 490   fi
 491   AC_MSG_RESULT($lyx_cv_$3)])
 492
 493
 494 dnl Usage: LYX_LOOP_DIR(value,action)
 495 dnl Executes action for values of variable `dir' in `values'. `values' can
 496 dnl use ":" as a separator.
 497 AC_DEFUN([LYX_LOOP_DIR],[
 498 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 499 for dir in `eval "echo $1"`; do
 500   if test ! "$dir" = NONE; then
 501     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 502     $2
 503   fi
 504 done
 505 IFS=$ac_save_ifs
 506 ])
 507
 508
 509 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 510 dnl var-name.
 511 AC_DEFUN([LYX_ADD_LIB_DIR],[
 512 $1="${$1} -L$2"
 513 if test "`(uname) 2>/dev/null`" = SunOS &&
 514     uname -r | grep '^5' >/dev/null; then
 515   if test $ac_cv_prog_gxx = yes ; then
 516     $1="${$1} -Wl[,]-R$2"
 517   else
 518     $1="${$1} -R$2"
 519   fi
 520 fi])
 521
 522
 523 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 524 dnl var-name.
 525 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 526
 527 ### Check for a headers existence and location iff it exists
 528 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 529 ## It almost works.  I've tried a few variations but they give errors
 530 ## of one sort or other: bad substitution or file not found etc.  The
 531 ## actual header _is_ found though and the cache variable is set however
 532 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 533 ## reason.
 534 ## Additionally, autoheader can't figure out what to use as the name in
 535 ## the config.h.in file so we need to write our own entries there -- one for
 536 ## each header in the form PATH_HEADER_NAME_H
 537 ##
 538 AC_DEFUN([LYX_PATH_HEADER],
 539 [ AC_CHECK_HEADER($1,[
 540   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 541 ### the only remaining problem is getting the second parameter to this
 542 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 543 ### of $ac_safe being printed.
 544   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 545   [ cat > conftest.$ac_ext <<EOF
 546 #line __oline__ "configure"
 547 #include "confdefs.h"
 548
 549 #include <$1>
 550 EOF
 551 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 552   grep $1  2>/dev/null | \
 553   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 554 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 555 rm -f conftest*])
 556   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 557 ])
 558 ### end of LYX_PATH_HEADER
 559
 560 ## Check what kind of packaging should be used at install time.
 561 ## The default is autodetected.
 562 AC_DEFUN([LYX_USE_PACKAGING],
 563 [AC_MSG_CHECKING([what packaging should be used])
 564 AC_ARG_WITH(packaging,
 565   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 566                             Possible values: posix, windows, macosx, haiku])],
 567   [lyx_use_packaging="$withval"], [
 568   case $host in
 569     *-apple-darwin*) lyx_use_packaging=macosx ;;
 570     *-pc-mingw32*) lyx_use_packaging=windows ;;
 571     *haiku*) lyx_use_packaging=haiku ;;
 572     *) lyx_use_packaging=posix ;;
 573   esac])
 574 AC_MSG_RESULT($lyx_use_packaging)
 575 lyx_install_posix=false
 576 lyx_install_macosx=false
 577 lyx_install_cygwin=false
 578 lyx_install_windows=false
 579 case $lyx_use_packaging in
 580    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 581            PACKAGE=LyX${version_suffix}
 582            default_prefix="/Applications/${PACKAGE}.app"
 583            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 584            bindir='${prefix}/Contents/MacOS'
 585            libdir='${prefix}/Contents/Resources'
 586            datarootdir='${prefix}/Contents/Resources'
 587            pkgdatadir='${datadir}'
 588            mandir='${datadir}/man'
 589            lyx_install_macosx=true ;;
 590   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 591            PACKAGE=LyX${version_suffix}
 592            default_prefix="C:/Program Files/${PACKAGE}"
 593            bindir='${prefix}/bin'
 594            libdir='${prefix}/Resources'
 595            datarootdir='${prefix}/Resources'
 596            pkgdatadir='${datadir}'
 597            mandir='${prefix}/Resources/man'
 598            lyx_install_windows=true ;;
 599     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 600            PACKAGE=lyx${version_suffix}
 601            program_suffix=$version_suffix
 602            pkgdatadir='${datadir}/${PACKAGE}'
 603            default_prefix=$ac_default_prefix
 604            case ${host} in
 605              *cygwin*) lyx_install_cygwin=true ;;
 606              *apple-darwin*) lyx_install_macosx=true ;;
 607            esac
 608            lyx_install_posix=true ;;
 609         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 610            PACKAGE=lyx${version_suffix}
 611            program_suffix=$version_suffix
 612            pkgdatadir='${datadir}/${PACKAGE}'
 613            default_prefix=$ac_default_prefix
 614            lyx_install_posix=true ;;
 615     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 616 esac
 617 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 618 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 619 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 620 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 621 AC_SUBST(pkgdatadir)
 622 AC_SUBST(program_suffix)
 623 ])
 624
 625
 626 ## ------------------------------------------------------------------------
 627 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 628 ## one or two arguments.
 629 ##
 630 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 631 ## ------------------------------------------------------------------------
 632 ##
 633 AC_DEFUN([AC_FUNC_MKDIR],
 634 [AC_CHECK_FUNCS([mkdir _mkdir])
 635 AC_CACHE_CHECK([whether mkdir takes one argument],
 636                [ac_cv_mkdir_takes_one_arg],
 637 [AC_TRY_COMPILE([
 638 #include <sys/stat.h>
 639 #if HAVE_UNISTD_H
 640 #  include <unistd.h>
 641 #endif
 642 ], [mkdir (".");],
 643 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 644 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 645   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 646             [Define if mkdir takes only one argument.])
 647 fi
 648 ])
 649
 650
 651 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 652 dnl (which may be a relative path, and need not refer to any existing
 653 dnl entity).
 654
 655 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 656 dnl native Win32 path name, (but with slashes, not backslashes).
 657
 658 dnl On any other system, it is simply the result which would be obtained
 659 dnl if PATHNAME represented an existing directory, and the pwd command was
 660 dnl executed in that directory.
 661 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 662 [ac_dir="$2"
 663  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 664     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 665  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 666  do
 667    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 668  done
 669  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 670  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 671  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 672    s?/*$[]??'`
 673 ])
 674
 675 dnl this is used by the macro blow to general a proper config.h.in entry
 676 m4_define([LYX_AH_CHECK_DECL],
 677 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 678   [Define if you have the prototype for function `$1'])])
 679
 680 dnl Check things are declared in headers to avoid errors or warnings.
 681 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 682 dnl Defines HAVE_DECL_{FUNCTION}
 683 AC_DEFUN([LYX_CHECK_DECL],
 684 [LYX_AH_CHECK_DECL($1)
 685 for ac_header in $2
 686 do
 687   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 688   AC_EGREP_HEADER($1, $ac_header,
 689       [AC_MSG_RESULT(yes)
 690        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 691        break],
 692       [AC_MSG_RESULT(no)])
 693 done])
 694
 695 dnl this is used by the macro below to generate a proper config.h.in entry
 696 m4_define([LYX_AH_CHECK_DEF],
 697 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 698   [Define to 1 if `$1' is defined in `$2'])])
 699
 700 dnl Check whether name is defined in header by using it in codesnippet.
 701 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 702 dnl Defines HAVE_DEF_{NAME}
 703 AC_DEFUN([LYX_CHECK_DEF],
 704 [LYX_AH_CHECK_DEF($1, $2)
 705  AC_MSG_CHECKING([whether $1 is defined by header $2])
 706  AC_TRY_COMPILE([#include <$2>], [$3],
 707      lyx_have_def_name=yes,
 708      lyx_have_def_name=no)
 709  AC_MSG_RESULT($lyx_have_def_name)
 710  if test "x$lyx_have_def_name" = xyes; then
 711    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 712  fi
 713 ])
 714
 715 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 716 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 717 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 718 AC_DEFUN([LYX_SET_VERSION_INFO],
 719 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 720  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 721  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 722  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 723  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 724  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 725  test "x$lyx_patch" = "x" && lyx_patch=0
 726  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 727  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 728  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 729  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 730  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 731  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 732  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 733  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 734 ])
 735
 736 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 737 # ---------------------------------------------------------------------------
 738 # Copied from autoconf 2.68, added a check that python version is < 3.0
 739 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 740 # Run ACTION-IF-FALSE otherwise.
 741 # This test uses sys.hexversion instead of the string equivalent (first
 742 # word of sys.version), in order to cope with versions such as 2.2c1.
 743 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 744 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 745  [prog="import sys
 746 # split strings by '.' and convert to numeric.  Append some zeros
 747 # because we need at least 4 digits for the hex conversion.
 748 # map returns an iterator in Python 3.0 and a list in 2.x
 749 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 750 minverhex = 0
 751 maxverhex = 50331648 # = 3.0.0.0
 752 # xrange is not present in Python 3.0 and range returns an iterator
 753 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 754 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 755   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])