config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variables "lyx_devel_version" and "lyx_prerelease"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 changequote(, ) dnl
  11 echo "configuring LyX version $VERSION"
  12 if echo "$VERSION" | grep 'cvs' >/dev/null ; then
  13   lyx_devel_version=yes
  14   echo "WARNING: This is a development version. Expect bugs."
  15 else
  16   lyx_devel_version=no
  17 fi
  18 if echo "$VERSION" | grep 'pre' > /dev/null ; then
  19     lyx_prerelease=yes
  20     echo "WARNING: This is a prerelease. Be careful and backup your documents."
  21 else
  22     lyx_prerelease=no
  23 fi
  24 changequote([, ]) dnl
  25 AC_SUBST(lyx_devel_version)
  26 if test $lyx_devel_version = yes ; then
  27   AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  28 fi])
  29
  30
  31 dnl Define the option to set a LyX version on installed executables and directories
  32 dnl
  33 dnl
  34 AC_DEFUN([LYX_VERSION_SUFFIX],[
  35 AC_MSG_CHECKING([for install target ... ])
  36 AC_ARG_WITH(version-suffix,
  37   [  --with-version-suffix[=<version>]  install lyx files as lyx<version>],
  38   [if test "x$withval" = "xyes";
  39    then
  40      withval="-$VERSION"
  41      ac_configure_args=`echo $ac_configure_args | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  42    fi
  43    lyxname="lyx$withval"
  44    program_suffix=$withval],
  45   [lyxname=lyx])
  46 AC_MSG_RESULT([$lyxname])
  47 ])
  48
  49
  50 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  51 dnl flag lyx_error to yes.
  52 AC_DEFUN([LYX_ERROR],[
  53 lyx_error_txt="$lyx_error_txt
  54 ** $1
  55 "
  56 lyx_error=yes])
  57
  58
  59 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  60 dnl flag lyx_warning to yes.
  61 AC_DEFUN([LYX_WARNING],[
  62 lyx_warning_txt="$lyx_warning_txt
  63 == $1
  64 "
  65 lyx_warning=yes])
  66
  67
  68 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  69 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  70 AC_DEFUN([LYX_LIB_ERROR],[
  71 LYX_ERROR([Cannot find $1. Please check that the $2 library
  72    is correctly installed on your system.])])
  73
  74
  75 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  76 dnl   has occured previously.
  77 AC_DEFUN([LYX_CHECK_ERRORS],[
  78 if test x$lyx_error = xyes; then
  79 cat <<EOF
  80 **** The following problems have been detected by configure.
  81 **** Please check the messages below before running 'make'.
  82 **** (see the section 'Problems' in the INSTALL file)
  83 $lyx_error_txt
  84 $lyx_warning_txt
  85 EOF
  86 else
  87
  88 if test x$lyx_warning = xyes; then
  89 cat <<EOF
  90 === The following minor problems have been detected by configure.
  91 === Please check the messages below before running 'make'.
  92 === (see the section 'Problems' in the INSTALL file)
  93 $lyx_warning_txt
  94 EOF
  95 fi
  96 cat <<EOF
  97 Configuration of LyX was successful.
  98 Type 'make' to compile the program,
  99 and then 'make install' to install it.
 100 EOF
 101 fi])
 102
 103
 104 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 105 dnl
 106 define(LYX_SEARCH_PROG,[dnl
 107 for ac_prog in $2 ; do
 108 # Extract the first word of "$ac_prog", so it can be a program name with args.
 109   set dummy $ac_prog ; ac_word=$[2]
 110   if test -z "[$]$1"; then
 111     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 112     for ac_dir in $PATH; do
 113       test -z "$ac_dir" && ac_dir=.
 114       if test -f [$ac_dir/$ac_word]; then
 115         $1="$ac_prog"
 116         break
 117       fi
 118     done
 119     IFS="$ac_save_ifs"
 120   fi
 121
 122   if test -n "[$]$1"; then
 123     ac_result=yes
 124   else
 125     ac_result=no
 126   fi
 127   ifelse($3,,,[$3])
 128   test -n "[$]$1" && break
 129 done
 130 ])dnl
 131
 132
 133 AC_DEFUN([LYX_PROG_CXX_WORKS],
 134 [rm -f conftest.C
 135 cat >conftest.C <<EOF
 136 class foo {
 137    // we require the mutable keyword
 138    mutable int bar;
 139  };
 140  // we require namespace support
 141  namespace baz {
 142    int bar;
 143  }
 144  int main() {
 145    return(0);
 146  }
 147 EOF
 148 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 149 rm -f conftest.C conftest.o conftest.obj || true
 150 ])
 151
 152
 153 AC_DEFUN([LYX_PROG_CXX],
 154 [AC_MSG_CHECKING([for a good enough C++ compiler])
 155 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 156
 157 if test -z "$CXX" ; then
 158   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 159 fi
 160 AC_MSG_RESULT($CXX)
 161
 162 AC_PROG_CXX
 163
 164 ### We might want to get or shut warnings.
 165 AC_ARG_ENABLE(warnings,
 166   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 167   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 168         enable_warnings=yes;
 169     else
 170         enable_warnings=no;
 171     fi;])
 172 if test x$enable_warnings = xyes ; then
 173   lyx_flags="$lyx_flags warnings"
 174   AC_DEFINE(WITH_WARNINGS, 1,
 175   [Define this if you want to see the warning directives put here and
 176    there by the developpers to get attention])
 177 fi
 178
 179 ### We might want to disable debug
 180 AC_ARG_ENABLE(debug,
 181   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 182   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 183         enable_debug=yes;
 184     else
 185         enable_debug=no;
 186     fi;])
 187
 188 ### set up optimization
 189 AC_ARG_ENABLE(optimization,
 190   AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 191         enable_optimization=yes;)
 192 case $enable_optimization in
 193   yes) lyx_opt=-O;;
 194    no) lyx_opt=;;
 195     *) lyx_opt=${enable_optimization};;
 196 esac
 197
 198 # set the debug flags correctly.
 199 if test x$GXX = xyes; then
 200   dnl Useful for global version info
 201   gxx_version=`${CXX} -dumpversion`
 202   CXX_VERSION="($gxx_version)"
 203
 204   if test "$ac_test_CXXFLAGS" = set; then
 205     CXXFLAGS="$ac_save_CXXFLAGS"
 206   else
 207     case $gxx_version in
 208       2.95.1)  CXXFLAGS="$lyx_opt -fpermissive -ftemplate-depth-30";;
 209       2.95.*)  CXXFLAGS="$lyx_opt -Wno-non-template-friend -ftemplate-depth-30";;
 210       2.96*)  CXXFLAGS="$lyx_opt -fno-exceptions -ftemplate-depth-30 -Wno-non-template-friend";;
 211       3.0*)    CXXFLAGS="$lyx_opt";;
 212       3.1*)    CXXFLAGS="$lyx_opt -finline-limit=500 -fno-exceptions";;
 213       3.2*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 214       3.3*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 215       3.4*|3.5*)    CXXFLAGS="$lyx_opt -fno-exceptions";;
 216       *)       CXXFLAGS="$lyx_opt";;
 217     esac
 218     if test x$enable_debug = xyes ; then
 219         case $gxx_version in
 220             3.4*|3.5*) CXXFLAGS="-g $CXXFLAGS"
 221                 AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 222                 AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 223                 ;;
 224             *)    CXXFLAGS="-g $CXXFLAGS";;
 225         esac
 226     fi
 227   fi
 228   if test x$enable_warnings = xyes ; then
 229     case $gxx_version in
 230         2.95.*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 231         2.96*)  CXXFLAGS="$CXXFLAGS -W -Wall";;
 232         3.1*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 233         3.2*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 234         3.3*) CXXFLAGS="$CXXFLAGS -W -Wall";;
 235         *)    CXXFLAGS="$CXXFLAGS -Wextra -Wall";;
 236     esac
 237   fi
 238 fi])dnl
 239
 240
 241 dnl NOT USED CURRENTLY*************************************
 242 dnl Usage: LYX_CXX_RTTI : checks whether the C++ compiler
 243 dnl   supports RTTI
 244 AC_DEFUN([LYX_CXX_RTTI],[
 245 ### Check whether the compiler supports runtime type information
 246 AC_CACHE_CHECK(whether the C++ compiler supports RTTI,lyx_cv_rtti,
 247  [AC_TRY_RUN([
 248 class rtti {
 249 public:
 250    virtual int tag() { return 0; }
 251 };
 252 class derived1 : public rtti {
 253 public:
 254     int tag() { return 1; }
 255 };
 256 class derived2 : public rtti {
 257 public:
 258     int tag() { return 2; }
 259 };
 260 int main() {
 261     derived1 * foo1 = new derived1();
 262     derived2 * foo2 = new derived2();
 263     rtti * bar = foo1;
 264     derived1 * bar1 = dynamic_cast<derived1 *>(bar);
 265     if (bar1 == 0)
 266         exit(1);
 267     bar = foo2;
 268     bar1 = dynamic_cast<derived1 *>(bar);
 269     if (bar1 != 0)
 270         exit(1);
 271     return 0;
 272 }
 273 ],lyx_cv_rtti=yes,lyx_cv_rtti=no,lyx_cv_rtti=no)
 274 ])
 275 if test x$lyx_cv_rtti = xyes ; then
 276   AC_DEFINE(HAVE_RTTI, 1,
 277    [Define to 1 if your compiler supports runtime type information])
 278 fi])
 279
 280
 281 dnl Usage: LYX_CXX_EXPLICIT : checks whether the C++ compiler
 282 dnl   understands the "explicit" directive.
 283 AC_DEFUN([LYX_CXX_EXPLICIT],[
 284 ### Check whether the compiler understands the keyword `explicit'
 285 AC_CACHE_CHECK(whether the C++ compiler understands explicit,lyx_cv_explicit,
 286  [AC_TRY_COMPILE([
 287 class Expl {
 288 public:
 289         explicit Expl() {}
 290 };],,lyx_cv_explicit=yes,lyx_cv_explicit=no)
 291 ])
 292 if test $lyx_cv_explicit = no ; then
 293   AC_DEFINE(explicit,[ ],
 294    [Define to nothing if your compiler does not understand the
 295    'explicit' directive])
 296 fi])
 297
 298
 299 dnl NOT USED CURRENTLY*************************************
 300 dnl Usage: LYX_CXX_STL_STACK : checks whether the C++ compiler
 301 dnl   has a working stl stack template
 302 AC_DEFUN([LYX_CXX_STL_STACK],[
 303 AC_CACHE_CHECK(for broken STL stack template,lyx_cv_broken_stack,
 304  [AC_TRY_COMPILE([
 305 #include <stack>
 306 using std::stack;
 307 ],[
 308     stack<int> stakk;
 309     stakk.push(0);
 310 ],lyx_cv_broken_stack=no,lyx_cv_broken_stack=yes)
 311 ])
 312 if test $lyx_cv_broken_stack = yes ; then
 313   AC_DEFINE(BROKEN_STL_STACK, 1,
 314    [Define if you have the STL from libg++ 2.7.x, where stack<> is not defined
 315    correctly])
 316 fi])
 317
 318
 319 dnl Usage: LYX_STD_COUNT : checks wherer the C++ library have a conforming
 320 dnl    count template, if not the old HP version is assumed.
 321 AC_DEFUN([LYX_STD_COUNT],[
 322 AC_CACHE_CHECK(for conforming std::count,lyx_cv_std_count,
 323  [AC_TRY_COMPILE([
 324 #include <algorithm>
 325 using std::count;
 326 int countChar(char * b, char * e, char const c)
 327 {
 328         return count(b, e, c);
 329 }
 330 ],[
 331     char a[] = "hello";
 332     int i = countChar(a, a + 5, 'l');
 333 ],lyx_cv_std_count=yes,lyx_cv_std_count=no)
 334 ])
 335 if test $lyx_cv_std_count = yes ; then
 336     AC_DEFINE(HAVE_STD_COUNT, 1,
 337     [Define if you have a conforming std::count template, otherwise HP version of count template is assumed.])
 338 fi])
 339
 340
 341 dnl Usage: LYX_CXX_STL_MODERN_STREAMS : checks whether the C++ compiler
 342 dnl   supports modern STL streams
 343 AC_DEFUN([LYX_CXX_STL_MODERN_STREAMS],[
 344 AC_CACHE_CHECK(for modern STL streams,lyx_cv_modern_streams,
 345  [AC_TRY_COMPILE([
 346 #include <iostream>
 347 ],[
 348  std::streambuf * test = std::cerr.rdbuf();
 349  test->pubsync();
 350 ],lyx_cv_modern_streams=yes,lyx_cv_modern_streams=no)
 351 ])
 352 if test $lyx_cv_modern_streams = yes ; then
 353   AC_DEFINE(MODERN_STL_STREAMS, 1,
 354    [Define if you have modern standard-compliant STL streams])
 355 fi])
 356
 357
 358 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 359 dnl        be used.
 360 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 361         AC_ARG_WITH(included-boost,
 362             [  --with-included-boost  use the boost lib supplied with LyX],
 363             [lyx_cv_with_included_boost=$withval
 364                 AC_MSG_RESULT([$with_included_boost])],
 365             [lyx_cv_with_included_boost=yes])
 366         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 367 ])
 368
 369
 370 dnl NOT USED CURRENTLY*************************************
 371 dnl LYX_CXX_PARTIAL
 372 AC_DEFUN([LYX_CXX_PARTIAL], [
 373     AC_REQUIRE([AC_PROG_CXX])
 374     AC_CACHE_CHECK([if C++ compiler supports partial specialization],
 375         [lyx_cv_cxx_partial_specialization],
 376         [AC_TRY_COMPILE(
 377             [
 378             template<class T, class K>
 379             class k {
 380             public:
 381             };
 382             template<class T> class k<void,T> { };
 383             ],[
 384             k<float, float> b;
 385             k<void,void> a;
 386             ],[
 387             lyx_cv_cxx_partial_specialization=yes
 388             ],[
 389             lyx_cv_cxx_partial_specialization=no
 390             ])
 391         ])
 392     if test x$lyx_cv_cxx_partial_specialization = xyes ; then
 393         AC_DEFINE(HAVE_PARTIAL_SPECIALIZATION, 1,
 394         [Defined if your compiler supports partial specialization.])
 395     fi
 396 ])
 397
 398
 399 dnl Usage: LYX_CXX_CHEADERS : checks whether the C++ compiler
 400 dnl   provides wrappers for C headers and use our alternate version otherwise.
 401 AC_DEFUN([LYX_CXX_CHEADERS],[
 402 AC_CACHE_CHECK(for C headers wrappers,lyx_cv_cxx_cheaders,
 403  [AC_TRY_CPP([
 404 #include <clocale>
 405 #include <cctype>
 406 #include <cerrno>
 407 #include <cmath>
 408 #include <csignal>
 409 #include <cstdio>
 410 #include <cstdlib>
 411 #include <cstring>
 412 #include <ctime>],[lyx_cv_cxx_cheaders=yes],[lyx_cv_cxx_cheaders=no])])
 413 if test $lyx_cv_cxx_cheaders = no ; then
 414   LYX_ADD_INC_DIR(lyx_cppflags,\$(top_srcdir)/src/cheaders)
 415 fi])
 416
 417
 418 dnl Usage: LYX_CXX_GLOBAL_CSTD: checks whether C library functions
 419 dnl   are already in the global namespace
 420 AC_DEFUN([LYX_CXX_GLOBAL_CSTD],[
 421     AC_CACHE_CHECK(whether C library functions are already in the global namespace,
 422     lyx_cv_cxx_global_cstd,
 423     [AC_TRY_COMPILE([
 424     #include <cctype>
 425     using std::tolower;
 426     ],[
 427     return 0;
 428     ],[lyx_cv_cxx_global_cstd=no],[lyx_cv_cxx_global_cstd=yes])])
 429     if test x$lyx_cv_cxx_global_cstd = xyes; then
 430         AC_DEFINE(CXX_GLOBAL_CSTD,1,
 431         [Define if your C++ compiler puts C library functions in the global namespace])
 432     fi
 433 ])
 434
 435
 436 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 437 dnl                       [default-yes-value])
 438 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 439 dnl  resulting directory name in 'dir-var-name'.
 440 AC_DEFUN([LYX_WITH_DIR],[
 441   AC_ARG_WITH($1,[  --with-$1        specify $2])
 442   AC_MSG_CHECKING([for $2])
 443   if test -z "$with_$3"; then
 444      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 445   else
 446     test "x$with_$3" = xyes && with_$3=$5
 447     lyx_cv_$3="$with_$3"
 448   fi
 449   AC_MSG_RESULT($lyx_cv_$3)])
 450
 451
 452 dnl Usage: LYX_LOOP_DIR(value,action)
 453 dnl Executes action for values of variable `dir' in `values'. `values' can
 454 dnl use ":" as a separator.
 455 AC_DEFUN([LYX_LOOP_DIR],[
 456 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 457 for dir in `eval "echo $1"`; do
 458   if test ! "$dir" = NONE; then
 459     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 460     $2
 461   fi
 462 done
 463 IFS=$ac_save_ifs
 464 ])
 465
 466
 467 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 468 dnl var-name.
 469 AC_DEFUN([LYX_ADD_LIB_DIR],[
 470 $1="${$1} -L$2"
 471 if test "`(uname) 2>/dev/null`" = SunOS &&
 472     uname -r | grep '^5' >/dev/null; then
 473   if test $ac_cv_prog_gxx = yes ; then
 474     $1="${$1} -Wl[,]-R$2"
 475   else
 476     $1="${$1} -R$2"
 477   fi
 478 fi])
 479
 480
 481 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 482 dnl var-name.
 483 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 484
 485 ### Check for a headers existence and location iff it exists
 486 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 487 ## It almost works.  I've tried a few variations but they give errors
 488 ## of one sort or other: bad substitution or file not found etc.  The
 489 ## actual header _is_ found though and the cache variable is set however
 490 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 491 ## reason.
 492 ## Additionally, autoheader can't figure out what to use as the name in
 493 ## the config.h.in file so we need to write our own entries there -- one for
 494 ## each header in the form PATH_HEADER_NAME_H
 495 ##
 496 AC_DEFUN([LYX_PATH_HEADER],
 497 [ AC_CHECK_HEADER($1,[
 498   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 499 ### the only remaining problem is getting the second parameter to this
 500 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 501 ### of $ac_safe being printed.
 502   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 503   [ cat > conftest.$ac_ext <<EOF
 504 #line __oline__ "configure"
 505 #include "confdefs.h"
 506
 507 #include <$1>
 508 EOF
 509 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 510   grep $1  2>/dev/null | \
 511   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 512 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 513 rm -f conftest*])
 514   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 515 ])
 516 ### end of LYX_PATH_HEADER
 517
 518 ### Check which frontends we want to use. The default is XForms only
 519 ###
 520 AC_DEFUN([LYX_USE_FRONTENDS],
 521 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 522 AC_ARG_WITH(frontend,
 523   [  --with-frontend=THIS    Use THIS frontend as main GUI:
 524                             Possible values: xforms, qt],
 525   [FRONTENDS="$withval"], [FRONTENDS="xforms"])
 526 AC_MSG_RESULT($FRONTENDS)
 527 AC_SUBST(FRONTENDS)
 528 AC_SUBST(FRONTENDS_SUBDIRS)
 529 AC_SUBST(FRONTENDS_PROGS)
 530 ])
 531
 532
 533
 534 ## ------------------------------------------------------------------------
 535 ## Find a file (or one of more files in a list of dirs)
 536 ## ------------------------------------------------------------------------
 537 ##
 538 AC_DEFUN([AC_FIND_FILE],
 539 [
 540 $3=NO
 541 for i in $2;
 542 do
 543   for j in $1;
 544   do
 545     if test -r "$i/$j"; then
 546       $3=$i
 547       break 2
 548     fi
 549   done
 550 done
 551 ])
 552
 553 dnl just a wrapper to clean up configure.in
 554 AC_DEFUN([LYX_PROG_LIBTOOL],
 555 [
 556 AC_REQUIRE([AC_ENABLE_SHARED])
 557 AC_REQUIRE([AC_ENABLE_STATIC])
 558 dnl libtool is only for C, so I must force him
 559 dnl to find the correct flags for C++
 560 ac_save_cc=$CC
 561 ac_save_cflags="$CFLAGS"
 562 CC=$CXX
 563 CFLAGS="$CXXFLAGS"
 564 AM_PROG_LIBTOOL dnl for libraries
 565 CC=$ac_save_cc
 566 CFLAGS="$ac_save_cflags"
 567 ])