config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4
   5
   6 dnl Usage LYX_GET_VERSION   Sets "lyx_version" to the version of LyX being
   7 dnl   built, displays it and sets variable "lyx_devel" to yes or no depending
   8 dnl   whether the version is a development release or not.
   9 AC_DEFUN(LYX_GET_VERSION,[
  10 changequote(, ) dnl
  11 VERSION=`grep '#define *LYX_VERSION' $1 |
  12               sed -e 's/^.*"\(.*\)"$/\1/' 2>/dev/null`
  13 echo "configuring LyX version $VERSION"
  14 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  15   lyx_devel_version=yes
  16   echo "WARNING: This is a development version. Expect bugs."
  17 else
  18   lyx_devel_version=no
  19 fi
  20 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  21     lyx_prerelease=yes
  22     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  23 else
  24     lyx_prerelease=no
  25 fi
  26 changequote([, ]) dnl
  27 PACKAGE=lyx${program_suffix}
  28 AC_SUBST(lyx_devel_version)
  29 if test $lyx_devel_version = yes ; then
  30   AC_DEFINE(DEVEL_VERSION, 1, Define if you are building a development version of LyX)
  31 fi])
  32
  33 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  34 dnl flag lyx_error to yes.
  35 AC_DEFUN(LYX_ERROR,[
  36 lyx_error_txt="$lyx_error_txt
  37 ** $1
  38 "
  39 lyx_error=yes])
  40
  41
  42 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  43 dnl flag lyx_warning to yes.
  44 AC_DEFUN(LYX_WARNING,[
  45 lyx_warning_txt="$lyx_warning_txt
  46 == $1
  47 "
  48 lyx_warning=yes])
  49
  50
  51 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  52 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  53 AC_DEFUN(LYX_LIB_ERROR,[
  54 LYX_ERROR([Cannot find $1. Please check that the $2 library
  55    is correctly installed on your system.])])
  56
  57
  58 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  59 dnl   has occured previously.
  60 AC_DEFUN(LYX_CHECK_ERRORS,[
  61 if test x$lyx_error = xyes; then
  62 cat <<EOF
  63 **** The following problems have been detected by configure.
  64 **** Please check the messages below before running 'make'.
  65 **** (see the section 'Problems' in the INSTALL file)
  66 $lyx_error_txt
  67 $lyx_warning_txt
  68 deleting cache $cache_file
  69 EOF
  70   rm -f $cache_file
  71 else
  72
  73 if test x$lyx_warning = xyes; then
  74 cat <<EOF
  75 === The following minor problems have been detected by configure.
  76 === Please check the messages below before running 'make'.
  77 === (see the section 'Problems' in the INSTALL file)
  78 $lyx_warning_txt
  79 EOF
  80 fi
  81 cat <<EOF
  82 Configuration of LyX was successful.
  83 Type 'make' to compile the program,
  84 and then 'make install' to install it.
  85 EOF
  86 fi])
  87
  88
  89 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
  90 dnl
  91 define(LYX_SEARCH_PROG,[dnl
  92 for ac_prog in $2 ; do
  93 # Extract the first word of "$ac_prog", so it can be a program name with args.
  94   set dummy $ac_prog ; ac_word=$[2]
  95   if test -z "[$]$1"; then
  96     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS=":"
  97     for ac_dir in $PATH; do
  98       test -z "$ac_dir" && ac_dir=.
  99       if test -f [$ac_dir/$ac_word]; then
 100         $1="$ac_prog"
 101         break
 102       fi
 103     done
 104     IFS="$ac_save_ifs"
 105   fi
 106
 107   if test -n "[$]$1"; then
 108     ac_result=yes
 109   else
 110     ac_result=no
 111   fi
 112   ifelse($3,,,[$3])
 113   test -n "[$]$1" && break
 114 done
 115 ])dnl
 116
 117
 118 AC_DEFUN(LYX_PROG_CXX_WORKS,
 119 [AC_LANG_SAVE
 120 AC_LANG_CPLUSPLUS
 121 AC_TRY_COMPILER([class foo { int bar; }; int main(){return(0);}], ac_cv_prog_cxx_works, ac_cv_prog_cxx_cross)
 122 AC_LANG_RESTORE
 123 if test $ac_cv_prog_cxx_works = no; then
 124   CXX=
 125 fi
 126 cross_compiling=$ac_cv_prog_cxx_cross
 127 ])
 128
 129
 130 AC_DEFUN(LYX_PROG_CXX,
 131 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 132 AC_MSG_CHECKING([for a working C++ compiler])
 133 LYX_SEARCH_PROG(CXX, $CCC g++ gcc c++ CC cxx xlC cc++, LYX_PROG_CXX_WORKS)
 134
 135 if test -z "$CXX" ; then
 136   AC_ERROR([Unable to find a working C++ compiler])
 137 fi
 138
 139 AC_SUBST(CXX)
 140 AC_MSG_RESULT($CXX)
 141
 142 AC_MSG_CHECKING([whether the C++ compiler ($CXX $CXXFLAGS $LDFLAGS) is a cross-compiler])
 143 AC_MSG_RESULT($cross_compiling)
 144
 145 AC_PROG_CXX_GNU
 146
 147 dnl We might want to get or shut warnings.
 148 AC_ARG_WITH(warnings,
 149   [  --with-warnings         tell the compiler to display more warnings],,
 150   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 151         with_warnings=yes;
 152     else
 153         with_warnings=no;
 154     fi;])
 155 if test x$with_warnings = xyes ; then
 156   lyx_flags="$lyx_flags warnings"
 157   AC_DEFINE(WITH_WARNINGS, 1,
 158   [Define this if you want to see the warning directives put here and
 159    there by the developpers to get attention])
 160 fi
 161
 162 # optimize less for development versions
 163 if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 164   lyx_opt="-O"
 165 else
 166   lyx_opt="-O2"
 167 fi
 168
 169 # set the debug flags correctly.
 170 if test $ac_cv_prog_gxx = yes; then
 171   GXX=yes
 172 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 173 dnl plays around with CXXFLAGS (such as to build both debugging and
 174 dnl normal versions of a library), tasteless as that idea is.
 175   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 176   ac_save_CXXFLAGS="$CXXFLAGS"
 177   CXXFLAGS=
 178 dnl Check the version of g++
 179   gxx_version=`g++ --version`
 180
 181   AC_PROG_CXX_G
 182   if test "$ac_test_CXXFLAGS" = set; then
 183     CXXFLAGS="$ac_save_CXXFLAGS"
 184   elif test $ac_cv_prog_cxx_g = yes; then
 185     case $gxx_version in
 186       2.7*) CXXFLAGS="$lyx_opt";;
 187       2.95.1) CXXFLAGS="-g $lyx_opt -fpermissive -fno-rtti";;
 188       2.95.*) CXXFLAGS="-g $lyx_opt -fno-rtti -fno-exceptions";;
 189       *2.91.*) CXXFLAGS="-g $lyx_opt -Wno-return-type -fno-exceptions -fno-rtti";;
 190       *)    CXXFLAGS="-g $lyx_opt -fno-exceptions -fno-rtti";;
 191     esac
 192   else
 193     CXXFLAGS="$lyx_opt"
 194   fi
 195   if test x$with_warnings = xyes ; then
 196     case $gxx_version in
 197         2.95.*) CXXFLAGS="$CXXFLAGS -Wall -W -Wconversion";;
 198         *) CXXFLAGS="$CXXFLAGS -ansi -Wall -W";;
 199     esac
 200     if test $lyx_devel_version = yes ; then
 201         case $gxx_version in
 202             2.95.*) ;;
 203             *) CXXFLAGS="$CXXFLAGS -pedantic";;
 204         esac
 205     fi
 206   fi
 207 else
 208   GXX=
 209   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 210 fi
 211 ])dnl
 212
 213
 214 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 215 dnl   supports RTTI
 216 AC_DEFUN(LYX_CXX_RTTI,[
 217 ### Check whether the compiler supports runtime type information
 218 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 219  [AC_TRY_RUN([
 220 class rtti {
 221 public:
 222    virtual int tag() { return 0; }
 223 };
 224 class derived1 : public rtti {
 225 public:
 226     int tag() { return 1; }
 227 };
 228 class derived2 : public rtti {
 229 public:
 230     int tag() { return 2; }
 231 };
 232 int main() {
 233     derived1 * foo1 = new derived1();
 234     derived2 * foo2 = new derived2();
 235     rtti * bar = foo1;
 236     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 237     if (bar1 == 0)
 238         exit(1);
 239     bar = foo2;
 240     bar1 = dynamic_cast<derived1 *>(bar);
 241     if (bar1 != 0)
 242         exit(1);
 243     return 0;
 244 }
 245 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 246 ])
 247 if test x$lyx_cv_rtti = xyes ; then
 248   AC_DEFINE(HAVE_RTTI, 1,
 249    [Define to 1 if your compiler supports runtime type information])
 250 fi])
 251
 252
 253 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 254 dnl   understands the "explicit" directive.
 255 AC_DEFUN(LYX_CXX_EXPLICIT,[
 256 ### Check whether the compiler understands the keyword `explicit'
 257 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 258  [AC_TRY_COMPILE([
 259 class Expl {
 260 public:
 261         explicit Expl() {};
 262 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 263 ])
 264 if test $lyx_cv_explicit = no ; then
 265   AC_DEFINE(explicit,[ ],
 266    [Define to nothing if your compiler does not understand the
 267    'explicit' directive])
 268 fi])
 269
 270
 271 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 272 dnl   has a working stl stack template
 273 AC_DEFUN(LYX_CXX_STL_STACK,[
 274 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 275  [AC_TRY_COMPILE([
 276 #include <stack>
 277 using std::stack;
 278 ],[
 279     stack<int> stakk;
 280     stakk.push(0);
 281 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 282 ])
 283 if test $lyx_cv_broken_stack = yes ; then
 284   AC_DEFINE(BROKEN_STL_STACK, 1,
 285    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 286    correctly])
 287 fi])
 288
 289
 290 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 291 dnl    count template, if not the old HP version is assumed.
 292 AC_DEFUN(LYX_STD_COUNT,[
 293 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 294  [AC_TRY_COMPILE([
 295 #include <string>
 296 #include <algorithm>
 297 using std::string;
 298 using std::count;
 299 int countChar(string const & a, char const c)
 300 {
 301         return count(a.begin(), a.end(), c);
 302 }
 303 ],[
 304     string a("hello");
 305     int i = countChar(a, 'l');
 306 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 307 ])
 308 if test $lyx_cv_std_count = yes ; then
 309     AC_DEFINE(HAVE_STD_COUNT, 1,
 310     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 311 fi])
 312
 313
 314 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 315 dnl   supports modern STL streams
 316 AC_DEFUN(LYX_CXX_STL_MODERN_STREAMS,[
 317 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 318  [AC_TRY_COMPILE([
 319 #include <iostream>
 320 ],[
 321  std::streambuf * test = std::cerr.rdbuf();
 322  test->pubsync();
 323 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 324 ])
 325 if test $lyx_cv_modern_streams = yes ; then
 326   AC_DEFINE(MODERN_STL_STREAMS, 1,
 327    [Define if you have modern standard-compliant STL streams])
 328 fi])
 329
 330
 331 dnl Usage: LYX_CXX_STL_STRING : checks whether the C++ compiler
 332 dnl   has a working stl string container, the check is really stupid
 333 dnl   and could need some improvement.
 334 AC_DEFUN(LYX_CXX_STL_STRING,[
 335     AC_REQUIRE([LYX_PROG_CXX])
 336     AC_MSG_CHECKING(whether the included std::string should be used)
 337     AC_ARG_WITH(included-string,
 338        [  --with-included-string  use LyX string class instead of STL string],
 339        [with_included_string=$withval],
 340        [AC_TRY_COMPILE([
 341             #include <string>
 342             using std::string;
 343         ],[
 344             string a("hello there");
 345             a.clear();
 346             a = "hey";
 347             a.erase();
 348         ],[
 349             with_included_string=no
 350         ],[
 351             with_included_string=yes
 352
 353         ])
 354     ])
 355     if test x$with_included_string = xyes ; then
 356         AC_DEFINE(USE_INCLUDED_STRING, 1,
 357             [Define to use the lyxstring class bundled with LyX.])
 358             lyx_flags="$lyx_flags included-string"
 359     fi
 360     AM_CONDITIONAL(USE_LYXSTRING, test x$with_included_string = xyes)
 361     AC_MSG_RESULT([$with_included_string])
 362 ])
 363
 364
 365 dnl Usage: LYX_REGEX : checks if the header regex.h is available
 366 dnl   if it is not available the automake variable USE_REGEX will be
 367 dnl   defined and the regex.h and regex.c that we provide will be used.
 368 AC_DEFUN(LYX_REGEX,[
 369     AC_CHECK_HEADERS(regex.h, lyx_regex=no, lyx_regex=yes)
 370     AM_CONDITIONAL(USE_REGEX, test x$lyx_regex = xyes)
 371 ])
 372
 373
 374 dnl LYX_CXX_MUTABLE
 375 AC_DEFUN(LYX_CXX_MUTABLE, [
 376 AC_REQUIRE([LYX_PROG_CXX])
 377 AC_MSG_CHECKING(if C++ compiler supports mutable)
 378 AC_TRY_COMPILE(
 379 [
 380 class k {
 381         mutable char *c;
 382 public:
 383    void foo() const { c=0; }
 384 };
 385 ],[
 386 ],[
 387   ac_mutable=yes
 388   AC_DEFINE(HAVE_MUTABLE, 1,
 389    [Defined if you compiler supports 'mutable'.])
 390 ],[
 391   ac_mutable=no
 392 ])
 393 AC_MSG_RESULT([$ac_mutable])
 394 ])
 395
 396
 397 dnl LYX_CXX_PARTIAL
 398 AC_DEFUN(LYX_CXX_PARTIAL, [
 399 AC_REQUIRE([LYX_PROG_CXX])
 400 AC_MSG_CHECKING(if C++ compiler supports partial specialization)
 401 AC_TRY_COMPILE(
 402 [
 403 template<class T, class K>
 404 class k {
 405 public:
 406 };
 407 template<class T> class k<void,T> { };
 408 ],[
 409   k<float, float> b;
 410   k<void,void> a;
 411 ],[
 412   ac_partial_specialization=yes
 413   AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 414    [Defined if your compiler supports partial specialization.])
 415 ],[
 416   ac_partial_specialization=no
 417 ])
 418 AC_MSG_RESULT([$ac_partial_specialization])
 419 ])
 420
 421
 422 dnl Usage: LYX_CXX_NAMESPACES : checks whether the C++ compiler
 423 dnl   has a correct namespace handling and define CXX_WORKING_NAMESPACES
 424 dnl   if true. This macro does not do a thourough test, but it should be
 425 dnl   good enough to suit our needs.
 426 AC_DEFUN(LYX_CXX_NAMESPACES,[
 427 AC_CACHE_CHECK(for correct namespaces support,lyx_cv_cxx_namespace,
 428  [AC_TRY_COMPILE([
 429   namespace foo {
 430     int bar;
 431   }
 432 ],[
 433         foo::bar = 0;
 434         return 0;
 435 ],lyx_cv_cxx_namespace=yes,lyx_cv_cxx_namespace=no)
 436 ])
 437 if test $lyx_cv_cxx_namespace = yes ; then
 438   AC_DEFINE(CXX_WORKING_NAMESPACES, 1,
 439    [Define if your C++ compiler has correct support for namespaces])
 440 fi])
 441
 442
 443 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 444 dnl   provides wrappers for C headers and use our alternate version otherwise.
 445 AC_DEFUN(LYX_CXX_CHEADERS,[
 446 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 447  [AC_TRY_CPP([
 448 #include <clocale>
 449 #include <cctype>
 450 #include <cerrno>
 451 #include <cmath>
 452 #include <csignal>
 453 #include <cstdio>
 454 #include <cstdlib>
 455 #include <cstring>
 456 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 457 if test $lyx_cv_cxx_cheaders = no ; then
 458   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 459 fi])
 460
 461
 462 dnl Usage LYX_PATH_XPM: Checks for xpm library and header
 463 AC_DEFUN(LYX_PATH_XPM,[
 464 ### Check for Xpm library
 465 AC_CHECK_LIB(Xpm, XpmCreateBufferFromImage,LYX_LIBS="-lXpm $LYX_LIBS",
 466         [LYX_LIB_ERROR(libXpm,Xpm)], $LYX_LIBS)
 467
 468 ### Check for Xpm headers
 469 lyx_cv_xpm_h_location="<xpm.h>"
 470 AC_CHECK_HEADER(X11/xpm.h,[
 471   ac_cv_header_xpm_h=yes
 472   lyx_cv_xpm_h_location="<X11/xpm.h>"],[
 473 AC_CHECK_HEADER(xpm.h,[],[
 474 LYX_LIB_ERROR(xpm.h,Xpm)])])
 475 AC_DEFINE_UNQUOTED(XPM_H_LOCATION,$lyx_cv_xpm_h_location)
 476
 477 ### Test for the header version
 478 if test $ac_cv_header_xpm_h = yes; then
 479   AC_CACHE_CHECK([xpm header version],lyx_cv_xpmversion,
 480   [ cat > conftest.$ac_ext <<EOF
 481 #line __oline__ "configure"
 482 #include "confdefs.h"
 483
 484 #include XPM_H_LOCATION
 485 "%%%"lyx_cv_xpmv=XpmVersion;lyx_cv_xpmr=XpmRevision"%%%"
 486 EOF
 487     eval `(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 488       grep '^"%%%"'  2>/dev/null | \
 489       sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 490     case "$lyx_cv_xpmr" in
 491 changequote(,)
 492      [0-9]) lyxxpmr_alpha=`echo $lyx_cv_xpmr |tr 123456789 abcdefghi`
 493             lyxxpmv_alpha=" (aka 3.$lyx_cv_xpmv$lyxxpmr_alpha)";;
 494 changequote([,])
 495          *) ;;
 496     esac
 497     lyx_cv_xpmversion="$lyx_cv_xpmv.$lyx_cv_xpmr$lyxxpmv_alpha"
 498     rm -f conftest*])
 499   case "$lyx_cv_xpmr" in
 500 changequote(,)
 501         [789]|[0-9][0-9]*) ;;
 502 changequote([,])
 503         *) LYX_WARNING([Version $lyx_cv_xpmversion of the Xpm library is a bit old.
 504    If you experience strange crashes with LyX, try to upgrade
 505    to at least version 4.7 (aka 3.4g).
 506    If you have installed a newer version of the library, check whether you
 507    have an old xpm.h header file in your include path.]);;
 508   esac
 509 fi])
 510
 511
 512 dnl Usage LYX_PATH_XFORMS: Checks for xforms library and flags
 513 AC_DEFUN(LYX_PATH_XFORMS,[
 514 ### Check for xforms library
 515 AC_CHECK_LIB(forms, fl_initialize, LYX_LIBS="-lforms $LYX_LIBS",
 516   [AC_CHECK_LIB(xforms, fl_initialize, LYX_LIBS="-lxforms $LYX_LIBS",
 517     [LYX_LIB_ERROR(libforms or libxforms,xforms)], $LYX_LIBS)], $LYX_LIBS)
 518
 519 ### Check for xforms headers
 520 lyx_cv_forms_h_location="<forms.h>"
 521 AC_CHECK_HEADER(X11/forms.h,[
 522   ac_cv_header_forms_h=yes
 523   lyx_cv_forms_h_location="<X11/forms.h>"],[
 524 AC_CHECK_HEADER(forms.h,[],[
 525 LYX_LIB_ERROR(forms.h,forms)])])
 526 AC_DEFINE_UNQUOTED(FORMS_H_LOCATION,$lyx_cv_forms_h_location)
 527 if test $ac_cv_header_forms_h = yes; then
 528   AC_CACHE_CHECK([xforms header version],lyx_cv_xfversion,
 529   [ cat > conftest.$ac_ext <<EOF
 530 #line __oline__ "configure"
 531 #include "confdefs.h"
 532
 533 #include FORMS_H_LOCATION
 534 #if ! defined(FL_INCLUDE_VERSION)
 535 "%%%"(unknown)"%%%"
 536 #else
 537 "%%%"FL_VERSION.FL_REVISION"%%%"
 538 #endif
 539 EOF
 540 lyx_cv_xfversion=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 541   grep '^"%%%"'  2>/dev/null | \
 542   sed -e 's/^"%%%"\(.*\)"%%%"/\1/' -e 's/ //g'`
 543 rm -f conftest*])
 544 case "$lyx_cv_xfversion" in
 545   "(unknown)"|0.82|0.83|0.84|0.85)
 546      LYX_ERROR(dnl
 547 Version $lyx_cv_xfversion of xforms is not compatible with LyX.
 548    This version of LyX works best with version 0.88[,] although it
 549    supports also versions 0.81[,] 0.86 and 0.87.) ;;
 550   0.81|0.86|0.87)
 551      LYX_WARNING(dnl
 552 While LyX is compatible with version $lyx_cv_xfversion of xforms[,]
 553    it is recommended that you upgrade to version 0.88.) ;;
 554      0.88) ;;
 555      0.89) LYX_WARNING(dnl
 556 LyX should work ok with version $lyx_cv_xfversion of xforms[,] but
 557 it is an unproven version and might still have some bugs. If you
 558 have problems[,] please use version 0.88 instead.) ;;
 559           *) LYX_WARNING(dnl
 560 Version $lyx_cv_xfversion of xforms might not be compatible with LyX[,]
 561    since it is newer than 0.88. You might have slight problems with it.);;
 562 esac
 563 fi])
 564
 565
 566 dnl Usage: LYX_HPUX  Checks for HP-UX and update CXXFLAGS accordingly
 567 AC_DEFUN(LYX_HPUX,
 568 [#It seems that HPUX requires using -fpcc-struct-return with gcc.
 569 AC_CACHE_CHECK(for HP-UX,ac_cv_hpux,[
 570 os=`uname -s | tr '[A-Z]' '[a-z]'`
 571 ac_cv_hpux=no
 572 test "$os" = hp-ux && ac_cv_hpux=yes])
 573 if test "$ac_cv_hpux" = yes; then
 574  test "x$GXX" = xyes && CXXFLAGS="$CXXFLAGS -fpcc-struct-return"
 575 fi])
 576
 577
 578 dnl Usage: LYX_SUNOS4 Checks for SunOS 4.x and sets the flag lyx_broken_headers
 579 dnl   if necessary
 580 AC_DEFUN(LYX_SUNOS4,
 581 [#The headers are not correct under SunOS4
 582 AC_CACHE_CHECK(for SunOS 4.x,ac_cv_sunos4,[
 583 changequote(, ) dnl
 584 os=`uname -a | sed -e 's/^\([^ ]*\) [^ ]* \([0-9]\)\..*/\1\2/'`
 585 changequote([, ]) dnl
 586 ac_cv_sunos4=no
 587 test "$os" = SunOS4 && ac_cv_sunos4=yes])
 588 if test "$ac_cv_sunos4" = yes; then
 589  test "x$GXX" = xyes && lyx_broken_headers=yes
 590 fi])
 591
 592
 593 dnl Usage: LYX_SCO Checks for SCO and sets the flag lyx_broken_headers
 594 dnl   if necessary
 595 AC_DEFUN(LYX_SCO,
 596 [AC_CACHE_CHECK(for SCO 3.2v4,ac_cv_sco,[
 597 ac_cv_sco=no
 598 if test `uname -s` != "SCO_SV"; then
 599   lyx_machine_rel=`uname -m`:`uname -r`
 600   if test $lyx_machine_rel = i386:3.2 || test $lyx_machine_rel = i486:3.2;
 601   then
 602     if test -f /usr/options/cb.name; then
 603       ac_cv_sco=no
 604     elif /bin/uname -X 2>/dev/null >/dev/null ; then
 605       ac_cv_sco=yes
 606     fi
 607   fi
 608 fi])
 609 if test "$ac_cv_sco" = yes; then
 610  test "x$GXX" = xyes && lyx_broken_headers=yes
 611 fi])
 612
 613 dnl Usage: LYX_FUNC_PUTENV_ARGTYPE
 614 dnl Checks whether putenv() takes 'char const *' or 'char *' as
 615 dnl argument. This is needed because Solaris 7 (wrongly?) uses 'char *',
 616 dnl while everybody else uses the former...
 617 AC_DEFUN(LYX_FUNC_PUTENV_ARGTYPE,
 618 [AC_MSG_CHECKING([type of argument for putenv()])
 619  AC_CACHE_VAL(lyx_cv_func_putenv_arg,dnl
 620   [AC_TRY_COMPILE(dnl
 621 [#include <cstdlib>],
 622 [char const * foo = "bar";
 623  putenv(foo);],dnl
 624    [lyx_cv_func_putenv_arg='char const *'],[lyx_cv_func_putenv_arg='char *'])])
 625  AC_MSG_RESULT($lyx_cv_func_putenv_arg)
 626  AC_DEFINE_UNQUOTED(PUTENV_TYPE_ARG,$lyx_cv_func_putenv_arg,dnl
 627    [Define to the type of the argument of putenv(). Needed on Solaris 7.])])
 628
 629
 630 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 631 dnl                       [default-yes-value])
 632 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 633 dnl  resulting directory name in 'dir-var-name'.
 634 AC_DEFUN(LYX_WITH_DIR,[
 635   AC_ARG_WITH($1,[  --with-$1        specify $2])
 636   AC_MSG_CHECKING([for $2])
 637   if test -z "$with_$3"; then
 638      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 639   else
 640     test "x$with_$3" = xyes && with_$3=$5
 641     lyx_cv_$3="$with_$3"
 642   fi
 643   AC_MSG_RESULT($lyx_cv_$3)])
 644
 645
 646 dnl Usage: LYX_LOOP_DIR(value,action)
 647 dnl Executes action for values of variable `dir' in `values'. `values' can
 648 dnl use ":" as a separator.
 649 AC_DEFUN(LYX_LOOP_DIR,[
 650 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 651 for dir in `eval "echo $1"`; do
 652   if test ! "$dir" = NONE; then
 653     test ! -d "$dir" && AC_ERROR([\"$dir\" is not a directory])
 654     $2
 655   fi
 656 done
 657 IFS=$ac_save_ifs
 658 ])
 659
 660
 661 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 662 dnl var-name.
 663 AC_DEFUN(LYX_ADD_LIB_DIR,[
 664 $1="${$1} -L$2"
 665 if test "`(uname) 2>/dev/null`" = SunOS &&
 666     uname -r | grep '^5' >/dev/null; then
 667   if test $ac_cv_prog_gxx = yes ; then
 668     $1="${$1} -Wl[,]-R$2"
 669   else
 670     $1="${$1} -R$2"
 671   fi
 672 fi])
 673
 674
 675 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 676 dnl var-name.
 677 AC_DEFUN(LYX_ADD_INC_DIR,[$1="${$1} -I$2 "])
 678
 679 ### Check for a headers existence and location iff it exists
 680 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 681 ## It almost works.  I've tried a few variations but they give errors
 682 ## of one sort or other: bad substitution or file not found etc.  The
 683 ## actual header _is_ found though and the cache variable is set however
 684 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 685 ## reason.
 686 AC_DEFUN(LYX_PATH_HEADER,
 687 [ AC_CHECK_HEADER($1,[
 688   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 689   AC_CACHE_CHECK([path to $1],lyx_cv_path_$ac_safe,
 690   [ cat > conftest.$ac_ext <<EOF
 691 #line __oline__ "configure"
 692 #include "confdefs.h"
 693
 694 #include <$1>
 695 EOF
 696 lyx_cv_path_$ac_safe=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 697   grep $1  2>/dev/null | \
 698   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 699 rm -f conftest*])
 700   AC_DEFINE_UNQUOTED(${ac_tr_safe},${lyx_cv_path_$ac_safe})])
 701 ])
 702 ### end of LYX_PATH_HEADER
 703
 704 ### Check for stl_string_fwd.h existence and location if it exists
 705 AC_DEFUN(LYX_STL_STRING_FWD,
 706 [ AC_CHECK_HEADER(stl_string_fwd.h,[
 707   AC_CACHE_CHECK([path to stl_string_fwd.h],lyx_cv_path_stl_string_fwd_h,
 708   [ cat > conftest.$ac_ext <<EOF
 709 #line __oline__ "configure"
 710 #include "confdefs.h"
 711
 712 #include <stl_string_fwd.h>
 713 EOF
 714 lyx_cv_path_stl_string_fwd_h=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 715   grep 'stl_string_fwd.h'  2>/dev/null | \
 716   sed -e 's/.*\(".*stl_string_fwd.h"\).*/\1/' -e "1q"`
 717 rm -f conftest*])
 718   AC_DEFINE_UNQUOTED(STL_STRING_FWD_H_LOCATION,$lyx_cv_path_stl_string_fwd_h,
 719 [define this to the location of stl_string_fwd.h to be used with #include,
 720   NOTE: Do not set it to <stl_string_fwd.h> as that will find the LyX
 721         supplied version of the header.
 722   e.g. <../include/stl_string_fwd.h> or better yet use an absolute path])])
 723 ])
 724
 725
 726 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
 727 dnl if the cache file is inconsistent with the current host,
 728 dnl target and build system types, execute CMD or print a default
 729 dnl error message.
 730 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
 731     AC_REQUIRE([AC_CANONICAL_SYSTEM])
 732     AC_MSG_CHECKING([config.cache system type])
 733     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
 734          test x"$ac_cv_host_system_type" != x"$host"; } ||
 735        { test x"${ac_cv_build_system_type+set}" = x"set" &&
 736          test x"$ac_cv_build_system_type" != x"$build"; } ||
 737        { test x"${ac_cv_target_system_type+set}" = x"set" &&
 738          test x"$ac_cv_target_system_type" != x"$target"; }; then
 739         AC_MSG_RESULT([different])
 740         ifelse($#, 1, [$1],
 741                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
 742     else
 743         AC_MSG_RESULT([same])
 744     fi
 745     ac_cv_host_system_type="$host"
 746     ac_cv_build_system_type="$build"
 747     ac_cv_target_system_type="$target"
 748 ])
 749
 750 dnl We use this until autoconf fixes its version.
 751 AC_DEFUN(LYX_FUNC_SELECT_ARGTYPES,
 752 [AC_MSG_CHECKING([types of arguments for select()])
 753  AC_CACHE_VAL(ac_cv_func_select_arg234,dnl
 754  [AC_CACHE_VAL(ac_cv_func_select_arg1,dnl
 755   [AC_CACHE_VAL(ac_cv_func_select_arg5,dnl
 756    [for ac_cv_func_select_arg234 in 'fd_set *' 'int *' 'void *'; do
 757      for ac_cv_func_select_arg1 in 'int' 'size_t' 'unsigned long' 'unsigned'; do      for ac_cv_func_select_arg5 in 'struct timeval *' 'const struct timeval *'; do
 758        AC_TRY_COMPILE(dnl
 759 [#ifdef HAVE_SYS_TYPES_H
 760 #include <sys/types.h>
 761 #endif
 762 #ifdef HAVE_SYS_TIME_H
 763 #include <sys/time.h>
 764 #endif
 765 #ifdef HAVE_SYS_SELECT_H
 766 #include <sys/select.h>
 767 #endif
 768 #ifdef HAVE_SYS_SOCKET_H
 769 #include <sys/socket.h>
 770 #endif
 771 extern int select ($ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5);],,dnl
 772         [ac_not_found=no ; break 3],ac_not_found=yes)
 773       done
 774      done
 775     done
 776    ])dnl AC_CACHE_VAL
 777   ])dnl AC_CACHE_VAL
 778  ])dnl AC_CACHE_VAL
 779  if test "$ac_not_found" = yes; then
 780   ac_cv_func_select_arg1=int
 781   ac_cv_func_select_arg234='int *'
 782   ac_cv_func_select_arg5='struct timeval *'
 783  fi
 784  AC_MSG_RESULT([$ac_cv_func_select_arg1,$ac_cv_func_select_arg234,$ac_cv_func_select_arg5])
 785  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG1,$ac_cv_func_select_arg1)
 786  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG234,($ac_cv_func_select_arg234))
 787  AC_DEFINE_UNQUOTED(SELECT_TYPE_ARG5,($ac_cv_func_select_arg5))
 788 ])
 789