config/lyxinclude.m4

   1 dnl Some useful functions for LyXs configure.in                 -*- sh -*-
   2 dnl Author: Jean-Marc Lasgouttes (Jean-Marc.Lasgouttes@inria.fr)
   3 dnl         Lars Gullik Bjønnes (larsbj@lyx.org)
   4 dnl         Allan Rae (rae@lyx.org)
   5
   6
   7 dnl Usage LYX_CHECK_VERSION   Displays version of LyX being built and
   8 dnl sets variable "build_type"
   9 AC_DEFUN([LYX_CHECK_VERSION],[
  10 echo "configuring LyX version" AC_PACKAGE_VERSION
  11
  12 AC_MSG_CHECKING([for build type])
  13 lyx_devel_version=no
  14 lyx_prerelease=no
  15 AC_ARG_ENABLE(build-type,
  16   AC_HELP_STRING([--enable-build-type=TYPE],[set build setting according to TYPE=rel(ease), pre(release), dev(elopment), prof(iling), gprof]),
  17   [case $enableval in
  18     dev*) build_type=development;;
  19     pre*) build_type=prerelease;;
  20     prof*)  build_type=profiling;;
  21     gprof*) build_type=gprof;;
  22     rel*) build_type=release;;
  23     *) AC_MSG_ERROR([bad build type specification \"$enableval\". Please use one of rel(ease), pre(release), dev(elopment), prof(iling), or gprof]);;
  24    esac],
  25   [case AC_PACKAGE_VERSION in
  26     *dev*) build_type=development;;
  27     *pre*|*alpha*|*beta*|*rc*) build_type=prerelease;;
  28     *) build_type=release ;;
  29    esac])
  30 AC_MSG_RESULT([$build_type])
  31 lyx_flags="$lyx_flags build=$build_type"
  32 case $build_type in
  33     development) lyx_devel_version=yes
  34                  AC_DEFINE(DEVEL_VERSION, 1, [Define if you are building a development version of LyX])
  35                  LYX_DATE="not released yet" ;;
  36     prerelease) lyx_prerelease=yes ;;
  37 esac
  38
  39 AC_SUBST(lyx_devel_version)
  40 ])
  41
  42
  43 dnl Define the option to set a LyX version on installed executables and directories
  44 dnl
  45 dnl
  46 AC_DEFUN([LYX_VERSION_SUFFIX],[
  47 AC_MSG_CHECKING([for version suffix])
  48 dnl We need the literal double quotes in the rpm spec file
  49 RPM_VERSION_SUFFIX='""'
  50 AC_ARG_WITH(version-suffix,
  51   [AC_HELP_STRING([--with-version-suffix@<:@=VERSION@:>@], install lyx files as lyxVERSION (VERSION=-AC_PACKAGE_VERSION))],
  52   [if test "x$withval" = "xyes";
  53    then
  54      withval="-"AC_PACKAGE_VERSION
  55      ac_configure_args=`echo "$ac_configure_args" | sed "s,--with-version-suffix,--with-version-suffix=$withval,"`
  56    fi
  57    AC_SUBST(version_suffix,$withval)
  58    RPM_VERSION_SUFFIX="--with-version-suffix=$withval"])
  59 AC_SUBST(RPM_VERSION_SUFFIX)
  60 AC_SUBST(program_base_name,"lyx")
  61 AC_MSG_RESULT([$withval])
  62 ])
  63
  64
  65 dnl Check whether to configure for Qt5. Default is Qt4.
  66 dnl
  67 AC_DEFUN([LYX_CHECK_QT5],[
  68 AC_MSG_CHECKING([whether Qt5 is requested])
  69 AC_ARG_ENABLE([qt5],
  70   [  --enable-qt5            use Qt5 for building],
  71   USE_QT5=$enableval, USE_QT5=no)
  72 AC_MSG_RESULT([$USE_QT5])
  73 AC_SUBST([USE_QT5])
  74 ])
  75
  76
  77 dnl Usage: LYX_WARNING(message)  Displays the warning "message" and sets the
  78 dnl flag lyx_warning to yes.
  79 AC_DEFUN([LYX_WARNING],[
  80 lyx_warning_txt="$lyx_warning_txt
  81 == $1
  82 "
  83 lyx_warning=yes])
  84
  85
  86 dnl Usage: LYX_LIB_ERROR(file,library)  Displays an error message indication
  87 dnl  that 'file' cannot be found because 'lib' may be uncorrectly installed.
  88 AC_DEFUN([LYX_LIB_ERROR],[
  89 AC_MSG_ERROR([cannot find $1. Please check that the $2 library
  90    is correctly installed on your system.])])
  91
  92
  93 dnl Usage: LYX_CHECK_WARNINGS  Displays a warning message if a LYX_WARNING
  94 dnl   has occurred previously.
  95 AC_DEFUN([LYX_CHECK_WARNINGS],[
  96 if test x$lyx_warning = xyes; then
  97 cat <<EOF
  98 === The following minor problems have been detected by configure.
  99 === Please check the messages below before running 'make'.
 100 === (see the section 'Problems' in the INSTALL file)
 101 $lyx_warning_txt
 102
 103 EOF
 104 fi])
 105
 106
 107 dnl LYX_SEARCH_PROG(VARIABLE-NAME,PROGRAMS-LIST,ACTION-IF-FOUND)
 108 dnl
 109 define(LYX_SEARCH_PROG,[dnl
 110 for ac_prog in $2 ; do
 111 # Extract the first word of "$ac_prog", so it can be a program name with args.
 112   set dummy $ac_prog ; ac_word=$[2]
 113   if test -z "[$]$1"; then
 114     IFS="${IFS= }"; ac_save_ifs="$IFS"; IFS=":"
 115     for ac_dir in $PATH; do
 116       test -z "$ac_dir" && ac_dir=.
 117       if test -f [$ac_dir/$ac_word]; then
 118         $1="$ac_prog"
 119         break
 120       fi
 121     done
 122     IFS="$ac_save_ifs"
 123   fi
 124
 125   if test -n "[$]$1"; then
 126     ac_result=yes
 127   else
 128     ac_result=no
 129   fi
 130   ifelse($3,,,[$3])
 131   test -n "[$]$1" && break
 132 done
 133 ])dnl
 134
 135
 136 dnl Usage: LYX_PROG_CLANG: set CLANG to yes if the compiler is clang.
 137 AC_DEFUN([LYX_PROG_CLANG],
 138 [AC_CACHE_CHECK([whether the compiler is clang],
 139                [lyx_cv_prog_clang],
 140 [AC_TRY_COMPILE([], [
 141 #ifndef __clang__
 142             this is not clang
 143 #endif
 144 ],
 145 [lyx_cv_prog_clang=yes ; CLANG=yes], [lyx_cv_prog_clang=no ; CLANG=no])])
 146 ])
 147
 148
 149 dnl Usage: LYX_CXX_CXX11: set lyx_use_cxx11 to yes if the compiler implements
 150 dnl the C++11 standard.
 151 AC_DEFUN([LYX_CXX_CXX11],
 152 [AC_CACHE_CHECK([whether the compiler implements C++11],
 153                [lyx_cv_cxx_cxx11],
 154  [save_CXXFLAGS=$CXXFLAGS
 155   CXXFLAGS="$AM_CXXFLAGS $CXXFLAGS"
 156   AC_LANG_PUSH(C++)
 157   AC_TRY_COMPILE([], [
 158 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 159             this is a c++11 compiler
 160 #endif
 161   ],
 162   [lyx_cv_cxx_cxx11=no], [lyx_cv_cxx_cxx11=yes ; lyx_flags="$lyx_flags c++11"])
 163  AC_LANG_POP(C++)
 164  CXXFLAGS=$save_CXXFLAGS])
 165 lyx_use_cxx11=$lyx_cv_cxx_cxx11
 166 ])
 167
 168
 169 dnl Usage: LYX_LIB_STDCXX: set lyx_cv_lib_stdcxx to yes if the STL library is libstdc++.
 170 AC_DEFUN([LYX_LIB_STDCXX],
 171 [AC_CACHE_CHECK([whether STL is libstdc++],
 172                [lyx_cv_lib_stdcxx],
 173 [AC_TRY_COMPILE([#include<vector>], [
 174 #if ! defined(__GLIBCXX__) && ! defined(__GLIBCPP__)
 175             this is not libstdc++
 176 #endif
 177 ],
 178 [lyx_cv_lib_stdcxx=yes], [lyx_cv_lib_stdcxx=no])])
 179 ])
 180
 181
 182 dnl Usage: LYX_LIB_STDCXX_CXX11_ABI: set lyx_cv_lib_stdcxx_cxx11_abi to yes
 183 dnl        if the STL library is GNU libstdc++ and the C++11 ABI is used.
 184 AC_DEFUN([LYX_LIB_STDCXX_CXX11_ABI],
 185 [AC_CACHE_CHECK([whether STL is libstdc++ using the C++11 ABI],
 186                [lyx_cv_lib_stdcxx_cxx11_abi],
 187 [AC_TRY_COMPILE([#include<vector>], [
 188 #if ! defined(_GLIBCXX_USE_CXX11_ABI) || ! _GLIBCXX_USE_CXX11_ABI
 189             this is not libstdc++ using the C++11 ABI
 190 #endif
 191 ],
 192 [lyx_cv_lib_stdcxx_cxx11_abi=yes], [lyx_cv_lib_stdcxx_cxx11_abi=no])])
 193 ])
 194
 195
 196 AC_DEFUN([LYX_PROG_CXX],
 197 [AC_REQUIRE([AC_PROG_CXX])
 198 AC_REQUIRE([AC_PROG_CXXCPP])
 199
 200 AC_LANG_PUSH(C++)
 201 LYX_PROG_CLANG
 202 LYX_LIB_STDCXX
 203 LYX_LIB_STDCXX_CXX11_ABI
 204 AC_LANG_POP(C++)
 205
 206 if test $lyx_cv_lib_stdcxx = "yes" ; then
 207   if test $lyx_cv_lib_stdcxx_cxx11_abi = "yes" ; then
 208     AC_DEFINE(USE_GLIBCXX_CXX11_ABI, 1, [use GNU libstdc++ with C++11 ABI])
 209   else
 210     AC_DEFINE(STD_STRING_USES_COW, 1, [std::string uses copy-on-write])
 211   fi
 212 else
 213   if test $lyx_cv_prog_clang = "yes" ; then
 214     AC_DEFINE(USE_LLVM_LIBCPP, 1, [use libc++ provided by llvm instead of GNU libstdc++])
 215   fi
 216 fi
 217
 218 ### We might want to get or shut warnings.
 219 AC_ARG_ENABLE(warnings,
 220   AC_HELP_STRING([--enable-warnings],[tell the compiler to display more warnings]),,
 221   [ if test $lyx_devel_version = yes -o $lyx_prerelease = yes && test $ac_cv_prog_gxx = yes ; then
 222         enable_warnings=yes;
 223     else
 224         enable_warnings=no;
 225     fi;])
 226 if test x$enable_warnings = xyes ; then
 227   lyx_flags="$lyx_flags warnings"
 228 fi
 229
 230 ### We might want to disable debug
 231 AC_ARG_ENABLE(debug,
 232   AC_HELP_STRING([--enable-debug],[enable debug information]),,
 233   [AS_CASE([$build_type], [rel*], [enable_debug=no], [enable_debug=yes])]
 234 )
 235
 236 AC_ARG_ENABLE(stdlib-debug,
 237   AC_HELP_STRING([--enable-stdlib-debug],[enable debug mode in the standard library]),,
 238   [AS_CASE([$build_type], [dev*], [enable_stdlib_debug=yes],
 239           [enable_stdlib_debug=no])]
 240 )
 241
 242 AC_ARG_ENABLE(concept-checks,
 243   AC_HELP_STRING([--enable-concept-checks],[enable concept checks]),,
 244   [AS_CASE([$build_type], [dev*|pre*], [enable_concept_checks=yes],
 245           [enable_concept_checks=no])]
 246   if test x$USE_QT5 = xyes ; then
 247       enable_concept_checks=no
 248   fi
 249 )
 250
 251 ### set up optimization
 252 AC_ARG_ENABLE(optimization,
 253     AC_HELP_STRING([--enable-optimization[=value]],[enable compiler optimisation]),,
 254     enable_optimization=yes;)
 255 case $enable_optimization in
 256     yes)
 257         if test $lyx_devel_version = yes ; then
 258             lyx_optim=-O
 259         else
 260             lyx_optim=-O2
 261         fi;;
 262     no) lyx_optim=;;
 263     *) lyx_optim=${enable_optimization};;
 264 esac
 265
 266 AC_ARG_ENABLE(cxx11,
 267   AC_HELP_STRING([--disable-cxx11],[disable C++11 mode (default: enabled for known good compilers)]),,
 268   enable_cxx11=auto;)
 269
 270 AC_ARG_ENABLE(assertions,
 271   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
 272   [AS_CASE([$build_type], [dev*|pre*], [enable_assertions=yes],
 273           [enable_assertions=no])]
 274 )
 275 if test "x$enable_assertions" = xyes ; then
 276    lyx_flags="$lyx_flags assertions"
 277    AC_DEFINE(ENABLE_ASSERTIONS,1,
 278     [Define if you want assertions to be enabled in the code])
 279 fi
 280
 281 # set the compiler options correctly.
 282 lyx_std_regex=no
 283 if test x$GXX = xyes; then
 284   dnl clang++ pretends to be g++ 4.2.1; this is not useful
 285   if test x$CLANG = xno; then
 286     dnl Useful for global version info
 287     gxx_version=`${CXX} -dumpversion`
 288     CXX_VERSION="($gxx_version)"
 289   else
 290     gxx_version=clang
 291   fi
 292
 293   AM_CXXFLAGS="$lyx_optim"
 294   if test x$enable_debug = xyes ; then
 295       AM_CXXFLAGS="-g $AM_CXXFLAGS"
 296   fi
 297   if test $build_type = gprof ; then
 298     AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 299     AM_LDFLAGS="$AM_LDFLAGS -pg"
 300   fi
 301   if test $build_type = profiling ; then
 302     AM_CXXFLAGS="$AM_CXXFLAGS -fno-omit-frame-pointer"
 303   fi
 304
 305   if test x$USE_QT5 = xyes ; then
 306       AS_CASE([$host], [*mingw*|*cygwin*], [], [AM_CXXFLAGS="-fPIC $AM_CXXFLAGS"])
 307   fi
 308   dnl Warnings are for preprocessor too
 309   if test x$enable_warnings = xyes ; then
 310       AM_CPPFLAGS="$AM_CPPFLAGS -Wall -Wextra"
 311   fi
 312   case $gxx_version in
 313       2.*|3.*) AC_ERROR([gcc 4.x is required]);;
 314   esac
 315   if test x$enable_stdlib_debug = xyes ; then
 316     dnl FIXME: for clang/libc++, one should define _LIBCPP_DEBUG2=0
 317     dnl See http://clang-developers.42468.n3.nabble.com/libc-debug-mode-td3336742.html
 318     case $gxx_version in
 319       *)
 320         lyx_flags="$lyx_flags stdlib-debug"
 321         AC_DEFINE(_GLIBCXX_DEBUG, 1, [libstdc++ debug mode])
 322         AC_DEFINE(_GLIBCXX_DEBUG_PEDANTIC, 1, [libstdc++ pedantic debug mode])
 323         ;;
 324     esac
 325   fi
 326   if test x$enable_concept_checks = xyes ; then
 327     case $gxx_version in
 328       4.*)
 329         lyx_flags="$lyx_flags concept-checks"
 330         dnl FIXME check whether this makes sense with clang/libc++
 331         AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1, [libstdc++ concept checking])
 332         ;;
 333     esac
 334   fi
 335   dnl enable_cxx11 can be yes/no/auto.
 336   dnl By default, it is auto and we enable C++11 when possible
 337   if test x$enable_cxx11 != xno ; then
 338     case $gxx_version in
 339       4.0*|4.1*|4.2*)
 340          if x$enable_cxx11 = xyes; then
 341             AC_ERROR([There is no C++11 support in gcc 4.2 or older])
 342          fi;;
 343       4.3*|4.4*|4.5*|4.6*)
 344         dnl Note that this will define __GXX_EXPERIMENTAL_CXX0X__.
 345         dnl The source code relies on that.
 346         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++0x";;
 347       clang)
 348         dnl presumably all clang version support c++11.
 349         dnl the deprecated-register warning is very annoying with Qt4.x right now.
 350         AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11 -Wno-deprecated-register";;
 351       *)
 352         AS_CASE([$host], [*cygwin*],
 353                 [AM_CXXFLAGS="$AM_CXXFLAGS -std=gnu++11"],
 354                 [AM_CXXFLAGS="$AM_CXXFLAGS -std=c++11"]);;
 355     esac
 356   fi
 357
 358   LYX_CXX_CXX11
 359   if test $lyx_use_cxx11 = yes ; then
 360     if test x$CLANG = xno || test $lyx_cv_lib_stdcxx = yes; then
 361       dnl <regex> in gcc is unusable in versions less than 4.9.0
 362       dnl see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 363       case $gxx_version in
 364         4.0*|4.1*|4.2*|4.3*|4.4*|4.5*|4.6*|4.7*|4.8*) ;;
 365         *) lyx_std_regex=yes ;;
 366       esac
 367     else
 368       lyx_std_regex=yes
 369     fi
 370
 371     if test $lyx_std_regex = yes ; then
 372       lyx_flags="$lyx_flags stdregex"
 373       AC_DEFINE([LYX_USE_STD_REGEX], 1, [define to 1 if std::regex should be preferred to boost::regex])
 374     fi
 375   fi
 376 fi
 377 AM_CONDITIONAL([LYX_USE_STD_REGEX], test $lyx_std_regex = yes)
 378 ])dnl
 379
 380 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 381 dnl        be used.
 382 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 383         AC_MSG_CHECKING([whether to use included boost library])
 384         AC_ARG_WITH(included-boost,
 385             [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 386             [lyx_cv_with_included_boost=$withval],
 387             [lyx_cv_with_included_boost=yes])
 388         AM_CONDITIONAL(USE_INCLUDED_BOOST, test x$lyx_cv_with_included_boost = xyes)
 389         AC_MSG_RESULT([$lyx_cv_with_included_boost])
 390         if test x$lyx_cv_with_included_boost = xyes ; then
 391             BOOST_INCLUDES='-I$(top_srcdir)/boost'
 392             BOOST_LIBS='$(top_builddir)/boost/liblyxboost.a'
 393         else
 394             AC_LANG_PUSH(C++)
 395             save_LIBS=$LIBS
 396
 397             AC_MSG_CHECKING([for multithreaded boost libraries])
 398             LIBS="$save_LIBS -lboost_signals-mt $LIBTHREAD"
 399             AC_LINK_IFELSE(
 400                 [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 401                         [boost::signal<void ()> s;])],
 402                 [AC_MSG_RESULT([yes])
 403                  BOOST_MT="-mt"],
 404                 [AC_MSG_RESULT([no])
 405                  AC_MSG_CHECKING([for plain boost libraries])
 406                  LIBS="$save_LIBS -lboost_signals"
 407                  AC_LINK_IFELSE(
 408                      [AC_LANG_PROGRAM([#include <boost/signal.hpp>],
 409                              [boost::signal<void ()> s;])],
 410                      [AC_MSG_RESULT([yes])
 411                       BOOST_MT=""],
 412                      [AC_MSG_RESULT([no])
 413                       AC_MSG_ERROR([cannot find suitable boost library (do not use --without-included-boost)])
 414                  ])
 415             ])
 416             LIBS=$save_LIBS
 417             AC_LANG_POP(C++)
 418             BOOST_INCLUDES=
 419             if test $lyx_std_regex = yes ; then
 420               BOOST_LIBS="-lboost_signals${BOOST_MT}"
 421             else
 422               BOOST_LIBS="-lboost_regex${BOOST_MT} -lboost_signals${BOOST_MT}"
 423             fi
 424
 425             dnl In general, system boost libraries are incompatible with
 426             dnl the use of stdlib-debug in libstdc++. See ticket #9736 for
 427             dnl details.
 428             if test $enable_stdlib_debug = "yes" ; then
 429                 LYX_WARNING([Compiling LyX with stdlib-debug and system boost libraries may lead to
 430    crashes. Consider using --disable-stdlib-debug or removing
 431    --without-included-boost.])
 432             fi
 433         fi
 434         AC_SUBST(BOOST_INCLUDES)
 435         AC_SUBST(BOOST_LIBS)
 436 ])
 437
 438
 439 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 440 dnl        necessary APIs are available to print callstacks.
 441 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],
 442 [AC_CACHE_CHECK([whether printing callstack is possible],
 443                [lyx_cv_callstack_printing],
 444 [AC_TRY_COMPILE([
 445 #include <execinfo.h>
 446 #include <cxxabi.h>
 447 ], [
 448         void* array[200];
 449         size_t size = backtrace(array, 200);
 450         backtrace_symbols(array, size);
 451         int status = 0;
 452         abi::__cxa_demangle("abcd", 0, 0, &status);
 453 ],
 454 [lyx_cv_callstack_printing=yes], [lyx_cv_callstack_printing=no])])
 455 if test x"$lyx_cv_callstack_printing" = xyes; then
 456   AC_DEFINE([LYX_CALLSTACK_PRINTING], 1,
 457             [Define if callstack can be printed])
 458 fi
 459 ])
 460
 461
 462 dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
 463 dnl        be used.
 464 AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
 465         AC_MSG_CHECKING([whether to use included MyThes library])
 466         AC_ARG_WITH(included-mythes,
 467             [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 468             [lyx_cv_with_included_mythes=$withval],
 469             [lyx_cv_with_included_mythes=yes])
 470         AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
 471         AC_MSG_RESULT([$lyx_cv_with_included_mythes])
 472         if test x$lyx_cv_with_included_mythes != xyes ; then
 473                 AC_LANG_PUSH(C++)
 474                 AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
 475                 if test x$ac_cv_header_mythes_h != xyes; then
 476                         AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
 477                 fi
 478                 AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no])
 479                 if test x$lyx_mythes != xyes; then
 480                         AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no])
 481                 fi
 482                 AC_LANG_POP(C++)
 483                 if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
 484                         AC_MSG_ERROR([cannot find suitable MyThes library (do not use --without-included-mythes)])
 485                 fi
 486                 AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
 487                 AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
 488                 AC_SUBST(MYTHES_LIBS)
 489         fi
 490 ])
 491
 492
 493 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 494 dnl                       [default-yes-value])
 495 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the
 496 dnl  resulting directory name in 'dir-var-name'.
 497 AC_DEFUN([LYX_WITH_DIR],[
 498   AC_ARG_WITH($1,[AC_HELP_STRING([--with-$1],[specify $2])])
 499   AC_MSG_CHECKING([for $2])
 500   if test -z "$with_$3"; then
 501      AC_CACHE_VAL(lyx_cv_$3, lyx_cv_$3=$4)
 502   else
 503     test "x$with_$3" = xyes && with_$3=$5
 504     lyx_cv_$3="$with_$3"
 505   fi
 506   AC_MSG_RESULT($lyx_cv_$3)])
 507
 508
 509 dnl Usage: LYX_LOOP_DIR(value,action)
 510 dnl Executes action for values of variable `dir' in `values'. `values' can
 511 dnl use ":" as a separator.
 512 AC_DEFUN([LYX_LOOP_DIR],[
 513 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 514 for dir in `eval "echo $1"`; do
 515   if test ! "$dir" = NONE; then
 516     test ! -d "$dir" && AC_MSG_ERROR([\"$dir\" is not a directory])
 517     $2
 518   fi
 519 done
 520 IFS=$ac_save_ifs
 521 ])
 522
 523
 524 dnl Usage: LYX_ADD_LIB_DIR(var-name,dir) Adds a -L directive to variable
 525 dnl var-name.
 526 AC_DEFUN([LYX_ADD_LIB_DIR],[
 527 $1="${$1} -L$2"
 528 if test "`(uname) 2>/dev/null`" = SunOS &&
 529     uname -r | grep '^5' >/dev/null; then
 530   if test $ac_cv_prog_gxx = yes ; then
 531     $1="${$1} -Wl[,]-R$2"
 532   else
 533     $1="${$1} -R$2"
 534   fi
 535 fi])
 536
 537
 538 dnl Usage: LYX_ADD_INC_DIR(var-name,dir) Adds a -I directive to variable
 539 dnl var-name.
 540 AC_DEFUN([LYX_ADD_INC_DIR],[$1="${$1} -I$2 "])
 541
 542 ### Check for a headers existence and location iff it exists
 543 ## This is supposed to be a generalised version of LYX_STL_STRING_FWD
 544 ## It almost works.  I've tried a few variations but they give errors
 545 ## of one sort or other: bad substitution or file not found etc.  The
 546 ## actual header _is_ found though and the cache variable is set however
 547 ## the reported setting (on screen) is equal to $ac_safe for some unknown
 548 ## reason.
 549 ## Additionally, autoheader can't figure out what to use as the name in
 550 ## the config.h.in file so we need to write our own entries there -- one for
 551 ## each header in the form PATH_HEADER_NAME_H
 552 ##
 553 AC_DEFUN([LYX_PATH_HEADER],
 554 [ AC_CHECK_HEADER($1,[
 555   ac_tr_safe=PATH_`echo $ac_safe | sed 'y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%'`
 556 ### the only remaining problem is getting the second parameter to this
 557 ### AC_CACHE_CACHE to print correctly. Currently it just results in value
 558 ### of $ac_safe being printed.
 559   AC_CACHE_CHECK([path to $1],[lyx_cv_path2_$ac_safe],
 560   [ cat > conftest.$ac_ext <<EOF
 561 #line __oline__ "configure"
 562 #include "confdefs.h"
 563
 564 #include <$1>
 565 EOF
 566 lyx_path_header_path=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 | \
 567   grep $1  2>/dev/null | \
 568   sed -e 's/.*\(".*$1"\).*/\1/' -e "1q"`
 569 eval "lyx_cv_path2_${ac_safe}=\$lyx_path_header_path"
 570 rm -f conftest*])
 571   AC_DEFINE_UNQUOTED($ac_tr_safe, $lyx_path_header_path, [dummy])])
 572 ])
 573 ### end of LYX_PATH_HEADER
 574
 575 ## Check what kind of packaging should be used at install time.
 576 ## The default is autodetected.
 577 AC_DEFUN([LYX_USE_PACKAGING],
 578 [AC_MSG_CHECKING([what packaging should be used])
 579 AC_ARG_WITH(packaging,
 580   [AC_HELP_STRING([--with-packaging=THIS], [use THIS packaging for installation:
 581                             Possible values: posix, windows, macosx, haiku])],
 582   [lyx_use_packaging="$withval"], [
 583   case $host in
 584     *-apple-darwin*) lyx_use_packaging=macosx ;;
 585     *-pc-mingw32*) lyx_use_packaging=windows ;;
 586     *haiku*) lyx_use_packaging=haiku ;;
 587     *) lyx_use_packaging=posix ;;
 588   esac])
 589 AC_MSG_RESULT($lyx_use_packaging)
 590 lyx_install_posix=false
 591 lyx_install_macosx=false
 592 lyx_install_cygwin=false
 593 lyx_install_windows=false
 594 case $lyx_use_packaging in
 595    macosx) AC_DEFINE(USE_MACOSX_PACKAGING, 1, [Define to 1 if LyX should use a MacOS X application bundle file layout])
 596            PACKAGE=LyX${version_suffix}
 597            default_prefix="/Applications/${PACKAGE}.app"
 598            AC_SUBST(osx_bundle_program_name,"${program_base_name}")
 599            bindir='${prefix}/Contents/MacOS'
 600            libdir='${prefix}/Contents/Resources'
 601            datarootdir='${prefix}/Contents/Resources'
 602            pkgdatadir='${datadir}'
 603            mandir='${datadir}/man'
 604            lyx_install_macosx=true ;;
 605   windows) AC_DEFINE(USE_WINDOWS_PACKAGING, 1, [Define to 1 if LyX should use a Windows-style file layout])
 606            PACKAGE=LyX${version_suffix}
 607            default_prefix="C:/Program Files/${PACKAGE}"
 608            bindir='${prefix}/bin'
 609            libdir='${prefix}/Resources'
 610            datarootdir='${prefix}/Resources'
 611            pkgdatadir='${datadir}'
 612            mandir='${prefix}/Resources/man'
 613            lyx_install_windows=true ;;
 614     posix) AC_DEFINE(USE_POSIX_PACKAGING, 1, [Define to 1 if LyX should use a POSIX-style file layout])
 615            PACKAGE=lyx${version_suffix}
 616            program_suffix=$version_suffix
 617            pkgdatadir='${datadir}/${PACKAGE}'
 618            default_prefix=$ac_default_prefix
 619            case ${host} in
 620              *cygwin*) lyx_install_cygwin=true ;;
 621              *apple-darwin*) lyx_install_macosx=true ;;
 622            esac
 623            lyx_install_posix=true ;;
 624         haiku) AC_DEFINE(USE_HAIKU_PACKAGING, 1, [Define to 1 if LyX should use a Haiku-style file layout])
 625            PACKAGE=lyx${version_suffix}
 626            program_suffix=$version_suffix
 627            pkgdatadir='${datadir}/${PACKAGE}'
 628            default_prefix=$ac_default_prefix
 629            lyx_install_posix=true ;;
 630     *) AC_MSG_ERROR([unknown packaging type $lyx_use_packaging.]) ;;
 631 esac
 632 AM_CONDITIONAL(INSTALL_MACOSX, $lyx_install_macosx)
 633 AM_CONDITIONAL(INSTALL_WINDOWS, $lyx_install_windows)
 634 AM_CONDITIONAL(INSTALL_CYGWIN, $lyx_install_cygwin)
 635 AM_CONDITIONAL(INSTALL_POSIX, $lyx_install_posix)
 636 AC_SUBST(pkgdatadir)
 637 AC_SUBST(program_suffix)
 638 ])
 639
 640
 641 ## ------------------------------------------------------------------------
 642 ## Check whether mkdir() is mkdir or _mkdir, and whether it takes
 643 ## one or two arguments.
 644 ##
 645 ## http://ac-archive.sourceforge.net/C_Support/ac_func_mkdir.html
 646 ## ------------------------------------------------------------------------
 647 ##
 648 AC_DEFUN([AC_FUNC_MKDIR],
 649 [AC_CHECK_FUNCS([mkdir _mkdir])
 650 AC_CACHE_CHECK([whether mkdir takes one argument],
 651                [ac_cv_mkdir_takes_one_arg],
 652 [AC_TRY_COMPILE([
 653 #include <sys/stat.h>
 654 #if HAVE_UNISTD_H
 655 #  include <unistd.h>
 656 #endif
 657 ], [mkdir (".");],
 658 [ac_cv_mkdir_takes_one_arg=yes], [ac_cv_mkdir_takes_one_arg=no])])
 659 if test x"$ac_cv_mkdir_takes_one_arg" = xyes; then
 660   AC_DEFINE([MKDIR_TAKES_ONE_ARG], 1,
 661             [Define if mkdir takes only one argument.])
 662 fi
 663 ])
 664
 665
 666 dnl Set VAR to the canonically resolved absolute equivalent of PATHNAME,
 667 dnl (which may be a relative path, and need not refer to any existing
 668 dnl entity).
 669
 670 dnl On Win32-MSYS build hosts, the returned path is resolved to its true
 671 dnl native Win32 path name, (but with slashes, not backslashes).
 672
 673 dnl On any other system, it is simply the result which would be obtained
 674 dnl if PATHNAME represented an existing directory, and the pwd command was
 675 dnl executed in that directory.
 676 AC_DEFUN([MSYS_AC_CANONICAL_PATH],
 677 [ac_dir="$2"
 678  ( exec 2>/dev/null; cd / && pwd -W ) | grep ':' >/dev/null &&
 679     ac_pwd_w="pwd -W" || ac_pwd_w=pwd
 680  until ac_val=`exec 2>/dev/null; cd "$ac_dir" && $ac_pwd_w`
 681  do
 682    ac_dir=`AS_DIRNAME(["$ac_dir"])`
 683  done
 684  ac_dir=`echo "$ac_dir" | sed 's?^[[./]]*??'`
 685  ac_val=`echo "$ac_val" | sed 's?/*$[]??'`
 686  $1=`echo "$2" | sed "s?^[[./]]*$ac_dir/*?$ac_val/?"'
 687    s?/*$[]??'`
 688 ])
 689
 690 dnl this is used by the macro blow to general a proper config.h.in entry
 691 m4_define([LYX_AH_CHECK_DECL],
 692 [AH_TEMPLATE(AS_TR_CPP(HAVE_DECL_$1),
 693   [Define if you have the prototype for function `$1'])])
 694
 695 dnl Check things are declared in headers to avoid errors or warnings.
 696 dnl Called like LYX_CHECK_DECL(function, header1 header2...)
 697 dnl Defines HAVE_DECL_{FUNCTION}
 698 AC_DEFUN([LYX_CHECK_DECL],
 699 [LYX_AH_CHECK_DECL($1)
 700 for ac_header in $2
 701 do
 702   AC_MSG_CHECKING([if $1 is declared by header $ac_header])
 703   AC_EGREP_HEADER($1, $ac_header,
 704       [AC_MSG_RESULT(yes)
 705        AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DECL_$1))
 706        break],
 707       [AC_MSG_RESULT(no)])
 708 done])
 709
 710 dnl this is used by the macro below to generate a proper config.h.in entry
 711 m4_define([LYX_AH_CHECK_DEF],
 712 [AH_TEMPLATE(AS_TR_CPP(HAVE_DEF_$1),
 713   [Define to 1 if `$1' is defined in `$2'])])
 714
 715 dnl Check whether name is defined in header by using it in codesnippet.
 716 dnl Called like LYX_CHECK_DEF(name, header, codesnippet)
 717 dnl Defines HAVE_DEF_{NAME}
 718 AC_DEFUN([LYX_CHECK_DEF],
 719 [LYX_AH_CHECK_DEF($1, $2)
 720  AC_MSG_CHECKING([whether $1 is defined by header $2])
 721  AC_TRY_COMPILE([#include <$2>], [$3],
 722      lyx_have_def_name=yes,
 723      lyx_have_def_name=no)
 724  AC_MSG_RESULT($lyx_have_def_name)
 725  if test "x$lyx_have_def_name" = xyes; then
 726    AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_DEF_$1))
 727  fi
 728 ])
 729
 730 dnl Extract the single digits from PACKAGE_VERSION and make them available.
 731 dnl Defines LYX_MAJOR_VERSION, LYX_MINOR_VERSION, LYX_RELEASE_LEVEL,
 732 dnl LYX_RELEASE_PATCH (possibly equal to 0), LYX_DIR_VER, and LYX_USERDIR_VER.
 733 AC_DEFUN([LYX_SET_VERSION_INFO],
 734 [lyx_major=`echo $PACKAGE_VERSION | sed -e 's/[[.]].*//'`
 735  lyx_patch=`echo $PACKAGE_VERSION | sed -e "s/^$lyx_major//" -e 's/^.//'`
 736  lyx_minor=`echo $lyx_patch | sed -e 's/[[.]].*//'`
 737  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_minor//" -e 's/^.//'`
 738  lyx_release=`echo $lyx_patch | sed -e 's/[[^0-9]].*//'`
 739  lyx_patch=`echo $lyx_patch | sed -e "s/^$lyx_release//" -e 's/^[[.]]//' -e 's/[[^0-9]].*//'`
 740  test "x$lyx_patch" = "x" && lyx_patch=0
 741  lyx_dir_ver=LYX_DIR_${lyx_major}${lyx_minor}x
 742  lyx_userdir_ver=LYX_USERDIR_${lyx_major}${lyx_minor}x
 743  AC_SUBST(LYX_MAJOR_VERSION,$lyx_major)
 744  AC_SUBST(LYX_MINOR_VERSION,$lyx_minor)
 745  AC_SUBST(LYX_RELEASE_LEVEL,$lyx_release)
 746  AC_SUBST(LYX_RELEASE_PATCH,$lyx_patch)
 747  AC_SUBST(LYX_DIR_VER,"$lyx_dir_ver")
 748  AC_SUBST(LYX_USERDIR_VER,"$lyx_userdir_ver")
 749 ])
 750
 751 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 752 # ---------------------------------------------------------------------------
 753 # Copied from autoconf 2.68, added a check that python version is < 3.0
 754 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 755 # Run ACTION-IF-FALSE otherwise.
 756 # This test uses sys.hexversion instead of the string equivalent (first
 757 # word of sys.version), in order to cope with versions such as 2.2c1.
 758 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 759 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 760  [prog="import sys
 761 # split strings by '.' and convert to numeric.  Append some zeros
 762 # because we need at least 4 digits for the hex conversion.
 763 # map returns an iterator in Python 3.0 and a list in 2.x
 764 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 765 minverhex = 0
 766 maxverhex = 50331648 # = 3.0.0.0
 767 # xrange is not present in Python 3.0 and range returns an iterator
 768 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 769 sys.exit(sys.hexversion < minverhex or sys.hexversion >= maxverhex)"
 770   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])