config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CXXFLAGS=$CXXFLAGS
 155   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 156   AC_LANG_PUSH(C++)
 157   AC_TRY_COMPILE([], [
 158 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 159             this is a c++11 compiler
 160 #endif
 161   ],
 162   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 163  AC_LANG_POP(C++)
 164  CXXFLAGS=$save_CXXFLAGS])
 165 lyx_use_cxx11=$lyx_cv_cxx_cxx11
 166 ])
 167
 168
 169 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 170 AC_DEFUN([LYX_LIB_STDCXX],
 171 [AC_CACHE_CHECK([whether STL is libstdc++],
 172                [lyx_cv_lib_stdcxx],
 173 [AC_TRY_COMPILE([#include<vector>], [
 174 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 175             this is not libstdc++
 176 #endif
 177 ],
 178 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 179 ])
 180
 181
 182 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 183 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 184 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 185 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 186                [lyx_cv_lib_stdcxx_cxx11_abi],
 187 [AC_TRY_COMPILE([#include<vector>], [
 188 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 189             this is not libstdc++ using the C++11 ABI
 190 #endif
 191 ],
 192 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 193 ])
 194
 195
 196 AC_DEFUN([LYX_PROG_CXX],
 197 [AC_REQUIRE([AC_PROG_CXX])
 198 AC_REQUIRE([AC_PROG_CXXCPP])
 199
 200 AC_LANG_PUSH(C++)
 201 LYX_PROG_CLANG
 202 LYX_LIB_STDCXX
 203 LYX_LIB_STDCXX_CXX11_ABI
 204 AC_LANG_POP(C++)
 205
 206 if test $lyx_cv_lib_stdcxx = "yes" ; then
 207   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 208     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 209   else
 210     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 211   fi
 212 else
 213   if test $lyx_cv_prog_clang = "yes" ; then
 214     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 215   fi
 216 fi
 217
 218 ### We might want to get or shut warnings.
 219 AC_ARG_ENABLE(warnings,
 220   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 221   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 222         enable_warnings=yes;
 223     else
 224         enable_warnings=no;
 225     fi;])
 226 if test x$enable_warnings = xyes ; then
 227   lyx_flags="$lyx_flags warnings"
 228 fi
 229
 230 ### We might want to disable debug
 231 AC_ARG_ENABLE(debug,
 232   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 233   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 234 )
 235
 236 AC_ARG_ENABLE(stdlib-debug,
 237   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 238   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 239           [enable_stdlib_debug=no])]
 240 )
 241
 242 AC_ARG_ENABLE(concept-checks,
 243   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 244   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 245           [enable_concept_checks=no])]
 246   if test x$USE_QT5 = xyes ; then
 247       enable_concept_checks=no
 248   fi
 249 )
 250
 251 ### set up optimization
 252 AC_ARG_ENABLE(optimization,
 253     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 254     enable_optimization=yes;)
 255 case $enable_optimization in
 256     yes)
 257         if test $lyx_devel_version = yes ; then
 258             lyx_optim=-O
 259         else
 260             lyx_optim=-O2
 261         fi;;
 262     no) lyx_optim=;;
 263     *) lyx_optim=${enable_optimization};;
 264 esac
 265
 266 AC_ARG_ENABLE(pch,
 267   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 268         enable_pch=no;)
 269 lyx_pch_comp=no
 270
 271 AC_ARG_ENABLE(cxx11,
 272   AC_HELP_STRING([--enable-cxx11],[enable C++11 mode (default: enabled for known good compilers)]),,
 273   enable_cxx11=auto;)
 274
 275 AC_ARG_ENABLE(assertions,
 276   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 277   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 278           [enable_assertions=no])]
 279 )
 280 if test "x$enable_assertions" = xyes ; then
 281    lyx_flags="$lyx_flags assertions"
 282    AC_DEFINE(ENABLE_ASSERTIONS,1,
 283     [Define if you want assertions to be enabled in the code])
 284 fi
 285
 286 # set the compiler options correctly.
 287 lyx_std_regex=no
 288 if test x$GXX = xyes; then
 289   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 290   if test x$CLANG = xno; then
 291     dnl Useful for global version info
 292     gxx_version=`${CXX} -dumpversion`
 293     CXX_VERSION="($gxx_version)"
 294   else
 295     gxx_version=clang
 296   fi
 297
 298   AM_CXXFLAGS="$lyx_optim"
 299   if test x$enable_debug = xyes ; then
 300       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 301   fi
 302   if test $build_type = gprof ; then
 303     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 304     AM_LDFLAGS="$AM_LDFLAGS -pg"
 305   fi
 306   if test $build_type = profiling ; then
 307     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 308   fi
 309
 310   if test x$USE_QT5 = xyes ; then
 311       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 312   fi
 313   dnl Warnings are for preprocessor too
 314   if test x$enable_warnings = xyes ; then
 315       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 316   fi
 317   case $gxx_version in
 318       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 319       *)  test $enable_pch = yes && lyx_pch_comp=yes ;;
 320   esac
 321   if test x$enable_stdlib_debug = xyes ; then
 322     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 323     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 324     case $gxx_version in
 325       *)
 326         lyx_flags="$lyx_flags stdlib-debug"
 327         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 328         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 329         ;;
 330     esac
 331   fi
 332   if test x$enable_concept_checks = xyes ; then
 333     case $gxx_version in
 334       4.*)
 335         lyx_flags="$lyx_flags concept-checks"
 336         dnl FIXME check whether this makes sense with clang/libc++
 337         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 338         ;;
 339     esac
 340   fi
 341   dnl enable_cxx11 can be yes/no/auto.
 342   dnl By default, it is auto and we enable C++11 when possible
 343   if test x$enable_cxx11 != xno ; then
 344     case $gxx_version in
 345       4.0*|4.1*|4.2*)
 346          if x$enable_cxx11 = xyes; then
 347             AC_ERROR([There is no C++11 support in gcc 4.2 or older])
 348          fi;;
 349       4.3*|4.4*|4.5*|4.6*)
 350         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 351         dnl The source code relies on that.
 352         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++0x";;
 353       clang)
 354         dnl presumably all clang version support c++11.
 355         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 356         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11 -Wno-deprecated-register";;
 357       *)
 358         AS_CASE([$host], [*cygwin*],
 359                 [AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++11"],
 360                 [AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11"]);;
 361     esac
 362   fi
 363
 364   LYX_CXX_CXX11
 365   if test $lyx_use_cxx11 = yes ; then
 366     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 367       dnl <regex> in gcc is unusable in versions less than 4.9.0
 368       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 369       case $gxx_version in
 370         4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 371         *) lyx_std_regex=yes ;;
 372       esac
 373     else
 374       lyx_std_regex=yes
 375     fi
 376
 377     if test $lyx_std_regex = yes ; then
 378       lyx_flags="$lyx_flags stdregex"
 379       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 380     fi
 381   fi
 382 fi
 383 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 384 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 385 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 386 ])dnl
 387
 388 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 389 dnl        be used.
 390 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 391         AC_MSG_CHECKING([whether to use included boost library])
 392         AC_ARG_WITH(included-boost,
 393             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 394             [lyx_cv_with_included_boost=$withval],
 395             [lyx_cv_with_included_boost=yes])
 396         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 397         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 398         if test x$lyx_cv_with_included_boost = xyes ; then
 399             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 400             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 401         else
 402             AC_LANG_PUSH(C++)
 403             save_LIBS=$LIBS
 404
 405             AC_MSG_CHECKING([for multithreaded boost libraries])
 406             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 407             AC_LINK_IFELSE(
 408                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 409                         [boost::signal<void ()> s;])],
 410                 [AC_MSG_RESULT([yes])
 411                  BOOST_MT="-mt"],
 412                 [AC_MSG_RESULT([no])
 413                  AC_MSG_CHECKING([for plain boost libraries])
 414                  LIBS="$save_LIBS -lboost_signals"
 415                  AC_LINK_IFELSE(
 416                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 417                              [boost::signal<void ()> s;])],
 418                      [AC_MSG_RESULT([yes])
 419                       BOOST_MT=""],
 420                      [AC_MSG_RESULT([no])
 421                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 422                  ])
 423             ])
 424             LIBS=$save_LIBS
 425             AC_LANG_POP(C++)
 426             BOOST_INCLUDES=
 427             if test $lyx_std_regex = yes ; then
 428               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 429             else
 430               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 431             fi
 432
 433             dnl In general, system boost libraries are incompatible with
 434             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 435             dnl details.
 436             if test $enable_stdlib_debug = "yes" ; then
 437                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 438    crashes. Consider using --disable-stdlib-debug or removing
 439    --without-included-boost.])
 440             fi
 441         fi
 442         AC_SUBST(BOOST_INCLUDES)
 443         AC_SUBST(BOOST_LIBS)
 444 ])
 445
 446
 447 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 448 dnl        necessary APIs are available to print callstacks.
 449 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 450 [AC_CACHE_CHECK([whether printing callstack is possible],
 451                [lyx_cv_callstack_printing],
 452 [AC_TRY_COMPILE([
 453 #include <execinfo.h>
 454 #include <cxxabi.h>
 455 ], [
 456         void* array[200];
 457         size_t size = backtrace(array, 200);
 458         backtrace_symbols(array, size);
 459         int status = 0;
 460         abi::__cxa_demangle("abcd", 0, 0, &status);
 461 ],
 462 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 463 if test x"$lyx_cv_callstack_printing" = xyes; then
 464   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 465             [Define if callstack can be printed])
 466 fi
 467 ])
 468
 469
 470 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 471 dnl        be used.
 472 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 473         AC_MSG_CHECKING([whether to use included MyThes library])
 474         AC_ARG_WITH(included-mythes,
 475             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 476             [lyx_cv_with_included_mythes=$withval],
 477             [lyx_cv_with_included_mythes=yes])
 478         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 479         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 480         if test x$lyx_cv_with_included_mythes != xyes ; then
 481                 AC_LANG_PUSH(C++)
 482                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 483                 if test x$ac_cv_header_mythes_h != xyes; then
 484                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 485                 fi
 486                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 487                 if test x$lyx_mythes != xyes; then
 488                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 489                 fi
 490                 AC_LANG_POP(C++)
 491                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 492                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 493                 fi
 494                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 495                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 496                 AC_SUBST(MYTHES_LIBS)
 497         fi
 498 ])
 499
 500
 501 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 502 dnl                       [default-yes-value])
 503 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 504 dnl  resulting directory name in 'dir-var-name'.
 505 AC_DEFUN([LYX_WITH_DIR],[
 506   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 507   AC_MSG_CHECKING([for $2])
 508   if test -z "$with_$3"; then
 509      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 510   else
 511     test "x$with_$3" = xyes && with_$3=$5
 512     lyx_cv_$3="$with_$3"
 513   fi
 514   AC_MSG_RESULT($lyx_cv_$3)])
 515
 516
 517 dnl Usage: LYX_LOOP_DIR(value,action)
 518 dnl Executes action for values of variable `dir' in `values'. `values' can
 519 dnl use ":" as a separator.
 520 AC_DEFUN([LYX_LOOP_DIR],[
 521 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 522 for dir in `eval "echo $1"`; do
 523   if test ! "$dir" = NONE; then
 524     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 525     $2
 526   fi
 527 done
 528 IFS=$ac_save_ifs
 529 ])
 530
 531
 532 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 533 dnl var-name.
 534 AC_DEFUN([LYX_ADD_LIB_DIR],[
 535 $1="${$1} -L$2"
 536 if test "`(uname) 2>/dev/null`" = SunOS &&
 537     uname -r | grep '^5' >/dev/null; then
 538   if test $ac_cv_prog_gxx = yes ; then
 539     $1="${$1} -Wl[,]-R$2"
 540   else
 541     $1="${$1} -R$2"
 542   fi
 543 fi])
 544
 545
 546 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 547 dnl var-name.
 548 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 549
 550 ### Check for a headers existence and location iff it exists
 551 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 552 ## It almost works.  I've tried a few variations but they give errors
 553 ## of one sort or other: bad substitution or file not found etc.  The
 554 ## actual header _is_ found though and the cache variable is set however
 555 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 556 ## reason.
 557 ## Additionally, autoheader can't figure out what to use as the name in
 558 ## the config.h.in file so we need to write our own entries there -- one for
 559 ## each header in the form PATH_HEADER_NAME_H
 560 ##
 561 AC_DEFUN([LYX_PATH_HEADER],
 562 [ AC_CHECK_HEADER($1,[
 563   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 564 ### the only remaining problem is getting the second parameter to this
 565 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 566 ### of $ac_safe being printed.
 567   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 568   [ cat > conftest.$ac_ext <<EOF
 569 #line __oline__ "configure"
 570 #include "confdefs.h"
 571
 572 #include <$1>
 573 EOF
 574 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 575   grep $1  2>/dev/null | \
 576   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 577 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 578 rm -f conftest*])
 579   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 580 ])
 581 ### end of LYX_PATH_HEADER
 582
 583 ## Check what kind of packaging should be used at install time.
 584 ## The default is autodetected.
 585 AC_DEFUN([LYX_USE_PACKAGING],
 586 [AC_MSG_CHECKING([what packaging should be used])
 587 AC_ARG_WITH(packaging,
 588   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 589                             Possible values: posix, windows, macosx, haiku])],
 590   [lyx_use_packaging="$withval"], [
 591   case $host in
 592     *-apple-darwin*) lyx_use_packaging=macosx ;;
 593     *-pc-mingw32*) lyx_use_packaging=windows ;;
 594     *haiku*) lyx_use_packaging=haiku ;;
 595     *) lyx_use_packaging=posix ;;
 596   esac])
 597 AC_MSG_RESULT($lyx_use_packaging)
 598 lyx_install_posix=false
 599 lyx_install_macosx=false
 600 lyx_install_cygwin=false
 601 lyx_install_windows=false
 602 case $lyx_use_packaging in
 603    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 604            PACKAGE=LyX${version_suffix}
 605            default_prefix="/Applications/${PACKAGE}.app"
 606            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 607            bindir='${prefix}/Contents/MacOS'
 608            libdir='${prefix}/Contents/Resources'
 609            datarootdir='${prefix}/Contents/Resources'
 610            pkgdatadir='${datadir}'
 611            mandir='${datadir}/man'
 612            lyx_install_macosx=true ;;
 613   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 614            PACKAGE=LyX${version_suffix}
 615            default_prefix="C:/Program Files/${PACKAGE}"
 616            bindir='${prefix}/bin'
 617            libdir='${prefix}/Resources'
 618            datarootdir='${prefix}/Resources'
 619            pkgdatadir='${datadir}'
 620            mandir='${prefix}/Resources/man'
 621            lyx_install_windows=true ;;
 622     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 623            PACKAGE=lyx${version_suffix}
 624            program_suffix=$version_suffix
 625            pkgdatadir='${datadir}/${PACKAGE}'
 626            default_prefix=$ac_default_prefix
 627            case ${host} in
 628              *cygwin*) lyx_install_cygwin=true ;;
 629              *apple-darwin*) lyx_install_macosx=true ;;
 630            esac
 631            lyx_install_posix=true ;;
 632         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 633            PACKAGE=lyx${version_suffix}
 634            program_suffix=$version_suffix
 635            pkgdatadir='${datadir}/${PACKAGE}'
 636            default_prefix=$ac_default_prefix
 637            lyx_install_posix=true ;;
 638     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 639 esac
 640 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 641 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 642 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 643 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 644 AC_SUBST(pkgdatadir)
 645 AC_SUBST(program_suffix)
 646 ])
 647
 648
 649 ## ------------------------------------------------------------------------
 650 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 651 ## one or two arguments.
 652 ##
 653 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 654 ## ------------------------------------------------------------------------
 655 ##
 656 AC_DEFUN([AC_FUNC_MKDIR],
 657 [AC_CHECK_FUNCS([mkdir _mkdir])
 658 AC_CACHE_CHECK([whether mkdir takes one argument],
 659                [ac_cv_mkdir_takes_one_arg],
 660 [AC_TRY_COMPILE([
 661 #include <sys/stat.h>
 662 #if HAVE_UNISTD_H
 663 #  include <unistd.h>
 664 #endif
 665 ], [mkdir (".");],
 666 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 667 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 668   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 669             [Define if mkdir takes only one argument.])
 670 fi
 671 ])
 672
 673
 674 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 675 dnl (which may be a relative path, and need not refer to any existing
 676 dnl entity).
 677
 678 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 679 dnl native Win32 path name, (but with slashes, not backslashes).
 680
 681 dnl On any other system, it is simply the result which would be obtained
 682 dnl if PATHNAME represented an existing directory, and the pwd command was
 683 dnl executed in that directory.
 684 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 685 [ac_dir="$2"
 686  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 687     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 688  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 689  do
 690    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 691  done
 692  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 693  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 694  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 695    s?/*$[]??'`
 696 ])
 697
 698 dnl this is used by the macro blow to general a proper config.h.in entry
 699 m4_define([LYX_AH_CHECK_DECL],
 700 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 701   [Define if you have the prototype for function `$1'])])
 702
 703 dnl Check things are declared in headers to avoid errors or warnings.
 704 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 705 dnl Defines HAVE_DECL_{FUNCTION}
 706 AC_DEFUN([LYX_CHECK_DECL],
 707 [LYX_AH_CHECK_DECL($1)
 708 for ac_header in $2
 709 do
 710   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 711   AC_EGREP_HEADER($1, $ac_header,
 712       [AC_MSG_RESULT(yes)
 713        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 714        break],
 715       [AC_MSG_RESULT(no)])
 716 done])
 717
 718 dnl this is used by the macro below to generate a proper config.h.in entry
 719 m4_define([LYX_AH_CHECK_DEF],
 720 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 721   [Define to 1 if `$1' is defined in `$2'])])
 722
 723 dnl Check whether name is defined in header by using it in codesnippet.
 724 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 725 dnl Defines HAVE_DEF_{NAME}
 726 AC_DEFUN([LYX_CHECK_DEF],
 727 [LYX_AH_CHECK_DEF($1, $2)
 728  AC_MSG_CHECKING([whether $1 is defined by header $2])
 729  AC_TRY_COMPILE([#include <$2>], [$3],
 730      lyx_have_def_name=yes,
 731      lyx_have_def_name=no)
 732  AC_MSG_RESULT($lyx_have_def_name)
 733  if test "x$lyx_have_def_name" = xyes; then
 734    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 735  fi
 736 ])
 737
 738 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 739 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 740 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 741 AC_DEFUN([LYX_SET_VERSION_INFO],
 742 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 743  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 744  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 745  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 746  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 747  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 748  test "x$lyx_patch" = "x" && lyx_patch=0
 749  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 750  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 751  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 752  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 753  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 754  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 755  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 756  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 757 ])
 758
 759 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 760 # ---------------------------------------------------------------------------
 761 # Copied from autoconf 2.68, added a check that python version is < 3.0
 762 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 763 # Run ACTION-IF-FALSE otherwise.
 764 # This test uses sys.hexversion instead of the string equivalent (first
 765 # word of sys.version), in order to cope with versions such as 2.2c1.
 766 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 767 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 768  [prog="import sys
 769 # split strings by '.' and convert to numeric.  Append some zeros
 770 # because we need at least 4 digits for the hex conversion.
 771 # map returns an iterator in Python 3.0 and a list in 2.x
 772 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 773 minverhex = 0
 774 maxverhex = 50331648 # = 3.0.0.0
 775 # xrange is not present in Python 3.0 and range returns an iterator
 776 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 777 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 778   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])