config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CXXFLAGS=$CXXFLAGS
 155   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 156   AC_LANG_PUSH(C++)
 157   AC_TRY_COMPILE([], [
 158 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 159             this is a c++11 compiler
 160 #endif
 161   ],
 162   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 163  AC_LANG_POP(C++)
 164  CXXFLAGS=$save_CXXFLAGS])
 165 lyx_use_cxx11=$lyx_cv_cxx_cxx11
 166 ])
 167
 168
 169 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 170 AC_DEFUN([LYX_LIB_STDCXX],
 171 [AC_CACHE_CHECK([whether STL is libstdc++],
 172                [lyx_cv_lib_stdcxx],
 173 [AC_TRY_COMPILE([#include<vector>], [
 174 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 175             this is not libstdc++
 176 #endif
 177 ],
 178 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 179 ])
 180
 181
 182 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 183 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 184 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 185 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 186                [lyx_cv_lib_stdcxx_cxx11_abi],
 187 [AC_TRY_COMPILE([#include<vector>], [
 188 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 189             this is not libstdc++ using the C++11 ABI
 190 #endif
 191 ],
 192 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 193 ])
 194
 195
 196 AC_DEFUN([LYX_PROG_CXX],
 197 [AC_REQUIRE([AC_PROG_CXX])
 198 AC_REQUIRE([AC_PROG_CXXCPP])
 199
 200 AC_LANG_PUSH(C++)
 201 LYX_PROG_CLANG
 202 LYX_LIB_STDCXX
 203 LYX_LIB_STDCXX_CXX11_ABI
 204 AC_LANG_POP(C++)
 205
 206 if test $lyx_cv_lib_stdcxx = "yes" ; then
 207   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 208     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 209   else
 210     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 211   fi
 212 else
 213   if test $lyx_cv_prog_clang = "yes" ; then
 214     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 215   fi
 216 fi
 217
 218 ### We might want to get or shut warnings.
 219 AC_ARG_ENABLE(warnings,
 220   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 221   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 222         enable_warnings=yes;
 223     else
 224         enable_warnings=no;
 225     fi;])
 226 if test x$enable_warnings = xyes ; then
 227   lyx_flags="$lyx_flags warnings"
 228 fi
 229
 230 ### We might want to disable debug
 231 AC_ARG_ENABLE(debug,
 232   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 233   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 234 )
 235
 236 AC_ARG_ENABLE(stdlib-debug,
 237   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 238   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 239           [enable_stdlib_debug=no])]
 240 )
 241
 242 AC_ARG_ENABLE(concept-checks,
 243   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 244   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 245           [enable_concept_checks=no])]
 246   if test x$USE_QT5 = xyes ; then
 247       enable_concept_checks=no
 248   fi
 249 )
 250
 251 ### set up optimization
 252 AC_ARG_ENABLE(optimization,
 253     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 254     enable_optimization=yes;)
 255 case $enable_optimization in
 256     yes)
 257         if test $lyx_devel_version = yes ; then
 258             lyx_optim=-O
 259         else
 260             lyx_optim=-O2
 261         fi;;
 262     no) lyx_optim=;;
 263     *) lyx_optim=${enable_optimization};;
 264 esac
 265
 266 AC_ARG_ENABLE(pch,
 267   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 268         enable_pch=no;)
 269 lyx_pch_comp=no
 270
 271 AC_ARG_ENABLE(cxx11,
 272   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode (default: enabled for known good compilers)]),,
 273   enable_cxx11=auto;)
 274
 275 AC_ARG_ENABLE(assertions,
 276   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 277   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 278           [enable_assertions=no])]
 279 )
 280 if test "x$enable_assertions" = xyes ; then
 281    lyx_flags="$lyx_flags assertions"
 282    AC_DEFINE(ENABLE_ASSERTIONS,1,
 283     [Define if you want assertions to be enabled in the code])
 284 fi
 285
 286 # set the compiler options correctly.
 287 lyx_std_regex=no
 288 if test x$GXX = xyes; then
 289   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 290   if test x$CLANG = xno; then
 291     dnl Useful for global version info
 292     gxx_version=`${CXX} -dumpversion`
 293     CXX_VERSION="($gxx_version)"
 294   else
 295     gxx_version=clang
 296   fi
 297
 298   AM_CXXFLAGS="$lyx_optim"
 299   if test x$enable_debug = xyes ; then
 300       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 301   fi
 302   if test $build_type = gprof ; then
 303     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 304     AM_LDFLAGS="$AM_LDFLAGS -pg"
 305   fi
 306   if test $build_type = profiling ; then
 307     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 308   fi
 309
 310   if test x$USE_QT5 = xyes ; then
 311       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 312   fi
 313   dnl Warnings are for preprocessor too
 314   if test x$enable_warnings = xyes ; then
 315       case $gxx_version in
 316           4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*|clang)
 317               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 318               ;;
 319           *)
 320               AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra -Wfloat-conversion"
 321               ;;
 322       esac
 323   fi
 324   case $gxx_version in
 325       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 326       *)  test $enable_pch = yes && lyx_pch_comp=yes ;;
 327   esac
 328   if test x$enable_stdlib_debug = xyes ; then
 329     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 330     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 331     case $gxx_version in
 332       *)
 333         lyx_flags="$lyx_flags stdlib-debug"
 334         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 335         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 336         ;;
 337     esac
 338   fi
 339   if test x$enable_concept_checks = xyes ; then
 340     case $gxx_version in
 341       4.*)
 342         lyx_flags="$lyx_flags concept-checks"
 343         dnl FIXME check whether this makes sense with clang/libc++
 344         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 345         ;;
 346     esac
 347   fi
 348   dnl enable_cxx11 can be yes/no/auto.
 349   dnl By default, it is auto and we enable C++11 when possible
 350   if test x$enable_cxx11 != xno ; then
 351     case $gxx_version in
 352       4.0*|4.1*|4.2*)
 353          if x$enable_cxx11 = xyes; then
 354             AC_ERROR([There is no C++11 support in gcc 4.2 or older])
 355          fi;;
 356       4.3*|4.4*|4.5*|4.6*)
 357         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 358         dnl The source code relies on that.
 359         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++0x";;
 360       clang)
 361         dnl presumably all clang version support c++11.
 362         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 363         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11 -Wno-deprecated-register";;
 364       *)
 365         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11";;
 366     esac
 367   fi
 368
 369   LYX_CXX_CXX11
 370   if test $lyx_use_cxx11 = yes ; then
 371     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 372       dnl <regex> in gcc is unusable in versions less than 4.9.0
 373       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 374       case $gxx_version in
 375         4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 376         *) lyx_std_regex=yes ;;
 377       esac
 378     else
 379       lyx_std_regex=yes
 380     fi
 381
 382     if test $lyx_std_regex = yes ; then
 383       lyx_flags="$lyx_flags stdregex"
 384       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 385     fi
 386   fi
 387 fi
 388 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 389 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 390 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 391 ])dnl
 392
 393 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 394 dnl        be used.
 395 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 396         AC_MSG_CHECKING([whether to use included boost library])
 397         AC_ARG_WITH(included-boost,
 398             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 399             [lyx_cv_with_included_boost=$withval],
 400             [lyx_cv_with_included_boost=yes])
 401         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 402         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 403         if test x$lyx_cv_with_included_boost = xyes ; then
 404             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 405             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 406         else
 407             AC_LANG_PUSH(C++)
 408             save_LIBS=$LIBS
 409
 410             AC_MSG_CHECKING([for multithreaded boost libraries])
 411             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 412             AC_LINK_IFELSE(
 413                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 414                         [boost::signal<void ()> s;])],
 415                 [AC_MSG_RESULT([yes])
 416                  BOOST_MT="-mt"],
 417                 [AC_MSG_RESULT([no])
 418                  AC_MSG_CHECKING([for plain boost libraries])
 419                  LIBS="$save_LIBS -lboost_signals"
 420                  AC_LINK_IFELSE(
 421                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 422                              [boost::signal<void ()> s;])],
 423                      [AC_MSG_RESULT([yes])
 424                       BOOST_MT=""],
 425                      [AC_MSG_RESULT([no])
 426                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 427                  ])
 428             ])
 429             LIBS=$save_LIBS
 430             AC_LANG_POP(C++)
 431             BOOST_INCLUDES=
 432             if test $lyx_std_regex = yes ; then
 433               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 434             else
 435               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 436             fi
 437         fi
 438         AC_SUBST(BOOST_INCLUDES)
 439         AC_SUBST(BOOST_LIBS)
 440 ])
 441
 442
 443 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 444 dnl        necessary APIs are available to print callstacks.
 445 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 446 [AC_CACHE_CHECK([whether printing callstack is possible],
 447                [lyx_cv_callstack_printing],
 448 [AC_TRY_COMPILE([
 449 #include <execinfo.h>
 450 #include <cxxabi.h>
 451 ], [
 452         void* array[200];
 453         size_t size = backtrace(array, 200);
 454         backtrace_symbols(array, size);
 455         int status = 0;
 456         abi::__cxa_demangle("abcd", 0, 0, &status);
 457 ],
 458 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 459 if test x"$lyx_cv_callstack_printing" = xyes; then
 460   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 461             [Define if callstack can be printed])
 462 fi
 463 ])
 464
 465
 466 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 467 dnl        be used.
 468 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 469         AC_MSG_CHECKING([whether to use included MyThes library])
 470         AC_ARG_WITH(included-mythes,
 471             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 472             [lyx_cv_with_included_mythes=$withval],
 473             [lyx_cv_with_included_mythes=yes])
 474         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 475         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 476         if test x$lyx_cv_with_included_mythes != xyes ; then
 477                 AC_LANG_PUSH(C++)
 478                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 479                 if test x$ac_cv_header_mythes_h != xyes; then
 480                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 481                 fi
 482                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 483                 if test x$lyx_mythes != xyes; then
 484                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 485                 fi
 486                 AC_LANG_POP(C++)
 487                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 488                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 489                 fi
 490                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 491                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 492                 AC_SUBST(MYTHES_LIBS)
 493         fi
 494 ])
 495
 496
 497 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 498 dnl                       [default-yes-value])
 499 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 500 dnl  resulting directory name in 'dir-var-name'.
 501 AC_DEFUN([LYX_WITH_DIR],[
 502   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 503   AC_MSG_CHECKING([for $2])
 504   if test -z "$with_$3"; then
 505      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 506   else
 507     test "x$with_$3" = xyes && with_$3=$5
 508     lyx_cv_$3="$with_$3"
 509   fi
 510   AC_MSG_RESULT($lyx_cv_$3)])
 511
 512
 513 dnl Usage: LYX_LOOP_DIR(value,action)
 514 dnl Executes action for values of variable `dir' in `values'. `values' can
 515 dnl use ":" as a separator.
 516 AC_DEFUN([LYX_LOOP_DIR],[
 517 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 518 for dir in `eval "echo $1"`; do
 519   if test ! "$dir" = NONE; then
 520     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 521     $2
 522   fi
 523 done
 524 IFS=$ac_save_ifs
 525 ])
 526
 527
 528 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 529 dnl var-name.
 530 AC_DEFUN([LYX_ADD_LIB_DIR],[
 531 $1="${$1} -L$2"
 532 if test "`(uname) 2>/dev/null`" = SunOS &&
 533     uname -r | grep '^5' >/dev/null; then
 534   if test $ac_cv_prog_gxx = yes ; then
 535     $1="${$1} -Wl[,]-R$2"
 536   else
 537     $1="${$1} -R$2"
 538   fi
 539 fi])
 540
 541
 542 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 543 dnl var-name.
 544 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 545
 546 ### Check for a headers existence and location iff it exists
 547 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 548 ## It almost works.  I've tried a few variations but they give errors
 549 ## of one sort or other: bad substitution or file not found etc.  The
 550 ## actual header _is_ found though and the cache variable is set however
 551 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 552 ## reason.
 553 ## Additionally, autoheader can't figure out what to use as the name in
 554 ## the config.h.in file so we need to write our own entries there -- one for
 555 ## each header in the form PATH_HEADER_NAME_H
 556 ##
 557 AC_DEFUN([LYX_PATH_HEADER],
 558 [ AC_CHECK_HEADER($1,[
 559   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 560 ### the only remaining problem is getting the second parameter to this
 561 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 562 ### of $ac_safe being printed.
 563   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 564   [ cat > conftest.$ac_ext <<EOF
 565 #line __oline__ "configure"
 566 #include "confdefs.h"
 567
 568 #include <$1>
 569 EOF
 570 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 571   grep $1  2>/dev/null | \
 572   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 573 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 574 rm -f conftest*])
 575   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 576 ])
 577 ### end of LYX_PATH_HEADER
 578
 579 ## Check what kind of packaging should be used at install time.
 580 ## The default is autodetected.
 581 AC_DEFUN([LYX_USE_PACKAGING],
 582 [AC_MSG_CHECKING([what packaging should be used])
 583 AC_ARG_WITH(packaging,
 584   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 585                             Possible values: posix, windows, macosx, haiku])],
 586   [lyx_use_packaging="$withval"], [
 587   case $host in
 588     *-apple-darwin*) lyx_use_packaging=macosx ;;
 589     *-pc-mingw32*) lyx_use_packaging=windows ;;
 590     *haiku*) lyx_use_packaging=haiku ;;
 591     *) lyx_use_packaging=posix ;;
 592   esac])
 593 AC_MSG_RESULT($lyx_use_packaging)
 594 lyx_install_posix=false
 595 lyx_install_macosx=false
 596 lyx_install_cygwin=false
 597 lyx_install_windows=false
 598 case $lyx_use_packaging in
 599    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 600            PACKAGE=LyX${version_suffix}
 601            default_prefix="/Applications/${PACKAGE}.app"
 602            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 603            bindir='${prefix}/Contents/MacOS'
 604            libdir='${prefix}/Contents/Resources'
 605            datarootdir='${prefix}/Contents/Resources'
 606            pkgdatadir='${datadir}'
 607            mandir='${datadir}/man'
 608            lyx_install_macosx=true ;;
 609   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 610            PACKAGE=LyX${version_suffix}
 611            default_prefix="C:/Program Files/${PACKAGE}"
 612            bindir='${prefix}/bin'
 613            libdir='${prefix}/Resources'
 614            datarootdir='${prefix}/Resources'
 615            pkgdatadir='${datadir}'
 616            mandir='${prefix}/Resources/man'
 617            lyx_install_windows=true ;;
 618     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 619            PACKAGE=lyx${version_suffix}
 620            program_suffix=$version_suffix
 621            pkgdatadir='${datadir}/${PACKAGE}'
 622            default_prefix=$ac_default_prefix
 623            case ${host} in
 624              *cygwin*) lyx_install_cygwin=true ;;
 625              *apple-darwin*) lyx_install_macosx=true ;;
 626            esac
 627            lyx_install_posix=true ;;
 628         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 629            PACKAGE=lyx${version_suffix}
 630            program_suffix=$version_suffix
 631            pkgdatadir='${datadir}/${PACKAGE}'
 632            default_prefix=$ac_default_prefix
 633            lyx_install_posix=true ;;
 634     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 635 esac
 636 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 637 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 638 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 639 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 640 AC_SUBST(pkgdatadir)
 641 AC_SUBST(program_suffix)
 642 ])
 643
 644
 645 ## ------------------------------------------------------------------------
 646 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 647 ## one or two arguments.
 648 ##
 649 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 650 ## ------------------------------------------------------------------------
 651 ##
 652 AC_DEFUN([AC_FUNC_MKDIR],
 653 [AC_CHECK_FUNCS([mkdir _mkdir])
 654 AC_CACHE_CHECK([whether mkdir takes one argument],
 655                [ac_cv_mkdir_takes_one_arg],
 656 [AC_TRY_COMPILE([
 657 #include <sys/stat.h>
 658 #if HAVE_UNISTD_H
 659 #  include <unistd.h>
 660 #endif
 661 ], [mkdir (".");],
 662 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 663 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 664   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 665             [Define if mkdir takes only one argument.])
 666 fi
 667 ])
 668
 669
 670 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 671 dnl (which may be a relative path, and need not refer to any existing
 672 dnl entity).
 673
 674 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 675 dnl native Win32 path name, (but with slashes, not backslashes).
 676
 677 dnl On any other system, it is simply the result which would be obtained
 678 dnl if PATHNAME represented an existing directory, and the pwd command was
 679 dnl executed in that directory.
 680 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 681 [ac_dir="$2"
 682  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 683     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 684  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 685  do
 686    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 687  done
 688  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 689  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 690  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 691    s?/*$[]??'`
 692 ])
 693
 694 dnl this is used by the macro blow to general a proper config.h.in entry
 695 m4_define([LYX_AH_CHECK_DECL],
 696 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 697   [Define if you have the prototype for function `$1'])])
 698
 699 dnl Check things are declared in headers to avoid errors or warnings.
 700 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 701 dnl Defines HAVE_DECL_{FUNCTION}
 702 AC_DEFUN([LYX_CHECK_DECL],
 703 [LYX_AH_CHECK_DECL($1)
 704 for ac_header in $2
 705 do
 706   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 707   AC_EGREP_HEADER($1, $ac_header,
 708       [AC_MSG_RESULT(yes)
 709        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 710        break],
 711       [AC_MSG_RESULT(no)])
 712 done])
 713
 714 dnl this is used by the macro below to generate a proper config.h.in entry
 715 m4_define([LYX_AH_CHECK_DEF],
 716 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 717   [Define to 1 if `$1' is defined in `$2'])])
 718
 719 dnl Check whether name is defined in header by using it in codesnippet.
 720 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 721 dnl Defines HAVE_DEF_{NAME}
 722 AC_DEFUN([LYX_CHECK_DEF],
 723 [LYX_AH_CHECK_DEF($1, $2)
 724  AC_MSG_CHECKING([whether $1 is defined by header $2])
 725  AC_TRY_COMPILE([#include <$2>], [$3],
 726      lyx_have_def_name=yes,
 727      lyx_have_def_name=no)
 728  AC_MSG_RESULT($lyx_have_def_name)
 729  if test "x$lyx_have_def_name" = xyes; then
 730    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 731  fi
 732 ])
 733
 734 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 735 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 736 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 737 AC_DEFUN([LYX_SET_VERSION_INFO],
 738 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 739  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 740  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 741  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 742  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 743  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 744  test "x$lyx_patch" = "x" && lyx_patch=0
 745  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 746  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 747  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 748  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 749  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 750  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 751  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 752  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 753 ])
 754
 755 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 756 # ---------------------------------------------------------------------------
 757 # Copied from autoconf 2.68, added a check that python version is < 3.0
 758 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 759 # Run ACTION-IF-FALSE otherwise.
 760 # This test uses sys.hexversion instead of the string equivalent (first
 761 # word of sys.version), in order to cope with versions such as 2.2c1.
 762 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 763 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 764  [prog="import sys
 765 # split strings by '.' and convert to numeric.  Append some zeros
 766 # because we need at least 4 digits for the hex conversion.
 767 # map returns an iterator in Python 3.0 and a list in 2.x
 768 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 769 minverhex = 0
 770 maxverhex = 50331648 # = 3.0.0.0
 771 # xrange is not present in Python 3.0 and range returns an iterator
 772 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 773 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 774   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])