config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11 lyx_devel_version=no
  12 lyx_prerelease=no
  13 AC_MSG_CHECKING([for build type])
  14 AC_ARG_ENABLE(build-type,
  15   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  16   [case $enableval in
  17     dev*) build_type=development;;
  18     pre*) build_type=prerelease;;
  19     prof*)  build_type=profiling;;
  20     gprof*) build_type=gprof;;
  21     rel*) build_type=release;;
  22     *) AC_ERROR([Bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  23    esac],
  24   [case AC_PACKAGE_VERSION in
  25     *svn*|*dev*) build_type=development;;
  26     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  27     *) build_type=release ;;
  28    esac])
  29 AC_MSG_RESULT([$build_type])
  30 lyx_flags="$lyx_flags build=$build_type"
  31 case $build_type in
  32     development) lyx_devel_version=yes
  33                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  34                  LYX_DATE="not released yet" ;;
  35     prerelease) lyx_prerelease=yes ;;
  36 esac
  37
  38 AC_SUBST(lyx_devel_version)
  39 ])
  40
  41
  42 dnl Define the option to set a LyX version on installed executables and directories
  43 dnl
  44 dnl
  45 AC_DEFUN([LYX_VERSION_SUFFIX],[
  46 AC_MSG_CHECKING([for version suffix])
  47 dnl We need the literal double quotes in the rpm spec file
  48 RPM_VERSION_SUFFIX='""'
  49 AC_ARG_WITH(version-suffix,
  50   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  51   [if test "x$withval" = "xyes";
  52    then
  53      withval="-"AC_PACKAGE_VERSION
  54      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  55    fi
  56    AC_SUBST(version_suffix,$withval)
  57    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  58 AC_SUBST(RPM_VERSION_SUFFIX)
  59 AC_MSG_RESULT([$withval])
  60 ])
  61
  62
  63 dnl Usage: LYX_ERROR(message)  Displays the warning "message" and sets the
  64 dnl flag lyx_error to yes.
  65 AC_DEFUN([LYX_ERROR],[
  66 lyx_error_txt="$lyx_error_txt
  67 ** $1
  68 "
  69 lyx_error=yes])
  70
  71
  72 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  73 dnl flag lyx_warning to yes.
  74 AC_DEFUN([LYX_WARNING],[
  75 lyx_warning_txt="$lyx_warning_txt
  76 == $1
  77 "
  78 lyx_warning=yes])
  79
  80
  81 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  82 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  83 AC_DEFUN([LYX_LIB_ERROR],[
  84 LYX_ERROR([Cannot find $1. Please check that the $2 library
  85    is correctly installed on your system.])])
  86
  87
  88 dnl Usage: LYX_CHECK_ERRORS  Displays a warning message if a LYX_ERROR
  89 dnl   has occured previously.
  90 AC_DEFUN([LYX_CHECK_ERRORS],[
  91 if test x$lyx_warning = xyes; then
  92 cat <<EOF
  93 === The following minor problems have been detected by configure.
  94 === Please check the messages below before running 'make'.
  95 === (see the section 'Problems' in the INSTALL file)
  96 $lyx_warning_txt
  97 EOF
  98 fi
  99 if test x$lyx_error = xyes; then
 100 cat <<EOF
 101 **** The following problems have been detected by configure.
 102 **** Please check the messages below before running 'make'.
 103 **** (see the section 'Problems' in the INSTALL file)
 104 $lyx_error_txt
 105 $lyx_warning_txt
 106 EOF
 107 exit 1
 108 else
 109
 110 cat <<EOF
 111 Configuration of LyX was successful.
 112 Type 'make' to compile the program,
 113 and then 'make install' to install it.
 114 EOF
 115 fi])
 116
 117
 118 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 119 dnl
 120 define(LYX_SEARCH_PROG,[dnl
 121 for ac_prog in $2 ; do
 122 # Extract the first word of "$ac_prog", so it can be a program name with args.
 123   set dummy $ac_prog ; ac_word=$[2]
 124   if test -z "[$]$1"; then
 125     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 126     for ac_dir in $PATH; do
 127       test -z "$ac_dir" && ac_dir=.
 128       if test -f [$ac_dir/$ac_word]; then
 129         $1="$ac_prog"
 130         break
 131       fi
 132     done
 133     IFS="$ac_save_ifs"
 134   fi
 135
 136   if test -n "[$]$1"; then
 137     ac_result=yes
 138   else
 139     ac_result=no
 140   fi
 141   ifelse($3,,,[$3])
 142   test -n "[$]$1" && break
 143 done
 144 ])dnl
 145
 146
 147 AC_DEFUN([LYX_PROG_CXX_WORKS],
 148 [rm -f conftest.C
 149 cat >conftest.C <<EOF
 150 class foo {
 151    // we require the mutable keyword
 152    mutable int bar;
 153  };
 154  // we require namespace support
 155  namespace baz {
 156    int bar;
 157  }
 158  int main() {
 159    return(0);
 160  }
 161 EOF
 162 $CXX -c $CXXFLAGS $CPPFLAGS conftest.C >&5 || CXX=
 163 rm -f conftest.C conftest.o conftest.obj || true
 164 ])
 165
 166
 167 AC_DEFUN([LYX_PROG_CXX],
 168 [AC_MSG_CHECKING([for a good enough C++ compiler])
 169 LYX_SEARCH_PROG(CXX, $CXX $CCC g++ gcc c++ CC cxx xlC cc++, [LYX_PROG_CXX_WORKS])
 170
 171 if test -z "$CXX" ; then
 172   AC_MSG_ERROR([Unable to find a good enough C++ compiler])
 173 fi
 174 AC_MSG_RESULT($CXX)
 175
 176 AC_PROG_CXX
 177 AC_PROG_CXXCPP
 178
 179 ### We might want to get or shut warnings.
 180 AC_ARG_ENABLE(warnings,
 181   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 182   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 183         enable_warnings=yes;
 184     else
 185         enable_warnings=no;
 186     fi;])
 187 if test x$enable_warnings = xyes ; then
 188   lyx_flags="$lyx_flags warnings"
 189 fi
 190
 191 ### We might want to disable debug
 192 AC_ARG_ENABLE(debug,
 193   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 194   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 195 )
 196
 197 AC_ARG_ENABLE(stdlib-debug,
 198   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 199   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 200           [enable_stdlib_debug=no])]
 201 )
 202
 203 AC_ARG_ENABLE(concept-checks,
 204   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 205   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 206           [enable_concept_checks=no])]
 207 )
 208
 209 AC_ARG_ENABLE(gprof,
 210   AC_HELP_STRING([--enable-gprof],[enable profiling using gprof]),,
 211   [AS_CASE([$build_type], [gprof], [enable_gprof=yes], [enable_gprof=no])]
 212 )
 213
 214 ### set up optimization
 215 AC_ARG_ENABLE(optimization,
 216     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 217     enable_optimization=yes;)
 218 case $enable_optimization in
 219     yes)
 220         if test $lyx_devel_version = yes ; then
 221             lyx_opt=-O
 222         else
 223             lyx_opt=-O2
 224         fi;;
 225     no) lyx_opt=;;
 226     *) lyx_opt=${enable_optimization};;
 227 esac
 228
 229 AC_ARG_ENABLE(pch,
 230   AC_HELP_STRING([--enable-pch],[enable precompiled headers]),,
 231         enable_pch=no;)
 232 lyx_pch_comp=no
 233
 234 AC_ARG_ENABLE(assertions,
 235   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 236   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 237           [enable_assertions=no])]
 238 )
 239 if test "x$enable_assertions" = xyes ; then
 240    lyx_flags="$lyx_flags assertions"
 241    AC_DEFINE(ENABLE_ASSERTIONS,1,
 242     [Define if you want assertions to be enabled in the code])
 243 fi
 244
 245 # set the compiler options correctly.
 246 if test x$GXX = xyes; then
 247   dnl Useful for global version info
 248   gxx_version=`${CXX} -dumpversion`
 249   CXX_VERSION="($gxx_version)"
 250
 251   if test "$ac_test_CXXFLAGS" = set; then
 252     CXXFLAGS="$ac_save_CXXFLAGS"
 253   else
 254       CFLAGS="$lyx_opt"
 255       CXXFLAGS="$lyx_opt"
 256     if test x$enable_debug = xyes ; then
 257         CFLAGS="-g $CFLAGS"
 258         CXXFLAGS="-g $CXXFLAGS"
 259     fi
 260     if test x$enable_gprof = xyes ; then
 261         CFLAGS="-pg $CFLAGS"
 262         CXXFLAGS="-pg $CXXFLAGS"
 263         LDFLAGS="-pg $LDFLAGS"
 264     fi
 265   fi
 266   if test "$ac_env_CPPFLAGS_set" != set; then
 267     if test x$enable_warnings = xyes ; then
 268         case $gxx_version in
 269             3.1*|3.2*|3.3*)
 270                 CPPFLAGS="-W -Wall $CPPFLAGS"
 271                 ;;
 272             *)
 273                 CPPFLAGS="-Wextra -Wall $CPPFLAGS "
 274                 ;;
 275         esac
 276     fi
 277   fi
 278   case $gxx_version in
 279       3.1*)    AM_CXXFLAGS="-finline-limit=500 ";;
 280       3.2*|3.3*)    AM_CXXFLAGS="";;
 281       3.4*|4.*)
 282           AM_CXXFLAGS=""
 283           test $enable_pch = yes && lyx_pch_comp=yes
 284           ;;
 285       *)       AM_CXXFLAGS="";;
 286   esac
 287   if test x$enable_stdlib_debug = xyes ; then
 288     case $gxx_version in
 289       3.4*|4.*)
 290         lyx_flags="$lyx_flags stdlib-debug"
 291         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 292         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 293         ;;
 294     esac
 295   fi
 296   if test x$enable_concept_checks = xyes ; then
 297     case $gxx_version in
 298       3.3*)
 299         lyx_flags="$lyx_flags concept-checks"
 300         AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 301         ;;
 302       3.4*|4.*)
 303         lyx_flags="$lyx_flags concept-checks"
 304         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 305         ;;
 306     esac
 307   fi
 308 fi
 309 test "$lyx_pch_comp" = yes && lyx_flags="$lyx_flags pch"
 310 AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 311 ])dnl
 312
 313 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 314 dnl        be used.
 315 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 316         AC_MSG_CHECKING([whether to use included boost library])
 317         AC_ARG_WITH(included-boost,
 318             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 319             [lyx_cv_with_included_boost=$withval],
 320             [lyx_cv_with_included_boost=yes])
 321         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 322         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 323         if test x$lyx_cv_with_included_boost != xyes ; then
 324                 AC_LANG_PUSH(C++)
 325                 save_LIBS=$LIBS
 326
 327                 LIBS="$save_LIBS -lboost_signals -lm"
 328                 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <boost/signal.hpp>], [boost::signal<void ()> s;])], [lyx_boost_plain=yes], [])
 329                 LIBS="$save_LIBS -lboost_signals-mt -lm $LIBTHREAD"
 330                 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <boost/signal.hpp>], [boost::signal<void ()> s;])], [lyx_boost_mt=yes], [])
 331
 332                 LIBS=$save_LIBS
 333                 AC_LANG_POP(C++)
 334
 335                 if test x$lyx_boost_mt = xyes ; then
 336                         BOOST_MT="-mt"
 337                 else
 338                         BOOST_MT=""
 339                         if test x$lyx_boost_plain != xyes ; then
 340                                 LYX_ERROR([No suitable boost library found (do not use --without-included-boost)])
 341                         fi
 342                 fi
 343                 AC_SUBST(BOOST_MT)
 344         fi
 345 ])
 346
 347
 348 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 349 dnl        be used.
 350 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 351         AC_MSG_CHECKING([whether to use included MyThes library])
 352         AC_ARG_WITH(included-mythes,
 353             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 354             [lyx_cv_with_included_mythes=$withval],
 355             [lyx_cv_with_included_mythes=yes])
 356         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 357         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 358         if test x$lyx_cv_with_included_mythes != xyes ; then
 359                 AC_LANG_PUSH(C++)
 360                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 361                 if test x$ac_cv_header_mythes_h != xyes; then
 362                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 363                 fi
 364                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 365                 if test x$lyx_mythes != xyes; then
 366                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
 367                 fi
 368                 AC_LANG_POP(C++)
 369                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 370                         LYX_ERROR([No suitable MyThes library found (do not use --without-included-mythes)])
 371                 fi
 372                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 373                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 374                 AC_SUBST(MYTHES_LIBS)
 375         fi
 376 ])
 377
 378
 379 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 380 dnl                       [default-yes-value])
 381 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 382 dnl  resulting directory name in 'dir-var-name'.
 383 AC_DEFUN([LYX_WITH_DIR],[
 384   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 385   AC_MSG_CHECKING([for $2])
 386   if test -z "$with_$3"; then
 387      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 388   else
 389     test "x$with_$3" = xyes && with_$3=$5
 390     lyx_cv_$3="$with_$3"
 391   fi
 392   AC_MSG_RESULT($lyx_cv_$3)])
 393
 394
 395 dnl Usage: LYX_LOOP_DIR(value,action)
 396 dnl Executes action for values of variable `dir' in `values'. `values' can
 397 dnl use ":" as a separator.
 398 AC_DEFUN([LYX_LOOP_DIR],[
 399 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 400 for dir in `eval "echo $1"`; do
 401   if test ! "$dir" = NONE; then
 402     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 403     $2
 404   fi
 405 done
 406 IFS=$ac_save_ifs
 407 ])
 408
 409
 410 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 411 dnl var-name.
 412 AC_DEFUN([LYX_ADD_LIB_DIR],[
 413 $1="${$1} -L$2"
 414 if test "`(uname) 2>/dev/null`" = SunOS &&
 415     uname -r | grep '^5' >/dev/null; then
 416   if test $ac_cv_prog_gxx = yes ; then
 417     $1="${$1} -Wl[,]-R$2"
 418   else
 419     $1="${$1} -R$2"
 420   fi
 421 fi])
 422
 423
 424 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 425 dnl var-name.
 426 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 427
 428 ### Check for a headers existence and location iff it exists
 429 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 430 ## It almost works.  I've tried a few variations but they give errors
 431 ## of one sort or other: bad substitution or file not found etc.  The
 432 ## actual header _is_ found though and the cache variable is set however
 433 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 434 ## reason.
 435 ## Additionally, autoheader can't figure out what to use as the name in
 436 ## the config.h.in file so we need to write our own entries there -- one for
 437 ## each header in the form PATH_HEADER_NAME_H
 438 ##
 439 AC_DEFUN([LYX_PATH_HEADER],
 440 [ AC_CHECK_HEADER($1,[
 441   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 442 ### the only remaining problem is getting the second parameter to this
 443 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 444 ### of $ac_safe being printed.
 445   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 446   [ cat > conftest.$ac_ext <<EOF
 447 #line __oline__ "configure"
 448 #include "confdefs.h"
 449
 450 #include <$1>
 451 EOF
 452 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 453   grep $1  2>/dev/null | \
 454   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 455 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 456 rm -f conftest*])
 457   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 458 ])
 459 ### end of LYX_PATH_HEADER
 460
 461 ### Check which frontends we want to use.
 462 ###
 463 AC_DEFUN([LYX_USE_FRONTENDS],
 464 [AC_MSG_CHECKING([what frontend should be used for the GUI])
 465 AC_ARG_WITH(frontend,
 466   [AC_HELP_STRING([--with-frontend=THIS], [use THIS frontend as main GUI:
 467                             Possible values: qt4])],
 468   [FRONTENDS="$withval"],[FRONTENDS="qt4"])
 469 if test "x$FRONTENDS" = x ; then
 470   AC_MSG_RESULT(none)
 471   AC_ERROR("Please select a frontend using --with-frontend")
 472 fi
 473 AC_MSG_RESULT($FRONTENDS)
 474 AC_SUBST(FRONTENDS)
 475 AC_SUBST(FRONTENDS_SUBDIRS)
 476 AC_SUBST(FRONTENDS_PROGS)
 477 ])
 478
 479
 480 ## Check what kind of packaging should be used at install time.
 481 ## The default is autodetected.
 482 AC_DEFUN([LYX_USE_PACKAGING],
 483 [AC_MSG_CHECKING([what packaging should be used])
 484 AC_ARG_WITH(packaging,
 485   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 486                             Possible values: posix, windows, macosx])],
 487   [lyx_use_packaging="$withval"], [
 488   case $host in
 489     *-apple-darwin*) lyx_use_packaging=macosx ;;
 490      *-pc-mingw32*) lyx_use_packaging=windows;;
 491                   *) lyx_use_packaging=posix;;
 492   esac])
 493 AC_MSG_RESULT($lyx_use_packaging)
 494 lyx_install_macosx=false
 495 lyx_install_cygwin=false
 496 lyx_install_windows=false
 497 case $lyx_use_packaging in
 498    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 499            PACKAGE=LyX${version_suffix}
 500            default_prefix="/Applications/${PACKAGE}.app"
 501            bindir='${prefix}/Contents/MacOS'
 502            libdir='${prefix}/Contents/Resources'
 503            datarootdir='${prefix}/Contents/Resources'
 504            pkgdatadir='${datadir}'
 505            mandir='${datadir}/man'
 506            lyx_install_macosx=true ;;
 507   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 508            PACKAGE=LyX${version_suffix}
 509            default_prefix="C:/Program Files/${PACKAGE}"
 510            bindir='${prefix}/bin'
 511            libdir='${prefix}/Resources'
 512            datarootdir='${prefix}/Resources'
 513            pkgdatadir='${datadir}'
 514            mandir='${prefix}/Resources/man'
 515            lyx_install_windows=true ;;
 516     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 517            PACKAGE=lyx${version_suffix}
 518            program_suffix=$version_suffix
 519            pkgdatadir='${datadir}/${PACKAGE}'
 520            default_prefix=$ac_default_prefix
 521            case ${host} in
 522            *cygwin*) lyx_install_cygwin=true ;;
 523                 *apple-darwin*) lyx_install_macosx=true ;;
 524            esac
 525            lyx_install_posix=true ;;
 526     *) LYX_ERROR([Unknown packaging type $lyx_use_packaging]) ;;
 527 esac
 528 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 529 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 530 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 531 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 532 dnl Next two lines are only for autoconf <= 2.59
 533 datadir='${datarootdir}'
 534 AC_SUBST(datarootdir)
 535 AC_SUBST(pkgdatadir)
 536 AC_SUBST(program_suffix)
 537 ])
 538
 539
 540 ## ------------------------------------------------------------------------
 541 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 542 ## one or two arguments.
 543 ##
 544 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 545 ## ------------------------------------------------------------------------
 546 ##
 547 AC_DEFUN([AC_FUNC_MKDIR],
 548 [AC_CHECK_FUNCS([mkdir _mkdir])
 549 AC_CACHE_CHECK([whether mkdir takes one argument],
 550                [ac_cv_mkdir_takes_one_arg],
 551 [AC_TRY_COMPILE([
 552 #include <sys/stat.h>
 553 #if HAVE_UNISTD_H
 554 #  include <unistd.h>
 555 #endif
 556 ], [mkdir (".");],
 557 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 558 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 559   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 560             [Define if mkdir takes only one argument.])
 561 fi
 562 ])
 563
 564
 565 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 566 dnl (which may be a relative path, and need not refer to any existing
 567 dnl entity).
 568
 569 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 570 dnl native Win32 path name, (but with slashes, not backslashes).
 571
 572 dnl On any other system, it is simply the result which would be obtained
 573 dnl if PATHNAME represented an existing directory, and the pwd command was
 574 dnl executed in that directory.
 575 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 576 [ac_dir="$2"
 577  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 578     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 579  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 580  do
 581    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 582  done
 583  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 584  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 585  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 586    s?/*$[]??'`
 587 ])
 588
 589 dnl this is used by the macro blow to general a proper config.h.in entry
 590 m4_define([LYX_AH_CHECK_DECL],
 591 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 592   [Define if you have the prototype for function `$1'])])
 593
 594 dnl Check things are declared in headers to avoid errors or warnings.
 595 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 596 dnl Defines HAVE_DECL_{FUNCTION}
 597 AC_DEFUN([LYX_CHECK_DECL],
 598 [LYX_AH_CHECK_DECL($1)
 599 for ac_header in $2
 600 do
 601   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 602   AC_EGREP_HEADER($1, $ac_header,
 603       [AC_MSG_RESULT(yes)
 604        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 605        break],
 606       [AC_MSG_RESULT(no)])
 607 done])
 608
 609 dnl this is used by the macro below to generate a proper config.h.in entry
 610 m4_define([LYX_AH_CHECK_DEF],
 611 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 612   [Define to 1 if `$1' is defined in `$2'])])
 613
 614 dnl Check whether name is defined in header by using it in codesnippet.
 615 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 616 dnl Defines HAVE_DEF_{NAME}
 617 AC_DEFUN([LYX_CHECK_DEF],
 618 [LYX_AH_CHECK_DEF($1, $2)
 619  AC_MSG_CHECKING([whether $1 is defined by header $2])
 620  AC_TRY_COMPILE([#include <$2>], [$3],
 621      lyx_have_def_name=yes,
 622      lyx_have_def_name=no)
 623  AC_MSG_RESULT($lyx_have_def_name)
 624  if test "x$lyx_have_def_name" = xyes; then
 625    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 626  fi
 627 ])
 628
 629 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 630 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 631 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 632 AC_DEFUN([LYX_SET_VERSION_INFO],
 633 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 634  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 635  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 636  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 637  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 638  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 639  test "x$lyx_patch" = "x" && lyx_patch=0
 640  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 641  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 642  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 643  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 644  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 645  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 646  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 647  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 648 ])
 649
 650 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 651 # ---------------------------------------------------------------------------
 652 # Copied from autoconf 2.68, added a check that python version is < 3.0
 653 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 654 # Run ACTION-IF-FALSE otherwise.
 655 # This test uses sys.hexversion instead of the string equivalent (first
 656 # word of sys.version), in order to cope with versions such as 2.2c1.
 657 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 658 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 659  [prog="import sys
 660 # split strings by '.' and convert to numeric.  Append some zeros
 661 # because we need at least 4 digits for the hex conversion.
 662 # map returns an iterator in Python 3.0 and a list in 2.x
 663 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 664 minverhex = 0
 665 maxverhex = 50331648 # = 3.0.0.0
 666 # xrange is not present in Python 3.0 and range returns an iterator
 667 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 668 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 669   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])