config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6 dnl Compute the default build type from AC_PACKAGE_VERSION at autoconf time.
   7 m4_define([LYX_BUILD_TYPE], [m4_bmatch(AC_PACKAGE_VERSION,
   8     [dev], [development],
   9     [pre\|alpha\|beta\|rc], [prerelease],
  10     [release])])
  11
  12
  13 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
  14 dnl sets variable "build_type"
  15 AC_DEFUN([LYX_CHECK_VERSION],[
  16 echo "configuring LyX version" AC_PACKAGE_VERSION
  17
  18 AC_MSG_CHECKING([for build type])
  19 lyx_devel_version=no
  20 lyx_prerelease=no
  21 AC_ARG_ENABLE(build-type,
  22   AS_HELP_STRING([--enable-build-type=STR],[set build type to rel(ease), pre(release), dev(elopment), prof(iling), or gprof (default: LYX_BUILD_TYPE)]),
  23   [case $enableval in
  24     dev*) build_type=development;;
  25     pre*) build_type=prerelease;;
  26     prof*)  build_type=profiling;;
  27     gprof*) build_type=gprof;;
  28     rel*) build_type=release;;
  29     *) AC_MSG_ERROR([bad build type specification '$enableval'. Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  30    esac],
  31   [build_type=LYX_BUILD_TYPE])
  32 AC_MSG_RESULT([$build_type])
  33 lyx_flags="$lyx_flags build=$build_type"
  34 case $build_type in
  35     development) lyx_devel_version=yes
  36                  LYX_DATE="not released yet" ;;
  37     prerelease) lyx_prerelease=yes ;;
  38 esac
  39
  40 AC_SUBST(lyx_devel_version)
  41 ])
  42
  43
  44 dnl Define the option to set a LyX version on installed executables and directories
  45 dnl
  46 dnl
  47 AC_DEFUN([LYX_VERSION_SUFFIX],[
  48 AC_MSG_CHECKING([for version suffix])
  49 dnl We need the literal double quotes in the rpm spec file
  50 RPM_VERSION_SUFFIX='""'
  51 AC_ARG_WITH(version-suffix,
  52   [AS_HELP_STRING([--with-version-suffix@<:@=STR@:>@], install lyx files as lyxSTR (default STR: -AC_PACKAGE_VERSION))],
  53   [if test "x$withval" = "xyes";
  54    then
  55      withval="-"AC_PACKAGE_VERSION
  56      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  57    fi
  58    AC_SUBST(version_suffix,$withval)
  59    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  60 AC_SUBST(RPM_VERSION_SUFFIX)
  61 AC_SUBST(program_base_name,"lyx")
  62 AC_MSG_RESULT([$withval])
  63 ])
  64
  65
  66 dnl Check whether to configure for Qt4 or Qt5. Default is Qt5.
  67 dnl
  68 AC_DEFUN([LYX_CHECK_QT5],[
  69 AC_MSG_CHECKING([whether Qt5 is disabled])
  70 AC_ARG_ENABLE([qt5],
  71   [AS_HELP_STRING([--disable-qt5],[do not use Qt5 for building])],
  72   USE_QT5=$enableval, USE_QT5=yes)
  73 if test x$USE_QT5 != xno ; then
  74   AC_MSG_RESULT([no])
  75 else
  76   AC_MSG_RESULT([yes])
  77 fi
  78 AC_SUBST([USE_QT5])
  79 ])
  80
  81
  82 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  83 dnl flag lyx_warning to yes.
  84 AC_DEFUN([LYX_WARNING],[
  85 lyx_warning_txt="$lyx_warning_txt
  86 == $1
  87 "
  88 lyx_warning=yes])
  89
  90
  91 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  92 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  93 AC_DEFUN([LYX_LIB_ERROR],[
  94 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  95    is correctly installed on your system.])])
  96
  97
  98 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  99 dnl   has occurred previously.
 100 AC_DEFUN([LYX_CHECK_WARNINGS],[
 101 if test x$lyx_warning = xyes; then
 102 cat <<EOF
 103 === The following minor problems have been detected by configure.
 104 === Please check the messages below before running 'make'.
 105 === (see the section 'Problems' in the INSTALL file)
 106 $lyx_warning_txt
 107
 108 EOF
 109 fi])
 110
 111
 112 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 113 dnl
 114 define(LYX_SEARCH_PROG,[dnl
 115 for ac_prog in $2 ; do
 116 # Extract the first word of "$ac_prog", so it can be a program name with args.
 117   set dummy $ac_prog ; ac_word=$[2]
 118   if test -z "[$]$1"; then
 119     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 120     for ac_dir in $PATH; do
 121       test -z "$ac_dir" && ac_dir=.
 122       if test -f [$ac_dir/$ac_word]; then
 123         $1="$ac_prog"
 124         break
 125       fi
 126     done
 127     IFS="$ac_save_ifs"
 128   fi
 129
 130   if test -n "[$]$1"; then
 131     ac_result=yes
 132   else
 133     ac_result=no
 134   fi
 135   ifelse($3,,,[$3])
 136   test -n "[$]$1" && break
 137 done
 138 ])dnl
 139
 140
 141 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 142 AC_DEFUN([LYX_PROG_CLANG],
 143 [AC_CACHE_CHECK([whether the compiler is clang],
 144                [lyx_cv_prog_clang],
 145 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 146 #ifndef __clang__
 147             this is not clang
 148 #endif
 149 ]])],[lyx_cv_prog_clang=yes ; CLANG=yes],[lyx_cv_prog_clang=no ; CLANG=no])])
 150 if test $CLANG = yes ; then
 151   AC_CACHE_CHECK([for clang version],
 152     [lyx_cv_clang_version],
 153     [clang_noversion=no
 154      AC_COMPUTE_INT(clang_major,__clang_major__,,[clang_noversion_=yes])
 155      AC_COMPUTE_INT(clang_minor,__clang_minor__,,[clang_noversion_=yes])
 156      AC_COMPUTE_INT(clang_patchlevel,__clang_patchlevel__,,[clang_noversion_=yes])
 157      if test $clang_noversion = yes ; then
 158        clang_version=unknown
 159      else
 160        clang_version=$clang_major.$clang_minor.$clang_patchlevel
 161      fi
 162      lyx_cv_clang_version=$clang_version])
 163 fi
 164 ])
 165
 166
 167 dnl Usage: LYX_CXX_CXX11_FLAGS(VERSION): add to AM_CXXFLAGS the best flag that
 168 dnl selects C++11 mode; gives an error when C++11 mode is not found.
 169 dnl VERSION is a list of years to try (e.g. 11 or {14,11}).
 170 AC_DEFUN([LYX_CXX_CXX11_FLAGS],
 171 [AC_CACHE_CHECK([for a good C++ mode], [lyx_cv_cxx11_flags],
 172  [lyx_cv_cxx11_flags=none
 173   for flag in `eval echo -std=c++$1 default -std=gnu++$1` ; do
 174     if test $flag = default ; then
 175       flag=
 176     fi
 177     save_CPPFLAGS=$CPPFLAGS
 178     CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 179     save_CXXFLAGS=$CXXFLAGS
 180     CXXFLAGS="$flag $AM_CXXFLAGS $CXXFLAGS"
 181     dnl sample openmp source code to test
 182     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 183        template <typename T>
 184        struct check
 185        {
 186            static_assert(sizeof(int) <= sizeof(T), "not big enough");
 187        };
 188
 189        typedef check<check<bool>> right_angle_brackets;
 190
 191        class TestDeleted
 192        {
 193        public:
 194            TestDeleted() = delete;
 195        };
 196
 197
 198        int a;
 199        decltype(a) b;
 200
 201        typedef check<int> check_type;
 202        check_type c;
 203        check_type&& cr = static_cast<check_type&&>(c);
 204
 205        auto d = a;]], [[]])],[lyx_cv_cxx11_flags=$flag; break],[])
 206    CXXFLAGS=$save_CXXFLAGS
 207    CPPFLAGS=$save_CPPFLAGS
 208   done])
 209   if test x$lyx_cv_cxx11_flags = xnone ; then
 210     AC_MSG_ERROR([Cannot find suitable mode for compiler $CXX])
 211   fi
 212   AM_CXXFLAGS="$lyx_cv_cxx11_flags $AM_CXXFLAGS"
 213 ])
 214
 215
 216 dnl Usage: LYX_CXX_USE_CALL_ONCE
 217 dnl check whether we can use std::call_once and set the
 218 dnl LYX_USE_STD_CALL_ONCE macro and conditional accordingly.
 219 AC_DEFUN([LYX_CXX_USE_CALL_ONCE],
 220 [AC_MSG_CHECKING([for std::call_once availability])
 221    save_CPPFLAGS=$CPPFLAGS
 222    CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 223    save_CXXFLAGS=$CXXFLAGS
 224    CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 225    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 226         #include <mutex>
 227         static std::once_flag flag;
 228      ]], [[
 229         std::call_once(flag, [](){ return; });
 230    ]])],[lyx_std_call_once=yes],[lyx_std_call_once=no])
 231    CXXFLAGS=$save_CXXFLAGS
 232    CPPFLAGS=$save_CPPFLAGS
 233    AC_MSG_RESULT([$lyx_std_call_once])
 234
 235  if test $lyx_std_call_once = yes ; then
 236   AC_DEFINE([LYX_USE_STD_CALL_ONCE], 1, [define to 1 if std::call_once is supported by the compiler])
 237  fi
 238  AM_CONDITIONAL([LYX_USE_STD_CALL_ONCE], test $lyx_std_call_once = yes)
 239 ])
 240
 241
 242 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 243 AC_DEFUN([LYX_LIB_STDCXX],
 244 [AC_CACHE_CHECK([whether STL is libstdc++],
 245                [lyx_cv_lib_stdcxx],
 246 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 247 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 248             this is not libstdc++
 249 #endif
 250 ]])],[lyx_cv_lib_stdcxx=yes],[lyx_cv_lib_stdcxx=no])])
 251 ])
 252
 253
 254 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 255 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 256 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 257 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 258                [lyx_cv_lib_stdcxx_cxx11_abi],
 259 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include<vector>]], [[
 260 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 261             this is not libstdc++ using the C++11 ABI
 262 #endif
 263 ]])],[lyx_cv_lib_stdcxx_cxx11_abi=yes],[lyx_cv_lib_stdcxx_cxx11_abi=no])])
 264 ])
 265
 266
 267 AC_DEFUN([LYX_PROG_CXX],
 268 [AC_REQUIRE([AC_PROG_CXX])
 269 AC_REQUIRE([AC_PROG_CXXCPP])
 270
 271 ### We might want to force the C++ standard.
 272 AC_ARG_ENABLE(cxx-mode,
 273   AS_HELP_STRING([--enable-cxx-mode],[choose C++ standard (default: 17, 14, then 11)]),,
 274   [enable_cxx_mode={17,14,11}]
 275 )
 276
 277 AC_LANG_PUSH(C++)
 278 LYX_PROG_CLANG
 279 LYX_CXX_CXX11_FLAGS($enable_cxx_mode)
 280 LYX_LIB_STDCXX
 281 LYX_LIB_STDCXX_CXX11_ABI
 282 LYX_CXX_USE_CALL_ONCE
 283 AC_LANG_POP(C++)
 284
 285 if test $lyx_cv_lib_stdcxx = "yes" ; then
 286   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 287     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 288   else
 289     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 290   fi
 291 else
 292   if test $lyx_cv_prog_clang = "yes" ; then
 293     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 294   fi
 295 fi
 296
 297 ### We might want to get or shut warnings.
 298 AC_ARG_ENABLE(warnings,
 299   AS_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 300   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $GXX = yes ; then
 301         enable_warnings=yes;
 302     else
 303         enable_warnings=no;
 304     fi;])
 305 if test x$enable_warnings = xyes ; then
 306   lyx_flags="$lyx_flags warnings"
 307 fi
 308
 309 ### We might want to disable debug
 310 AC_ARG_ENABLE(debug,
 311   AS_HELP_STRING([--enable-debug],[enable debug information]),,
 312   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 313 )
 314
 315 AC_ARG_ENABLE(stdlib-debug,
 316   AS_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 317   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 318           [enable_stdlib_debug=no])]
 319 )
 320
 321 ### set up optimization
 322 AC_ARG_ENABLE(optimization,
 323     AS_HELP_STRING([--enable-optimization@<:@=ARG@:>@],[enable compiler optimisation]),,
 324     enable_optimization=yes;)
 325 case $enable_optimization in
 326     yes)
 327         if test $lyx_devel_version = yes ; then
 328             lyx_optim=-O
 329         else
 330             lyx_optim=-O2
 331         fi;;
 332     no) lyx_optim=;;
 333     *) lyx_optim=${enable_optimization};;
 334 esac
 335
 336 AC_ARG_ENABLE(assertions,
 337   AS_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 338   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 339           [enable_assertions=no])]
 340 )
 341 if test "x$enable_assertions" = xyes ; then
 342    lyx_flags="$lyx_flags assertions"
 343    AC_DEFINE(ENABLE_ASSERTIONS,1,
 344     [Define if you want assertions to be enabled in the code])
 345 fi
 346
 347 # set the compiler options correctly.
 348 if test x$GXX = xyes; then
 349   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 350   if test x$CLANG = xno; then
 351     dnl Useful for global version info
 352     gxx_version=`${CXX} -dumpversion`
 353     case $gxx_version in
 354         *.*) ;;
 355         *) gxx_version=`${CXX} -dumpfullversion` ;;
 356     esac
 357     CXX_VERSION="($gxx_version)"
 358   else
 359     gxx_version=clang-$clang_version
 360     CXX_VERSION="($clang_version)"
 361   fi
 362
 363   AM_CXXFLAGS="$lyx_optim $AM_CXXFLAGS"
 364   if test x$enable_debug = xyes ; then
 365       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 366   fi
 367   if test $build_type = gprof ; then
 368     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 369     AM_LDFLAGS="$AM_LDFLAGS -pg"
 370   fi
 371   if test $build_type = profiling ; then
 372     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 373   fi
 374
 375   if test x$USE_QT5 = xyes ; then
 376       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 377   fi
 378   dnl Warnings are for preprocessor too
 379   if test x$enable_warnings = xyes ; then
 380       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 381       dnl Shut off warning -Wdeprecated-copy, which triggers too much
 382       dnl note that g++ always accepts -Wno-xxx, even when -Wxxx is an error.
 383       AC_LANG_PUSH(C++)
 384       AX_CHECK_COMPILE_FLAG([-Wno-deprecated-copy],
 385         [AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-copy"], [], [-Werror])
 386       AC_LANG_POP(C++)
 387     fi
 388   case $gxx_version in
 389       2.*|3.*|4.@<:@0-8@:>@) AC_MSG_ERROR([gcc >= 4.9 is required]);;
 390   esac
 391   if test x$enable_stdlib_debug = xyes ; then
 392     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 393     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 394     if test x$lyx_cv_lib_stdcxx = xyes ; then
 395         lyx_flags="$lyx_flags stdlib-debug"
 396         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 397         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 398         AC_SUBST(STDLIB_DEBUG, "-D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 399     else
 400         enable_stdlib_debug=no
 401     fi
 402   fi
 403 fi
 404
 405 # Some additional flags may be needed
 406 if test x$GXX = xyes; then
 407     case $gxx_version in
 408       clang-3.0*|clang-3.1*|clang-3.2*|clang-3.3*)
 409         dnl boost contains pragmas that are annoying on older clang versions
 410         AM_CPPFLAGS="-Wno-unknown-pragmas $AM_CPPFLAGS";;
 411       clang*)
 412         dnl the more recent versions support the deprecated-register warning,
 413         dnl which  is very annoying with Qt4.x right now.
 414         AM_CXXFLAGS="$AM_CXXFLAGS -Wno-deprecated-register";;
 415     esac
 416 fi
 417 ])
 418
 419 dnl Usage: LYX_USE_INCLUDED_NOD : select if the included nod should be used.
 420 AC_DEFUN([LYX_USE_INCLUDED_NOD],[
 421         AC_MSG_CHECKING([whether to use included nod library])
 422         AC_ARG_WITH(included-nod,
 423             [AS_HELP_STRING([--without-included-nod], [do not use the nod lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 424             [lyx_cv_with_included_nod=$withval],
 425             [lyx_cv_with_included_nod=yes])
 426         AM_CONDITIONAL(USE_INCLUDED_NOD, test x$lyx_cv_with_included_nod = xyes)
 427         AC_MSG_RESULT([$lyx_cv_with_included_nod])
 428         if test x$lyx_cv_with_included_nod = xyes ; then
 429             lyx_included_libs="$lyx_included_libs nod"
 430             NOD_INCLUDES='-I$(top_srcdir)/3rdparty/nod'
 431         else
 432             NOD_INCLUDES=
 433             AC_LANG_PUSH(C++)
 434             AC_MSG_CHECKING([for nod library])
 435             AC_LINK_IFELSE(
 436                 [AC_LANG_PROGRAM([#include <nod.hpp>],
 437                     [nod::scoped_connection conn;])],
 438                 [AC_MSG_RESULT([yes])],
 439                 [AC_MSG_RESULT([no])
 440                 AC_MSG_ERROR([cannot find suitable nod library (do not use --without-included-nod)])
 441             ])
 442             AC_LANG_POP(C++)
 443         fi
 444         AC_SUBST(NOD_INCLUDES)
 445 ])
 446
 447 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 448 dnl        be used.
 449 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 450         AC_MSG_CHECKING([whether to use included boost library])
 451         AC_ARG_WITH(included-boost,
 452             [AS_HELP_STRING([--with-included-boost], [use the boost lib supplied with LyX])],
 453             [lyx_cv_with_included_boost=$withval],
 454             [lyx_cv_with_included_boost=no])
 455         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 456         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 457         if test x$lyx_cv_with_included_boost = xno ; then
 458             AC_LANG_PUSH(C++)
 459             AC_MSG_CHECKING([for boost library])
 460             AC_LINK_IFELSE(
 461                 [AC_LANG_PROGRAM([#include <boost/crc.hpp>],
 462                     [boost::crc_32_type crc;])],
 463                 [AC_MSG_RESULT([yes])],
 464                 [AC_MSG_RESULT([no])
 465                 lyx_cv_with_included_boost=yes
 466             ])
 467             AC_LANG_POP(C++)
 468         fi
 469         if test x$lyx_cv_with_included_boost = xyes ; then
 470             lyx_included_libs="$lyx_included_libs boost"
 471             BOOST_INCLUDES='-I$(top_srcdir)/3rdparty/boost'
 472         else
 473             BOOST_INCLUDES=
 474         fi
 475         AC_SUBST(BOOST_INCLUDES)
 476 ])
 477
 478
 479 dnl Usage: LYX_USE_INCLUDED_ICONV : select if the included iconv should
 480 dnl        be used.
 481 AC_DEFUN([LYX_USE_INCLUDED_ICONV],[
 482   AC_MSG_CHECKING([whether to use included iconv library])
 483   AC_ARG_WITH(included-iconv,
 484     [AS_HELP_STRING([--with-included-iconv], [use the iconv lib supplied with LyX instead of the system one])],
 485     [lyx_cv_with_included_iconv=$withval],
 486     [lyx_cv_with_included_iconv=no])
 487   AM_CONDITIONAL(USE_INCLUDED_ICONV, test x$lyx_cv_with_included_iconv = xyes)
 488   AC_MSG_RESULT([$lyx_cv_with_included_iconv])
 489   if test x$lyx_cv_with_included_iconv = xyes ; then
 490   lyx_included_libs="$lyx_included_libs iconv"
 491
 492 dnl This is hardcoded to make it compile
 493     AC_DEFINE([HAVE_WORKING_O_NOFOLLOW], 0, [Define to 1 if O_NOFOLLOW works.])
 494
 495 dnl Some bits from libiconv configure.ac to avoid a nested configure call:
 496     AC_EILSEQ
 497     AC_TYPE_MBSTATE_T
 498     AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
 499 dnl Ymbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see 3rdparty/libiconv/1.15/lib/loop_wchar.h.
 500     if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
 501       USE_MBSTATE_T=1
 502     else
 503       USE_MBSTATE_T=0
 504     fi
 505     AC_SUBST([USE_MBSTATE_T])
 506     AC_CACHE_CHECK([whether <wchar.h> is standalone],
 507       [gl_cv_header_wchar_h_standalone],
 508       [AC_COMPILE_IFELSE(
 509         [AC_LANG_PROGRAM(
 510           [[#include <wchar.h>
 511             wchar_t w;]],
 512           [[]])],
 513         [gl_cv_header_wchar_h_standalone=yes],
 514         [gl_cv_header_wchar_h_standalone=no])])
 515     if test $gl_cv_header_wchar_h_standalone = yes; then
 516       BROKEN_WCHAR_H=0
 517     else
 518       BROKEN_WCHAR_H=1
 519     fi
 520     AC_SUBST([BROKEN_WCHAR_H])
 521 dnl we want const correctness
 522     AC_DEFINE_UNQUOTED([ICONV_CONST], [const],
 523       [Define as const if the declaration of iconv() needs const.])
 524     ICONV_CONST=const
 525     AC_SUBST([ICONV_CONST])
 526 dnl we build a static lib
 527     DLL_VARIABLE=
 528     AC_SUBST([DLL_VARIABLE])
 529     ICONV_INCLUDES='-I$(top_srcdir)/3rdparty/libiconv/1.15 -I$(top_builddir)/3rdparty/libiconv'
 530     ICONV_LIBS='\$(top_builddir)/3rdparty/libiconv/liblyxiconv.a'
 531     ICONV_ICONV_H_IN=3rdparty/libiconv/iconv.h:3rdparty/libiconv/1.15/include/iconv.h.in
 532   else
 533     ICONV_INCLUDES=
 534     AM_ICONV
 535     if test "$am_cv_func_iconv" = no; then
 536       AC_MSG_ERROR([cannot find required library iconv.])
 537     else
 538       ICONV_LIBS="$LIBICONV"
 539     fi
 540     ICONV_ICONV_H_IN=
 541   fi
 542   AC_SUBST(ICONV_INCLUDES)
 543   AC_SUBST(ICONV_LIBS)
 544   AC_SUBST(ICONV_ICONV_H_IN)
 545 ])
 546
 547
 548 dnl Usage: LYX_USE_INCLUDED_ZLIB : select if the included zlib should
 549 dnl        be used.
 550 AC_DEFUN([LYX_USE_INCLUDED_ZLIB],[
 551   AC_MSG_CHECKING([whether to use included zlib library])
 552   AC_ARG_WITH(included-zlib,
 553     [AS_HELP_STRING([--with-included-zlib], [use the zlib lib supplied with LyX instead of the system one])],
 554     [lyx_cv_with_included_zlib=$withval],
 555     [lyx_cv_with_included_zlib=no])
 556   AM_CONDITIONAL(USE_INCLUDED_ZLIB, test x$lyx_cv_with_included_zlib = xyes)
 557   AC_MSG_RESULT([$lyx_cv_with_included_zlib])
 558   if test x$lyx_cv_with_included_zlib = xyes ; then
 559     lyx_included_libs="$lyx_included_libs zlib"
 560     ZLIB_INCLUDES='-I$(top_srcdir)/3rdparty/zlib/1.2.8 -I$(top_builddir)/3rdparty/zlib'
 561     ZLIB_LIBS='$(top_builddir)/3rdparty/zlib/liblyxzlib.a'
 562     mkdir -p 3rdparty/zlib
 563 dnl include standard config.h for HAVE_UNISTD_H
 564     echo "#include <../../config.h>" > 3rdparty/zlib/zconf.h
 565 dnl prevent clash with system zlib that might be dragged in by other libs
 566     echo "#define Z_PREFIX 1" >> 3rdparty/zlib/zconf.h
 567     cat "${srcdir}/3rdparty/zlib/1.2.8/zconf.h.in" >> 3rdparty/zlib/zconf.h
 568   else
 569     ZLIB_INCLUDES=
 570     AC_CHECK_HEADERS(zlib.h,
 571       [AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="-lz"], LYX_LIB_ERROR(libz,zlib))],
 572       [LYX_LIB_ERROR(zlib.h,zlib)])
 573   fi
 574   AC_SUBST(ZLIB_INCLUDES)
 575   AC_SUBST(ZLIB_LIBS)
 576 ])
 577
 578
 579 dnl Usage: LYX_BUILD_INCLUDED_DTL : select if the included dtl should
 580 dnl        be built and installed.
 581 AC_DEFUN([LYX_BUILD_INCLUDED_DTL],[
 582         AC_MSG_CHECKING([whether to build dv2dt and dt2dv])
 583         AC_ARG_WITH(included-dtl,
 584             [AS_HELP_STRING([--with-included-dtl], [build and install the dv2dt and dt2dv programs supplied with LyX])],
 585             [lyx_cv_with_included_dtl=$withval],
 586             [lyx_cv_with_included_dtl=no])
 587         AM_CONDITIONAL(BUILD_INCLUDED_DTL, test x$lyx_cv_with_included_dtl = xyes)
 588         AC_MSG_RESULT([$lyx_cv_with_included_dtl])
 589         if test x$lyx_cv_with_included_dtl = xyes ; then
 590             lyx_flags="$lyx_flags build-dtl"
 591         fi])
 592
 593
 594 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 595 dnl        necessary APIs are available to print callstacks.
 596 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 597 [AC_ARG_ENABLE([callstack-printing],
 598                [AS_HELP_STRING([--disable-callstack-printing],[do not print a callstack when crashing])],
 599                lyx_cv_callstack_printing=$enableval, lyx_cv_callstack_printing=yes)
 600
 601 if test x"$lyx_cv_callstack_printing" = xyes; then
 602   AC_CACHE_CHECK([whether printing callstack is possible],
 603                  [lyx_cv_callstack_printing],
 604   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 605   #include <execinfo.h>
 606   #include <cxxabi.h>
 607   ]], [[
 608           void* array[200];
 609           size_t size = backtrace(array, 200);
 610           backtrace_symbols(array, size);
 611           int status = 0;
 612           abi::__cxa_demangle("abcd", 0, 0, &status);
 613   ]])],[],[lyx_cv_callstack_printing=no])])
 614 fi
 615 if test x"$lyx_cv_callstack_printing" = xyes; then
 616   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 617             [Define if callstack can be printed])
 618   lyx_flags="$lyx_flags callback-printing"
 619   AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"
 620 fi
 621 ])
 622
 623
 624 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 625 dnl        be used.
 626 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 627   AC_ARG_WITH(included-mythes,
 628     [AS_HELP_STRING([--with-included-mythes], [force to use the MyThes lib supplied with LyX])],
 629     [use_included_mythes=$withval],
 630     [use_included_mythes=no])
 631   if test x$use_included_mythes != xyes ; then
 632     AC_LANG_PUSH(C++)
 633     use_included_mythes=yes
 634     AC_CHECK_HEADERS([mythes.hxx mythes/mythes.hxx],
 635       [mythes_h_location="<$ac_header>"
 636        save_LIBS=$LIBS
 637        AC_MSG_CHECKING([checking for MyThes library])
 638        for ac_lib in mythes mythes-1.2 ; do
 639          LIBS="-l$ac_lib $save_LIBS"
 640          AC_LINK_IFELSE(
 641            [AC_LANG_PROGRAM([#include <cstdio>]
 642               [#include $mythes_h_location], [MyThes dummy("idx","dat")])],
 643            [MYTHES_LIBS=-l$ac_lib
 644             AC_MSG_RESULT([$MYTHES_LIBS])
 645             use_included_mythes=no])
 646        done
 647        if test $use_included_mythes != no ; then
 648          AC_MSG_RESULT([not found])
 649        fi
 650        break])
 651     AC_LANG_POP(C++)
 652   fi
 653   if test $use_included_mythes = yes ; then
 654     mythes_h_location="<mythes.hxx>"
 655     MYTHES_INCLUDES='-I$(top_srcdir)/3rdparty/mythes/1.2.5/'
 656     MYTHES_LIBS='$(top_builddir)/3rdparty/mythes/liblyxmythes.a'
 657     lyx_included_libs="$lyx_included_libs mythes"
 658   fi
 659   AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$use_included_mythes = xyes)
 660   AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$mythes_h_location,[Location of mythes.hxx])
 661   AC_SUBST(MYTHES_INCLUDES)
 662   AC_SUBST(MYTHES_LIBS)
 663   AC_MSG_CHECKING([whether to use included MyThes library])
 664   AC_MSG_RESULT([$use_included_mythes])
 665 ])
 666
 667
 668 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 669 dnl                       [default-yes-value])
 670 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 671 dnl  resulting directory name in 'dir-var-name'.
 672 AC_DEFUN([LYX_WITH_DIR],[
 673   AC_ARG_WITH($1,[AS_HELP_STRING([--with-$1],[specify $2])])
 674   AC_MSG_CHECKING([for $2])
 675   if test -z "$with_$3"; then
 676      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 677   else
 678     test "x$with_$3" = xyes && with_$3=$5
 679     lyx_cv_$3="$with_$3"
 680   fi
 681   AC_MSG_RESULT($lyx_cv_$3)
 682 ])
 683
 684
 685 dnl Usage: LYX_LOOP_DIR(value,action)
 686 dnl Executes action for values of variable `dir' in `values'. `values' can
 687 dnl use ":" as a separator.
 688 AC_DEFUN([LYX_LOOP_DIR],[
 689 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 690 for dir in `eval "echo $1"`; do
 691   if test ! "$dir" = NONE; then
 692     test ! -d "$dir" && AC_MSG_ERROR(['$dir' is not a directory])
 693     $2
 694   fi
 695 done
 696 IFS=$ac_save_ifs
 697 ])
 698
 699
 700 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 701 dnl var-name.
 702 AC_DEFUN([LYX_ADD_LIB_DIR],[
 703 $1="${$1} -L$2"
 704 if test "`(uname) 2>/dev/null`" = SunOS &&
 705     uname -r | grep '^5' >/dev/null; then
 706   if test $GXX = yes ; then
 707     $1="${$1} -Wl[,]-R$2"
 708   else
 709     $1="${$1} -R$2"
 710   fi
 711 fi])
 712
 713
 714 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 715 dnl var-name.
 716 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 717
 718 ### Check for a headers existence and location iff it exists
 719 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 720 ## It almost works.  I've tried a few variations but they give errors
 721 ## of one sort or other: bad substitution or file not found etc.  The
 722 ## actual header _is_ found though and the cache variable is set however
 723 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 724 ## reason.
 725 ## Additionally, autoheader can't figure out what to use as the name in
 726 ## the config.h.in file so we need to write our own entries there -- one for
 727 ## each header in the form PATH_HEADER_NAME_H
 728 ##
 729 AC_DEFUN([LYX_PATH_HEADER],
 730 [ AC_CHECK_HEADER($1,[
 731   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 732 ### the only remaining problem is getting the second parameter to this
 733 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 734 ### of $ac_safe being printed.
 735   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 736   [ cat > conftest.$ac_ext <<EOF
 737 #line __oline__ "configure"
 738 #include "confdefs.h"
 739
 740 #include <$1>
 741 EOF
 742 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 743   grep $1  2>/dev/null | \
 744   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 745 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 746 rm -f conftest*])
 747   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 748 ])
 749 ### end of LYX_PATH_HEADER
 750
 751 ## Check what kind of packaging should be used at install time.
 752 ## The default is autodetected.
 753 AC_DEFUN([LYX_USE_PACKAGING],
 754 [AC_MSG_CHECKING([what packaging should be used])
 755 AC_ARG_WITH(packaging,
 756   [AS_HELP_STRING([--with-packaging=STR], [set packaging for installation among:
 757                             posix, windows, macosx, haiku (default is autodetected)])],
 758   [lyx_use_packaging="$withval"], [
 759   case $host in
 760     *-apple-darwin*) lyx_use_packaging=macosx ;;
 761     *-pc-mingw*) lyx_use_packaging=windows ;;
 762     *-mingw32*) lyx_use_packaging=windows ;;
 763     *haiku*) lyx_use_packaging=haiku ;;
 764     *) lyx_use_packaging=posix ;;
 765   esac])
 766 AC_MSG_RESULT($lyx_use_packaging)
 767 lyx_install_posix=false
 768 lyx_install_macosx=false
 769 lyx_install_cygwin=false
 770 lyx_install_windows=false
 771 case $lyx_use_packaging in
 772    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 773            PACKAGE=LyX${version_suffix}
 774            default_prefix="/Applications/${PACKAGE}.app"
 775            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 776            bindir='${prefix}/Contents/MacOS'
 777            libdir='${prefix}/Contents/Resources'
 778            datarootdir='${prefix}/Contents/Resources'
 779            pkgdatadir='${datadir}'
 780            mandir='${datadir}/man'
 781            lyx_install_macosx=true ;;
 782   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 783            PACKAGE=LyX${version_suffix}
 784            default_prefix="C:/Program Files/${PACKAGE}"
 785            bindir='${prefix}/bin'
 786            libdir='${prefix}/Resources'
 787            datarootdir='${prefix}/Resources'
 788            pkgdatadir='${datadir}'
 789            mandir='${prefix}/Resources/man'
 790            lyx_install_windows=true ;;
 791     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 792            PACKAGE=lyx${version_suffix}
 793            program_suffix=$version_suffix
 794            pkgdatadir='${datadir}/${PACKAGE}'
 795            default_prefix=$ac_default_prefix
 796            case ${host} in
 797              *cygwin*) lyx_install_cygwin=true ;;
 798              *apple-darwin*) lyx_install_macosx=true ;;
 799            esac
 800            lyx_install_posix=true ;;
 801         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 802            PACKAGE=lyx${version_suffix}
 803            program_suffix=$version_suffix
 804            pkgdatadir='${datadir}/${PACKAGE}'
 805            default_prefix=$ac_default_prefix
 806            lyx_install_posix=true ;;
 807     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 808 esac
 809 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 810 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 811 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 812 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 813 AC_SUBST(pkgdatadir)
 814 AC_SUBST(program_suffix)
 815 ])
 816
 817
 818 ## ------------------------------------------------------------------------
 819 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 820 ## one or two arguments.
 821 ##
 822 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 823 ## ------------------------------------------------------------------------
 824 ##
 825 AC_DEFUN([AC_FUNC_MKDIR],
 826 [AC_CHECK_FUNCS([mkdir _mkdir])
 827 AC_CACHE_CHECK([whether mkdir takes one argument],
 828                [ac_cv_mkdir_takes_one_arg],
 829 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 830 #include <sys/stat.h>
 831 #if HAVE_UNISTD_H
 832 #  include <unistd.h>
 833 #endif
 834 ]], [[mkdir (".");]])],[ac_cv_mkdir_takes_one_arg=yes],[ac_cv_mkdir_takes_one_arg=no])])
 835 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 836   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 837             [Define if mkdir takes only one argument.])
 838 fi
 839 ])
 840
 841
 842 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 843 dnl (which may be a relative path, and need not refer to any existing
 844 dnl entity).
 845
 846 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 847 dnl native Win32 path name, (but with slashes, not backslashes).
 848
 849 dnl On any other system, it is simply the result which would be obtained
 850 dnl if PATHNAME represented an existing directory, and the pwd command was
 851 dnl executed in that directory.
 852 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 853 [ac_dir="$2"
 854  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 855     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 856  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 857  do
 858    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 859  done
 860  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 861  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 862  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 863    s?/*$[]??'`
 864 ])
 865
 866 dnl this is used by the macro blow to general a proper config.h.in entry
 867 m4_define([LYX_AH_CHECK_DECL],
 868 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 869   [Define if you have the prototype for function `$1'])])dnl`
 870
 871 dnl Check things are declared in headers to avoid errors or warnings.
 872 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 873 dnl Defines HAVE_DECL_{FUNCTION}
 874 AC_DEFUN([LYX_CHECK_DECL],
 875 [LYX_AH_CHECK_DECL($1)
 876 for ac_header in $2
 877 do
 878   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 879   AC_EGREP_HEADER($1, $ac_header,
 880       [AC_MSG_RESULT(yes)
 881        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 882        break],
 883       [AC_MSG_RESULT(no)])
 884 done])
 885
 886 dnl this is used by the macro below to generate a proper config.h.in entry
 887 m4_define([LYX_AH_CHECK_DEF],
 888 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 889   [Define to 1 if `$1' is defined in `$2'])])dnl'
 890
 891 dnl Check whether name is defined in header by using it in codesnippet.
 892 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 893 dnl Defines HAVE_DEF_{NAME}
 894 AC_DEFUN([LYX_CHECK_DEF],
 895 [LYX_AH_CHECK_DEF($1, $2)
 896  AC_MSG_CHECKING([whether $1 is defined by header $2])
 897  save_CPPFLAGS=$CPPFLAGS
 898  CPPFLAGS="$AM_CPPFLAGS $CPPFLAGS"
 899  save_CXXFLAGS=$CXXFLAGS
 900  CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 901  AC_LANG_PUSH(C++)
 902  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <$2>]], [[$3]])],[lyx_have_def_name=yes],[lyx_have_def_name=no])
 903  AC_LANG_POP(C++)
 904  CXXFLAGS=$save_CXXFLAGS
 905  CPPFLAGS=$save_CPPFLAGS
 906  AC_MSG_RESULT($lyx_have_def_name)
 907  if test "x$lyx_have_def_name" = xyes; then
 908    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 909  fi
 910 ])
 911
 912 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 913 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 914 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 915 AC_DEFUN([LYX_SET_VERSION_INFO],
 916 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 917  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 918  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 919  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 920  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 921  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 922  test "x$lyx_patch" = "x" && lyx_patch=0
 923  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 924  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 925  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 926  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 927  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 928  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 929  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 930  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 931 ])
 932