config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CPPFLAGS=$CPPFLAGS
 155   CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 156   save_CXXFLAGS=$CXXFLAGS
 157   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 158   AC_LANG_PUSH(C++)
 159   AC_TRY_COMPILE([], [
 160 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 161             this is a c++11 compiler
 162 #endif
 163   ],
 164   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 165  AC_LANG_POP(C++)
 166  CXXFLAGS=$save_CXXFLAGS
 167  CPPFLAGS=$save_CPPFLAGS])
 168  lyx_use_cxx11=$lyx_cv_cxx_cxx11
 169 ])
 170
 171 dnl decide whether we want to use std::regex and set the
 172 dnl LYX_USE_STD_REGEX accordingly.
 173 AC_DEFUN([LYX_CXX_USE_REGEX],
 174 [lyx_std_regex=no
 175  if test $lyx_use_cxx11 = yes; then
 176    save_CPPFLAGS=$CPPFLAGS
 177    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 178    save_CXXFLAGS=$CXXFLAGS
 179    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 180    AC_LANG_PUSH(C++)
 181    AC_CHECK_HEADER([regex], [lyx_std_regex=yes], [lyx_std_regex=no])
 182    AC_LANG_POP(C++)
 183    CXXFLAGS=$save_CXXFLAGS
 184    CPPFLAGS=$save_CPPFLAGS
 185    if test x$GXX = xyes && test $lyx_std_regex = yes ; then
 186      AC_MSG_CHECKING([for correct regex implementation])
 187      if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 188        dnl <regex> in gcc is unusable in versions less than 4.9.0
 189        dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 190        case $gxx_version in
 191          4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) lyx_std_regex=no ;;
 192          *) ;;
 193        esac
 194      fi
 195    fi
 196    AC_MSG_RESULT([$lyx_std_regex])
 197  fi
 198
 199  if test $lyx_std_regex = yes ; then
 200   lyx_flags="$lyx_flags std-regex"
 201   AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 202  fi
 203  AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 204 ])
 205
 206
 207 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 208 AC_DEFUN([LYX_LIB_STDCXX],
 209 [AC_CACHE_CHECK([whether STL is libstdc++],
 210                [lyx_cv_lib_stdcxx],
 211 [AC_TRY_COMPILE([#include<vector>], [
 212 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 213             this is not libstdc++
 214 #endif
 215 ],
 216 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 217 ])
 218
 219
 220 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 221 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 222 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 223 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 224                [lyx_cv_lib_stdcxx_cxx11_abi],
 225 [AC_TRY_COMPILE([#include<vector>], [
 226 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 227             this is not libstdc++ using the C++11 ABI
 228 #endif
 229 ],
 230 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 231 ])
 232
 233
 234 AC_DEFUN([LYX_PROG_CXX],
 235 [AC_REQUIRE([AC_PROG_CXX])
 236 AC_REQUIRE([AC_PROG_CXXCPP])
 237
 238 AC_LANG_PUSH(C++)
 239 LYX_PROG_CLANG
 240 LYX_LIB_STDCXX
 241 LYX_LIB_STDCXX_CXX11_ABI
 242 AC_LANG_POP(C++)
 243
 244 if test $lyx_cv_lib_stdcxx = "yes" ; then
 245   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 246     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 247   else
 248     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 249   fi
 250 else
 251   if test $lyx_cv_prog_clang = "yes" ; then
 252     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 253   fi
 254 fi
 255
 256 ### We might want to get or shut warnings.
 257 AC_ARG_ENABLE(warnings,
 258   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 259   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 260         enable_warnings=yes;
 261     else
 262         enable_warnings=no;
 263     fi;])
 264 if test x$enable_warnings = xyes ; then
 265   lyx_flags="$lyx_flags warnings"
 266 fi
 267
 268 ### We might want to disable debug
 269 AC_ARG_ENABLE(debug,
 270   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 271   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 272 )
 273
 274 AC_ARG_ENABLE(stdlib-debug,
 275   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 276   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 277           [enable_stdlib_debug=no])]
 278 )
 279
 280 ### set up optimization
 281 AC_ARG_ENABLE(optimization,
 282     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 283     enable_optimization=yes;)
 284 case $enable_optimization in
 285     yes)
 286         if test $lyx_devel_version = yes ; then
 287             lyx_optim=-O
 288         else
 289             lyx_optim=-O2
 290         fi;;
 291     no) lyx_optim=;;
 292     *) lyx_optim=${enable_optimization};;
 293 esac
 294
 295 AC_ARG_ENABLE(cxx11,
 296   AC_HELP_STRING([--disable-cxx11],[disable C++11 mode (default: enabled for known good compilers)]),,
 297   enable_cxx11=auto;)
 298
 299 AC_ARG_ENABLE(assertions,
 300   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 301   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 302           [enable_assertions=no])]
 303 )
 304 if test "x$enable_assertions" = xyes ; then
 305    lyx_flags="$lyx_flags assertions"
 306    AC_DEFINE(ENABLE_ASSERTIONS,1,
 307     [Define if you want assertions to be enabled in the code])
 308 fi
 309
 310 # set the compiler options correctly.
 311 if test x$GXX = xyes; then
 312   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 313   if test x$CLANG = xno; then
 314     dnl Useful for global version info
 315     gxx_version=`${CXX} -dumpversion`
 316     CXX_VERSION="($gxx_version)"
 317   else
 318     gxx_version=clang
 319   fi
 320
 321   AM_CXXFLAGS="$lyx_optim"
 322   if test x$enable_debug = xyes ; then
 323       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 324   fi
 325   if test $build_type = gprof ; then
 326     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 327     AM_LDFLAGS="$AM_LDFLAGS -pg"
 328   fi
 329   if test $build_type = profiling ; then
 330     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 331   fi
 332
 333   if test x$USE_QT5 = xyes ; then
 334       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 335   fi
 336   dnl Warnings are for preprocessor too
 337   if test x$enable_warnings = xyes ; then
 338       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 339   fi
 340   case $gxx_version in
 341       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 342   esac
 343   if test x$enable_stdlib_debug = xyes ; then
 344     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 345     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 346     case $gxx_version in
 347       *)
 348         lyx_flags="$lyx_flags stdlib-debug"
 349         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 350         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 351         ;;
 352     esac
 353   fi
 354   dnl enable_cxx11 can be yes/no/auto.
 355   dnl By default, it is auto and we enable C++11 when possible
 356   if test x$enable_cxx11 != xno ; then
 357     case $gxx_version in
 358       4.0*|4.1*|4.2*)
 359          if test x$enable_cxx11 = xyes; then
 360             AC_ERROR([There is no C++11 support in gcc 4.2 or older])
 361          fi;;
 362       4.3*|4.4*|4.5*|4.6*)
 363         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 364         dnl The source code relies on that.
 365         AM_CPPFLAGS="$AM_CPPFLAGS -std=c++0x";;
 366       clang)
 367         dnl presumably all clang versions support c++11.
 368         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 369         AM_CPPFLAGS="$AM_CPPFLAGS -std=c++11"
 370         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 371       *)
 372         AS_CASE([$host], [*cygwin*],
 373                 [AM_CPPFLAGS="$AM_CPPFLAGS -std=gnu++11"],
 374                 [AM_CPPFLAGS="$AM_CPPFLAGS -std=c++11"]);;
 375     esac
 376   fi
 377 fi
 378
 379 LYX_CXX_CXX11
 380 if test $lyx_use_cxx11 = yes; then
 381   if test x$GXX = xyes; then
 382     dnl We still use auto_ptr, which is obsoleted. Shut off the warnings.
 383     AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-declarations"
 384   fi
 385 fi
 386 LYX_CXX_USE_REGEX
 387 ])
 388
 389 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 390 dnl        be used.
 391 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 392         AC_MSG_CHECKING([whether to use included boost library])
 393         AC_ARG_WITH(included-boost,
 394             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 395             [lyx_cv_with_included_boost=$withval],
 396             [lyx_cv_with_included_boost=yes])
 397         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 398         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 399         if test x$lyx_cv_with_included_boost = xyes ; then
 400             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 401             BOOST_LIBS='$(top_builddir)/3rdparty/boost/liblyxboost.a'
 402         else
 403             AC_LANG_PUSH(C++)
 404             save_LIBS=$LIBS
 405
 406             AC_MSG_CHECKING([for multithreaded boost libraries])
 407             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 408             AC_LINK_IFELSE(
 409                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 410                         [boost::signal<void ()> s;])],
 411                 [AC_MSG_RESULT([yes])
 412                  BOOST_MT="-mt"],
 413                 [AC_MSG_RESULT([no])
 414                  AC_MSG_CHECKING([for plain boost libraries])
 415                  LIBS="$save_LIBS -lboost_signals"
 416                  AC_LINK_IFELSE(
 417                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 418                              [boost::signal<void ()> s;])],
 419                      [AC_MSG_RESULT([yes])
 420                       BOOST_MT=""],
 421                      [AC_MSG_RESULT([no])
 422                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 423                  ])
 424             ])
 425             LIBS=$save_LIBS
 426             AC_LANG_POP(C++)
 427             BOOST_INCLUDES=
 428             if test $lyx_std_regex = yes ; then
 429               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 430             else
 431               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 432             fi
 433
 434             dnl In general, system boost libraries are incompatible with
 435             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 436             dnl details.
 437             if test $enable_stdlib_debug = "yes" ; then
 438                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 439    crashes. Consider using --disable-stdlib-debug or removing
 440    --without-included-boost.])
 441             fi
 442         fi
 443         AC_SUBST(BOOST_INCLUDES)
 444         AC_SUBST(BOOST_LIBS)
 445 ])
 446
 447
 448 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 449 dnl        necessary APIs are available to print callstacks.
 450 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 451 [AC_CACHE_CHECK([whether printing callstack is possible],
 452                [lyx_cv_callstack_printing],
 453 [AC_TRY_COMPILE([
 454 #include <execinfo.h>
 455 #include <cxxabi.h>
 456 ], [
 457         void* array[200];
 458         size_t size = backtrace(array, 200);
 459         backtrace_symbols(array, size);
 460         int status = 0;
 461         abi::__cxa_demangle("abcd", 0, 0, &status);
 462 ],
 463 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 464 if test x"$lyx_cv_callstack_printing" = xyes; then
 465   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 466             [Define if callstack can be printed])
 467 fi
 468 ])
 469
 470
 471 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 472 dnl        be used.
 473 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 474         AC_MSG_CHECKING([whether to use included MyThes library])
 475         AC_ARG_WITH(included-mythes,
 476             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 477             [lyx_cv_with_included_mythes=$withval],
 478             [lyx_cv_with_included_mythes=yes])
 479         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 480         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 481         if test x$lyx_cv_with_included_mythes != xyes ; then
 482                 AC_LANG_PUSH(C++)
 483                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 484                 if test x$ac_cv_header_mythes_h != xyes; then
 485                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 486                 fi
 487                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 488                 if test x$lyx_mythes != xyes; then
 489                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 490                 fi
 491                 AC_LANG_POP(C++)
 492                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 493                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 494                 fi
 495                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 496                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 497                 AC_SUBST(MYTHES_LIBS)
 498         fi
 499 ])
 500
 501
 502 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 503 dnl                       [default-yes-value])
 504 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 505 dnl  resulting directory name in 'dir-var-name'.
 506 AC_DEFUN([LYX_WITH_DIR],[
 507   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 508   AC_MSG_CHECKING([for $2])
 509   if test -z "$with_$3"; then
 510      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 511   else
 512     test "x$with_$3" = xyes && with_$3=$5
 513     lyx_cv_$3="$with_$3"
 514   fi
 515   AC_MSG_RESULT($lyx_cv_$3)])
 516
 517
 518 dnl Usage: LYX_LOOP_DIR(value,action)
 519 dnl Executes action for values of variable `dir' in `values'. `values' can
 520 dnl use ":" as a separator.
 521 AC_DEFUN([LYX_LOOP_DIR],[
 522 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 523 for dir in `eval "echo $1"`; do
 524   if test ! "$dir" = NONE; then
 525     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 526     $2
 527   fi
 528 done
 529 IFS=$ac_save_ifs
 530 ])
 531
 532
 533 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 534 dnl var-name.
 535 AC_DEFUN([LYX_ADD_LIB_DIR],[
 536 $1="${$1} -L$2"
 537 if test "`(uname) 2>/dev/null`" = SunOS &&
 538     uname -r | grep '^5' >/dev/null; then
 539   if test $ac_cv_prog_gxx = yes ; then
 540     $1="${$1} -Wl[,]-R$2"
 541   else
 542     $1="${$1} -R$2"
 543   fi
 544 fi])
 545
 546
 547 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 548 dnl var-name.
 549 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 550
 551 ### Check for a headers existence and location iff it exists
 552 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 553 ## It almost works.  I've tried a few variations but they give errors
 554 ## of one sort or other: bad substitution or file not found etc.  The
 555 ## actual header _is_ found though and the cache variable is set however
 556 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 557 ## reason.
 558 ## Additionally, autoheader can't figure out what to use as the name in
 559 ## the config.h.in file so we need to write our own entries there -- one for
 560 ## each header in the form PATH_HEADER_NAME_H
 561 ##
 562 AC_DEFUN([LYX_PATH_HEADER],
 563 [ AC_CHECK_HEADER($1,[
 564   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 565 ### the only remaining problem is getting the second parameter to this
 566 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 567 ### of $ac_safe being printed.
 568   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 569   [ cat > conftest.$ac_ext <<EOF
 570 #line __oline__ "configure"
 571 #include "confdefs.h"
 572
 573 #include <$1>
 574 EOF
 575 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 576   grep $1  2>/dev/null | \
 577   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 578 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 579 rm -f conftest*])
 580   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 581 ])
 582 ### end of LYX_PATH_HEADER
 583
 584 ## Check what kind of packaging should be used at install time.
 585 ## The default is autodetected.
 586 AC_DEFUN([LYX_USE_PACKAGING],
 587 [AC_MSG_CHECKING([what packaging should be used])
 588 AC_ARG_WITH(packaging,
 589   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 590                             Possible values: posix, windows, macosx, haiku])],
 591   [lyx_use_packaging="$withval"], [
 592   case $host in
 593     *-apple-darwin*) lyx_use_packaging=macosx ;;
 594     *-pc-mingw32*) lyx_use_packaging=windows ;;
 595     *haiku*) lyx_use_packaging=haiku ;;
 596     *) lyx_use_packaging=posix ;;
 597   esac])
 598 AC_MSG_RESULT($lyx_use_packaging)
 599 lyx_install_posix=false
 600 lyx_install_macosx=false
 601 lyx_install_cygwin=false
 602 lyx_install_windows=false
 603 case $lyx_use_packaging in
 604    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 605            PACKAGE=LyX${version_suffix}
 606            default_prefix="/Applications/${PACKAGE}.app"
 607            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 608            bindir='${prefix}/Contents/MacOS'
 609            libdir='${prefix}/Contents/Resources'
 610            datarootdir='${prefix}/Contents/Resources'
 611            pkgdatadir='${datadir}'
 612            mandir='${datadir}/man'
 613            lyx_install_macosx=true ;;
 614   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 615            PACKAGE=LyX${version_suffix}
 616            default_prefix="C:/Program Files/${PACKAGE}"
 617            bindir='${prefix}/bin'
 618            libdir='${prefix}/Resources'
 619            datarootdir='${prefix}/Resources'
 620            pkgdatadir='${datadir}'
 621            mandir='${prefix}/Resources/man'
 622            lyx_install_windows=true ;;
 623     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 624            PACKAGE=lyx${version_suffix}
 625            program_suffix=$version_suffix
 626            pkgdatadir='${datadir}/${PACKAGE}'
 627            default_prefix=$ac_default_prefix
 628            case ${host} in
 629              *cygwin*) lyx_install_cygwin=true ;;
 630              *apple-darwin*) lyx_install_macosx=true ;;
 631            esac
 632            lyx_install_posix=true ;;
 633         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 634            PACKAGE=lyx${version_suffix}
 635            program_suffix=$version_suffix
 636            pkgdatadir='${datadir}/${PACKAGE}'
 637            default_prefix=$ac_default_prefix
 638            lyx_install_posix=true ;;
 639     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 640 esac
 641 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 642 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 643 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 644 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 645 AC_SUBST(pkgdatadir)
 646 AC_SUBST(program_suffix)
 647 ])
 648
 649
 650 ## ------------------------------------------------------------------------
 651 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 652 ## one or two arguments.
 653 ##
 654 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 655 ## ------------------------------------------------------------------------
 656 ##
 657 AC_DEFUN([AC_FUNC_MKDIR],
 658 [AC_CHECK_FUNCS([mkdir _mkdir])
 659 AC_CACHE_CHECK([whether mkdir takes one argument],
 660                [ac_cv_mkdir_takes_one_arg],
 661 [AC_TRY_COMPILE([
 662 #include <sys/stat.h>
 663 #if HAVE_UNISTD_H
 664 #  include <unistd.h>
 665 #endif
 666 ], [mkdir (".");],
 667 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 668 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 669   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 670             [Define if mkdir takes only one argument.])
 671 fi
 672 ])
 673
 674
 675 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 676 dnl (which may be a relative path, and need not refer to any existing
 677 dnl entity).
 678
 679 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 680 dnl native Win32 path name, (but with slashes, not backslashes).
 681
 682 dnl On any other system, it is simply the result which would be obtained
 683 dnl if PATHNAME represented an existing directory, and the pwd command was
 684 dnl executed in that directory.
 685 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 686 [ac_dir="$2"
 687  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 688     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 689  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 690  do
 691    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 692  done
 693  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 694  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 695  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 696    s?/*$[]??'`
 697 ])
 698
 699 dnl this is used by the macro blow to general a proper config.h.in entry
 700 m4_define([LYX_AH_CHECK_DECL],
 701 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 702   [Define if you have the prototype for function `$1'])])
 703
 704 dnl Check things are declared in headers to avoid errors or warnings.
 705 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 706 dnl Defines HAVE_DECL_{FUNCTION}
 707 AC_DEFUN([LYX_CHECK_DECL],
 708 [LYX_AH_CHECK_DECL($1)
 709 for ac_header in $2
 710 do
 711   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 712   AC_EGREP_HEADER($1, $ac_header,
 713       [AC_MSG_RESULT(yes)
 714        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 715        break],
 716       [AC_MSG_RESULT(no)])
 717 done])
 718
 719 dnl this is used by the macro below to generate a proper config.h.in entry
 720 m4_define([LYX_AH_CHECK_DEF],
 721 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 722   [Define to 1 if `$1' is defined in `$2'])])
 723
 724 dnl Check whether name is defined in header by using it in codesnippet.
 725 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 726 dnl Defines HAVE_DEF_{NAME}
 727 AC_DEFUN([LYX_CHECK_DEF],
 728 [LYX_AH_CHECK_DEF($1, $2)
 729  AC_MSG_CHECKING([whether $1 is defined by header $2])
 730  AC_TRY_COMPILE([#include <$2>], [$3],
 731      lyx_have_def_name=yes,
 732      lyx_have_def_name=no)
 733  AC_MSG_RESULT($lyx_have_def_name)
 734  if test "x$lyx_have_def_name" = xyes; then
 735    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 736  fi
 737 ])
 738
 739 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 740 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 741 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 742 AC_DEFUN([LYX_SET_VERSION_INFO],
 743 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 744  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 745  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 746  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 747  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 748  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 749  test "x$lyx_patch" = "x" && lyx_patch=0
 750  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 751  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 752  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 753  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 754  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 755  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 756  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 757  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 758 ])
 759
 760 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 761 # ---------------------------------------------------------------------------
 762 # Copied from autoconf 2.68, added a check that python version is < 3.0
 763 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 764 # Run ACTION-IF-FALSE otherwise.
 765 # This test uses sys.hexversion instead of the string equivalent (first
 766 # word of sys.version), in order to cope with versions such as 2.2c1.
 767 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 768 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 769  [prog="import sys
 770 # split strings by '.' and convert to numeric.  Append some zeros
 771 # because we need at least 4 digits for the hex conversion.
 772 # map returns an iterator in Python 3.0 and a list in 2.x
 773 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 774 minverhex = 0
 775 maxverhex = 50331648 # = 3.0.0.0
 776 # xrange is not present in Python 3.0 and range returns an iterator
 777 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 778 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 779   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])