config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42 dnl If LyX is compiled from a git clone, find the HEAD commit hash
  43 dnl
  44 dnl
  45 AC_DEFUN([LYX_CHECK_GIT_COMMIT], [
  46 AC_MSG_CHECKING([for git commit hash])
  47 lyxgitcommit=`cd "$srcdir" && git log -1 --pretty=format:%H 2>/dev/null || true`
  48 test x$lyxgitcommit = x && lyxgitcommit="none"
  49 AC_MSG_RESULT($lyxgitcommit)
  50 ])
  51
  52
  53 dnl Define the option to set a LyX version on installed executables and directories
  54 dnl
  55 dnl
  56 AC_DEFUN([LYX_VERSION_SUFFIX],[
  57 AC_MSG_CHECKING([for version suffix])
  58 dnl We need the literal double quotes in the rpm spec file
  59 RPM_VERSION_SUFFIX='""'
  60 AC_ARG_WITH(version-suffix,
  61   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  62   [if test "x$withval" = "xyes";
  63    then
  64      withval="-"AC_PACKAGE_VERSION
  65      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  66    fi
  67    AC_SUBST(version_suffix,$withval)
  68    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  69 AC_SUBST(RPM_VERSION_SUFFIX)
  70 AC_SUBST(program_base_name,"lyx")
  71 AC_MSG_RESULT([$withval])
  72 ])
  73
  74
  75 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  76 dnl flag lyx_warning to yes.
  77 AC_DEFUN([LYX_WARNING],[
  78 lyx_warning_txt="$lyx_warning_txt
  79 == $1
  80 "
  81 lyx_warning=yes])
  82
  83
  84 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  85 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  86 AC_DEFUN([LYX_LIB_ERROR],[
  87 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  88    is correctly installed on your system.])])
  89
  90
  91 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  92 dnl   has occured previously.
  93 AC_DEFUN([LYX_CHECK_WARNINGS],[
  94 if test x$lyx_warning = xyes; then
  95 cat <<EOF
  96 === The following minor problems have been detected by configure.
  97 === Please check the messages below before running 'make'.
  98 === (see the section 'Problems' in the INSTALL file)
  99 $lyx_warning_txt
 100
 101 EOF
 102 fi])
 103
 104
 105 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 106 dnl
 107 define(LYX_SEARCH_PROG,[dnl
 108 for ac_prog in $2 ; do
 109 # Extract the first word of "$ac_prog", so it can be a program name with args.
 110   set dummy $ac_prog ; ac_word=$[2]
 111   if test -z "[$]$1"; then
 112     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 113     for ac_dir in $PATH; do
 114       test -z "$ac_dir" && ac_dir=.
 115       if test -f [$ac_dir/$ac_word]; then
 116         $1="$ac_prog"
 117         break
 118       fi
 119     done
 120     IFS="$ac_save_ifs"
 121   fi
 122
 123   if test -n "[$]$1"; then
 124     ac_result=yes
 125   else
 126     ac_result=no
 127   fi
 128   ifelse($3,,,[$3])
 129   test -n "[$]$1" && break
 130 done
 131 ])dnl
 132
 133
 134 AC_DEFUN([LYX_PROG_CXX_WORKS],
 135 [rm -f conftest.C
 136 cat >conftest.C <<EOF
 137 class foo {
 138    // we require the mutable keyword
 139    mutable int bar;
 140  };
 141  // we require namespace support
 142  namespace baz {
 143    int bar;
 144  }
 145  int main() {
 146    return(0);
 147  }
 148 EOF
 149 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 150 rm -f conftest.C conftest.o conftest.obj || true
 151 ])
 152
 153
 154 AC_DEFUN([LYX_PROG_CXX],
 155 [AC_MSG_CHECKING([for a good enough C++ compiler])
 156 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 157
 158 if test -z "$CXX" ; then
 159   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 160 fi
 161 AC_MSG_RESULT($CXX)
 162
 163 AC_PROG_CXX
 164 AC_PROG_CXXCPP
 165
 166 ### We might want to get or shut warnings.
 167 AC_ARG_ENABLE(warnings,
 168   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 169   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 170         enable_warnings=yes;
 171     else
 172         enable_warnings=no;
 173     fi;])
 174 if test x$enable_warnings = xyes ; then
 175   lyx_flags="$lyx_flags warnings"
 176 fi
 177
 178 ### We might want to disable debug
 179 AC_ARG_ENABLE(debug,
 180   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 181   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 182 )
 183
 184 AC_ARG_ENABLE(stdlib-debug,
 185   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 186   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 187           [enable_stdlib_debug=no])]
 188 )
 189
 190 AC_ARG_ENABLE(concept-checks,
 191   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 192   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 193           [enable_concept_checks=no])]
 194 )
 195
 196 ### set up optimization
 197 AC_ARG_ENABLE(optimization,
 198     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 199     enable_optimization=yes;)
 200 case $enable_optimization in
 201     yes)
 202         if test $lyx_devel_version = yes ; then
 203             lyx_opt=-O
 204         else
 205             lyx_opt=-O2
 206         fi;;
 207     no) lyx_opt=;;
 208     *) lyx_opt=${enable_optimization};;
 209 esac
 210
 211 AC_ARG_ENABLE(pch,
 212   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 213         enable_pch=no;)
 214 lyx_pch_comp=no
 215
 216 AC_ARG_ENABLE(cxx11,
 217   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode]),,
 218   enable_cxx11=no;)
 219
 220 AC_ARG_ENABLE(assertions,
 221   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 222   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 223           [enable_assertions=no])]
 224 )
 225 if test "x$enable_assertions" = xyes ; then
 226    lyx_flags="$lyx_flags assertions"
 227    AC_DEFINE(ENABLE_ASSERTIONS,1,
 228     [Define if you want assertions to be enabled in the code])
 229 fi
 230
 231 # set the compiler options correctly.
 232 if test x$GXX = xyes; then
 233   dnl Useful for global version info
 234   gxx_version=`${CXX} -dumpversion`
 235   CXX_VERSION="($gxx_version)"
 236
 237   if test "$ac_test_CXXFLAGS" = set; then
 238     CXXFLAGS="$ac_save_CXXFLAGS"
 239   else
 240     CFLAGS="$lyx_opt"
 241     CXXFLAGS="$lyx_opt"
 242     if test x$enable_debug = xyes ; then
 243       CFLAGS="-g $CFLAGS"
 244       CXXFLAGS="-g $CXXFLAGS"
 245     fi
 246     if test $build_type = gprof ; then
 247       CFLAGS="-pg $CFLAGS"
 248       CXXFLAGS="-pg $CXXFLAGS"
 249       LDFLAGS="-pg $LDFLAGS"
 250     fi
 251     if test $build_type = profiling ; then
 252       CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 253       CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 254     fi
 255   fi
 256   if test "$ac_env_CPPFLAGS_set" != set; then
 257     if test x$enable_warnings = xyes ; then
 258         case $gxx_version in
 259             3.1*|3.2*|3.3*)
 260                 CPPFLAGS="-W -Wall $CPPFLAGS"
 261                 ;;
 262             *)
 263                 CPPFLAGS="-Wextra -Wall $CPPFLAGS "
 264                 ;;
 265         esac
 266     fi
 267   fi
 268   case $gxx_version in
 269       3.1*)    AM_CXXFLAGS="-finline-limit=500 ";;
 270       3.2*|3.3*)    AM_CXXFLAGS="";;
 271       3.4*|4.*)
 272           AM_CXXFLAGS=""
 273           test $enable_pch = yes && lyx_pch_comp=yes
 274           ;;
 275       *)       AM_CXXFLAGS="";;
 276   esac
 277   if test x$enable_stdlib_debug = xyes ; then
 278     case $gxx_version in
 279       3.4*|4.*)
 280         lyx_flags="$lyx_flags stdlib-debug"
 281         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 282         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 283         ;;
 284     esac
 285   fi
 286   if test x$enable_concept_checks = xyes ; then
 287     case $gxx_version in
 288       3.3*)
 289         lyx_flags="$lyx_flags concept-checks"
 290         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 291         ;;
 292       3.4*|4.*)
 293         lyx_flags="$lyx_flags concept-checks"
 294         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 295         ;;
 296     esac
 297   fi
 298   if test x$enable_cxx11 = xyes ; then
 299       case $gxx_version in
 300           4.3*|4.4*|4.5*|4.6*)
 301               lyx_flags="$lyx_flags c++11-mode"
 302               CXXFLAGS="-std=gnu++0x $CXXFLAGS"
 303               ;;
 304           4.7*|4.8*)
 305               lyx_flags="$lyx_flags c++11-mode"
 306               CXXFLAGS="-std=gnu++11 $CXXFLAGS"
 307               ;;
 308       esac
 309   fi
 310 fi
 311 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 312 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 313 ])dnl
 314
 315 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 316 dnl        be used.
 317 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 318         AC_MSG_CHECKING([whether to use included boost library])
 319         AC_ARG_WITH(included-boost,
 320             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 321             [lyx_cv_with_included_boost=$withval],
 322             [lyx_cv_with_included_boost=yes])
 323         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 324         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 325         if test x$lyx_cv_with_included_boost = xyes ; then
 326             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 327             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 328         else
 329             AC_LANG_PUSH(C++)
 330             save_LIBS=$LIBS
 331
 332             AC_MSG_CHECKING([for multithreaded boost libraries])
 333             LIBS="$save_LIBS -lboost_signals-mt -lm $LIBTHREAD"
 334             AC_LINK_IFELSE(
 335                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 336                         [boost::signal<void ()> s;])],
 337                 [AC_MSG_RESULT([yes])
 338                  BOOST_MT="-mt"],
 339                 [AC_MSG_RESULT([no])
 340                  AC_MSG_CHECKING([for plain boost libraries])
 341                  LIBS="$save_LIBS -lboost_signals -lm"
 342                  AC_LINK_IFELSE(
 343                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 344                              [boost::signal<void ()> s;])],
 345                      [AC_MSG_RESULT([yes])
 346                       BOOST_MT=""],
 347                      [AC_MSG_RESULT([no])
 348                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 349                  ])
 350             ])
 351             LIBS=$save_LIBS
 352             AC_LANG_POP(C++)
 353             BOOST_INCLUDES=
 354             BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 355         fi
 356         AC_SUBST(BOOST_INCLUDES)
 357         AC_SUBST(BOOST_LIBS)
 358 ])
 359
 360
 361 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 362 dnl        necessary APIs are available to print callstacks.
 363 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 364 [AC_CACHE_CHECK([whether printing callstack is possible],
 365                [lyx_cv_callstack_printing],
 366 [AC_TRY_COMPILE([
 367 #include <execinfo.h>
 368 #include <cxxabi.h>
 369 ], [
 370         void* array[200];
 371         size_t size = backtrace(array, 200);
 372         backtrace_symbols(array, size);
 373         int status = 0;
 374         abi::__cxa_demangle("abcd", 0, 0, &status);
 375 ],
 376 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 377 if test x"$lyx_cv_callstack_printing" = xyes; then
 378   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 379             [Define if callstack can be printed])
 380 fi
 381 ])
 382
 383
 384 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 385 dnl        be used.
 386 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 387         AC_MSG_CHECKING([whether to use included MyThes library])
 388         AC_ARG_WITH(included-mythes,
 389             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 390             [lyx_cv_with_included_mythes=$withval],
 391             [lyx_cv_with_included_mythes=yes])
 392         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 393         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 394         if test x$lyx_cv_with_included_mythes != xyes ; then
 395                 AC_LANG_PUSH(C++)
 396                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 397                 if test x$ac_cv_header_mythes_h != xyes; then
 398                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 399                 fi
 400                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 401                 if test x$lyx_mythes != xyes; then
 402                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 403                 fi
 404                 AC_LANG_POP(C++)
 405                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 406                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 407                 fi
 408                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 409                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 410                 AC_SUBST(MYTHES_LIBS)
 411         fi
 412 ])
 413
 414
 415 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 416 dnl                       [default-yes-value])
 417 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 418 dnl  resulting directory name in 'dir-var-name'.
 419 AC_DEFUN([LYX_WITH_DIR],[
 420   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 421   AC_MSG_CHECKING([for $2])
 422   if test -z "$with_$3"; then
 423      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 424   else
 425     test "x$with_$3" = xyes && with_$3=$5
 426     lyx_cv_$3="$with_$3"
 427   fi
 428   AC_MSG_RESULT($lyx_cv_$3)])
 429
 430
 431 dnl Usage: LYX_LOOP_DIR(value,action)
 432 dnl Executes action for values of variable `dir' in `values'. `values' can
 433 dnl use ":" as a separator.
 434 AC_DEFUN([LYX_LOOP_DIR],[
 435 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 436 for dir in `eval "echo $1"`; do
 437   if test ! "$dir" = NONE; then
 438     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 439     $2
 440   fi
 441 done
 442 IFS=$ac_save_ifs
 443 ])
 444
 445
 446 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 447 dnl var-name.
 448 AC_DEFUN([LYX_ADD_LIB_DIR],[
 449 $1="${$1} -L$2"
 450 if test "`(uname) 2>/dev/null`" = SunOS &&
 451     uname -r | grep '^5' >/dev/null; then
 452   if test $ac_cv_prog_gxx = yes ; then
 453     $1="${$1} -Wl[,]-R$2"
 454   else
 455     $1="${$1} -R$2"
 456   fi
 457 fi])
 458
 459
 460 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 461 dnl var-name.
 462 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 463
 464 ### Check for a headers existence and location iff it exists
 465 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 466 ## It almost works.  I've tried a few variations but they give errors
 467 ## of one sort or other: bad substitution or file not found etc.  The
 468 ## actual header _is_ found though and the cache variable is set however
 469 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 470 ## reason.
 471 ## Additionally, autoheader can't figure out what to use as the name in
 472 ## the config.h.in file so we need to write our own entries there -- one for
 473 ## each header in the form PATH_HEADER_NAME_H
 474 ##
 475 AC_DEFUN([LYX_PATH_HEADER],
 476 [ AC_CHECK_HEADER($1,[
 477   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 478 ### the only remaining problem is getting the second parameter to this
 479 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 480 ### of $ac_safe being printed.
 481   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 482   [ cat > conftest.$ac_ext <<EOF
 483 #line __oline__ "configure"
 484 #include "confdefs.h"
 485
 486 #include <$1>
 487 EOF
 488 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 489   grep $1  2>/dev/null | \
 490   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 491 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 492 rm -f conftest*])
 493   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 494 ])
 495 ### end of LYX_PATH_HEADER
 496
 497 ## Check what kind of packaging should be used at install time.
 498 ## The default is autodetected.
 499 AC_DEFUN([LYX_USE_PACKAGING],
 500 [AC_MSG_CHECKING([what packaging should be used])
 501 AC_ARG_WITH(packaging,
 502   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 503                             Possible values: posix, windows, macosx])],
 504   [lyx_use_packaging="$withval"], [
 505   case $host in
 506     *-apple-darwin*) lyx_use_packaging=macosx ;;
 507      *-pc-mingw32*) lyx_use_packaging=windows;;
 508                   *) lyx_use_packaging=posix;;
 509   esac])
 510 AC_MSG_RESULT($lyx_use_packaging)
 511 lyx_install_posix=false
 512 lyx_install_macosx=false
 513 lyx_install_cygwin=false
 514 lyx_install_windows=false
 515 case $lyx_use_packaging in
 516    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 517            PACKAGE=LyX${version_suffix}
 518            default_prefix="/Applications/${PACKAGE}.app"
 519            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 520            bindir='${prefix}/Contents/MacOS'
 521            libdir='${prefix}/Contents/Resources'
 522            datarootdir='${prefix}/Contents/Resources'
 523            pkgdatadir='${datadir}'
 524            mandir='${datadir}/man'
 525            lyx_install_macosx=true ;;
 526   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 527            PACKAGE=LyX${version_suffix}
 528            default_prefix="C:/Program Files/${PACKAGE}"
 529            bindir='${prefix}/bin'
 530            libdir='${prefix}/Resources'
 531            datarootdir='${prefix}/Resources'
 532            pkgdatadir='${datadir}'
 533            mandir='${prefix}/Resources/man'
 534            lyx_install_windows=true ;;
 535     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 536            PACKAGE=lyx${version_suffix}
 537            program_suffix=$version_suffix
 538            pkgdatadir='${datadir}/${PACKAGE}'
 539            default_prefix=$ac_default_prefix
 540            case ${host} in
 541            *cygwin*) lyx_install_cygwin=true ;;
 542                 *apple-darwin*) lyx_install_macosx=true ;;
 543            esac
 544            lyx_install_posix=true ;;
 545     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 546 esac
 547 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 548 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 549 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 550 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 551 AC_SUBST(pkgdatadir)
 552 AC_SUBST(program_suffix)
 553 ])
 554
 555
 556 ## ------------------------------------------------------------------------
 557 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 558 ## one or two arguments.
 559 ##
 560 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 561 ## ------------------------------------------------------------------------
 562 ##
 563 AC_DEFUN([AC_FUNC_MKDIR],
 564 [AC_CHECK_FUNCS([mkdir _mkdir])
 565 AC_CACHE_CHECK([whether mkdir takes one argument],
 566                [ac_cv_mkdir_takes_one_arg],
 567 [AC_TRY_COMPILE([
 568 #include <sys/stat.h>
 569 #if HAVE_UNISTD_H
 570 #  include <unistd.h>
 571 #endif
 572 ], [mkdir (".");],
 573 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 574 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 575   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 576             [Define if mkdir takes only one argument.])
 577 fi
 578 ])
 579
 580
 581 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 582 dnl (which may be a relative path, and need not refer to any existing
 583 dnl entity).
 584
 585 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 586 dnl native Win32 path name, (but with slashes, not backslashes).
 587
 588 dnl On any other system, it is simply the result which would be obtained
 589 dnl if PATHNAME represented an existing directory, and the pwd command was
 590 dnl executed in that directory.
 591 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 592 [ac_dir="$2"
 593  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 594     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 595  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 596  do
 597    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 598  done
 599  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 600  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 601  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 602    s?/*$[]??'`
 603 ])
 604
 605 dnl this is used by the macro blow to general a proper config.h.in entry
 606 m4_define([LYX_AH_CHECK_DECL],
 607 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 608   [Define if you have the prototype for function `$1'])])
 609
 610 dnl Check things are declared in headers to avoid errors or warnings.
 611 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 612 dnl Defines HAVE_DECL_{FUNCTION}
 613 AC_DEFUN([LYX_CHECK_DECL],
 614 [LYX_AH_CHECK_DECL($1)
 615 for ac_header in $2
 616 do
 617   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 618   AC_EGREP_HEADER($1, $ac_header,
 619       [AC_MSG_RESULT(yes)
 620        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 621        break],
 622       [AC_MSG_RESULT(no)])
 623 done])
 624
 625 dnl this is used by the macro below to generate a proper config.h.in entry
 626 m4_define([LYX_AH_CHECK_DEF],
 627 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 628   [Define to 1 if `$1' is defined in `$2'])])
 629
 630 dnl Check whether name is defined in header by using it in codesnippet.
 631 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 632 dnl Defines HAVE_DEF_{NAME}
 633 AC_DEFUN([LYX_CHECK_DEF],
 634 [LYX_AH_CHECK_DEF($1, $2)
 635  AC_MSG_CHECKING([whether $1 is defined by header $2])
 636  AC_TRY_COMPILE([#include <$2>], [$3],
 637      lyx_have_def_name=yes,
 638      lyx_have_def_name=no)
 639  AC_MSG_RESULT($lyx_have_def_name)
 640  if test "x$lyx_have_def_name" = xyes; then
 641    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 642  fi
 643 ])
 644
 645 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 646 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 647 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 648 AC_DEFUN([LYX_SET_VERSION_INFO],
 649 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 650  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 651  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 652  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 653  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 654  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 655  test "x$lyx_patch" = "x" && lyx_patch=0
 656  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 657  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 658  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 659  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 660  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 661  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 662  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 663  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 664 ])
 665
 666 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 667 # ---------------------------------------------------------------------------
 668 # Copied from autoconf 2.68, added a check that python version is < 3.0
 669 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 670 # Run ACTION-IF-FALSE otherwise.
 671 # This test uses sys.hexversion instead of the string equivalent (first
 672 # word of sys.version), in order to cope with versions such as 2.2c1.
 673 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 674 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 675  [prog="import sys
 676 # split strings by '.' and convert to numeric.  Append some zeros
 677 # because we need at least 4 digits for the hex conversion.
 678 # map returns an iterator in Python 3.0 and a list in 2.x
 679 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 680 minverhex = 0
 681 maxverhex = 50331648 # = 3.0.0.0
 682 # xrange is not present in Python 3.0 and range returns an iterator
 683 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 684 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 685   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])